helm/ocaml/grafite2/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 exception Drop
  27 exception IncludedFileNotCompiled of string (* file name *)
  28 exception MetadataNotFound of string        (* file name *)
  29
  30 type options = {
  31   do_heavy_checks: bool ;
  32   clean_baseuri: bool
  33 }
  34
  35 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  36   * names as long as they are available, then it fallbacks to name generation
  37   * using FreshNamesGenerator module *)
  38 let namer_of names =
  39   let len = List.length names in
  40   let count = ref 0 in
  41   fun metasenv context name ~typ ->
  42     if !count < len then begin
  43       let name = Cic.Name (List.nth names !count) in
  44       incr count;
  45       name
  46     end else
  47       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  48
  49 let tactic_of_ast ast =
  50   let module PET = ProofEngineTypes in
  51   match ast with
  52   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  53   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  54   | GrafiteAst.Assumption _ -> Tactics.assumption
  55   | GrafiteAst.Auto (_,depth,width,paramodulation,full) ->
  56       AutoTactic.auto_tac ?depth ?width ?paramodulation ?full
  57         ~dbd:(LibraryDb.instance ()) ()
  58   | GrafiteAst.Change (_, pattern, with_what) ->
  59      Tactics.change ~pattern with_what
  60   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  61   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  62   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  63   | GrafiteAst.Compare (_, term) -> Tactics.compare term
  64   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  65   | GrafiteAst.Cut (_, ident, term) ->
  66      let names = match ident with None -> [] | Some id -> [id] in
  67      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  68   | GrafiteAst.DecideEquality _ -> Tactics.decide_equality
  69   | GrafiteAst.Decompose (_, types, what, names) ->
  70       let to_type = function
  71          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  72          | GrafiteAst.Ident _            -> assert false
  73       in
  74       let user_types = List.rev_map to_type types in
  75       let dbd = LibraryDb.instance () in
  76       let mk_fresh_name_callback = namer_of names in
  77       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types what
  78   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  79   | GrafiteAst.Elim (_, what, using, depth, names) ->
  80       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  81         what
  82   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  83       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  84         what
  85   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  86   | GrafiteAst.Exists _ -> Tactics.exists
  87   | GrafiteAst.Fail _ -> Tactics.fail
  88   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  89       let reduction =
  90         match reduction_kind with
  91         | `Normalize ->
  92             PET.const_lazy_reduction
  93               (CicReduction.normalize ~delta:false ~subst:[])
  94         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
  95         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
  96         | `Unfold None ->
  97             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
  98         | `Unfold (Some lazy_term) ->
  99            (fun context metasenv ugraph ->
 100              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 101              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 102         | `Whd ->
 103             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 104       in
 105       Tactics.fold ~reduction ~term ~pattern
 106   | GrafiteAst.Fourier _ -> Tactics.fourier
 107   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 108      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 109       ~dbd:(LibraryDb.instance ()) hyp
 110   | GrafiteAst.Generalize (_,pattern,ident) ->
 111      let names = match ident with None -> [] | Some id -> [id] in
 112      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 113   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 114   | GrafiteAst.IdTac _ -> Tactics.id
 115   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 116   | GrafiteAst.Intros (_, None, names) ->
 117       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 118   | GrafiteAst.Intros (_, Some num, names) ->
 119       PrimitiveTactics.intros_tac ~howmany:num
 120         ~mk_fresh_name_callback:(namer_of names) ()
 121   | GrafiteAst.LApply (_, how_many, to_what, what, ident) ->
 122       let names = match ident with None -> [] | Some id -> [id] in
 123       Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many
 124         ~to_what what
 125   | GrafiteAst.Left _ -> Tactics.left
 126   | GrafiteAst.LetIn (loc,term,name) ->
 127       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 128   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 129       (match reduction_kind with
 130       | `Normalize -> Tactics.normalize ~pattern
 131       | `Reduce -> Tactics.reduce ~pattern
 132       | `Simpl -> Tactics.simpl ~pattern
 133       | `Unfold what -> Tactics.unfold ~pattern what
 134       | `Whd -> Tactics.whd ~pattern)
 135   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 136   | GrafiteAst.Replace (_, pattern, with_what) ->
 137      Tactics.replace ~pattern ~with_what
 138   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 139      EqualityTactics.rewrite_tac ~direction ~pattern t
 140   | GrafiteAst.Right _ -> Tactics.right
 141   | GrafiteAst.Ring _ -> Tactics.ring
 142   | GrafiteAst.Split _ -> Tactics.split
 143   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 144   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 145
 146 (* maybe we only need special cases for apply and goal *)
 147 let classify_tactic tactic =
 148   match tactic with
 149   (* tactics that can't close the goal (return a goal we want to "select") *)
 150   | GrafiteAst.Rewrite _
 151   | GrafiteAst.Split _
 152   | GrafiteAst.Replace _
 153   | GrafiteAst.Reduce _
 154   | GrafiteAst.Injection _
 155   | GrafiteAst.IdTac _
 156   | GrafiteAst.Generalize _
 157   | GrafiteAst.Elim _
 158   | GrafiteAst.Cut _
 159   | GrafiteAst.Decompose _ -> true, true
 160   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 161   | GrafiteAst.Goal _ -> false, true
 162   (* tactics like apply *)
 163   | _ -> true, false
 164
 165 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 166   let module PEH = ProofEngineHelpers in
 167 (*   let print_m name metasenv =
 168     prerr_endline (">>>>> " ^ name);
 169     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 170   in *)
 171   (* phase one calculates:
 172    *   new_goals_from_refine:  goals added by refine
 173    *   head_goal:              the first goal opened by ythe tactic
 174    *   other_goals:            other goals opened by the tactic
 175    *)
 176   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 177   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 178   let head_goal, other_goals, goals =
 179     match goals with
 180     | [] -> None,[],goals
 181     | hd::tl ->
 182         (* assert (List.mem hd new_goals_from_tactic);
 183          * invalidato dalla goal_tac
 184          * *)
 185         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 186         hd) goals
 187   in
 188   let produced_goals =
 189     match head_goal with
 190     | None -> new_goals_from_refine @ other_goals
 191     | Some x -> x :: new_goals_from_refine @ other_goals
 192   in
 193   (* extract the metas generated by refine and tactic *)
 194   let metas_for_tactic_head =
 195     match head_goal with
 196     | None -> []
 197     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 198   let metas_for_tactic_goals =
 199     List.map
 200       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 201     goals
 202   in
 203   let metas_for_refine_goals =
 204     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 205   let produced_metas, goals =
 206     let produced_metas =
 207       if always_opens_a_goal then
 208         metas_for_tactic_head @ metas_for_refine_goals @
 209           metas_for_tactic_goals
 210       else begin
 211 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 212         print_m "metas_for_tactic_head" metas_for_tactic_head;
 213         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 214         metas_for_refine_goals @ metas_for_tactic_head @
 215           metas_for_tactic_goals
 216       end
 217     in
 218     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 219     produced_metas, goals
 220   in
 221   (* residual metas, preserving the original order *)
 222   let before, after =
 223     let rec split e =
 224       function
 225       | [] -> [],[]
 226       | (metano, _, _) :: tl when metano = e ->
 227           [], List.map (fun (x,_,_) -> x) tl
 228       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 229     in
 230     let find n metasenv =
 231       try
 232         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 233       with Not_found -> None
 234     in
 235     let extract l =
 236       List.fold_right
 237         (fun n acc ->
 238           match find n tactic with
 239           | Some x -> x::acc
 240           | None -> acc
 241         ) l [] in
 242     let before_l, after_l = split current_goal start in
 243     let before_l =
 244       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 245     let after_l =
 246       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 247     let before = extract before_l in
 248     let after = extract after_l in
 249       before, after
 250   in
 251 (* |+   DEBUG CODE  +|
 252   print_m "BEGIN" start;
 253   prerr_endline ("goal was: " ^ string_of_int current_goal);
 254   prerr_endline ("and metas from refine are:");
 255   List.iter
 256     (fun t -> prerr_string (" " ^ string_of_int t))
 257   new_goals_from_refine;
 258   prerr_endline "";
 259   print_m "before" before;
 260   print_m "metas_for_tactic_head" metas_for_tactic_head;
 261   print_m "metas_for_refine_goals" metas_for_refine_goals;
 262   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 263   print_m "produced_metas" produced_metas;
 264   print_m "after" after;
 265 |+   FINE DEBUG CODE +| *)
 266   before @ produced_metas @ after, goals
 267
 268 let apply_tactic ~disambiguate_tactic tactic (status, goal) =
 269 (* prerr_endline "apply_tactic"; *)
 270 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 271  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 272  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 273 (* prerr_endline "disambiguate"; *)
 274  let status_ref, tactic = disambiguate_tactic status goal tactic in
 275  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv !status_ref in
 276  let proof = GrafiteTypes.get_current_proof !status_ref in
 277  let proof_status = proof, goal in
 278  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 279  let tactic = tactic_of_ast tactic in
 280  (* apply tactic will change the status pointed by status_ref ... *)
 281 (* prerr_endline "apply_tactic bassa"; *)
 282  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 283  let after = ProofEngineTypes.goals_of_proof proof in
 284  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 285 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 286 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 287 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 288 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 289 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 290  let proof, opened_goals =
 291    if needs_reordering then begin
 292      let uri, metasenv_after_tactic, t, ty = proof in
 293 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 294      let reordered_metasenv, opened_goals =
 295        reorder_metasenv
 296         starting_metasenv
 297         metasenv_after_refinement metasenv_after_tactic
 298         opened goal always_opens_a_goal
 299      in
 300      let proof' = uri, reordered_metasenv, t, ty in
 301 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 302      proof', opened_goals
 303    end
 304       else
 305         proof, opened_goals
 306  in
 307  let incomplete_proof =
 308    match !status_ref.GrafiteTypes.proof_status with
 309    | GrafiteTypes.Incomplete_proof p -> p
 310    | _ -> assert false
 311  in
 312  { !status_ref with GrafiteTypes.proof_status =
 313     GrafiteTypes.Incomplete_proof
 314      { incomplete_proof with GrafiteTypes.proof = proof } },
 315  opened_goals, closed_goals
 316
 317 type eval_ast =
 318  {ea_go:
 319   'term 'lazy_term 'reduction 'obj 'ident.
 320   baseuri_of_script:(string -> string) ->
 321   disambiguate_tactic:
 322    (GrafiteTypes.status ->
 323     ProofEngineTypes.goal ->
 324     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 325    GrafiteTypes.status ref *
 326     (Cic.term, ProofEngineTypes.lazy_term, ProofEngineTypes.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 327
 328   disambiguate_command:
 329    (GrafiteTypes.status ->
 330     ('term, 'obj) GrafiteAst.command ->
 331     GrafiteTypes.status * (Cic.term, Cic.obj) GrafiteAst.command) ->
 332
 333   ?do_heavy_checks:bool ->
 334   ?clean_baseuri:bool ->
 335   GrafiteTypes.status ->
 336   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement ->
 337   GrafiteTypes.status
 338  }
 339
 340 type 'a eval_command =
 341  {ec_go: 'term 'obj.
 342   baseuri_of_script:(string -> string) ->
 343   disambiguate_command:
 344    (GrafiteTypes.status ->
 345     ('term,'obj) GrafiteAst.command ->
 346     GrafiteTypes.status * (Cic.term, Cic.obj) GrafiteAst.command) ->
 347   options -> GrafiteTypes.status -> ('term,'obj) GrafiteAst.command ->
 348    GrafiteTypes.status
 349  }
 350
 351 type 'a eval_executable =
 352  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 353   baseuri_of_script:(string -> string) ->
 354   disambiguate_tactic:
 355    (GrafiteTypes.status ->
 356     ProofEngineTypes.goal ->
 357     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 358    GrafiteTypes.status ref *
 359     (Cic.term, ProofEngineTypes.lazy_term, ProofEngineTypes.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 360
 361   disambiguate_command:
 362    (GrafiteTypes.status ->
 363     ('term, 'obj) GrafiteAst.command ->
 364     GrafiteTypes.status * (Cic.term, Cic.obj) GrafiteAst.command) ->
 365
 366   options ->
 367   GrafiteTypes.status ->
 368   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code -> GrafiteTypes.status
 369  }
 370
 371 type 'a eval_from_moo = { efm_go: GrafiteTypes.status ref -> string -> unit }
 372
 373 let eval_coercion status ~add_composites coercion =
 374  let uri = CicUtil.uri_of_term coercion in
 375  let status = MatitaSync.add_coercion status ~add_composites uri in
 376   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof}
 377
 378 let eval_tactical ~disambiguate_tactic status tac =
 379  let apply_tactic = apply_tactic ~disambiguate_tactic in
 380  let module MatitaStatus =
 381   struct
 382    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 383
 384    type output_status =
 385      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 386
 387    type tactic = input_status -> output_status
 388
 389    let id_tactic = apply_tactic (GrafiteAst.IdTac DisambiguateTypes.dummy_floc)
 390    let mk_tactic tac = tac
 391    let apply_tactic tac = tac
 392    let goals (_, opened, closed) = opened, closed
 393    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 394    let get_stack (status, _) = GrafiteTypes.get_stack status
 395
 396    let set_stack stack (status, opened, closed) =
 397      GrafiteTypes.set_stack stack status, opened, closed
 398
 399    let inject (status, _) = (status, [], [])
 400    let focus goal (status, _, _) = (status, goal)
 401   end
 402  in
 403  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 404   let rec tactical_of_ast l tac =
 405     match tac with
 406     | GrafiteAst.Tactic (loc, tactic) ->
 407         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 408     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 409        assert (l > 0);
 410        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 411     | GrafiteAst.Do (loc, n, tactical) ->
 412         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 413     | GrafiteAst.Repeat (loc, tactical) ->
 414         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 415     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 416         assert (l > 0);
 417         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 418           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 419     | GrafiteAst.First (loc, tacticals) ->
 420         MatitaTacticals.first
 421           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 422     | GrafiteAst.Try (loc, tactical) ->
 423         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 424     | GrafiteAst.Solve (loc, tacticals) ->
 425         MatitaTacticals.solve_tactics
 426          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 427
 428     | GrafiteAst.Skip loc -> MatitaTacticals.skip
 429     | GrafiteAst.Dot loc -> MatitaTacticals.dot
 430     | GrafiteAst.Semicolon loc -> MatitaTacticals.semicolon
 431     | GrafiteAst.Branch loc -> MatitaTacticals.branch
 432     | GrafiteAst.Shift loc -> MatitaTacticals.shift
 433     | GrafiteAst.Pos (loc, i) -> MatitaTacticals.pos i
 434     | GrafiteAst.Merge loc -> MatitaTacticals.merge
 435     | GrafiteAst.Focus (loc, goals) -> MatitaTacticals.focus goals
 436     | GrafiteAst.Unfocus loc -> MatitaTacticals.unfocus
 437   in
 438   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 439   let status =  (* is proof completed? *)
 440     match status.GrafiteTypes.proof_status with
 441     | GrafiteTypes.Incomplete_proof
 442        { GrafiteTypes.stack = stack; proof = proof }
 443       when Continuationals.Stack.is_empty stack ->
 444         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 445     | _ -> status
 446   in
 447   status
 448
 449 let eval_comment status c = status
 450
 451 let rec eval_command = {ec_go = fun ~baseuri_of_script ~disambiguate_command opts status cmd ->
 452   let status,cmd = disambiguate_command status cmd in
 453   let cmd,notation_ids' = CicNotation.process_notation cmd in
 454   let status =
 455     { status with
 456        GrafiteTypes.notation_ids =
 457         notation_ids' @ status.GrafiteTypes.notation_ids } in
 458   let basedir = Helm_registry.get "matita.basedir" in
 459   match cmd with
 460   | GrafiteAst.Default (loc, what, uris) as cmd ->
 461      LibraryObjects.set_default what uris;
 462      GrafiteTypes.add_moo_content [cmd] status
 463   | GrafiteAst.Include (loc, path) ->
 464      let baseuri = baseuri_of_script path in
 465      let moopath = LibraryMisc.obj_file_of_baseuri ~basedir ~baseuri in
 466      let metadatapath= LibraryMisc.metadata_file_of_baseuri ~basedir ~baseuri in
 467      if not (Sys.file_exists moopath) then
 468        raise (IncludedFileNotCompiled moopath);
 469      let status =
 470        if Helm_registry.get_bool "db.nodb" then
 471          if not (Sys.file_exists metadatapath) then
 472            raise (MetadataNotFound metadatapath)
 473          else
 474            GrafiteTypes.add_metadata
 475              (LibraryNoDb.load_metadata ~fname:metadatapath) status
 476        else
 477          status
 478      in
 479      let status = ref status in
 480      eval_from_moo.efm_go status moopath;
 481      !status
 482   | GrafiteAst.Set (loc, name, value) ->
 483       let status =
 484         if name = "baseuri" then begin
 485           let value =
 486             let v = Http_getter_misc.strip_trailing_slash value in
 487             try
 488               ignore (String.index v ' ');
 489               raise (GrafiteTypes.Command_error "baseuri can't contain spaces")
 490             with Not_found -> v
 491           in
 492           if not (GrafiteMisc.is_empty value) && opts.clean_baseuri then begin
 493             HLog.warn ("baseuri " ^ value ^ " is not empty");
 494             HLog.message ("cleaning baseuri " ^ value);
 495             LibraryClean.clean_baseuris ~basedir [value]
 496           end;
 497           GrafiteTypes.add_metadata [LibraryNoDb.Baseuri value] status
 498         end else
 499           status
 500       in
 501       GrafiteTypes.set_option status name value
 502   | GrafiteAst.Drop loc -> raise Drop
 503   | GrafiteAst.Qed loc ->
 504       let uri, metasenv, bo, ty =
 505         match status.GrafiteTypes.proof_status with
 506         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 507             uri, metasenv, body, ty
 508         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 509             raise (GrafiteTypes.Command_error
 510               ("Someone allows to start a theorem without giving the "^
 511                "name/uri. This should be fixed!"))
 512         | _->
 513           raise
 514            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 515       in
 516       if metasenv <> [] then
 517         raise
 518          (GrafiteTypes.Command_error
 519            "Proof not completed! metasenv is not empty!");
 520       let name = UriManager.name_of_uri uri in
 521       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 522       MatitaSync.add_obj uri obj
 523        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof}
 524   | GrafiteAst.Coercion (loc, coercion, add_composites) ->
 525      eval_coercion status ~add_composites coercion
 526   | GrafiteAst.Alias (loc, spec) ->
 527      let diff =
 528       (*CSC: Warning: this code should be factorized with the corresponding
 529              code in DisambiguatePp *)
 530       match spec with
 531       | GrafiteAst.Ident_alias (id,uri) ->
 532          [DisambiguateTypes.Id id,
 533           (uri,(fun _ _ _-> CicUtil.term_of_uri(UriManager.uri_of_string uri)))]
 534       | GrafiteAst.Symbol_alias (symb, instance, desc) ->
 535          [DisambiguateTypes.Symbol (symb,instance),
 536           DisambiguateChoices.lookup_symbol_by_dsc symb desc]
 537       | GrafiteAst.Number_alias (instance,desc) ->
 538          [DisambiguateTypes.Num instance,
 539           DisambiguateChoices.lookup_num_by_dsc desc]
 540      in
 541       MatitaSync.set_proof_aliases status diff
 542   | GrafiteAst.Render _ -> assert false (* ZACK: to be removed *)
 543   | GrafiteAst.Dump _ -> assert false   (* ZACK: to be removed *)
 544   | GrafiteAst.Interpretation (_, dsc, (symbol, _), cic_appl_pattern) as stm ->
 545       let status = GrafiteTypes.add_moo_content [stm] status in
 546       let uris =
 547         List.map
 548           (fun uri -> LibraryNoDb.Dependency (UriManager.buri_of_uri uri))
 549           (CicNotationUtil.find_appl_pattern_uris cic_appl_pattern)
 550       in
 551       let diff =
 552        [DisambiguateTypes.Symbol (symbol, 0),
 553          DisambiguateChoices.lookup_symbol_by_dsc symbol dsc]
 554       in
 555       let status = MatitaSync.set_proof_aliases status diff in
 556       let status = GrafiteTypes.add_metadata uris status in
 557       status
 558   | GrafiteAst.Notation _ as stm -> GrafiteTypes.add_moo_content [stm] status
 559   | GrafiteAst.Obj (loc,obj) ->
 560      let ext,name =
 561       match obj with
 562          Cic.Constant (name,_,_,_,_)
 563        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 564        | Cic.InductiveDefinition (types,_,_,_) ->
 565           ".ind",
 566           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 567        | _ -> assert false in
 568      let uri =
 569        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext)
 570      in
 571      let metasenv = GrafiteTypes.get_proof_metasenv status in
 572      match obj with
 573      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 574          let name = UriManager.name_of_uri uri in
 575          if not(CicPp.check name ty) then
 576            HLog.error ("Bad name: " ^ name);
 577          if opts.do_heavy_checks then
 578            begin
 579              let dbd = LibraryDb.instance () in
 580              let similar = Whelp.match_term ~dbd ty in
 581              let similar_len = List.length similar in
 582              if similar_len> 30 then
 583                (HLog.message
 584                  ("Duplicate check will compare your theorem with " ^
 585                    string_of_int similar_len ^
 586                    " theorems, this may take a while."));
 587              let convertible =
 588                List.filter (
 589                  fun u ->
 590                    let t = CicUtil.term_of_uri u in
 591                    let ty',g =
 592                      CicTypeChecker.type_of_aux'
 593                        metasenv' [] t CicUniv.empty_ugraph
 594                    in
 595                    fst(CicReduction.are_convertible [] ty' ty g))
 596                similar
 597              in
 598              (match convertible with
 599              | [] -> ()
 600              | x::_ ->
 601                  HLog.warn
 602                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 603                   "\nPlease use a variant."));
 604            end;
 605          assert (metasenv = metasenv');
 606          let goalno =
 607            match metasenv' with (goalno,_,_)::_ -> goalno | _ -> assert false
 608          in
 609          let initial_proof = (Some uri, metasenv, bo, ty) in
 610          let initial_stack = Continuationals.Stack.of_metasenv metasenv in
 611          { status with GrafiteTypes.proof_status =
 612             GrafiteTypes.Incomplete_proof
 613              { GrafiteTypes.proof = initial_proof; stack = initial_stack } }
 614      | _ ->
 615          if metasenv <> [] then
 616           raise (GrafiteTypes.Command_error (
 617             "metasenv not empty while giving a definition with body: " ^
 618             CicMetaSubst.ppmetasenv [] metasenv));
 619          MatitaSync.add_obj uri obj
 620           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof}
 621
 622 } and eval_executable = {ee_go = fun ~baseuri_of_script ~disambiguate_tactic ~disambiguate_command opts status ex ->
 623   match ex with
 624   | GrafiteAst.Tactical (_, tac, None) ->
 625      eval_tactical ~disambiguate_tactic status tac
 626   | GrafiteAst.Tactical (_, tac, Some punct) ->
 627      let status = eval_tactical ~disambiguate_tactic status tac in
 628       eval_tactical ~disambiguate_tactic status punct
 629   | GrafiteAst.Command (_, cmd) ->
 630       eval_command.ec_go ~baseuri_of_script ~disambiguate_command
 631        opts status cmd
 632   | GrafiteAst.Macro (_, mac) ->
 633 (*CSC: DA RIPRISTINARE CON UN TIPO DIVERSO
 634       raise (Command_error
 635        (Printf.sprintf "The macro %s can't be in a script"
 636         (GrafiteAstPp.pp_macro_ast mac)))
 637 *) assert false
 638
 639 } and eval_from_moo = {efm_go = fun status fname ->
 640   let ast_of_cmd cmd =
 641     GrafiteAst.Executable (DisambiguateTypes.dummy_floc,
 642       GrafiteAst.Command (DisambiguateTypes.dummy_floc,
 643         cmd))
 644   in
 645   let moo = GrafiteMarshal.load_moo fname in
 646   List.iter
 647     (fun ast ->
 648       let ast = ast_of_cmd ast in
 649       status :=
 650         eval_ast.ea_go
 651          ~baseuri_of_script:(fun _ -> assert false)
 652          ~disambiguate_tactic:(fun status _ tactic -> ref status,tactic)
 653          ~disambiguate_command:(fun status cmd -> status,cmd)
 654          !status ast)
 655     moo
 656 } and eval_ast = {ea_go = fun ~baseuri_of_script ~disambiguate_tactic
 657  ~disambiguate_command ?(do_heavy_checks=false) ?(clean_baseuri=true) status
 658  st
 659 ->
 660   let opts = {
 661     do_heavy_checks = do_heavy_checks ;
 662     clean_baseuri = clean_baseuri }
 663   in
 664   match st with
 665   | GrafiteAst.Executable (_,ex) ->
 666      eval_executable.ee_go ~baseuri_of_script ~disambiguate_tactic
 667       ~disambiguate_command opts status ex
 668   | GrafiteAst.Comment (_,c) -> eval_comment status c
 669 }
 670
 671 let eval_ast = eval_ast.ea_go