helm/ocaml/mathql_generator/cGMatchConclusion.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (*  AUTOR: Ferruccio Guidi <fguidi@cs.unibo.it>
  27  *)
  28
  29 module T = MQGTypes
  30
  31 let text_of_entries out entries =
  32    out "(** MatchConclusion: results of the term inspection **)\n";
  33    let text_of_entry (u, b, v) =
  34       out (string_of_int v ^ " ");
  35       out (if b then "$MC " else "$IC ");
  36       out (u ^ "\n")
  37    in List.iter text_of_entry entries
  38
  39 let sort_entries entries =
  40    let comparator (_, _, v1) (_, _, v2) = compare v1 v2 in
  41    List.fast_sort comparator entries
  42
  43 let levels_of_term metasenv context term =
  44    let module TC = CicTypeChecker in
  45    let module Red = CicReduction in
  46    let degree t =
  47       let rec degree_aux = function
  48          | Cic.Sort _         -> 1
  49          | Cic.Cast (u, _)    -> degree_aux u
  50          | Cic.Prod (_, _, t) -> degree_aux t
  51          | _                  -> 2
  52       in
  53       let u,_ = TC.type_of_aux' metasenv context t CicUniv.empty_ugraph in
  54       degree_aux (Red.whd context u)
  55    in
  56    let entry_eq (s1, b1, v1) (s2, b2, v2) =
  57       s1 = s2 && b1 = b2
  58    in
  59    let rec entry_in e = function
  60       | []           -> [e]
  61       | head :: tail ->
  62          head :: if entry_eq head e then tail else entry_in e tail
  63    in
  64    let inspect_uri main l uri tc v term =
  65       let d = degree term in
  66       entry_in (UriManager.string_of_uriref (uri, tc), main, 2 * v + d - 1) l
  67    in
  68    let rec inspect_term main l v term = match term with
  69         Cic.Rel _                        -> l
  70       | Cic.Meta _                       -> l
  71       | Cic.Sort _                       -> l
  72       | Cic.Implicit _                   -> l
  73       | Cic.Var (u,exp_named_subst)      ->
  74          inspect_exp_named_subst l (succ v) exp_named_subst
  75 (*
  76          let l' = inspect_uri main l u [] v term in
  77           inspect_exp_named_subst l' (succ v) exp_named_subst
  78 *)
  79       | Cic.Const (u,exp_named_subst)    ->
  80          let l' = inspect_uri main l u [] v term in
  81           inspect_exp_named_subst l' (succ v) exp_named_subst
  82       | Cic.MutInd (u, t, exp_named_subst) ->
  83          let l' = inspect_uri main l u [t] v term in
  84           inspect_exp_named_subst l' (succ v) exp_named_subst
  85       | Cic.MutConstruct (u, t, c, exp_named_subst)    ->
  86          let l' = inspect_uri main l u [t; c] v term in
  87           inspect_exp_named_subst l' (succ v) exp_named_subst
  88       | Cic.Cast (uu, _)                 ->
  89          inspect_term main l v uu
  90       | Cic.Prod (_, uu, tt)             ->
  91          let luu = inspect_term false l (succ v) uu in
  92          inspect_term main luu (succ v) tt
  93       | Cic.Lambda (_, uu, tt)           ->
  94          let luu = inspect_term false l (succ v) uu in
  95          inspect_term false luu (succ v) tt
  96       | Cic.LetIn (_, uu, tt)            ->
  97          let luu = inspect_term false l (succ v) uu in
  98          inspect_term false luu (succ v) tt
  99       | Cic.Appl m                       -> inspect_list main l true v m
 100       | Cic.MutCase (u, t, tt, uu, m) ->
 101          let lu = inspect_uri main l u [t] (succ v) term in
 102          let ltt = inspect_term false lu (succ v) tt in
 103          let luu = inspect_term false ltt (succ v) uu in
 104          inspect_list main luu false (succ v) m
 105       | Cic.Fix (_, m)                   -> inspect_ind l (succ v) m
 106       | Cic.CoFix (_, m)                 -> inspect_coind l (succ v) m
 107    and inspect_list main l head v = function
 108       | []      -> l
 109       | tt :: m ->
 110          let ltt = inspect_term main l (if head then v else v + 1) tt in
 111          inspect_list false ltt false v m
 112    and inspect_exp_named_subst l v = function
 113         []      -> l
 114       | (_,t) :: tl ->
 115          let l' = inspect_term false l v t in
 116           inspect_exp_named_subst l' v tl
 117    and inspect_ind l v = function
 118       | []                  -> l
 119       | (_, _, tt, uu) :: m ->
 120          let ltt = inspect_term false l v tt in
 121          let luu = inspect_term false ltt v uu in
 122          inspect_ind luu v m
 123    and inspect_coind l v = function
 124       | []               -> l
 125       | (_, tt, uu) :: m ->
 126          let ltt = inspect_term false l v tt in
 127          let luu = inspect_term false ltt v uu in
 128          inspect_coind luu v m
 129    in
 130    let rec inspect_backbone = function
 131       | Cic.Cast (uu, _)      -> inspect_backbone uu
 132       | Cic.Prod (_, _, tt)   -> inspect_backbone tt
 133       | Cic.LetIn (_, uu, tt) -> inspect_backbone tt
 134       | t                     -> inspect_term true [] 0 t
 135    in
 136    inspect_backbone term
 137
 138 let get_constraints e c t =
 139    let can = sort_entries (levels_of_term e c t) in  (* can restrictions *)
 140    text_of_entries prerr_string can; flush stderr;   (* logging *)
 141    let rest_of (u, b, _) =
 142       let p = if b then `MainConclusion None else `InConclusion in (p, u)
 143    in
 144    let rec split vp = function
 145       | [], ((_, _, v) as hd) :: tl -> split v ([rest_of hd], tl)
 146       | prev, ((_, _, ve) as hd) :: tl  when vp = ve ->
 147          split vp (rest_of hd :: prev, tl)
 148       | p, l -> p, l
 149    in
 150    let rec mk_musts prev acc = function
 151       | [] -> prev, acc
 152       | l  ->
 153          let slice, next = split 0 ([], l) in
 154          let acc = acc @ slice in
 155          mk_musts (prev @ [acc]) acc next
 156    in
 157    mk_musts [] [] can
 158
 159 let universe = [T.MainConclusion; T.InConclusion]