helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri suri =
  57   let term = CicUtil.term_of_uri (UriManager.uri_of_string suri) in
  58   (suri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72 let statements = Grammar.Entry.create grammar "statements"
  73
  74 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  75
  76 let fail floc msg =
  77   let (x, y) = CicAst.loc_of_floc floc in
  78   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  79
  80 let name_of_string = function
  81   | "_" -> Cic.Anonymous
  82   | s -> Cic.Name s
  83
  84 let string_of_name = function
  85   | Cic.Anonymous -> "_"
  86   | Cic.Name s -> s
  87
  88 let int_opt = function
  89   | None -> None
  90   | Some lexeme -> Some (int_of_string lexeme)
  91
  92 let int_of_string s =
  93   try
  94     Pervasives.int_of_string s
  95   with Failure _ ->
  96     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  97
  98   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  99   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
 100   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 101   * type in a block of mutual inductive types.
 102   *
 103   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 104   *)
 105 let ind_expansion uri =
 106   let len = String.length uri in
 107   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 108     uri ^ "#xpointer(1/1)"
 109   else
 110     uri
 111
 112 let mk_binder_ast binder typ vars body =
 113   List.fold_right
 114     (fun var body ->
 115        let name = name_of_string var in
 116        CicAst.Binder (binder, (name, typ), body))
 117     vars body
 118
 119 EXTEND
 120   GLOBAL: term term0 statement statements;
 121   int: [
 122     [ num = NUM ->
 123         try
 124           int_of_string num
 125         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 126     ]
 127   ];
 128   meta_subst: [
 129     [ s = SYMBOL "_" -> None
 130     | t = term -> Some t ]
 131   ];
 132   binder_low: [
 133     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 134     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 135     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 136   ];
 137   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 138   sort: [
 139     [ "Prop" -> `Prop
 140     | "Set" -> `Set
 141     | "Type" -> `Type
 142     | "CProp" -> `CProp ]
 143   ];
 144   typed_name: [
 145     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 146         (Cic.Name i, Some typ)
 147     | i = IDENT -> (Cic.Name i, None)
 148     ]
 149   ];
 150   subst: [
 151     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152       PAREN "[";
 153       substs = LIST1 [
 154         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155       ] SEP SYMBOL ";";
 156       PAREN "]" ->
 157         substs
 158     ]
 159   ];
 160   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 161     [ s = IDENT; subst = OPT subst -> CicAst.Ident (s, subst)
 162     | s = URI; subst = OPT subst -> CicAst.Uri (ind_expansion s, subst)
 163     ]
 164   ];
 165   name: [ (* as substituted_name with no explicit substitution *)
 166     [ s = [ IDENT | SYMBOL ] -> s ]
 167   ];
 168   pattern: [
 169     [ n = name -> (n, [])
 170     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 171         (head, vars)
 172     ]
 173   ];
 174   arg: [
 175    [ PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ",";
 176       SYMBOL ":"; ty = term; PAREN ")" -> names,ty
 177    | name = IDENT -> [name],CicAst.Implicit
 178    ]
 179   ];
 180   let_defs:[
 181     [ defs = LIST1 [
 182         name = IDENT;
 183         args = LIST1 [arg = arg -> arg];
 184         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 185         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 186         SYMBOL <:unicode<def>> (* ≝ *);
 187         t1 = term ->
 188           let rec list_of_binder binder ty final_term = function
 189             | [] -> final_term
 190             | name::tl ->
 191                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 192                   list_of_binder binder ty final_term tl)
 193           in
 194           let rec binder_of_arg_list binder final_term = function
 195             | [] -> final_term
 196             | (l,ty)::tl ->
 197                 list_of_binder binder ty
 198                   (binder_of_arg_list binder final_term tl) l
 199           in
 200           let t1' = binder_of_arg_list `Lambda t1 args in
 201           let ty' =
 202             match ty with
 203             | None -> None
 204             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 205           in
 206           let rec get_position_of name n = function
 207             | [] -> (None,n)
 208             | nam::tl ->
 209                 if nam = name then
 210                   (Some n,n)
 211                 else
 212                   (get_position_of name (n+1) tl)
 213           in
 214           let rec find_arg name n = function
 215             | [] -> (fail loc (sprintf "Argument %s not found" name))
 216             | (l,_)::tl ->
 217                 let (got,len) = get_position_of name 0 l in
 218                 (match got with
 219                 | None -> (find_arg name (n+len) tl)
 220                 | Some where -> n + where)
 221           in
 222           let index =
 223             (match index_name with
 224              | None -> 0
 225              | (Some name) -> find_arg name 0 args)
 226           in
 227           ((Cic.Name name,ty'), t1', index)
 228       ] SEP "and" -> defs
 229     ]];
 230   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 231   binder_vars: [
 232       [ vars = LIST1 IDENT SEP SYMBOL ",";
 233         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 234       | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
 235         typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
 236       ]
 237   ];
 238   term0: [ [ t = term; EOI -> return_term loc t ] ];
 239   term:
 240     [ "letin" NONA
 241       [ "let"; var = typed_name;
 242         SYMBOL <:unicode<def>> (* ≝ *);
 243         t1 = term; "in"; t2 = term ->
 244           return_term loc (CicAst.LetIn (var, t1, t2))
 245       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 246         defs = let_defs; "in"; body = term ->
 247             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 248       ]
 249     | "binder" RIGHTA
 250       [
 251         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 252           let binder = mk_binder_ast b typ vars body in
 253           return_term loc binder
 254       | b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 255           let binder = mk_binder_ast b typ vars body in
 256           return_term loc binder
 257       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 258           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 259       ]
 260     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 261     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 262     | "logic_inv" NONA    [ (* nothing here by default *) ]
 263     | "relop" LEFTA
 264       [ t1 = term; SYMBOL "="; t2 = term ->
 265         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 266       ]
 267     | "add" LEFTA     [ (* nothing here by default *) ]
 268     | "mult" LEFTA    [ (* nothing here by default *) ]
 269     | "power" LEFTA   [ (* nothing here by default *) ]
 270     | "inv" NONA      [ (* nothing here by default *) ]
 271     | "apply" LEFTA
 272       [ t1 = term; t2 = term ->
 273         let rec aux = function
 274           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 275           | term -> [term]
 276         in
 277         CicAst.Appl (aux t1 @ [t2])
 278       ]
 279     | "simple" NONA
 280       [ sort = sort -> CicAst.Sort sort
 281       | n = substituted_name -> return_term loc n
 282       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 283       | IMPLICIT -> return_term loc CicAst.Implicit
 284       | PLACEHOLDER -> return_term loc CicAst.UserInput
 285       | m = META;
 286         substs = [
 287           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 288             substs
 289         ] ->
 290             let index =
 291               try
 292                 int_of_string (String.sub m 1 (String.length m - 1))
 293               with Failure "int_of_string" ->
 294                 fail loc ("Invalid meta variable number: " ^ m)
 295             in
 296             return_term loc (CicAst.Meta (index, substs))
 297       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 298         "match"; t = term;
 299         indty_ident = OPT ["in" ; id = IDENT -> id ];
 300         "with";
 301         PAREN "[";
 302         patterns = LIST0 [
 303           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 304           ->
 305             ((lhs: CicAst.case_pattern), rhs)
 306         ] SEP SYMBOL "|";
 307         PAREN "]" ->
 308           return_term loc
 309             (CicAst.Case (t, indty_ident, outtyp, patterns))
 310       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 311           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 312       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 313       ]
 314     ];
 315   tactic_term: [ [ t = term -> t ] ];
 316   ident_list0: [
 317     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 318   ];
 319   reduction_kind: [
 320     [ [ IDENT "reduce" ] -> `Reduce
 321     | [ IDENT "simplify" ] -> `Simpl
 322     | [ IDENT "whd" ] -> `Whd
 323     | [ IDENT "normalize" ] -> `Normalize ]
 324   ];
 325   pattern_spec: [
 326     [ "in";
 327       hyp_paths =
 328        LIST0
 329         [ id = IDENT ;
 330           path = OPT [SYMBOL ":" ; path = term -> path ] ->
 331           (id,match path with Some p -> p | None -> CicAst.UserInput) ]
 332         SEP SYMBOL ";";
 333       goal_path = OPT [ SYMBOL <:unicode<vdash>>; term = term -> term ] ->
 334         (hyp_paths, goal_path) ]
 335   ];
 336   direction: [
 337     [ IDENT "left" -> `Left
 338     | SYMBOL ">" -> `Left
 339     | IDENT "right" -> `Right
 340     | SYMBOL "<" -> `Right ]
 341   ];
 342   tactic: [
 343     [ [ IDENT "absurd" ]; t = tactic_term ->
 344         TacticAst.Absurd (loc, t)
 345     | [ IDENT "apply" ]; t = tactic_term ->
 346         TacticAst.Apply (loc, t)
 347     | [ IDENT "assumption" ] ->
 348         TacticAst.Assumption loc
 349     | [ IDENT "auto" ] ; num = OPT [ i = NUM -> int_of_string i ] ->
 350           TacticAst.Auto (loc,num)
 351     | [ IDENT "change" ];
 352       t1 = tactic_term; "with"; t2 = tactic_term; where = pattern_spec ->
 353         TacticAst.Change (loc, t1, t2, where)
 354     (* TODO Change_pattern *)
 355     | [ IDENT "contradiction" ] ->
 356         TacticAst.Contradiction loc
 357     | [ IDENT "cut" ];
 358       t = tactic_term ->
 359         TacticAst.Cut (loc, t)
 360     | [ IDENT "decompose" ]; where = term ->
 361         TacticAst.Decompose (loc, where)
 362     | [ IDENT "discriminate" ];
 363       t = tactic_term ->
 364         TacticAst.Discriminate (loc, t)
 365     | [ IDENT "elimType" ]; t = tactic_term ->
 366         TacticAst.ElimType (loc, t)
 367     | [ IDENT "elim" ];
 368       t1 = tactic_term;
 369       using = OPT [ "using"; using = tactic_term -> using ] ->
 370         TacticAst.Elim (loc, t1, using)
 371     | [ IDENT "exact" ]; t = tactic_term ->
 372         TacticAst.Exact (loc, t)
 373     | [ IDENT "exists" ] ->
 374         TacticAst.Exists loc
 375     | [ IDENT "fold" ];
 376       kind = reduction_kind; t = tactic_term ->
 377         TacticAst.Fold (loc, kind, t)
 378     | [ IDENT "fourier" ] ->
 379         TacticAst.Fourier loc
 380     | IDENT "goal"; n = NUM -> TacticAst.Goal (loc, int_of_string n)
 381     | [ IDENT "injection" ]; t = term ->
 382         TacticAst.Injection (loc, t)
 383     | [ IDENT "intros" ];
 384       num = OPT [ num = int -> num ];
 385       idents = OPT ident_list0 ->
 386         let idents = match idents with None -> [] | Some idents -> idents in
 387         TacticAst.Intros (loc, num, idents)
 388     | [ IDENT "intro" ] ->
 389         TacticAst.Intros (loc, Some 1, [])
 390     | [ IDENT "left" ] -> TacticAst.Left loc
 391     | [ IDENT "letin" ];
 392        where = IDENT ; SYMBOL <:unicode<def>> ; t = tactic_term ->
 393         TacticAst.LetIn (loc, t, where)
 394     | kind = reduction_kind;
 395       p = OPT [ pattern_spec ] ->
 396         let p = match p with None -> [], None | Some p -> p in
 397         TacticAst.Reduce (loc, kind, p)
 398     | IDENT "generalize"; t = tactic_term; p = OPT [ pattern_spec ] ->
 399        let p = match p with None -> [], None | Some p -> p in
 400        TacticAst.Generalize (loc,t,p)
 401     | [ IDENT "reflexivity" ] ->
 402         TacticAst.Reflexivity loc
 403     | [ IDENT "replace" ];
 404       t1 = tactic_term; "with"; t2 = tactic_term ->
 405         TacticAst.Replace (loc, t1, t2)
 406     | IDENT "rewrite" ; d = direction; t = term ;
 407       p = OPT [ pattern_spec ] ->
 408         let p = match p with None -> [], None | Some p -> p in
 409         TacticAst.Rewrite (loc, d, t, p)
 410     | [ IDENT "right" ] -> TacticAst.Right loc
 411     | [ IDENT "ring" ] -> TacticAst.Ring loc
 412     | [ IDENT "split" ] -> TacticAst.Split loc
 413     | [ IDENT "symmetry" ] ->
 414         TacticAst.Symmetry loc
 415     | [ IDENT "transitivity" ];
 416       t = tactic_term ->
 417         TacticAst.Transitivity (loc, t)
 418     | [ IDENT "fwd" ]; t = term ->
 419         TacticAst.FwdSimpl (loc, t)
 420     | [ IDENT "lapply" ]; what = tactic_term;
 421         to_what = OPT [ "to" ; t = tactic_term -> t ] ->
 422           TacticAst.LApply (loc, to_what, what)
 423     ]
 424   ];
 425   tactical:
 426     [ "sequence" LEFTA
 427       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 428           TacticAst.Seq (loc, tacticals)
 429       ]
 430     | "then" NONA
 431       [ tac = tactical;
 432         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 433           (TacticAst.Then (loc, tac, tacs))
 434       ]
 435     | "loops" RIGHTA
 436       [ [ IDENT "do" ]; count = int; tac = tactical ->
 437           TacticAst.Do (loc, count, tac)
 438       | [ IDENT "repeat" ]; tac = tactical ->
 439           TacticAst.Repeat (loc, tac)
 440       ]
 441     | "simple" NONA
 442       [ IDENT "tries";
 443         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 444           TacticAst.Tries (loc, tacs)
 445       | IDENT "try"; tac = NEXT ->
 446           TacticAst.Try (loc, tac)
 447       | IDENT "fail" -> TacticAst.Fail loc
 448       | IDENT "id" -> TacticAst.IdTac loc
 449       | PAREN "("; tac = tactical; PAREN ")" -> tac
 450       | tac = tactic -> TacticAst.Tactic (loc, tac)
 451       ]
 452     ];
 453   theorem_flavour: [
 454     [ [ IDENT "definition"  ] -> `Definition
 455     | [ IDENT "fact"        ] -> `Fact
 456     | [ IDENT "lemma"       ] -> `Lemma
 457     | [ IDENT "remark"      ] -> `Remark
 458     | [ IDENT "theorem"     ] -> `Theorem
 459     ]
 460   ];
 461   inductive_spec: [ [
 462     fst_name = IDENT; params = LIST0 [ arg=arg -> arg ];
 463     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 464     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 465     tl = OPT [ "with";
 466       types = LIST1 [
 467         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 468        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 469           (name, true, typ, constructors) ] SEP "with" -> types
 470     ] ->
 471       let params =
 472         List.fold_right
 473           (fun (names, typ) acc ->
 474             (List.map (fun name -> (name, typ)) names) @ acc)
 475           params []
 476       in
 477       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 478       let tl_ind_types = match tl with None -> [] | Some types -> types in
 479       let ind_types = fst_ind_type :: tl_ind_types in
 480       (params, ind_types)
 481   ] ];
 482
 483   record_spec: [ [
 484     name = IDENT; params = LIST0 [ arg = arg -> arg ] ;
 485      SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>; PAREN "{" ;
 486      fields = LIST0 [
 487        name = IDENT ; SYMBOL ":" ; ty = term -> (name,ty)
 488      ] SEP SYMBOL ";"; PAREN "}" ->
 489       let params =
 490         List.fold_right
 491           (fun (names, typ) acc ->
 492             (List.map (fun name -> (name, typ)) names) @ acc)
 493           params []
 494       in
 495       (params,name,typ,fields)
 496   ] ];
 497
 498   macro: [
 499     [ [ IDENT "quit"  ] -> TacticAst.Quit loc
 500 (*     | [ IDENT "abort" ] -> TacticAst.Abort loc *)
 501     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 502 (*     | [ IDENT "undo"   ]; steps = OPT NUM ->
 503         TacticAst.Undo (loc, int_opt steps)
 504     | [ IDENT "redo"   ]; steps = OPT NUM ->
 505         TacticAst.Redo (loc, int_opt steps) *)
 506     | [ IDENT "check"   ]; t = term ->
 507         TacticAst.Check (loc, t)
 508     | [ IDENT "hint" ] -> TacticAst.Hint loc
 509     | [ IDENT "whelp"; "match" ] ; t = term ->
 510         TacticAst.WMatch (loc,t)
 511     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 512         TacticAst.WInstance (loc,t)
 513     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 514         TacticAst.WLocate (loc,id)
 515     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 516         TacticAst.WElim (loc, t)
 517     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 518         TacticAst.WHint (loc,t)
 519     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 520     ]
 521   ];
 522
 523   alias_spec: [
 524     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 525       let alpha = "[a-zA-Z]" in
 526       let num = "[0-9]+" in
 527       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 528       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 529       let rex = Str.regexp ("^"^ident^"$") in
 530       if Str.string_match rex id 0 then
 531         let rex = Str.regexp
 532           ("^\\(cic:/\\|theory:/\\)"^ident^
 533            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 534            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 535         in
 536         if Str.string_match rex uri 0 then
 537           TacticAst.Ident_alias (id, uri)
 538         else
 539           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 540       else
 541         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 542     | IDENT "symbol"; symbol = QSTRING;
 543       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 544       SYMBOL "="; dsc = QSTRING ->
 545         let instance =
 546           match instance with Some i -> int_of_string i | None -> 0
 547         in
 548         TacticAst.Symbol_alias (symbol, instance, dsc)
 549     | IDENT "num";
 550       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 551       SYMBOL "="; dsc = QSTRING ->
 552         let instance =
 553           match instance with Some i -> int_of_string i | None -> 0
 554         in
 555         TacticAst.Number_alias (instance, dsc)
 556     ]
 557   ];
 558
 559   command: [[
 560       [ IDENT "set"    ]; n = QSTRING; v = QSTRING ->
 561         TacticAst.Set (loc, n, v)
 562     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 563     | flavour = theorem_flavour; name = IDENT; SYMBOL ":"; typ = term;
 564       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 565         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, typ, body))
 566     | flavour = theorem_flavour; name = IDENT;
 567       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 568         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, CicAst.Implicit, body))
 569     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 570         defs = let_defs ->
 571           let name,ty =
 572             match defs with
 573             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 574             | ((Cic.Name name,None),_,_) :: _ -> name,CicAst.Implicit
 575             | _ -> assert false
 576           in
 577           let body = CicAst.Ident (name,None) in
 578           TacticAst.Obj (loc,TacticAst.Theorem(`Definition, name, ty,
 579             Some (CicAst.LetRec (ind_kind, defs, body))))
 580
 581     | [ IDENT "inductive" ]; spec = inductive_spec ->
 582         let (params, ind_types) = spec in
 583         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 584     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 585         let (params, ind_types) = spec in
 586         let ind_types = (* set inductive flags to false (coinductive) *)
 587           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 588             ind_types
 589         in
 590         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 591     | [ IDENT "coercion" ] ; name = IDENT ->
 592         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 593     | [ IDENT "coercion" ] ; name = URI ->
 594         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 595     | [ IDENT "alias"   ]; spec = alias_spec ->
 596         TacticAst.Alias (loc, spec)
 597     | [ IDENT "record" ]; (params,name,ty,fields) = record_spec ->
 598         TacticAst.Obj (loc,TacticAst.Record (params,name,ty,fields))
 599   ]];
 600
 601   executable: [
 602     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 603     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 604     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 605     ]
 606   ];
 607
 608   comment: [
 609     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 610        TacticAst.Code (loc, ex)
 611     | str = NOTE ->
 612        TacticAst.Note (loc, str)
 613     ]
 614   ];
 615
 616   statement: [
 617     [ ex = executable -> TacticAst.Executable (loc,ex)
 618     | com = comment -> TacticAst.Comment (loc, com)
 619     ]
 620   ];
 621   statements: [
 622     [ l = LIST0 statement ; EOI -> l
 623     ]
 624   ];
 625 END
 626
 627 let exc_located_wrapper f =
 628   try
 629     f ()
 630   with
 631   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 632       raise (Parse_error (floc, msg))
 633   | Stdpp.Exc_located (floc, exn) ->
 634       raise (Parse_error (floc, (Printexc.to_string exn)))
 635
 636 let parse_term stream =
 637   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 638 let parse_statement stream =
 639   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 640 let parse_statements stream =
 641   exc_located_wrapper (fun () -> (Grammar.Entry.parse statements stream))
 642
 643
 644 (**/**)
 645
 646 (** {2 Interface for gTopLevel} *)
 647
 648 module EnvironmentP3 =
 649   struct
 650     type t = environment
 651
 652     let empty = ""
 653
 654     let aliases_grammar = Grammar.gcreate cic_lexer
 655     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 656
 657     let to_string env =
 658       let aliases =
 659         Environment.fold
 660           (fun domain_item (dsc, _) acc ->
 661             let s =
 662               match domain_item with
 663               | Id id ->
 664                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 665               | Symbol (symb, i) ->
 666                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 667                   ^ "."
 668               | Num i ->
 669                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 670             in
 671             s :: acc)
 672           env []
 673       in
 674       String.concat "\n" (List.sort compare aliases)
 675
 676     EXTEND
 677       GLOBAL: aliases;
 678       aliases: [  (* build an environment from an aliases list *)
 679         [ aliases = LIST0 alias; EOI ->
 680             List.fold_left
 681               (fun env (domain_item, codomain_item) ->
 682                 Environment.add domain_item codomain_item env)
 683               Environment.empty aliases
 684         ]
 685       ];
 686       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 687         [ IDENT "alias";
 688           choice =
 689             [ IDENT "id"; id = IDENT; SYMBOL "="; suri = URI ->
 690                 (Id id, choice_of_uri suri)
 691             | IDENT "symbol"; symbol = QSTRING;
 692               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 693               SYMBOL "="; dsc = QSTRING ->
 694                 (Symbol (symbol, int_of_string instance),
 695                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 696             | IDENT "num";
 697               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 698               SYMBOL "="; dsc = QSTRING ->
 699                 (Num (int_of_string instance),
 700                  DisambiguateChoices.lookup_num_by_dsc dsc)
 701             ] -> choice ]
 702       ];
 703     END
 704
 705     let of_string s =
 706       if s = empty then
 707         Environment.empty
 708       else
 709         exc_located_wrapper
 710           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 711   end
 712
 713 (* vim:set encoding=utf8: *)