helm/ocaml/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  50
  51 let int_of_string s =
  52   try
  53     Pervasives.int_of_string s
  54   with Failure _ ->
  55     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  56
  57 (** {2 Grammar extension} *)
  58
  59 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  60 let gram_ident s = Gramext.Stoken ("IDENT", s)
  61 let gram_number s = Gramext.Stoken ("NUMBER", s)
  62 let gram_keyword s = Gramext.Stoken ("", s)
  63 let gram_term = Gramext.Sself
  64
  65 let gram_of_literal =
  66   function
  67   | `Symbol s -> gram_symbol s
  68   | `Keyword s -> gram_keyword s
  69   | `Number s -> gram_number s
  70
  71 type binding =
  72   | NoBinding
  73   | Binding of string * Env.value_type
  74   | Env of (string * Env.value_type) list
  75
  76 let make_action action bindings =
  77   let rec aux (vl : CicNotationEnv.t) =
  78     function
  79       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  80     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  81     (* LUCA: DEFCON 3 BEGIN *)
  82     | Binding (name, Env.TermType) :: tl ->
  83         Gramext.action
  84           (fun (v:Ast.term) ->
  85             aux ((name, (Env.TermType, Env.TermValue v))::vl) tl)
  86     | Binding (name, Env.StringType) :: tl ->
  87         Gramext.action
  88           (fun (v:string) ->
  89             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
  90     | Binding (name, Env.NumType) :: tl ->
  91         Gramext.action
  92           (fun (v:string) ->
  93             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
  94     | Binding (name, Env.OptType t) :: tl ->
  95         Gramext.action
  96           (fun (v:'a option) ->
  97             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
  98     | Binding (name, Env.ListType t) :: tl ->
  99         Gramext.action
 100           (fun (v:'a list) ->
 101             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 102     | Env _ :: tl ->
 103         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 104     (* LUCA: DEFCON 3 END *)
 105   in
 106     aux [] (List.rev bindings)
 107
 108 let flatten_opt =
 109   let rec aux acc =
 110     function
 111       [] -> List.rev acc
 112     | NoBinding :: tl -> aux acc tl
 113     | Env names :: tl -> aux (List.rev names @ acc) tl
 114     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 115   in
 116   aux []
 117
 118   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 119 let extract_term_production pattern =
 120   let rec aux = function
 121     | Ast.AttributedTerm (_, t) -> aux t
 122     | Ast.Literal l -> aux_literal l
 123     | Ast.Layout l -> aux_layout l
 124     | Ast.Magic m -> aux_magic m
 125     | Ast.Variable v -> aux_variable v
 126     | t ->
 127         prerr_endline (CicNotationPp.pp_term t);
 128         assert false
 129   and aux_literal =
 130     function
 131     | `Symbol s -> [NoBinding, gram_symbol s]
 132     | `Keyword s ->
 133         (* assumption: s will be registered as a keyword with the lexer *)
 134         [NoBinding, gram_keyword s]
 135     | `Number s -> [NoBinding, gram_number s]
 136   and aux_layout = function
 137     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 138     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 139     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 140     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 141     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 142     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 143     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 144     | Ast.Root (p1, p2) ->
 145         [NoBinding, gram_symbol "\\root"] @ aux p2
 146         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 147     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 148     | Ast.Break -> []
 149     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 150     | Ast.Group pl -> List.flatten (List.map aux pl)
 151   and aux_magic magic =
 152     match magic with
 153     | Ast.Opt p ->
 154         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 155         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 156           match env_opt with
 157           | Some env -> List.map Env.opt_binding_some env
 158           | None -> List.map Env.opt_binding_of_name p_names
 159         in
 160         [ Env (List.map Env.opt_declaration p_names),
 161           Gramext.srules
 162             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 163               Gramext.action action ] ]
 164     | Ast.List0 (p, _)
 165     | Ast.List1 (p, _) ->
 166         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 167 (*         let env0 = List.map list_binding_of_name p_names in
 168         let grow_env_entry env n v =
 169           List.map
 170             (function
 171               | (n', (ty, ListValue vl)) as entry ->
 172                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 173               | _ -> assert false)
 174             env
 175         in
 176         let grow_env env_i env =
 177           List.fold_left
 178             (fun env (n, (_, v)) -> grow_env_entry env n v)
 179             env env_i
 180         in *)
 181         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 182           CicNotationEnv.coalesce_env p_names env_list
 183         in
 184         let gram_of_list s =
 185           match magic with
 186           | Ast.List0 (_, None) -> Gramext.Slist0 s
 187           | Ast.List1 (_, None) -> Gramext.Slist1 s
 188           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 189           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 190           | _ -> assert false
 191         in
 192         [ Env (List.map Env.list_declaration p_names),
 193           Gramext.srules
 194             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 195               Gramext.action action ] ]
 196     | _ -> assert false
 197   and aux_variable =
 198     function
 199     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 200     | Ast.TermVar s -> [Binding (s, Env.TermType), gram_term]
 201     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 202     | Ast.Ascription (p, s) -> assert false (* TODO *)
 203     | Ast.FreshVar _ -> assert false
 204   and inner_pattern p =
 205     let p_bindings, p_atoms = List.split (aux p) in
 206     let p_names = flatten_opt p_bindings in
 207     let action =
 208       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 209         p_bindings
 210     in
 211     p_bindings, p_atoms, p_names, action
 212   in
 213   aux pattern
 214
 215 let level_of precedence associativity =
 216   if precedence < min_precedence || precedence > max_precedence then
 217     raise (Level_not_found precedence);
 218   let assoc_string =
 219     match associativity with
 220     | Gramext.NonA -> "N"
 221     | Gramext.LeftA -> "L"
 222     | Gramext.RightA -> "R"
 223   in
 224   string_of_int precedence ^ assoc_string
 225
 226 type rule_id = Token.t Gramext.g_symbol list
 227
 228   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 229 let owned_keywords = Hashtbl.create 23
 230
 231 let extend level1_pattern ~precedence ~associativity action =
 232   let p_bindings, p_atoms =
 233     List.split (extract_term_production level1_pattern)
 234   in
 235   let level = level_of precedence associativity in
 236 (*   let p_names = flatten_opt p_bindings in *)
 237   let _ =
 238     Grammar.extend
 239       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 240         Some (Gramext.Level level),
 241         [ None,
 242           Some associativity,
 243           [ p_atoms,
 244             (make_action
 245               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 246                 (action env loc))
 247               p_bindings) ]]]
 248   in
 249   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 250   let rule_id = p_atoms in
 251   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 252   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 253   rule_id
 254
 255 let delete rule_id =
 256   let atoms = rule_id in
 257   (try
 258     let keywords = Hashtbl.find owned_keywords rule_id in
 259     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 260   with Not_found -> assert false);
 261   Grammar.delete_rule term atoms
 262
 263 (** {2 Grammar} *)
 264
 265 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 266 let parse_level2_ast_ref = ref (fun _ -> assert false)
 267 let parse_level2_meta_ref = ref (fun _ -> assert false)
 268
 269 let fold_cluster binder terms ty body =
 270   List.fold_right
 271     (fun term body -> Ast.Binder (binder, (term, ty), body))
 272     terms body  (* terms are names: either Ident or FreshVar *)
 273
 274 let fold_exists terms ty body =
 275   List.fold_right
 276     (fun term body ->
 277       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 278       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 279     terms body
 280
 281 let fold_binder binder pt_names body =
 282   List.fold_right
 283     (fun (names, ty) body -> fold_cluster binder names ty body)
 284     pt_names body
 285
 286 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 287
 288   (* create empty precedence level for "term" *)
 289 let _ =
 290   let dummy_action =
 291     Gramext.action (fun _ ->
 292       failwith "internal error, lexer generated a dummy token")
 293   in
 294   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 295    * empty after the deletion. The lexer never generate the Stoken below. *)
 296   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 297   let mk_level_list first last =
 298     let rec aux acc = function
 299       | i when i < first -> acc
 300       | i ->
 301           aux
 302             ((Some (string_of_int i ^ "N"), Some Gramext.NonA, dummy_prod)
 303              :: (Some (string_of_int i ^ "L"), Some Gramext.LeftA, dummy_prod)
 304              :: (Some (string_of_int i ^ "R"), Some Gramext.RightA, dummy_prod)
 305              :: acc)
 306             (i - 1)
 307     in
 308     aux [] last
 309   in
 310   Grammar.extend
 311     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 312       None,
 313       mk_level_list min_precedence max_precedence ]
 314
 315 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 316 EXTEND
 317   GLOBAL: level1_pattern;
 318
 319   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 320   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 321   literal: [
 322     [ s = SYMBOL -> `Symbol s
 323     | k = QKEYWORD -> `Keyword k
 324     | n = NUMBER -> `Number n
 325     ]
 326   ];
 327   sep:       [ [ "sep";      sep = literal -> sep ] ];
 328 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 329   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 330   l1_magic_pattern: [
 331     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> Ast.List0 (p, sep)
 332     | "list1"; p = l1_simple_pattern; sep = OPT sep -> Ast.List1 (p, sep)
 333     | "opt";   p = l1_simple_pattern -> Ast.Opt p
 334     ]
 335   ];
 336   l1_pattern_variable: [
 337     [ "term"; id = IDENT -> Ast.TermVar id
 338     | "number"; id = IDENT -> Ast.NumVar id
 339     | "ident"; id = IDENT -> Ast.IdentVar id
 340     ]
 341   ];
 342   l1_simple_pattern:
 343     [ "layout" LEFTA
 344       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 345           return_term loc (Ast.Layout (Ast.Sub (p1, p2)))
 346       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 347           return_term loc (Ast.Layout (Ast.Sup (p1, p2)))
 348       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 349           return_term loc (Ast.Layout (Ast.Below (p1, p2)))
 350       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 351           return_term loc (Ast.Layout (Ast.Above (p1, p2)))
 352       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 353           return_term loc (Ast.Layout (Ast.Over (p1, p2)))
 354       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 355           return_term loc (Ast.Layout (Ast.Atop (p1, p2)))
 356 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 357           return_term loc (Array (p, csep, rsep)) *)
 358       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 359           return_term loc (Ast.Layout (Ast.Frac (p1, p2)))
 360       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Ast.Layout (Ast.Sqrt p))
 361       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 362           return_term loc (Ast.Layout (Ast.Root (arg, index)))
 363       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 364           return_term loc (Ast.Layout (Ast.Box ((Ast.H, false, false), p)))
 365       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 366           return_term loc (Ast.Layout (Ast.Box ((Ast.V, false, false), p)))
 367       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 368           return_term loc (Ast.Layout (Ast.Box ((Ast.HV, false, false), p)))
 369       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 370           return_term loc (Ast.Layout (Ast.Box ((Ast.HOV, false, false), p)))
 371       | "break" -> return_term loc (Ast.Layout Ast.Break)
 372 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 373       | LPAREN; p = l1_pattern; RPAREN ->
 374           return_term loc (CicNotationUtil.group p)
 375       ]
 376     | "simple" NONA
 377       [ i = IDENT -> return_term loc (Ast.Variable (Ast.TermVar i))
 378       | m = l1_magic_pattern -> return_term loc (Ast.Magic m)
 379       | v = l1_pattern_variable -> return_term loc (Ast.Variable v)
 380       | l = literal -> return_term loc (Ast.Literal l)
 381       ]
 382     ];
 383   END
 384 (* }}} *)
 385
 386 (* {{{ Grammar for ast magics, notation level 2 *)
 387 EXTEND
 388   GLOBAL: level2_meta;
 389   l2_variable: [
 390     [ "term"; id = IDENT -> Ast.TermVar id
 391     | "number"; id = IDENT -> Ast.NumVar id
 392     | "ident"; id = IDENT -> Ast.IdentVar id
 393     | "fresh"; id = IDENT -> Ast.FreshVar id
 394     | "anonymous" -> Ast.TermVar "_"
 395     | id = IDENT -> Ast.TermVar id
 396     ]
 397   ];
 398   l2_magic: [
 399     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 400       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 401         Ast.Fold (kind, base, [id], recursive)
 402     | "default"; some = level2_meta; none = level2_meta ->
 403         Ast.Default (some, none)
 404     | "if"; p_test = level2_meta;
 405       "then"; p_true = level2_meta;
 406       "else"; p_false = level2_meta ->
 407         Ast.If (p_test, p_true, p_false)
 408     | "fail" -> Ast.Fail
 409     ]
 410   ];
 411   level2_meta: [
 412     [ magic = l2_magic -> Ast.Magic magic
 413     | var = l2_variable -> Ast.Variable var
 414     | blob = UNPARSED_AST ->
 415         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 416     ]
 417   ];
 418 END
 419 (* }}} *)
 420
 421 (* {{{ Grammar for ast patterns, notation level 2 *)
 422 EXTEND
 423   GLOBAL: level2_ast term let_defs;
 424   level2_ast: [ [ p = term -> p ] ];
 425   sort: [
 426     [ "Prop" -> `Prop
 427     | "Set" -> `Set
 428     | "Type" -> `Type (CicUniv.fresh ())
 429     | "CProp" -> `CProp
 430     ]
 431   ];
 432   explicit_subst: [
 433     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 434       SYMBOL "[";
 435       substs = LIST1 [
 436         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 437       ] SEP SYMBOL ";";
 438       SYMBOL "]" ->
 439         substs
 440     ]
 441   ];
 442   meta_subst: [
 443     [ s = SYMBOL "_" -> None
 444     | p = term -> Some p ]
 445   ];
 446   meta_substs: [
 447     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 448   ];
 449   possibly_typed_name: [
 450     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 451         id, Some typ
 452     | arg = single_arg -> arg, None
 453     ]
 454   ];
 455   match_pattern: [
 456     [ id = IDENT -> id, None, []
 457     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 458         id, None, vars
 459     ]
 460   ];
 461   binder: [
 462     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 463 (*     | SYMBOL <:unicode<exists>> |+ ∃ +| -> `Exists *)
 464     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 465     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 466     ]
 467   ];
 468   arg: [
 469     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 470       SYMBOL ":"; ty = term; RPAREN ->
 471         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 472     | name = IDENT -> [Ast.Ident (name, None)], None
 473     | blob = UNPARSED_META ->
 474         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 475         match meta with
 476         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 477         | Ast.Variable (Ast.TermVar "_") -> [Ast.Ident ("_", None)], None
 478         | _ -> failwith "Invalid bound name."
 479    ]
 480   ];
 481   single_arg: [
 482     [ name = IDENT -> Ast.Ident (name, None)
 483     | blob = UNPARSED_META ->
 484         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 485         match meta with
 486         | Ast.Variable (Ast.FreshVar _)
 487         | Ast.Variable (Ast.IdentVar _) -> meta
 488         | Ast.Variable (Ast.TermVar "_") -> Ast.Ident ("_", None)
 489         | _ -> failwith "Invalid index name."
 490     ]
 491   ];
 492   induction_kind: [
 493     [ "rec" -> `Inductive
 494     | "corec" -> `CoInductive
 495     ]
 496   ];
 497   let_defs: [
 498     [ defs = LIST1 [
 499         name = single_arg;
 500         args = LIST1 arg;
 501         index_name = OPT [ "on"; id = single_arg -> id ];
 502         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 503         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 504           let body = fold_binder `Lambda args body in
 505           let ty =
 506             match ty with
 507             | None -> None
 508             | Some ty -> Some (fold_binder `Pi args ty)
 509           in
 510           let rec position_of name p = function
 511             | [] -> None, p
 512             | n :: _ when n = name -> Some p, p
 513             | _ :: tl -> position_of name (p + 1) tl
 514           in
 515           let rec find_arg name n = function
 516             | [] ->
 517                 Ast.fail loc (sprintf "Argument %s not found"
 518                   (CicNotationPp.pp_term name))
 519             | (l,_) :: tl ->
 520                 (match position_of name 0 l with
 521                 | None, len -> find_arg name (n + len) tl
 522                 | Some where, len -> n + where)
 523           in
 524           let index =
 525             match index_name with
 526             | None -> 0
 527             | Some index_name -> find_arg index_name 0 args
 528           in
 529           (name, ty), body, index
 530       ] SEP "and" ->
 531         defs
 532     ]
 533   ];
 534   binder_vars: [
 535     [ vars = [
 536           l = LIST1 single_arg SEP SYMBOL "," -> l
 537         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 538       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 539     | LPAREN;
 540         vars = [
 541             l =  LIST1 single_arg SEP SYMBOL "," -> l
 542           | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 543       typ = OPT [ SYMBOL ":"; t = term -> t ];
 544       RPAREN -> (vars, typ)
 545     ]
 546   ];
 547   term: LEVEL "10N" [ (* let in *)
 548     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 549       p1 = term; "in"; p2 = term ->
 550         return_term loc (Ast.LetIn (var, p1, p2))
 551     | "let"; k = induction_kind; defs = let_defs; "in";
 552       body = term ->
 553         return_term loc (Ast.LetRec (k, defs, body))
 554     ]
 555   ];
 556   term: LEVEL "20R"  (* binder *)
 557     [
 558       [ b = binder; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 559           return_term loc (fold_cluster b vars typ body)
 560       | SYMBOL <:unicode<exists>> (* ∃ *);
 561         (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 562           return_term loc (fold_exists vars typ body)
 563       ]
 564     ];
 565   term: LEVEL "70L"  (* apply *)
 566     [
 567       [ p1 = term; p2 = term ->
 568           let rec aux = function
 569             | Ast.Appl (hd :: tl)
 570             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 571                 aux hd @ tl
 572             | term -> [term]
 573           in
 574           return_term loc (Ast.Appl (aux p1 @ [p2]))
 575       ]
 576     ];
 577   term: LEVEL "90N"  (* simple *)
 578     [
 579       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 580       | id = IDENT; s = explicit_subst ->
 581           return_term loc (Ast.Ident (id, Some s))
 582       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 583       | u = URI -> return_term loc (Ast.Uri (u, None))
 584       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 585       | IMPLICIT -> return_term loc (Ast.Implicit)
 586       | PLACEHOLDER -> return_term loc Ast.UserInput
 587       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 588       | m = META; s = meta_substs ->
 589           return_term loc (Ast.Meta (int_of_string m, s))
 590       | s = sort -> return_term loc (Ast.Sort s)
 591       | "match"; t = term;
 592         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 593         outtyp = OPT [ "return"; ty = term -> ty ];
 594         "with"; SYMBOL "[";
 595         patterns = LIST0 [
 596           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 597           rhs = term ->
 598             lhs, rhs
 599         ] SEP SYMBOL "|";
 600         SYMBOL "]" ->
 601           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 602       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 603           return_term loc (Ast.Cast (p1, p2))
 604       | LPAREN; p = term; RPAREN -> p
 605       | blob = UNPARSED_META ->
 606           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 607       ]
 608     ];
 609 END
 610 (* }}} *)
 611
 612 (** {2 API implementation} *)
 613
 614 let exc_located_wrapper f =
 615   try
 616     f ()
 617   with
 618   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 619       raise (HExtlib.Localized (floc, Parse_error msg))
 620   | Stdpp.Exc_located (floc, exn) ->
 621       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 622
 623 let parse_level1_pattern lexbuf =
 624   exc_located_wrapper
 625     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf))
 626
 627 let parse_level2_ast lexbuf =
 628   exc_located_wrapper
 629     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 630
 631 let parse_level2_meta lexbuf =
 632   exc_located_wrapper
 633     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 634
 635 let _ =
 636   parse_level1_pattern_ref := parse_level1_pattern;
 637   parse_level2_ast_ref := parse_level2_ast;
 638   parse_level2_meta_ref := parse_level2_meta
 639
 640 (** {2 Debugging} *)
 641
 642 let print_l2_pattern () =
 643   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 644   Format.pp_print_flush Format.std_formatter ();
 645   flush stdout
 646
 647 (* vim:set encoding=utf8 foldmethod=marker: *)