helm/ocaml/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 exception Drop
  27 exception IncludedFileNotCompiled of string (* file name *)
  28 (* the integer is expected to be the goal the user is currently seeing *)
  29 exception Macro of
  30  GrafiteAst.loc * (int -> GrafiteTypes.status * Cic.term GrafiteAst.macro)
  31
  32 type options = {
  33   do_heavy_checks: bool ;
  34   clean_baseuri: bool
  35 }
  36
  37 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  38   * names as long as they are available, then it fallbacks to name generation
  39   * using FreshNamesGenerator module *)
  40 let namer_of names =
  41   let len = List.length names in
  42   let count = ref 0 in
  43   fun metasenv context name ~typ ->
  44     if !count < len then begin
  45       let name = Cic.Name (List.nth names !count) in
  46       incr count;
  47       name
  48     end else
  49       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  50
  51 let tactic_of_ast ast =
  52   let module PET = ProofEngineTypes in
  53   match ast with
  54   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  55   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  56   | GrafiteAst.Assumption _ -> Tactics.assumption
  57   | GrafiteAst.Auto (_,depth,width,paramodulation,full) ->
  58       AutoTactic.auto_tac ?depth ?width ?paramodulation ?full
  59         ~dbd:(LibraryDb.instance ()) ()
  60   | GrafiteAst.Change (_, pattern, with_what) ->
  61      Tactics.change ~pattern with_what
  62   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  63   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  64   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  65   | GrafiteAst.Compare (_, term) -> Tactics.compare term
  66   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  67   | GrafiteAst.Cut (_, ident, term) ->
  68      let names = match ident with None -> [] | Some id -> [id] in
  69      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  70   | GrafiteAst.DecideEquality _ -> Tactics.decide_equality
  71   | GrafiteAst.Decompose (_, types, what, names) ->
  72       let to_type = function
  73          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  74          | GrafiteAst.Ident _            -> assert false
  75       in
  76       let user_types = List.rev_map to_type types in
  77       let dbd = LibraryDb.instance () in
  78       let mk_fresh_name_callback = namer_of names in
  79       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types what
  80   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  81   | GrafiteAst.Elim (_, what, using, depth, names) ->
  82       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  83         what
  84   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  85       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  86         what
  87   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  88   | GrafiteAst.Exists _ -> Tactics.exists
  89   | GrafiteAst.Fail _ -> Tactics.fail
  90   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  91       let reduction =
  92         match reduction_kind with
  93         | `Normalize ->
  94             PET.const_lazy_reduction
  95               (CicReduction.normalize ~delta:false ~subst:[])
  96         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
  97         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
  98         | `Unfold None ->
  99             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 100         | `Unfold (Some lazy_term) ->
 101            (fun context metasenv ugraph ->
 102              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 103              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 104         | `Whd ->
 105             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 106       in
 107       Tactics.fold ~reduction ~term ~pattern
 108   | GrafiteAst.Fourier _ -> Tactics.fourier
 109   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 110      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 111       ~dbd:(LibraryDb.instance ()) hyp
 112   | GrafiteAst.Generalize (_,pattern,ident) ->
 113      let names = match ident with None -> [] | Some id -> [id] in
 114      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 115   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 116   | GrafiteAst.IdTac _ -> Tactics.id
 117   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 118   | GrafiteAst.Intros (_, None, names) ->
 119       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 120   | GrafiteAst.Intros (_, Some num, names) ->
 121       PrimitiveTactics.intros_tac ~howmany:num
 122         ~mk_fresh_name_callback:(namer_of names) ()
 123   | GrafiteAst.Inversion (_, term) ->
 124       Tactics.inversion term
 125   | GrafiteAst.LApply (_, how_many, to_what, what, ident) ->
 126       let names = match ident with None -> [] | Some id -> [id] in
 127       Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many
 128         ~to_what what
 129   | GrafiteAst.Left _ -> Tactics.left
 130   | GrafiteAst.LetIn (loc,term,name) ->
 131       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 132   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 133       (match reduction_kind with
 134       | `Normalize -> Tactics.normalize ~pattern
 135       | `Reduce -> Tactics.reduce ~pattern
 136       | `Simpl -> Tactics.simpl ~pattern
 137       | `Unfold what -> Tactics.unfold ~pattern what
 138       | `Whd -> Tactics.whd ~pattern)
 139   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 140   | GrafiteAst.Replace (_, pattern, with_what) ->
 141      Tactics.replace ~pattern ~with_what
 142   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 143      EqualityTactics.rewrite_tac ~direction ~pattern t
 144   | GrafiteAst.Right _ -> Tactics.right
 145   | GrafiteAst.Ring _ -> Tactics.ring
 146   | GrafiteAst.Split _ -> Tactics.split
 147   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 148   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 149
 150 (* maybe we only need special cases for apply and goal *)
 151 let classify_tactic tactic =
 152   match tactic with
 153   (* tactics that can't close the goal (return a goal we want to "select") *)
 154   | GrafiteAst.Rewrite _
 155   | GrafiteAst.Split _
 156   | GrafiteAst.Replace _
 157   | GrafiteAst.Reduce _
 158   | GrafiteAst.Injection _
 159   | GrafiteAst.IdTac _
 160   | GrafiteAst.Generalize _
 161   | GrafiteAst.Elim _
 162   | GrafiteAst.Cut _
 163   | GrafiteAst.Decompose _ -> true, true
 164   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 165   | GrafiteAst.Goal _ -> false, true
 166   (* tactics like apply *)
 167   | _ -> true, false
 168
 169 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 170   let module PEH = ProofEngineHelpers in
 171 (*   let print_m name metasenv =
 172     prerr_endline (">>>>> " ^ name);
 173     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 174   in *)
 175   (* phase one calculates:
 176    *   new_goals_from_refine:  goals added by refine
 177    *   head_goal:              the first goal opened by ythe tactic
 178    *   other_goals:            other goals opened by the tactic
 179    *)
 180   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 181   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 182   let head_goal, other_goals, goals =
 183     match goals with
 184     | [] -> None,[],goals
 185     | hd::tl ->
 186         (* assert (List.mem hd new_goals_from_tactic);
 187          * invalidato dalla goal_tac
 188          * *)
 189         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 190         hd) goals
 191   in
 192   let produced_goals =
 193     match head_goal with
 194     | None -> new_goals_from_refine @ other_goals
 195     | Some x -> x :: new_goals_from_refine @ other_goals
 196   in
 197   (* extract the metas generated by refine and tactic *)
 198   let metas_for_tactic_head =
 199     match head_goal with
 200     | None -> []
 201     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 202   let metas_for_tactic_goals =
 203     List.map
 204       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 205     goals
 206   in
 207   let metas_for_refine_goals =
 208     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 209   let produced_metas, goals =
 210     let produced_metas =
 211       if always_opens_a_goal then
 212         metas_for_tactic_head @ metas_for_refine_goals @
 213           metas_for_tactic_goals
 214       else begin
 215 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 216         print_m "metas_for_tactic_head" metas_for_tactic_head;
 217         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 218         metas_for_refine_goals @ metas_for_tactic_head @
 219           metas_for_tactic_goals
 220       end
 221     in
 222     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 223     produced_metas, goals
 224   in
 225   (* residual metas, preserving the original order *)
 226   let before, after =
 227     let rec split e =
 228       function
 229       | [] -> [],[]
 230       | (metano, _, _) :: tl when metano = e ->
 231           [], List.map (fun (x,_,_) -> x) tl
 232       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 233     in
 234     let find n metasenv =
 235       try
 236         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 237       with Not_found -> None
 238     in
 239     let extract l =
 240       List.fold_right
 241         (fun n acc ->
 242           match find n tactic with
 243           | Some x -> x::acc
 244           | None -> acc
 245         ) l [] in
 246     let before_l, after_l = split current_goal start in
 247     let before_l =
 248       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 249     let after_l =
 250       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 251     let before = extract before_l in
 252     let after = extract after_l in
 253       before, after
 254   in
 255 (* |+   DEBUG CODE  +|
 256   print_m "BEGIN" start;
 257   prerr_endline ("goal was: " ^ string_of_int current_goal);
 258   prerr_endline ("and metas from refine are:");
 259   List.iter
 260     (fun t -> prerr_string (" " ^ string_of_int t))
 261   new_goals_from_refine;
 262   prerr_endline "";
 263   print_m "before" before;
 264   print_m "metas_for_tactic_head" metas_for_tactic_head;
 265   print_m "metas_for_refine_goals" metas_for_refine_goals;
 266   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 267   print_m "produced_metas" produced_metas;
 268   print_m "after" after;
 269 |+   FINE DEBUG CODE +| *)
 270   before @ produced_metas @ after, goals
 271
 272 let apply_tactic ~disambiguate_tactic tactic (status, goal) =
 273 (* prerr_endline "apply_tactic"; *)
 274 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 275  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 276  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 277 (* prerr_endline "disambiguate"; *)
 278  let status, tactic = disambiguate_tactic status goal tactic in
 279  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 280  let proof = GrafiteTypes.get_current_proof status in
 281  let proof_status = proof, goal in
 282  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 283  let tactic = tactic_of_ast tactic in
 284  (* apply tactic will change the lexicon_status ... *)
 285 (* prerr_endline "apply_tactic bassa"; *)
 286  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 287  let after = ProofEngineTypes.goals_of_proof proof in
 288  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 289 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 290 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 291 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 292 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 293 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 294  let proof, opened_goals =
 295    if needs_reordering then begin
 296      let uri, metasenv_after_tactic, t, ty = proof in
 297 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 298      let reordered_metasenv, opened_goals =
 299        reorder_metasenv
 300         starting_metasenv
 301         metasenv_after_refinement metasenv_after_tactic
 302         opened goal always_opens_a_goal
 303      in
 304      let proof' = uri, reordered_metasenv, t, ty in
 305 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 306      proof', opened_goals
 307    end
 308       else
 309         proof, opened_goals
 310  in
 311  let incomplete_proof =
 312    match status.GrafiteTypes.proof_status with
 313    | GrafiteTypes.Incomplete_proof p -> p
 314    | _ -> assert false
 315  in
 316  { status with GrafiteTypes.proof_status =
 317     GrafiteTypes.Incomplete_proof
 318      { incomplete_proof with GrafiteTypes.proof = proof } },
 319  opened_goals, closed_goals
 320
 321 type eval_ast =
 322  {ea_go:
 323   'term 'lazy_term 'reduction 'obj 'ident.
 324   disambiguate_tactic:
 325    (GrafiteTypes.status ->
 326     ProofEngineTypes.goal ->
 327     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 328     GrafiteTypes.status *
 329    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 330
 331   disambiguate_command:
 332    (GrafiteTypes.status ->
 333     'obj GrafiteAst.command ->
 334     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 335
 336   disambiguate_macro:
 337    (GrafiteTypes.status ->
 338     'term GrafiteAst.macro ->
 339     int -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 340
 341   ?do_heavy_checks:bool ->
 342   ?clean_baseuri:bool ->
 343   GrafiteTypes.status ->
 344   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement ->
 345   GrafiteTypes.status * UriManager.uri list
 346  }
 347
 348 type 'a eval_command =
 349  {ec_go: 'term 'obj.
 350   disambiguate_command:
 351    (GrafiteTypes.status ->
 352     'obj GrafiteAst.command ->
 353     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 354   options -> GrafiteTypes.status -> 'obj GrafiteAst.command ->
 355    GrafiteTypes.status * UriManager.uri list
 356  }
 357
 358 type 'a eval_executable =
 359  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 360   disambiguate_tactic:
 361    (GrafiteTypes.status ->
 362     ProofEngineTypes.goal ->
 363     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 364     GrafiteTypes.status *
 365    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 366
 367   disambiguate_command:
 368    (GrafiteTypes.status ->
 369     'obj GrafiteAst.command ->
 370     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 371
 372   disambiguate_macro:
 373    (GrafiteTypes.status ->
 374     'term GrafiteAst.macro ->
 375     int -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 376
 377   options ->
 378   GrafiteTypes.status ->
 379   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code ->
 380   GrafiteTypes.status * UriManager.uri list
 381  }
 382
 383 type 'a eval_from_moo =
 384  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 385
 386 let coercion_moo_statement_of uri =
 387   GrafiteAst.Coercion (HExtlib.dummy_floc, uri, false)
 388
 389 let eval_coercion status ~add_composites uri =
 390  let basedir = Helm_registry.get "matita.basedir" in
 391  let status,compounds =
 392   GrafiteSync.add_coercion ~basedir ~add_composites status uri in
 393  let moo_content = coercion_moo_statement_of uri in
 394  let status = GrafiteTypes.add_moo_content [moo_content] status in
 395   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 396    compounds
 397
 398 let eval_tactical ~disambiguate_tactic status tac =
 399  let apply_tactic = apply_tactic ~disambiguate_tactic in
 400  let module MatitaStatus =
 401   struct
 402    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 403
 404    type output_status =
 405      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 406
 407    type tactic = input_status -> output_status
 408
 409    let id_tactic = apply_tactic (GrafiteAst.IdTac HExtlib.dummy_floc)
 410    let mk_tactic tac = tac
 411    let apply_tactic tac = tac
 412    let goals (_, opened, closed) = opened, closed
 413    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 414    let get_stack (status, _) = GrafiteTypes.get_stack status
 415
 416    let set_stack stack (status, opened, closed) =
 417      GrafiteTypes.set_stack stack status, opened, closed
 418
 419    let inject (status, _) = (status, [], [])
 420    let focus goal (status, _, _) = (status, goal)
 421   end
 422  in
 423  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 424   let rec tactical_of_ast l tac =
 425     match tac with
 426     | GrafiteAst.Tactic (loc, tactic) ->
 427         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 428     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 429        assert (l > 0);
 430        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 431     | GrafiteAst.Do (loc, n, tactical) ->
 432         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 433     | GrafiteAst.Repeat (loc, tactical) ->
 434         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 435     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 436         assert (l > 0);
 437         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 438           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 439     | GrafiteAst.First (loc, tacticals) ->
 440         MatitaTacticals.first
 441           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 442     | GrafiteAst.Try (loc, tactical) ->
 443         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 444     | GrafiteAst.Solve (loc, tacticals) ->
 445         MatitaTacticals.solve_tactics
 446          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 447
 448     | GrafiteAst.Skip loc -> MatitaTacticals.skip
 449     | GrafiteAst.Dot loc -> MatitaTacticals.dot
 450     | GrafiteAst.Semicolon loc -> MatitaTacticals.semicolon
 451     | GrafiteAst.Branch loc -> MatitaTacticals.branch
 452     | GrafiteAst.Shift loc -> MatitaTacticals.shift
 453     | GrafiteAst.Pos (loc, i) -> MatitaTacticals.pos i
 454     | GrafiteAst.Merge loc -> MatitaTacticals.merge
 455     | GrafiteAst.Focus (loc, goals) -> MatitaTacticals.focus goals
 456     | GrafiteAst.Unfocus loc -> MatitaTacticals.unfocus
 457   in
 458   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 459   let status =  (* is proof completed? *)
 460     match status.GrafiteTypes.proof_status with
 461     | GrafiteTypes.Incomplete_proof
 462        { GrafiteTypes.stack = stack; proof = proof }
 463       when Continuationals.Stack.is_empty stack ->
 464         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 465     | _ -> status
 466   in
 467   status
 468
 469 let eval_comment status c = status
 470
 471 (* since the record syntax allows to declare coercions, we have to put this
 472  * information inside the moo *)
 473 let add_coercions_of_record_to_moo obj lemmas status =
 474   let attributes = CicUtil.attributes_of_obj obj in
 475   let is_record = function `Class (`Record att) -> Some att | _-> None in
 476   match HExtlib.list_findopt is_record attributes with
 477   | None -> status,[]
 478   | Some fields ->
 479       let is_a_coercion uri =
 480         try
 481           let obj,_ =
 482             CicEnvironment.get_cooked_obj  CicUniv.empty_ugraph uri in
 483           let attrs = CicUtil.attributes_of_obj obj in
 484           List.mem (`Class `Projection) attrs
 485         with Not_found -> assert false
 486       in
 487       (* looking at the fields we can know the 'wanted' coercions, but not the
 488        * actually generated ones. So, only the intersection between the wanted
 489        * and the actual should be in the moo as coercion, while everithing in
 490        * lemmas should go as aliases *)
 491       let wanted_coercions =
 492         HExtlib.filter_map
 493           (function
 494             | (name,true) ->
 495                Some
 496                  (UriManager.uri_of_string
 497                    (GrafiteTypes.qualify status name ^ ".con"))
 498             | _ -> None)
 499           fields
 500       in
 501       prerr_endline "wanted coercions:";
 502       List.iter
 503         (fun u -> prerr_endline (UriManager.string_of_uri u))
 504         wanted_coercions;
 505       let coercions, moo_content =
 506         List.split
 507           (HExtlib.filter_map
 508             (fun uri ->
 509               let is_a_wanted_coercion =
 510                 List.exists (UriManager.eq uri) wanted_coercions in
 511               if is_a_coercion uri && is_a_wanted_coercion then
 512                 Some (uri, coercion_moo_statement_of uri)
 513               else
 514                 None)
 515             lemmas)
 516       in
 517       List.iter
 518         (fun u -> prerr_endline (UriManager.string_of_uri u))
 519         coercions;
 520       let status = GrafiteTypes.add_moo_content moo_content status in
 521       let basedir = Helm_registry.get "matita.basedir" in
 522       List.fold_left
 523         (fun (status,lemmas) uri ->
 524           let status,new_lemmas =
 525            GrafiteSync.add_coercion ~basedir ~add_composites:true status uri
 526           in
 527            status,new_lemmas@lemmas
 528         ) (status,[]) coercions
 529
 530 let add_obj uri obj status =
 531  let basedir = Helm_registry.get "matita.basedir" in
 532  let status,lemmas = GrafiteSync.add_obj ~basedir uri obj status in
 533  status, lemmas
 534
 535 let rec eval_command = {ec_go = fun ~disambiguate_command opts status cmd ->
 536  let status,cmd = disambiguate_command status cmd in
 537  let basedir = Helm_registry.get "matita.basedir" in
 538  let status,uris =
 539   match cmd with
 540   | GrafiteAst.Default (loc, what, uris) as cmd ->
 541      LibraryObjects.set_default what uris;
 542      GrafiteTypes.add_moo_content [cmd] status,[]
 543   | GrafiteAst.Include (loc, baseuri) ->
 544      let moopath = LibraryMisc.obj_file_of_baseuri ~basedir ~baseuri in
 545      let metadatapath= LibraryMisc.metadata_file_of_baseuri ~basedir ~baseuri in
 546      if not (Sys.file_exists moopath) then
 547        raise (IncludedFileNotCompiled moopath);
 548      let status = eval_from_moo.efm_go status moopath in
 549      status,[]
 550   | GrafiteAst.Set (loc, name, value) ->
 551       if name = "baseuri" then begin
 552         let value =
 553           let v = Http_getter_misc.strip_trailing_slash value in
 554           try
 555             ignore (String.index v ' ');
 556             raise (GrafiteTypes.Command_error "baseuri can't contain spaces")
 557           with Not_found -> v
 558         in
 559         if not (GrafiteMisc.is_empty value) && opts.clean_baseuri then begin
 560           HLog.warn ("baseuri " ^ value ^ " is not empty");
 561           HLog.message ("cleaning baseuri " ^ value);
 562           LibraryClean.clean_baseuris ~basedir [value];
 563         end;
 564       end;
 565       GrafiteTypes.set_option status name value,[]
 566   | GrafiteAst.Drop loc -> raise Drop
 567   | GrafiteAst.Qed loc ->
 568       let uri, metasenv, bo, ty =
 569         match status.GrafiteTypes.proof_status with
 570         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 571             uri, metasenv, body, ty
 572         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 573             raise (GrafiteTypes.Command_error
 574               ("Someone allows to start a theorem without giving the "^
 575                "name/uri. This should be fixed!"))
 576         | _->
 577           raise
 578            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 579       in
 580       if metasenv <> [] then
 581         raise
 582          (GrafiteTypes.Command_error
 583            "Proof not completed! metasenv is not empty!");
 584       let name = UriManager.name_of_uri uri in
 585       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 586       let status, lemmas = add_obj uri obj status in
 587        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 588         uri::lemmas
 589   | GrafiteAst.Coercion (loc, uri, add_composites) ->
 590      eval_coercion status ~add_composites uri
 591   | GrafiteAst.Obj (loc,obj) ->
 592      let ext,name =
 593       match obj with
 594          Cic.Constant (name,_,_,_,_)
 595        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 596        | Cic.InductiveDefinition (types,_,_,_) ->
 597           ".ind",
 598           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 599        | _ -> assert false in
 600      let uri =
 601        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext)
 602      in
 603      let metasenv = GrafiteTypes.get_proof_metasenv status in
 604      match obj with
 605      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 606          let name = UriManager.name_of_uri uri in
 607          if not(CicPp.check name ty) then
 608            HLog.error ("Bad name: " ^ name);
 609          if opts.do_heavy_checks then
 610            begin
 611              let dbd = LibraryDb.instance () in
 612              let similar = Whelp.match_term ~dbd ty in
 613              let similar_len = List.length similar in
 614              if similar_len> 30 then
 615                (HLog.message
 616                  ("Duplicate check will compare your theorem with " ^
 617                    string_of_int similar_len ^
 618                    " theorems, this may take a while."));
 619              let convertible =
 620                List.filter (
 621                  fun u ->
 622                    let t = CicUtil.term_of_uri u in
 623                    let ty',g =
 624                      CicTypeChecker.type_of_aux'
 625                        metasenv' [] t CicUniv.empty_ugraph
 626                    in
 627                    fst(CicReduction.are_convertible [] ty' ty g))
 628                similar
 629              in
 630              (match convertible with
 631              | [] -> ()
 632              | x::_ ->
 633                  HLog.warn
 634                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 635                   "\nPlease use a variant."));
 636            end;
 637          assert (metasenv = metasenv');
 638          let goalno =
 639            match metasenv' with (goalno,_,_)::_ -> goalno | _ -> assert false
 640          in
 641          let initial_proof = (Some uri, metasenv, bo, ty) in
 642          let initial_stack = Continuationals.Stack.of_metasenv metasenv in
 643          { status with GrafiteTypes.proof_status =
 644             GrafiteTypes.Incomplete_proof
 645              { GrafiteTypes.proof = initial_proof; stack = initial_stack } },
 646           []
 647      | _ ->
 648          if metasenv <> [] then
 649           raise (GrafiteTypes.Command_error (
 650             "metasenv not empty while giving a definition with body: " ^
 651             CicMetaSubst.ppmetasenv [] metasenv));
 652          let status, lemmas = add_obj uri obj status in
 653          let status,new_lemmas =
 654           add_coercions_of_record_to_moo obj lemmas status
 655          in
 656           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 657            uri::new_lemmas@lemmas
 658  in
 659   match status.GrafiteTypes.proof_status with
 660      GrafiteTypes.Intermediate _ ->
 661       {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},uris
 662    | _ -> status,uris
 663
 664 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command ~disambiguate_macro opts status ex ->
 665   match ex with
 666   | GrafiteAst.Tactical (_, tac, None) ->
 667      eval_tactical ~disambiguate_tactic status tac,[]
 668   | GrafiteAst.Tactical (_, tac, Some punct) ->
 669      let status = eval_tactical ~disambiguate_tactic status tac in
 670       eval_tactical ~disambiguate_tactic status punct,[]
 671   | GrafiteAst.Command (_, cmd) ->
 672       eval_command.ec_go ~disambiguate_command opts status cmd
 673   | GrafiteAst.Macro (loc, macro) ->
 674      raise (Macro (loc,disambiguate_macro status macro))
 675
 676 } and eval_from_moo = {efm_go = fun status fname ->
 677   let ast_of_cmd cmd =
 678     GrafiteAst.Executable (HExtlib.dummy_floc,
 679       GrafiteAst.Command (HExtlib.dummy_floc,
 680         cmd))
 681   in
 682   let moo = GrafiteMarshal.load_moo fname in
 683   List.fold_left
 684     (fun status ast ->
 685       let ast = ast_of_cmd ast in
 686       let status,lemmas =
 687        eval_ast.ea_go
 688          ~disambiguate_tactic:(fun status _ tactic -> status,tactic)
 689          ~disambiguate_command:(fun status cmd -> status,cmd)
 690          ~disambiguate_macro:(fun _ _ -> assert false)
 691          status ast
 692       in
 693        assert (lemmas=[]);
 694        status)
 695     status moo
 696 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command ~disambiguate_macro ?(do_heavy_checks=false) ?(clean_baseuri=true) status st
 697 ->
 698   let opts = {
 699     do_heavy_checks = do_heavy_checks ;
 700     clean_baseuri = clean_baseuri }
 701   in
 702   match st with
 703   | GrafiteAst.Executable (_,ex) ->
 704      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
 705       ~disambiguate_macro opts status ex
 706   | GrafiteAst.Comment (_,c) -> eval_comment status c,[]
 707 }
 708
 709 let eval_ast = eval_ast.ea_go