helm/ocaml/lexicon/lexiconEngine.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception IncludedFileNotCompiled of string (* file name *)
  29 exception MetadataNotFound of string        (* file name *)
  30
  31 type status = {
  32   aliases: DisambiguateTypes.environment;         (** disambiguation aliases *)
  33   multi_aliases: DisambiguateTypes.multiple_environment;
  34   lexicon_content_rev: LexiconMarshal.lexicon;
  35   notation_ids: CicNotation.notation_id list;      (** in-scope notation ids *)
  36   metadata: LibraryNoDb.metadata list;
  37 }
  38
  39 let add_lexicon_content cmds status =
  40   let content = status.lexicon_content_rev in
  41   let content' =
  42     List.fold_right
  43      (fun cmd acc -> cmd :: (List.filter ((<>) cmd) acc))
  44      cmds content
  45   in
  46 (*   prerr_endline ("new lexicon content: " ^ String.concat " " (List.map
  47     LexiconAstPp.pp_command content')); *)
  48   { status with lexicon_content_rev = content' }
  49
  50 let add_metadata new_metadata status =
  51   if Helm_registry.get_bool "db.nodb" then
  52     let metadata = status.metadata in
  53     let metadata' =
  54       List.fold_left
  55         (fun acc m ->
  56           match m with
  57           | LibraryNoDb.Dependency buri ->
  58               if List.exists (LibraryNoDb.eq_metadata m) metadata
  59               then acc
  60               else m :: acc
  61           | _ -> m :: acc)
  62         metadata new_metadata
  63     in
  64     { status with metadata = metadata' }
  65   else
  66     status
  67
  68 let set_proof_aliases status new_aliases =
  69  let commands_of_aliases =
  70    List.map
  71     (fun alias -> LexiconAst.Alias (HExtlib.dummy_floc, alias))
  72  in
  73  let deps_of_aliases =
  74    HExtlib.filter_map
  75     (function
  76     | LexiconAst.Ident_alias (_, suri) ->
  77         let buri = UriManager.buri_of_uri (UriManager.uri_of_string suri) in
  78         Some (LibraryNoDb.Dependency buri)
  79     | _ -> None)
  80  in
  81  let aliases =
  82   List.fold_left (fun acc (d,c) -> DisambiguateTypes.Environment.add d c acc)
  83    status.aliases new_aliases in
  84  let multi_aliases =
  85   List.fold_left (fun acc (d,c) -> DisambiguateTypes.Environment.cons d c acc)
  86    status.multi_aliases new_aliases in
  87  let new_status =
  88    { status with multi_aliases = multi_aliases ; aliases = aliases}
  89  in
  90  if new_aliases = [] then
  91    new_status
  92  else
  93    let aliases =
  94      DisambiguatePp.aliases_of_domain_and_codomain_items_list new_aliases
  95    in
  96    let status = add_lexicon_content (commands_of_aliases aliases) new_status in
  97    let status = add_metadata (deps_of_aliases aliases) status in
  98    status
  99
 100 let rec eval_command status cmd =
 101  let notation_ids' = CicNotation.process_notation cmd in
 102  let status =
 103    { status with notation_ids = notation_ids' @ status.notation_ids } in
 104  let basedir = Helm_registry.get "matita.basedir" in
 105   match cmd with
 106   | LexiconAst.Include (loc, baseuri) ->
 107      let lexiconpath = LibraryMisc.lexicon_file_of_baseuri ~basedir ~baseuri in
 108      if not (Sys.file_exists lexiconpath) then
 109        raise (IncludedFileNotCompiled lexiconpath);
 110      let lexicon = LexiconMarshal.load_lexicon lexiconpath in
 111      let status = List.fold_left eval_command status lexicon in
 112       if Helm_registry.get_bool "db.nodb" then
 113        let metadatapath = LibraryMisc.metadata_file_of_baseuri ~basedir ~baseuri in
 114         if not (Sys.file_exists metadatapath) then
 115           raise (MetadataNotFound metadatapath)
 116         else
 117           add_metadata (LibraryNoDb.load_metadata ~fname:metadatapath) status
 118       else
 119          status
 120   | LexiconAst.Alias (loc, spec) ->
 121      let diff =
 122       (*CSC: Warning: this code should be factorized with the corresponding
 123              code in DisambiguatePp *)
 124       match spec with
 125       | LexiconAst.Ident_alias (id,uri) ->
 126          [DisambiguateTypes.Id id,
 127           (uri,(fun _ _ _-> CicUtil.term_of_uri(UriManager.uri_of_string uri)))]
 128       | LexiconAst.Symbol_alias (symb, instance, desc) ->
 129          [DisambiguateTypes.Symbol (symb,instance),
 130           DisambiguateChoices.lookup_symbol_by_dsc symb desc]
 131       | LexiconAst.Number_alias (instance,desc) ->
 132          [DisambiguateTypes.Num instance,
 133           DisambiguateChoices.lookup_num_by_dsc desc]
 134      in
 135       set_proof_aliases status diff
 136   | LexiconAst.Interpretation (_, dsc, (symbol, _), cic_appl_pattern) as stm ->
 137       let status = add_lexicon_content [stm] status in
 138       let uris =
 139         List.map
 140           (fun uri -> LibraryNoDb.Dependency (UriManager.buri_of_uri uri))
 141           (CicNotationUtil.find_appl_pattern_uris cic_appl_pattern)
 142       in
 143       let diff =
 144        [DisambiguateTypes.Symbol (symbol, 0),
 145          DisambiguateChoices.lookup_symbol_by_dsc symbol dsc]
 146       in
 147       let status = set_proof_aliases status diff in
 148       let status = add_metadata uris status in
 149       status
 150   | LexiconAst.Notation _ as stm -> add_lexicon_content [stm] status
 151