helm/ocaml/grafite2/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 exception Drop
  27 exception UnableToInclude of string
  28 exception IncludedFileNotCompiled of string (* file name *)
  29 exception MetadataNotFound of string        (* file name *)
  30
  31 type options = {
  32   do_heavy_checks: bool ;
  33   include_paths: string list ;
  34   clean_baseuri: bool
  35 }
  36
  37 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  38   * names as long as they are available, then it fallbacks to name generation
  39   * using FreshNamesGenerator module *)
  40 let namer_of names =
  41   let len = List.length names in
  42   let count = ref 0 in
  43   fun metasenv context name ~typ ->
  44     if !count < len then begin
  45       let name = Cic.Name (List.nth names !count) in
  46       incr count;
  47       name
  48     end else
  49       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  50
  51 let tactic_of_ast ast =
  52   let module PET = ProofEngineTypes in
  53   match ast with
  54   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  55   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  56   | GrafiteAst.Assumption _ -> Tactics.assumption
  57   | GrafiteAst.Auto (_,depth,width,paramodulation,full) ->
  58       AutoTactic.auto_tac ?depth ?width ?paramodulation ?full
  59         ~dbd:(LibraryDb.instance ()) ()
  60   | GrafiteAst.Change (_, pattern, with_what) ->
  61      Tactics.change ~pattern with_what
  62   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  63   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  64   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  65   | GrafiteAst.Compare (_, term) -> Tactics.compare term
  66   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  67   | GrafiteAst.Cut (_, ident, term) ->
  68      let names = match ident with None -> [] | Some id -> [id] in
  69      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  70   | GrafiteAst.DecideEquality _ -> Tactics.decide_equality
  71   | GrafiteAst.Decompose (_, types, what, names) ->
  72       let to_type = function
  73          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  74          | GrafiteAst.Ident _            -> assert false
  75       in
  76       let user_types = List.rev_map to_type types in
  77       let dbd = LibraryDb.instance () in
  78       let mk_fresh_name_callback = namer_of names in
  79       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types what
  80   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  81   | GrafiteAst.Elim (_, what, using, depth, names) ->
  82       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  83         what
  84   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  85       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  86         what
  87   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  88   | GrafiteAst.Exists _ -> Tactics.exists
  89   | GrafiteAst.Fail _ -> Tactics.fail
  90   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  91       let reduction =
  92         match reduction_kind with
  93         | `Normalize ->
  94             PET.const_lazy_reduction
  95               (CicReduction.normalize ~delta:false ~subst:[])
  96         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
  97         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
  98         | `Unfold None ->
  99             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 100         | `Unfold (Some lazy_term) ->
 101            (fun context metasenv ugraph ->
 102              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 103              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 104         | `Whd ->
 105             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 106       in
 107       Tactics.fold ~reduction ~term ~pattern
 108   | GrafiteAst.Fourier _ -> Tactics.fourier
 109   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 110      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 111       ~dbd:(LibraryDb.instance ()) hyp
 112   | GrafiteAst.Generalize (_,pattern,ident) ->
 113      let names = match ident with None -> [] | Some id -> [id] in
 114      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 115   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 116   | GrafiteAst.IdTac _ -> Tactics.id
 117   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 118   | GrafiteAst.Intros (_, None, names) ->
 119       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 120   | GrafiteAst.Intros (_, Some num, names) ->
 121       PrimitiveTactics.intros_tac ~howmany:num
 122         ~mk_fresh_name_callback:(namer_of names) ()
 123   | GrafiteAst.LApply (_, how_many, to_what, what, ident) ->
 124       let names = match ident with None -> [] | Some id -> [id] in
 125       Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many
 126         ~to_what what
 127   | GrafiteAst.Left _ -> Tactics.left
 128   | GrafiteAst.LetIn (loc,term,name) ->
 129       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 130   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 131       (match reduction_kind with
 132       | `Normalize -> Tactics.normalize ~pattern
 133       | `Reduce -> Tactics.reduce ~pattern
 134       | `Simpl -> Tactics.simpl ~pattern
 135       | `Unfold what -> Tactics.unfold ~pattern what
 136       | `Whd -> Tactics.whd ~pattern)
 137   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 138   | GrafiteAst.Replace (_, pattern, with_what) ->
 139      Tactics.replace ~pattern ~with_what
 140   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 141      EqualityTactics.rewrite_tac ~direction ~pattern t
 142   | GrafiteAst.Right _ -> Tactics.right
 143   | GrafiteAst.Ring _ -> Tactics.ring
 144   | GrafiteAst.Split _ -> Tactics.split
 145   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 146   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 147
 148 (* maybe we only need special cases for apply and goal *)
 149 let classify_tactic tactic =
 150   match tactic with
 151   (* tactics that can't close the goal (return a goal we want to "select") *)
 152   | GrafiteAst.Rewrite _
 153   | GrafiteAst.Split _
 154   | GrafiteAst.Replace _
 155   | GrafiteAst.Reduce _
 156   | GrafiteAst.Injection _
 157   | GrafiteAst.IdTac _
 158   | GrafiteAst.Generalize _
 159   | GrafiteAst.Elim _
 160   | GrafiteAst.Cut _
 161   | GrafiteAst.Decompose _ -> true, true
 162   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 163   | GrafiteAst.Goal _ -> false, true
 164   (* tactics like apply *)
 165   | _ -> true, false
 166
 167 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 168   let module PEH = ProofEngineHelpers in
 169 (*   let print_m name metasenv =
 170     prerr_endline (">>>>> " ^ name);
 171     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 172   in *)
 173   (* phase one calculates:
 174    *   new_goals_from_refine:  goals added by refine
 175    *   head_goal:              the first goal opened by ythe tactic
 176    *   other_goals:            other goals opened by the tactic
 177    *)
 178   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 179   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 180   let head_goal, other_goals, goals =
 181     match goals with
 182     | [] -> None,[],goals
 183     | hd::tl ->
 184         (* assert (List.mem hd new_goals_from_tactic);
 185          * invalidato dalla goal_tac
 186          * *)
 187         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 188         hd) goals
 189   in
 190   let produced_goals =
 191     match head_goal with
 192     | None -> new_goals_from_refine @ other_goals
 193     | Some x -> x :: new_goals_from_refine @ other_goals
 194   in
 195   (* extract the metas generated by refine and tactic *)
 196   let metas_for_tactic_head =
 197     match head_goal with
 198     | None -> []
 199     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 200   let metas_for_tactic_goals =
 201     List.map
 202       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 203     goals
 204   in
 205   let metas_for_refine_goals =
 206     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 207   let produced_metas, goals =
 208     let produced_metas =
 209       if always_opens_a_goal then
 210         metas_for_tactic_head @ metas_for_refine_goals @
 211           metas_for_tactic_goals
 212       else begin
 213 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 214         print_m "metas_for_tactic_head" metas_for_tactic_head;
 215         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 216         metas_for_refine_goals @ metas_for_tactic_head @
 217           metas_for_tactic_goals
 218       end
 219     in
 220     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 221     produced_metas, goals
 222   in
 223   (* residual metas, preserving the original order *)
 224   let before, after =
 225     let rec split e =
 226       function
 227       | [] -> [],[]
 228       | (metano, _, _) :: tl when metano = e ->
 229           [], List.map (fun (x,_,_) -> x) tl
 230       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 231     in
 232     let find n metasenv =
 233       try
 234         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 235       with Not_found -> None
 236     in
 237     let extract l =
 238       List.fold_right
 239         (fun n acc ->
 240           match find n tactic with
 241           | Some x -> x::acc
 242           | None -> acc
 243         ) l [] in
 244     let before_l, after_l = split current_goal start in
 245     let before_l =
 246       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 247     let after_l =
 248       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 249     let before = extract before_l in
 250     let after = extract after_l in
 251       before, after
 252   in
 253 (* |+   DEBUG CODE  +|
 254   print_m "BEGIN" start;
 255   prerr_endline ("goal was: " ^ string_of_int current_goal);
 256   prerr_endline ("and metas from refine are:");
 257   List.iter
 258     (fun t -> prerr_string (" " ^ string_of_int t))
 259   new_goals_from_refine;
 260   prerr_endline "";
 261   print_m "before" before;
 262   print_m "metas_for_tactic_head" metas_for_tactic_head;
 263   print_m "metas_for_refine_goals" metas_for_refine_goals;
 264   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 265   print_m "produced_metas" produced_metas;
 266   print_m "after" after;
 267 |+   FINE DEBUG CODE +| *)
 268   before @ produced_metas @ after, goals
 269
 270 let apply_tactic ~disambiguate_tactic tactic (status, goal) =
 271 (* prerr_endline "apply_tactic"; *)
 272 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 273  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 274  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 275 (* prerr_endline "disambiguate"; *)
 276  let status_ref, tactic = disambiguate_tactic status goal tactic in
 277  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv !status_ref in
 278  let proof = GrafiteTypes.get_current_proof !status_ref in
 279  let proof_status = proof, goal in
 280  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 281  let tactic = tactic_of_ast tactic in
 282  (* apply tactic will change the status pointed by status_ref ... *)
 283 (* prerr_endline "apply_tactic bassa"; *)
 284  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 285  let after = ProofEngineTypes.goals_of_proof proof in
 286  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 287 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 288 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 289 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 290 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 291 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 292  let proof, opened_goals =
 293    if needs_reordering then begin
 294      let uri, metasenv_after_tactic, t, ty = proof in
 295 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 296      let reordered_metasenv, opened_goals =
 297        reorder_metasenv
 298         starting_metasenv
 299         metasenv_after_refinement metasenv_after_tactic
 300         opened goal always_opens_a_goal
 301      in
 302      let proof' = uri, reordered_metasenv, t, ty in
 303 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 304      proof', opened_goals
 305    end
 306       else
 307         proof, opened_goals
 308  in
 309  let incomplete_proof =
 310    match !status_ref.GrafiteTypes.proof_status with
 311    | GrafiteTypes.Incomplete_proof p -> p
 312    | _ -> assert false
 313  in
 314  { !status_ref with GrafiteTypes.proof_status =
 315     GrafiteTypes.Incomplete_proof
 316      { incomplete_proof with GrafiteTypes.proof = proof } },
 317  opened_goals, closed_goals
 318
 319 type eval_ast =
 320  {ea_go:
 321   'term 'lazy_term 'reduction 'obj 'ident.
 322   disambiguate_tactic:
 323    (GrafiteTypes.status ->
 324     ProofEngineTypes.goal ->
 325     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 326    GrafiteTypes.status ref *
 327     (Cic.term, ProofEngineTypes.lazy_term, ProofEngineTypes.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 328
 329   disambiguate_command:
 330    (GrafiteTypes.status ->
 331     ('term, 'obj) GrafiteAst.command ->
 332     GrafiteTypes.status * (Cic.term, Cic.obj) GrafiteAst.command) ->
 333
 334   ?do_heavy_checks:bool ->
 335   ?include_paths:string list ->
 336   ?clean_baseuri:bool ->
 337   GrafiteTypes.status ->
 338   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement ->
 339   GrafiteTypes.status
 340  }
 341
 342 type 'a eval_command =
 343  {ec_go: 'term 'obj.
 344   disambiguate_command:
 345    (GrafiteTypes.status ->
 346     ('term,'obj) GrafiteAst.command ->
 347     GrafiteTypes.status * (Cic.term, Cic.obj) GrafiteAst.command) ->
 348   options -> GrafiteTypes.status -> ('term,'obj) GrafiteAst.command ->
 349    GrafiteTypes.status
 350  }
 351
 352 type 'a eval_executable =
 353  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 354   disambiguate_tactic:
 355    (GrafiteTypes.status ->
 356     ProofEngineTypes.goal ->
 357     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 358    GrafiteTypes.status ref *
 359     (Cic.term, ProofEngineTypes.lazy_term, ProofEngineTypes.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 360
 361   disambiguate_command:
 362    (GrafiteTypes.status ->
 363     ('term, 'obj) GrafiteAst.command ->
 364     GrafiteTypes.status * (Cic.term, Cic.obj) GrafiteAst.command) ->
 365
 366   options ->
 367   GrafiteTypes.status ->
 368   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code -> GrafiteTypes.status
 369  }
 370
 371 type 'a eval_from_moo = { efm_go: GrafiteTypes.status ref -> string -> unit }
 372
 373 let eval_coercion status ~add_composites coercion =
 374  let uri = CicUtil.uri_of_term coercion in
 375  let status = MatitaSync.add_coercion status ~add_composites uri in
 376   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof}
 377
 378 let eval_tactical ~disambiguate_tactic status tac =
 379  let apply_tactic = apply_tactic ~disambiguate_tactic in
 380  let module MatitaStatus =
 381   struct
 382    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 383
 384    type output_status =
 385      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 386
 387    type tactic = input_status -> output_status
 388
 389    let id_tactic = apply_tactic (GrafiteAst.IdTac DisambiguateTypes.dummy_floc)
 390    let mk_tactic tac = tac
 391    let apply_tactic tac = tac
 392    let goals (_, opened, closed) = opened, closed
 393    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 394    let get_stack (status, _) = GrafiteTypes.get_stack status
 395
 396    let set_stack stack (status, opened, closed) =
 397      GrafiteTypes.set_stack stack status, opened, closed
 398
 399    let inject (status, _) = (status, [], [])
 400    let focus goal (status, _, _) = (status, goal)
 401   end
 402  in
 403  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 404   let rec tactical_of_ast l tac =
 405     match tac with
 406     | GrafiteAst.Tactic (loc, tactic) ->
 407         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 408     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 409        assert (l > 0);
 410        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 411     | GrafiteAst.Do (loc, n, tactical) ->
 412         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 413     | GrafiteAst.Repeat (loc, tactical) ->
 414         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 415     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 416         assert (l > 0);
 417         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 418           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 419     | GrafiteAst.First (loc, tacticals) ->
 420         MatitaTacticals.first
 421           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 422     | GrafiteAst.Try (loc, tactical) ->
 423         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 424     | GrafiteAst.Solve (loc, tacticals) ->
 425         MatitaTacticals.solve_tactics
 426          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 427
 428     | GrafiteAst.Skip loc -> MatitaTacticals.skip
 429     | GrafiteAst.Dot loc -> MatitaTacticals.dot
 430     | GrafiteAst.Semicolon loc -> MatitaTacticals.semicolon
 431     | GrafiteAst.Branch loc -> MatitaTacticals.branch
 432     | GrafiteAst.Shift loc -> MatitaTacticals.shift
 433     | GrafiteAst.Pos (loc, i) -> MatitaTacticals.pos i
 434     | GrafiteAst.Merge loc -> MatitaTacticals.merge
 435     | GrafiteAst.Focus (loc, goals) -> MatitaTacticals.focus goals
 436     | GrafiteAst.Unfocus loc -> MatitaTacticals.unfocus
 437   in
 438   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 439   let status =  (* is proof completed? *)
 440     match status.GrafiteTypes.proof_status with
 441     | GrafiteTypes.Incomplete_proof
 442        { GrafiteTypes.stack = stack; proof = proof }
 443       when Continuationals.Stack.is_empty stack ->
 444         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 445     | _ -> status
 446   in
 447   status
 448
 449 let make_absolute paths path =
 450    let rec aux = function
 451    | [] -> ignore (Unix.stat path); path
 452    | p :: tl ->
 453       let path = p ^ "/" ^ path in
 454        try
 455          ignore (Unix.stat path); path
 456        with Unix.Unix_error _ -> aux tl
 457    in
 458    try
 459      aux paths
 460    with Unix.Unix_error _ -> raise (UnableToInclude path)
 461 ;;
 462
 463 let eval_comment status c = status
 464
 465 let rec eval_command = {ec_go = fun ~disambiguate_command opts status cmd ->
 466   let status,cmd = disambiguate_command status cmd in
 467   let cmd,notation_ids' = CicNotation.process_notation cmd in
 468   let status =
 469     { status with
 470        GrafiteTypes.notation_ids =
 471         notation_ids' @ status.GrafiteTypes.notation_ids } in
 472   let basedir = Helm_registry.get "matita.basedir" in
 473   match cmd with
 474   | GrafiteAst.Default (loc, what, uris) as cmd ->
 475      LibraryObjects.set_default what uris;
 476      GrafiteTypes.add_moo_content [cmd] status
 477   | GrafiteAst.Include (loc, path) ->
 478      let absolute_path = make_absolute opts.include_paths path in
 479      let moopath = GrafiteMisc.obj_file_of_script ~basedir absolute_path in
 480      let metadatapath =
 481        GrafiteMisc.metadata_file_of_script ~basedir absolute_path in
 482      if not (Sys.file_exists moopath) then
 483        raise (IncludedFileNotCompiled moopath);
 484      let status =
 485        if Helm_registry.get_bool "db.nodb" then
 486          if not (Sys.file_exists metadatapath) then
 487            raise (MetadataNotFound metadatapath)
 488          else
 489            GrafiteTypes.add_metadata
 490              (LibraryNoDb.load_metadata ~fname:metadatapath) status
 491        else
 492          status
 493      in
 494      let status = ref status in
 495      eval_from_moo.efm_go status moopath;
 496      !status
 497   | GrafiteAst.Set (loc, name, value) ->
 498       let status =
 499         if name = "baseuri" then begin
 500           let value =
 501             let v = Http_getter_misc.strip_trailing_slash value in
 502             try
 503               ignore (String.index v ' ');
 504               raise (GrafiteTypes.Command_error "baseuri can't contain spaces")
 505             with Not_found -> v
 506           in
 507           if not (GrafiteMisc.is_empty value) && opts.clean_baseuri then begin
 508             HLog.warn ("baseuri " ^ value ^ " is not empty");
 509             HLog.message ("cleaning baseuri " ^ value);
 510             LibraryClean.clean_baseuris ~basedir [value]
 511           end;
 512           GrafiteTypes.add_metadata [LibraryNoDb.Baseuri value] status
 513         end else
 514           status
 515       in
 516       GrafiteTypes.set_option status name value
 517   | GrafiteAst.Drop loc -> raise Drop
 518   | GrafiteAst.Qed loc ->
 519       let uri, metasenv, bo, ty =
 520         match status.GrafiteTypes.proof_status with
 521         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 522             uri, metasenv, body, ty
 523         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 524             raise (GrafiteTypes.Command_error
 525               ("Someone allows to start a theorem without giving the "^
 526                "name/uri. This should be fixed!"))
 527         | _->
 528           raise
 529            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 530       in
 531       if metasenv <> [] then
 532         raise
 533          (GrafiteTypes.Command_error
 534            "Proof not completed! metasenv is not empty!");
 535       let name = UriManager.name_of_uri uri in
 536       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 537       MatitaSync.add_obj uri obj
 538        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof}
 539   | GrafiteAst.Coercion (loc, coercion, add_composites) ->
 540      eval_coercion status ~add_composites coercion
 541   | GrafiteAst.Alias (loc, spec) ->
 542      let diff =
 543       (*CSC: Warning: this code should be factorized with the corresponding
 544              code in DisambiguatePp *)
 545       match spec with
 546       | GrafiteAst.Ident_alias (id,uri) ->
 547          [DisambiguateTypes.Id id,
 548           (uri,(fun _ _ _-> CicUtil.term_of_uri(UriManager.uri_of_string uri)))]
 549       | GrafiteAst.Symbol_alias (symb, instance, desc) ->
 550          [DisambiguateTypes.Symbol (symb,instance),
 551           DisambiguateChoices.lookup_symbol_by_dsc symb desc]
 552       | GrafiteAst.Number_alias (instance,desc) ->
 553          [DisambiguateTypes.Num instance,
 554           DisambiguateChoices.lookup_num_by_dsc desc]
 555      in
 556       MatitaSync.set_proof_aliases status diff
 557   | GrafiteAst.Render _ -> assert false (* ZACK: to be removed *)
 558   | GrafiteAst.Dump _ -> assert false   (* ZACK: to be removed *)
 559   | GrafiteAst.Interpretation (_, dsc, (symbol, _), cic_appl_pattern) as stm ->
 560       let status = GrafiteTypes.add_moo_content [stm] status in
 561       let uris =
 562         List.map
 563           (fun uri -> LibraryNoDb.Dependency (UriManager.buri_of_uri uri))
 564           (CicNotationUtil.find_appl_pattern_uris cic_appl_pattern)
 565       in
 566       let diff =
 567        [DisambiguateTypes.Symbol (symbol, 0),
 568          DisambiguateChoices.lookup_symbol_by_dsc symbol dsc]
 569       in
 570       let status = MatitaSync.set_proof_aliases status diff in
 571       let status = GrafiteTypes.add_metadata uris status in
 572       status
 573   | GrafiteAst.Notation _ as stm -> GrafiteTypes.add_moo_content [stm] status
 574   | GrafiteAst.Obj (loc,obj) ->
 575      let ext,name =
 576       match obj with
 577          Cic.Constant (name,_,_,_,_)
 578        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 579        | Cic.InductiveDefinition (types,_,_,_) ->
 580           ".ind",
 581           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 582        | _ -> assert false in
 583      let uri =
 584        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext)
 585      in
 586      let metasenv = GrafiteTypes.get_proof_metasenv status in
 587      match obj with
 588      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 589          let name = UriManager.name_of_uri uri in
 590          if not(CicPp.check name ty) then
 591            HLog.error ("Bad name: " ^ name);
 592          if opts.do_heavy_checks then
 593            begin
 594              let dbd = LibraryDb.instance () in
 595              let similar = Whelp.match_term ~dbd ty in
 596              let similar_len = List.length similar in
 597              if similar_len> 30 then
 598                (HLog.message
 599                  ("Duplicate check will compare your theorem with " ^
 600                    string_of_int similar_len ^
 601                    " theorems, this may take a while."));
 602              let convertible =
 603                List.filter (
 604                  fun u ->
 605                    let t = CicUtil.term_of_uri u in
 606                    let ty',g =
 607                      CicTypeChecker.type_of_aux'
 608                        metasenv' [] t CicUniv.empty_ugraph
 609                    in
 610                    fst(CicReduction.are_convertible [] ty' ty g))
 611                similar
 612              in
 613              (match convertible with
 614              | [] -> ()
 615              | x::_ ->
 616                  HLog.warn
 617                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 618                   "\nPlease use a variant."));
 619            end;
 620          assert (metasenv = metasenv');
 621          let goalno =
 622            match metasenv' with (goalno,_,_)::_ -> goalno | _ -> assert false
 623          in
 624          let initial_proof = (Some uri, metasenv, bo, ty) in
 625          let initial_stack = Continuationals.Stack.of_metasenv metasenv in
 626          { status with GrafiteTypes.proof_status =
 627             GrafiteTypes.Incomplete_proof
 628              { GrafiteTypes.proof = initial_proof; stack = initial_stack } }
 629      | _ ->
 630          if metasenv <> [] then
 631           raise (GrafiteTypes.Command_error (
 632             "metasenv not empty while giving a definition with body: " ^
 633             CicMetaSubst.ppmetasenv [] metasenv));
 634          MatitaSync.add_obj uri obj
 635           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof}
 636
 637 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command opts status ex ->
 638   match ex with
 639   | GrafiteAst.Tactical (_, tac, None) ->
 640      eval_tactical ~disambiguate_tactic status tac
 641   | GrafiteAst.Tactical (_, tac, Some punct) ->
 642      let status = eval_tactical ~disambiguate_tactic status tac in
 643       eval_tactical ~disambiguate_tactic status punct
 644   | GrafiteAst.Command (_, cmd) ->
 645       eval_command.ec_go ~disambiguate_command opts status cmd
 646   | GrafiteAst.Macro (_, mac) ->
 647 (*CSC: DA RIPRISTINARE CON UN TIPO DIVERSO
 648       raise (Command_error
 649        (Printf.sprintf "The macro %s can't be in a script"
 650         (GrafiteAstPp.pp_macro_ast mac)))
 651 *) assert false
 652
 653 } and eval_from_moo = {efm_go = fun status fname ->
 654   let ast_of_cmd cmd =
 655     GrafiteAst.Executable (DisambiguateTypes.dummy_floc,
 656       GrafiteAst.Command (DisambiguateTypes.dummy_floc,
 657         cmd))
 658   in
 659   let moo = GrafiteMarshal.load_moo fname in
 660   List.iter
 661     (fun ast ->
 662       let ast = ast_of_cmd ast in
 663       status :=
 664         eval_ast.ea_go
 665          ~disambiguate_tactic:(fun status _ tactic -> ref status,tactic)
 666          ~disambiguate_command:(fun status cmd -> status,cmd)
 667          !status ast)
 668     moo
 669 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command
 670   ?(do_heavy_checks=false) ?(include_paths=[]) ?(clean_baseuri=true) status st
 671 ->
 672   let opts = {
 673     do_heavy_checks = do_heavy_checks ;
 674     include_paths = include_paths;
 675     clean_baseuri = clean_baseuri }
 676   in
 677   match st with
 678   | GrafiteAst.Executable (_,ex) ->
 679      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command opts status ex
 680   | GrafiteAst.Comment (_,c) -> eval_comment status c
 681 }
 682
 683 let eval_ast = eval_ast.ea_go