helm/ocaml/grafite/grafiteAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open GrafiteAst
  29
  30 let tactical_terminator = ""
  31 let tactic_terminator = tactical_terminator
  32 let command_terminator = tactical_terminator
  33
  34 let pp_idents idents = "[" ^ String.concat "; " idents ^ "]"
  35
  36 let pp_reduction_kind ~term_pp = function
  37   | `Normalize -> "normalize"
  38   | `Reduce -> "reduce"
  39   | `Simpl -> "simplify"
  40   | `Unfold (Some t) -> "unfold " ^ term_pp t
  41   | `Unfold None -> "unfold"
  42   | `Whd -> "whd"
  43
  44 let pp_tactic_pattern ~term_pp ~lazy_term_pp (what, hyp, goal) =
  45   let what_text =
  46     match what with
  47     | None -> ""
  48     | Some t -> sprintf "in match (%s) " (lazy_term_pp t) in
  49   let hyp_text =
  50     String.concat " "
  51       (List.map (fun (name, p) -> sprintf "%s:(%s)" name (term_pp p)) hyp) in
  52   let goal_text =
  53     match goal with
  54     | None -> ""
  55     | Some t -> sprintf "\\vdash (%s)" (term_pp t) in
  56   sprintf "%sin %s%s" what_text hyp_text goal_text
  57
  58 let pp_intros_specs = function
  59    | None, []         -> ""
  60    | Some num, []     -> Printf.sprintf " names %i" num
  61    | None, idents     -> Printf.sprintf " names %s" (pp_idents idents)
  62    | Some num, idents -> Printf.sprintf " names %i %s" num (pp_idents idents)
  63
  64 let terms_pp ~term_pp terms = String.concat ", " (List.map term_pp terms)
  65
  66 let rec pp_tactic ~term_pp ~lazy_term_pp =
  67   let pp_reduction_kind = pp_reduction_kind ~term_pp in
  68   let pp_tactic_pattern = pp_tactic_pattern ~lazy_term_pp ~term_pp in
  69   function
  70   | Absurd (_, term) -> "absurd" ^ term_pp term
  71   | Apply (_, term) -> "apply " ^ term_pp term
  72   | Auto _ -> "auto"
  73   | Assumption _ -> "assumption"
  74   | Change (_, where, with_what) ->
  75       sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
  76   | Clear (_,id) -> sprintf "clear %s" id
  77   | ClearBody (_,id) -> sprintf "clearbody %s" id
  78   | Compare (_,term) -> "compare " ^ term_pp term
  79   | Constructor (_,n) -> "constructor " ^ string_of_int n
  80   | Contradiction _ -> "contradiction"
  81   | Cut (_, ident, term) ->
  82      "cut " ^ term_pp term ^
  83       (match ident with None -> "" | Some id -> " as " ^ id)
  84   | DecideEquality _ -> "decide equality"
  85   | Decompose (_, [], what, names) ->
  86       sprintf "decompose %s%s" what (pp_intros_specs (None, names))
  87   | Decompose (_, types, what, names) ->
  88       let to_ident = function
  89          | Ident id -> id
  90          | Type _   -> assert false
  91       in
  92       let types = List.rev_map to_ident types in
  93       sprintf "decompose %s %s%s" (pp_idents types) what (pp_intros_specs (None, names))
  94   | Discriminate (_, term) -> "discriminate " ^ term_pp term
  95   | Elim (_, term, using, num, idents) ->
  96       sprintf "elim " ^ term_pp term ^
  97       (match using with None -> "" | Some term -> " using " ^ term_pp term)
  98       ^ pp_intros_specs (num, idents)
  99   | ElimType (_, term, using, num, idents) ->
 100       sprintf "elim type " ^ term_pp term ^
 101       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 102       ^ pp_intros_specs (num, idents)
 103   | Exact (_, term) -> "exact " ^ term_pp term
 104   | Exists _ -> "exists"
 105   | Fold (_, kind, term, pattern) ->
 106       sprintf "fold %s %s %s" (pp_reduction_kind kind)
 107        (lazy_term_pp term) (pp_tactic_pattern pattern)
 108   | FwdSimpl (_, hyp, idents) ->
 109       sprintf "fwd %s%s" hyp
 110         (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
 111   | Generalize (_, pattern, ident) ->
 112      sprintf "generalize %s%s" (pp_tactic_pattern pattern)
 113       (match ident with None -> "" | Some id -> " as " ^ id)
 114   | Goal (_, n) -> "goal " ^ string_of_int n
 115   | Fail _ -> "fail"
 116   | Fourier _ -> "fourier"
 117   | IdTac _ -> "id"
 118   | Injection (_, term) -> "injection " ^ term_pp term
 119   | Intros (_, None, []) -> "intro"
 120   | Intros (_, num, idents) ->
 121       sprintf "intros%s%s"
 122         (match num with None -> "" | Some num -> " " ^ string_of_int num)
 123         (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
 124   | LApply (_, level_opt, terms, term, ident_opt) ->
 125       sprintf "lapply %s%s%s%s"
 126         (match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")
 127         (term_pp term)
 128         (match terms with [] -> "" | _ -> " to " ^ terms_pp ~term_pp terms)
 129         (match ident_opt with None -> "" | Some ident -> " using " ^ ident)
 130   | Left _ -> "left"
 131   | LetIn (_, term, ident) -> sprintf "let %s in %s" (term_pp term) ident
 132   | Reduce (_, kind, pat) ->
 133       sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
 134   | Reflexivity _ -> "reflexivity"
 135   | Replace (_, pattern, t) ->
 136       sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
 137   | Rewrite (_, pos, t, pattern) ->
 138       sprintf "rewrite %s %s %s"
 139         (if pos = `LeftToRight then ">" else "<")
 140         (term_pp t)
 141         (pp_tactic_pattern pattern)
 142   | Right _ -> "right"
 143   | Ring _ -> "ring"
 144   | Split _ -> "split"
 145   | Symmetry _ -> "symmetry"
 146   | Transitivity (_, term) -> "transitivity " ^ term_pp term
 147
 148 let pp_search_kind = function
 149   | `Locate -> "locate"
 150   | `Hint -> "hint"
 151   | `Match -> "match"
 152   | `Elim -> "elim"
 153   | `Instance -> "instance"
 154
 155 let pp_macro ~term_pp = function
 156   (* Whelp *)
 157   | WInstance (_, term) -> "whelp instance " ^ term_pp term
 158   | WHint (_, t) -> "whelp hint " ^ term_pp t
 159   | WLocate (_, s) -> "whelp locate " ^ s
 160   | WElim (_, t) -> "whelp elim " ^ term_pp t
 161   | WMatch (_, term) -> "whelp match " ^ term_pp term
 162   (* real macros *)
 163   | Check (_, term) -> sprintf "Check %s" (term_pp term)
 164   | Hint _ -> "hint"
 165   | Search_pat (_, kind, pat) ->
 166       sprintf "search %s \"%s\"" (pp_search_kind kind) pat
 167   | Search_term (_, kind, term) ->
 168       sprintf "search %s %s" (pp_search_kind kind) (term_pp term)
 169   | Print (_, name) -> sprintf "Print \"%s\"" name
 170   | Quit _ -> "Quit"
 171
 172 let pp_alias = function
 173   | Ident_alias (id, uri) -> sprintf "alias id \"%s\" = \"%s\"" id uri
 174   | Symbol_alias (symb, instance, desc) ->
 175       sprintf "alias symbol \"%s\" (instance %d) = \"%s\""
 176         symb instance desc
 177   | Number_alias (instance,desc) ->
 178       sprintf "alias num (instance %d) = \"%s\"" instance desc
 179
 180 let pp_argument_pattern = function
 181   | CicNotationPt.IdentArg (eta_depth, name) ->
 182       let eta_buf = Buffer.create 5 in
 183       for i = 1 to eta_depth do
 184         Buffer.add_string eta_buf "\\eta."
 185       done;
 186       sprintf "%s%s" (Buffer.contents eta_buf) name
 187
 188 let pp_l1_pattern = CicNotationPp.pp_term
 189 let pp_l2_pattern = CicNotationPp.pp_term
 190
 191 let pp_associativity = function
 192   | Gramext.LeftA -> "left associative"
 193   | Gramext.RightA -> "right associative"
 194   | Gramext.NonA -> "non associative"
 195
 196 let pp_precedence i = sprintf "with precedence %d" i
 197
 198 let pp_dir_opt = function
 199   | None -> ""
 200   | Some `LeftToRight -> "> "
 201   | Some `RightToLeft -> "< "
 202
 203 let pp_interpretation dsc symbol arg_patterns cic_appl_pattern =
 204   sprintf "interpretation \"%s\" '%s %s = %s"
 205     dsc symbol
 206     (String.concat " " (List.map pp_argument_pattern arg_patterns))
 207     (CicNotationPp.pp_cic_appl_pattern cic_appl_pattern)
 208
 209 let pp_default what uris =
 210   sprintf "default \"%s\" %s" what
 211     (String.concat " " (List.map UriManager.string_of_uri uris))
 212
 213 let pp_notation dir_opt l1_pattern assoc prec l2_pattern =
 214   sprintf "notation %s\"%s\" %s %s for %s"
 215     (pp_dir_opt dir_opt)
 216     (pp_l1_pattern l1_pattern)
 217     (pp_associativity assoc)
 218     (pp_precedence prec)
 219     (pp_l2_pattern l2_pattern)
 220
 221 let pp_coercion uri do_composites =
 222    sprintf "coercion %s (* %s *)" (UriManager.string_of_uri uri)
 223      (if do_composites then "compounds" else "no compounds")
 224
 225 let pp_command ~obj_pp = function
 226   | Include (_,path) -> "include " ^ path
 227   | Qed _ -> "qed"
 228   | Drop _ -> "drop"
 229   | Set (_, name, value) -> sprintf "set \"%s\" \"%s\"" name value
 230   | Coercion (_, uri, do_composites) -> pp_coercion uri do_composites
 231   | Alias (_,s) -> pp_alias s
 232   | Obj (_,obj) -> obj_pp obj
 233   | Default (_,what,uris) ->
 234       pp_default what uris
 235   | Interpretation (_, dsc, (symbol, arg_patterns), cic_appl_pattern) ->
 236       pp_interpretation dsc symbol arg_patterns cic_appl_pattern
 237   | Notation (_, dir_opt, l1_pattern, assoc, prec, l2_pattern) ->
 238       pp_notation dir_opt l1_pattern assoc prec l2_pattern
 239   | Render _
 240   | Dump _ -> assert false  (* ZACK: debugging *)
 241
 242 let rec pp_tactical ~term_pp ~lazy_term_pp =
 243   let pp_tactic = pp_tactic ~lazy_term_pp ~term_pp in
 244   let pp_tacticals = pp_tacticals ~lazy_term_pp ~term_pp in
 245   function
 246   | Tactic (_, tac) -> pp_tactic tac
 247   | Do (_, count, tac) ->
 248       sprintf "do %d %s" count (pp_tactical ~term_pp ~lazy_term_pp tac)
 249   | Repeat (_, tac) -> "repeat " ^ pp_tactical ~term_pp ~lazy_term_pp tac
 250   | Seq (_, tacs) -> pp_tacticals ~sep:"; " tacs
 251   | Then (_, tac, tacs) ->
 252       sprintf "%s; [%s]" (pp_tactical ~term_pp ~lazy_term_pp tac)
 253         (pp_tacticals ~sep:" | " tacs)
 254   | First (_, tacs) -> sprintf "tries [%s]" (pp_tacticals ~sep:" | " tacs)
 255   | Try (_, tac) -> "try " ^ pp_tactical ~term_pp ~lazy_term_pp tac
 256   | Solve (_, tac) -> sprintf "solve [%s]" (pp_tacticals ~sep:" | " tac)
 257
 258   | Dot _ -> "."
 259   | Semicolon _ -> ";"
 260   | Branch _ -> "["
 261   | Shift _ -> "|"
 262   | Pos (_, i) -> sprintf "%d:" i
 263   | Merge _ -> "]"
 264   | Focus (_, goals) ->
 265       sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
 266   | Unfocus _ -> "unfocus"
 267   | Skip _ -> "skip"
 268
 269 and pp_tacticals ~term_pp ~lazy_term_pp ~sep tacs =
 270   String.concat sep (List.map (pp_tactical~lazy_term_pp ~term_pp) tacs)
 271
 272 let pp_executable ~term_pp ~lazy_term_pp ~obj_pp =
 273   function
 274   | Macro (_, macro) -> pp_macro ~term_pp macro
 275   | Tactical (_, tac, Some punct) ->
 276       pp_tactical ~lazy_term_pp ~term_pp tac
 277       ^ pp_tactical ~lazy_term_pp ~term_pp punct
 278   | Tactical (_, tac, None) -> pp_tactical ~lazy_term_pp ~term_pp tac
 279   | Command (_, cmd) -> pp_command ~obj_pp cmd
 280
 281 let pp_comment ~term_pp ~lazy_term_pp ~obj_pp =
 282   function
 283   | Note (_,str) -> sprintf "(* %s *)" str
 284   | Code (_,code) ->
 285       sprintf "(** %s. **)" (pp_executable ~term_pp ~lazy_term_pp ~obj_pp code)
 286
 287 let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
 288   function
 289   | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex
 290   | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c
 291
 292 let pp_dependency = function
 293   | IncludeDep str -> "include \"" ^ str ^ "\""
 294   | BaseuriDep str -> "set \"baseuri\" \"" ^ str ^ "\""
 295   | UriDep uri -> "uri \"" ^ UriManager.string_of_uri uri ^ "\""
 296