helm/ocaml/cic_proof_checking/cicElim.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 exception Elim_failure of string
  29 exception Can_t_eliminate
  30
  31 let fresh_binder =
  32   let counter = ref ~-1 in
  33   function
  34     | true ->
  35         incr counter;
  36         Cic.Name ("e" ^ string_of_int !counter)
  37     | _ -> Cic.Anonymous
  38
  39   (** verifies if a given inductive type occurs in a term in target position *)
  40 let rec recursive uri typeno = function
  41   | Cic.Prod (_, _, target) -> recursive uri typeno target
  42   | Cic.MutInd (uri', typeno', [])
  43   | Cic.Appl (Cic.MutInd  (uri', typeno', []) :: _) ->
  44       UriManager.eq uri uri' && typeno = typeno'
  45   | _ -> false
  46
  47   (** given a list of constructor types, return true if at least one of them is
  48   * recursive, false otherwise *)
  49 let recursive_type uri typeno constructors =
  50   let rec aux = function
  51     | Cic.Prod (_, src, tgt) -> recursive uri typeno src || aux tgt
  52     | _ -> false
  53   in
  54   List.exists (fun (_, ty) -> aux ty) constructors
  55
  56 let unfold_appl = function
  57   | Cic.Appl ((Cic.Appl args) :: tl) -> Cic.Appl (args @ tl)
  58   | t -> t
  59
  60 let rec split l n =
  61  match (l,n) with
  62     (l,0) -> ([], l)
  63   | (he::tl, n) -> let (l1,l2) = split tl (n-1) in (he::l1,l2)
  64   | (_,_) -> assert false
  65
  66   (** build elimination principle part related to a single constructor
  67   * @param paramsno number of Prod to ignore in this constructor (i.e. number of
  68   * inductive parameters)
  69   * @param dependent true if we are in the dependent case (i.e. sort <> Prop) *)
  70 let rec delta (uri, typeno) dependent paramsno consno t p args =
  71   match t with
  72   | Cic.MutInd (uri', typeno', []) when
  73     UriManager.eq uri uri' && typeno = typeno' ->
  74       if dependent then
  75         (match args with
  76         | [] -> assert false
  77         | [arg] -> unfold_appl (Cic.Appl [p; arg])
  78         | _ -> unfold_appl (Cic.Appl [p; unfold_appl (Cic.Appl args)]))
  79       else
  80         p
  81   | Cic.Appl (Cic.MutInd (uri', typeno', []) :: tl) when
  82     UriManager.eq uri uri' && typeno = typeno' ->
  83       let (lparams, rparams) = split tl paramsno in
  84       if dependent then
  85         (match args with
  86         | [] -> assert false
  87         | [arg] -> unfold_appl (Cic.Appl (p :: rparams @ [arg]))
  88         | _ ->
  89             unfold_appl (Cic.Appl (p ::
  90               rparams @ [unfold_appl (Cic.Appl args)])))
  91       else  (* non dependent *)
  92         (match rparams with
  93         | [] -> p
  94         | _ -> Cic.Appl (p :: rparams))
  95   | Cic.Prod (binder, src, tgt) ->
  96       if recursive uri typeno src then
  97         let args = List.map (CicSubstitution.lift 2) args in
  98         let phi =
  99           let src = CicSubstitution.lift 1 src in
 100           delta (uri, typeno) dependent paramsno consno src
 101             (CicSubstitution.lift 1 p) [Cic.Rel 1]
 102         in
 103         let tgt = CicSubstitution.lift 1 tgt in
 104         Cic.Prod (fresh_binder dependent, src,
 105           Cic.Prod (Cic.Anonymous, phi,
 106             delta (uri, typeno) dependent paramsno consno tgt
 107               (CicSubstitution.lift 2 p) (args @ [Cic.Rel 2])))
 108       else  (* non recursive *)
 109         let args = List.map (CicSubstitution.lift 1) args in
 110         Cic.Prod (fresh_binder dependent, src,
 111           delta (uri, typeno) dependent paramsno consno tgt
 112             (CicSubstitution.lift 1 p) (args @ [Cic.Rel 1]))
 113   | _ -> assert false
 114
 115 let rec strip_left_params consno leftno = function
 116   | t when leftno = 0 -> t (* no need to lift, the term is (hopefully) closed *)
 117   | Cic.Prod (_, _, tgt) (* when leftno > 0 *) ->
 118       (* after stripping the parameters we lift of consno. consno is 1 based so,
 119       * the first constructor will be lifted by 1 (for P), the second by 2 (1
 120       * for P and 1 for the 1st constructor), and so on *)
 121       if leftno = 1 then
 122         CicSubstitution.lift consno tgt
 123       else
 124         strip_left_params consno (leftno - 1) tgt
 125   | _ -> assert false
 126
 127 let delta (ury, typeno) dependent paramsno consno t p args =
 128   let t = strip_left_params consno paramsno t in
 129   delta (ury, typeno) dependent paramsno consno t p args
 130
 131 let rec add_params binder indno ty eliminator =
 132   if indno = 0 then
 133     eliminator
 134   else
 135     match ty with
 136     | Cic.Prod (name, src, tgt) ->
 137         binder name src (add_params binder (indno - 1) tgt eliminator)
 138     | _ -> assert false
 139
 140 let rec mk_rels consno = function
 141   | 0 -> []
 142   | n -> Cic.Rel (n+consno) :: mk_rels consno (n-1)
 143
 144 let rec strip_pi = function
 145   | Cic.Prod (_, _, tgt) -> strip_pi tgt
 146   | t -> t
 147
 148 let rec count_pi = function
 149   | Cic.Prod (_, _, tgt) -> count_pi tgt + 1
 150   | t -> 0
 151
 152 let rec type_of_p sort dependent leftno indty = function
 153   | Cic.Prod (n, src, tgt) when leftno = 0 ->
 154       Cic.Prod (n, src, type_of_p sort dependent leftno indty tgt)
 155   | Cic.Prod (_, _, tgt) -> type_of_p sort dependent (leftno - 1) indty tgt
 156   | t ->
 157       if dependent then
 158         Cic.Prod (Cic.Anonymous, indty, Cic.Sort sort)
 159       else
 160         Cic.Sort sort
 161
 162 let rec add_right_pi dependent strip liftno liftfrom rightno indty = function
 163   | Cic.Prod (_, src, tgt) when strip = 0 ->
 164       Cic.Prod (fresh_binder true,
 165         CicSubstitution.lift_from liftfrom liftno src,
 166         add_right_pi dependent strip liftno (liftfrom + 1) rightno indty tgt)
 167   | Cic.Prod (_, _, tgt) ->
 168       add_right_pi dependent (strip - 1) liftno liftfrom rightno indty tgt
 169   | t ->
 170       if dependent then
 171         Cic.Prod (fresh_binder dependent,
 172           CicSubstitution.lift_from (rightno + 1) liftno indty,
 173           Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 0 (rightno + 1)))
 174       else
 175         Cic.Prod (Cic.Anonymous,
 176           CicSubstitution.lift_from (rightno + 1) liftno indty,
 177           if rightno = 0 then
 178             Cic.Rel (1 + liftno + rightno)
 179           else
 180             Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 1 rightno))
 181
 182 let rec add_right_lambda dependent strip liftno liftfrom rightno indty case =
 183 function
 184   | Cic.Prod (_, src, tgt) when strip = 0 ->
 185       Cic.Lambda (fresh_binder true,
 186         CicSubstitution.lift_from liftfrom liftno src,
 187         add_right_lambda dependent strip liftno (liftfrom + 1) rightno indty
 188           case tgt)
 189   | Cic.Prod (_, _, tgt) ->
 190       add_right_lambda dependent (strip - 1) liftno liftfrom rightno indty
 191         case tgt
 192   | t ->
 193       Cic.Lambda (fresh_binder true,
 194         CicSubstitution.lift_from (rightno + 1) liftno indty, case)
 195
 196 let string_of_sort = function
 197   | Cic.Prop -> "Prop"
 198   | Cic.CProp -> "CProp"
 199   | Cic.Set -> "Set"
 200   | Cic.Type _ -> "Type"
 201
 202 let rec branch (uri, typeno) insource paramsno t fix head args =
 203   match t with
 204   | Cic.MutInd (uri', typeno', []) when
 205     UriManager.eq uri uri' && typeno = typeno' ->
 206       if insource then
 207         (match args with
 208         | [arg] -> Cic.Appl (fix :: args)
 209         | _ -> Cic.Appl (head :: [Cic.Appl args]))
 210       else
 211         (match args with
 212         | [] -> head
 213         | _ -> Cic.Appl (head :: args))
 214   | Cic.Appl (Cic.MutInd (uri', typeno', []) :: tl) when
 215     UriManager.eq uri uri' && typeno = typeno' ->
 216       if insource then
 217         let (lparams, rparams) = split tl paramsno in
 218         match args with
 219         | [arg] -> Cic.Appl (fix :: rparams @ args)
 220         | _ -> Cic.Appl (fix :: rparams @ [Cic.Appl args])
 221       else
 222         (match args with
 223         | [] -> head
 224         | _ -> Cic.Appl (head :: args))
 225   | Cic.Prod (binder, src, tgt) ->
 226       if recursive uri typeno src then
 227         let args = List.map (CicSubstitution.lift 1) args in
 228         let phi =
 229           let fix = CicSubstitution.lift 1 fix in
 230           let src = CicSubstitution.lift 1 src in
 231           branch (uri, typeno) true paramsno src fix head [Cic.Rel 1]
 232         in
 233         Cic.Lambda (fresh_binder true, src,
 234           branch (uri, typeno) insource paramsno tgt
 235             (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 236             (args @ [Cic.Rel 1; phi]))
 237       else  (* non recursive *)
 238         let args = List.map (CicSubstitution.lift 1) args in
 239         Cic.Lambda (fresh_binder true, src,
 240           branch (uri, typeno) insource paramsno tgt
 241           (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 242             (args @ [Cic.Rel 1]))
 243   | _ -> assert false
 244
 245 let branch (uri, typeno) insource liftno paramsno t fix head args =
 246   let t = strip_left_params liftno paramsno t in
 247   branch (uri, typeno) insource paramsno t fix head args
 248
 249 let elim_of ?(sort = Cic.Type (CicUniv.fresh ())) uri typeno =
 250   let (obj, univ) = (CicEnvironment.get_obj CicUniv.empty_ugraph uri) in
 251   match obj with
 252   | Cic.InductiveDefinition (indTypes, params, leftno) ->
 253       let (name, inductive, ty, constructors) =
 254         try
 255           List.nth indTypes typeno
 256         with Failure _ -> assert false
 257       in
 258       let paramsno = count_pi ty in (* number of (left or right) parameters *)
 259       let rightno = paramsno - leftno in
 260       let dependent = (strip_pi ty <> Cic.Sort Cic.Prop) in
 261       let conslen = List.length constructors in
 262       let consno = ref (conslen + 1) in
 263       if (not dependent) && (sort <> Cic.Prop) && (conslen > 1) then
 264         raise Can_t_eliminate;
 265       let indty =
 266         let indty = Cic.MutInd (uri, typeno, []) in
 267         if paramsno = 0 then
 268           indty
 269         else
 270           Cic.Appl (indty :: mk_rels 0 paramsno)
 271       in
 272       let mk_constructor consno =
 273         let constructor = Cic.MutConstruct (uri, typeno, consno, []) in
 274         if leftno = 0 then
 275           constructor
 276         else
 277           Cic.Appl (constructor :: mk_rels consno leftno)
 278       in
 279       let p_ty = type_of_p sort dependent leftno indty ty in
 280       let final_ty =
 281         add_right_pi dependent leftno (conslen + 1) 1 rightno indty ty
 282       in
 283       let eliminator_type =
 284         let cic =
 285           Cic.Prod (Cic.Name "P", p_ty,
 286             (List.fold_right
 287               (fun (_, constructor) acc ->
 288                 decr consno;
 289                 let p = Cic.Rel !consno in
 290                 Cic.Prod (Cic.Anonymous,
 291                   (delta (uri, typeno) dependent leftno !consno
 292                     constructor p [mk_constructor !consno]),
 293                   acc))
 294               constructors final_ty))
 295         in
 296         add_params (fun b s t -> Cic.Prod (b, s, t)) leftno ty cic
 297       in
 298       let consno = ref (conslen + 1) in
 299       let eliminator_body =
 300         let fix = Cic.Rel (rightno + 2) in
 301         let is_recursive = recursive_type uri typeno constructors in
 302         let recshift = if is_recursive then 1 else 0 in
 303         let (_, branches) =
 304           List.fold_right
 305             (fun (_, ty) (shift, branches) ->
 306               let head = Cic.Rel (rightno + shift + 1 + recshift) in
 307               let b =
 308                 branch (uri, typeno) false
 309                   (rightno + conslen + 2 + recshift) leftno ty fix head []
 310               in
 311               (shift + 1,  b :: branches))
 312             constructors (1, [])
 313         in
 314         let mutcase =
 315           Cic.MutCase (uri, typeno, Cic.Rel (conslen + rightno + 2 + recshift),
 316             Cic.Rel 1, branches)
 317         in
 318         let body =
 319           if is_recursive then
 320             let fixfun =
 321               add_right_lambda dependent leftno (conslen + 2) 1 rightno
 322                 indty mutcase ty
 323             in
 324             (* rightno is the decreasing argument, i.e. the argument of
 325              * inductive type *)
 326             Cic.Fix (0, ["f", rightno, final_ty, fixfun])
 327           else
 328             add_right_lambda dependent leftno (conslen + 1) 1 rightno indty
 329               mutcase ty
 330         in
 331         let cic =
 332           Cic.Lambda (Cic.Name "P", p_ty,
 333             (List.fold_right
 334               (fun (_, constructor) acc ->
 335                 decr consno;
 336                 let p = Cic.Rel !consno in
 337                 Cic.Lambda (fresh_binder true,
 338                   (delta (uri, typeno) dependent leftno !consno
 339                     constructor p [mk_constructor !consno]),
 340                   acc))
 341               constructors body))
 342         in
 343         add_params (fun b s t -> Cic.Lambda (b, s, t)) leftno ty cic
 344       in
 345 (*
 346 prerr_endline (CicPp.ppterm eliminator_type);
 347 prerr_endline (CicPp.ppterm eliminator_body);
 348 *)
 349       let (computed_type, ugraph) =
 350         try
 351           CicTypeChecker.type_of_aux' [] [] eliminator_body CicUniv.empty_ugraph
 352         with CicTypeChecker.TypeCheckerFailure msg ->
 353           raise (Elim_failure (sprintf
 354             "type checker failure while type checking:\n%s\nerror:\n%s"
 355             (CicPp.ppterm eliminator_body) msg))
 356       in
 357       if not (fst (CicReduction.are_convertible []
 358         eliminator_type computed_type ugraph))
 359       then
 360         raise (Failure (sprintf
 361           "internal error: type mismatch on eliminator type\n%s\n%s"
 362           (CicPp.ppterm eliminator_type) (CicPp.ppterm computed_type)));
 363       let suffix =
 364         match sort with
 365         | Cic.Prop -> "_ind"
 366         | Cic.Set -> "_rec"
 367         | Cic.Type _ -> "_rect"
 368         | _ -> assert false
 369       in
 370       let name = UriManager.name_of_uri uri ^ suffix in
 371       Cic.Constant (name, Some eliminator_body, eliminator_type, [])
 372   | _ -> assert false
 373