helm/ocaml/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 let debug = false
  31 let debug_print s =
  32   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  33
  34   (** <helpers> *)
  35
  36 let list_uniq l =
  37   let rec aux last_element = function
  38     | [] -> []
  39     | hd :: tl ->
  40         (match last_element with
  41         | Some elt when elt = hd -> aux last_element tl
  42         | _ -> hd :: aux (Some hd) tl)
  43   in
  44   aux None l
  45
  46 let starts_with prefix =
  47 (*
  48   let rex = Str.regexp (Str.quote prefix) in
  49   fun s -> Str.string_match rex s 0
  50 *)
  51   let prefix_len = String.length prefix in
  52   fun s ->
  53     try
  54       String.sub s 0 prefix_len = prefix
  55     with Invalid_argument _ -> false
  56
  57 let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []
  58 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  59
  60   (** </helpers> *)
  61
  62 exception Malformed_key of string
  63 exception Key_not_found of string
  64 exception Cyclic_definition of string
  65 exception Type_error of string (* expected type, value, msg *)
  66 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  67
  68   (* root XML tag: used by save_to, ignored by load_from *)
  69 let root_tag = "helm_registry"
  70
  71 let magic_size = 127
  72
  73 let backup_registry registry = Hashtbl.copy registry
  74 let restore_registry backup registry =
  75   Hashtbl.clear registry;
  76   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  77
  78   (* as \\w but:
  79    * - no sequences of '_' longer than 1 are permitted
  80    *)
  81 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  82 let valid_key_rex_raw =
  83   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  84 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  85 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  86 let dot_rex = Str.regexp "\\."
  87 let spaces_rex = Str.regexp "[ \t\n\r]+"
  88 let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"
  89 let margin_blanks_rex =
  90   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  91
  92 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  93
  94 let split s =
  95   (* trailing blanks are removed per default by split *)
  96   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)
  97 let merge l = String.concat " " l
  98
  99 let handle_type_error f x =
 100   try f x with exn -> raise (Type_error (Printexc.to_string exn))
 101
 102   (** marshallers/unmarshallers *)
 103 let string x = x
 104 let int = handle_type_error int_of_string
 105 let float = handle_type_error float_of_string
 106 let bool = handle_type_error bool_of_string
 107 let of_string x = x
 108 let of_int = handle_type_error string_of_int
 109 let of_float = handle_type_error string_of_float
 110 let of_bool = handle_type_error string_of_bool
 111
 112   (* escapes for xml configuration file *)
 113 let (escape, unescape) =
 114   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 115   (Netencoding.Html.encode ~in_enc ~out_enc (),
 116    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())
 117
 118 let key_is_valid key =
 119   if not (Str.string_match valid_key_rex key 0) then
 120     raise (Malformed_key key)
 121
 122 let set' ?(replace=false) registry ~key ~value =
 123   debug_print (lazy(sprintf "Setting (replace: %b) %s = %s" replace key value));
 124   key_is_valid key;
 125   let add_fun = if replace then Hashtbl.replace else Hashtbl.add in
 126   add_fun registry key value
 127
 128 let unset registry = Hashtbl.remove registry
 129
 130 let env_var_of_key = Str.global_replace dot_rex "__"
 131
 132 let singleton = function
 133   | [] ->
 134       raise (Type_error ("empty list value found where singleton was expected"))
 135   | hd :: _ -> hd
 136
 137 let get registry key =
 138   let rec aux stack key =
 139     key_is_valid key;
 140     if List.mem key stack then begin
 141       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 142       raise (Cyclic_definition msg)
 143     end;
 144       (* internal value *)
 145     let registry_values = List.rev (Hashtbl.find_all registry key) in
 146     let env_value = (* environment value *)
 147       try
 148         Some (Sys.getenv (env_var_of_key key))
 149       with Not_found -> None
 150     in
 151     let values = (* resulting value *)
 152       match registry_values, env_value with
 153       | _, Some env -> [env]
 154       | [], None ->
 155           (try
 156             [ Sys.getenv key ]
 157           with Not_found -> raise (Key_not_found key))
 158       | values, None -> values
 159     in
 160     List.map (interpolate (key :: stack)) values
 161   and interpolate stack value =
 162     Str.global_substitute interpolated_key_rex
 163       (fun s ->
 164         let matched = Str.matched_string s in
 165           (* "$(var)" -> "var" *)
 166         let key = String.sub matched 2 (String.length matched - 3) in
 167         singleton (aux stack key))
 168       value
 169   in
 170   List.map strip_blanks (aux [] key)
 171
 172 let has registry key = Hashtbl.mem registry key
 173
 174 let get_typed registry unmarshaller key =
 175   let value = singleton (get registry key) in
 176   unmarshaller value
 177
 178 let set_typed registry marshaller ~key ~value =
 179   set' ~replace:true registry ~key ~value:(marshaller value)
 180
 181 let get_opt registry unmarshaller key =
 182   try
 183     Some (unmarshaller (singleton (get registry key)))
 184   with Key_not_found _ -> None
 185
 186 let get_opt_default registry unmarshaller ~default key =
 187   match get_opt registry unmarshaller key with
 188   | None -> default
 189   | Some v -> v
 190
 191 let set_opt registry marshaller ~key ~value =
 192   match value with
 193   | None -> unset registry key
 194   | Some value -> set' ~replace:true registry ~key ~value:(marshaller value)
 195
 196 let get_list registry unmarshaller key =
 197   try
 198     List.map unmarshaller (get registry key)
 199   with Key_not_found _ -> []
 200
 201 let get_pair registry fst_unmarshaller snd_unmarshaller key =
 202   let v = singleton (get registry key) in
 203   match Str.split spaces_rex v with
 204   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 205   | _ -> raise (Type_error "not a pair")
 206
 207 let set_list registry marshaller ~key ~value =
 208   Hashtbl.remove registry key;
 209   List.iter
 210     (fun v -> set' ~replace:false registry ~key ~value:(marshaller v))
 211     value
 212
 213 type xml_tree =
 214   | Cdata of string
 215   | Element of string * (string * string) list * xml_tree list
 216
 217 let dot_RE = Str.regexp "\\."
 218
 219 let xml_tree_of_registry registry =
 220   let has_child name elements =
 221     List.exists
 222       (function
 223         | Element (_, ["name", name'], _) when name = name' -> true
 224         | _ -> false)
 225       elements
 226   in
 227   let rec get_child name = function
 228     | [] -> assert false
 229     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 230         child, tl
 231     | hd :: tl ->
 232         let child, rest = get_child name tl in
 233         child, hd :: rest
 234   in
 235   let rec add_key path value tree =
 236     match path, tree with
 237     | [key], Element (name, attrs, children) ->
 238         Element (name, attrs,
 239           Element ("key", ["name", key],
 240             [Cdata (strip_blanks value)]) :: children)
 241     | dir :: path, Element (name, attrs, children) ->
 242         if has_child dir children then
 243           let child, rest = get_child dir children in
 244           Element (name, attrs, add_key path value child :: rest)
 245         else
 246           Element (name, attrs,
 247             ((add_key path value (Element ("section", ["name", dir], [])))
 248               :: children))
 249     | _ -> assert false
 250   in
 251   Hashtbl.fold
 252     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 253     registry
 254     (Element (root_tag, [], []))
 255
 256 let rec stream_of_xml_tree = function
 257   | Cdata s -> Xml.xml_cdata s
 258   | Element (name, attrs, children) ->
 259       Xml.xml_nempty name
 260         (List.map (fun (n, v) -> (None, n, v)) attrs)
 261         (stream_of_xml_trees children)
 262 and stream_of_xml_trees = function
 263   | [] -> [< >]
 264   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 265
 266 let save_to registry fname =
 267   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 268   let oc = open_out fname in
 269   Xml.pp_to_outchan token_stream oc;
 270   close_out oc
 271
 272 let rec load_from_absolute ?path registry fname =
 273   let _path = ref (match path with None -> [] | Some p -> p)in
 274     (* <section> elements entered so far *)
 275   let in_key = ref false in (* have we entered a <key> element? *)
 276   let cdata = ref "" in     (* collected cdata (inside <key> *)
 277   let push_path name = _path := name :: !_path in
 278   let pop_path () = _path := List.tl !_path in
 279   let start_element tag attrs =
 280     match tag, attrs with
 281     | "section", ["name", name] -> push_path name
 282     | "key", ["name", name] -> in_key := true; push_path name
 283     | "helm_registry", _ -> ()
 284     | "include", ["href", fname] ->
 285         debug_print (lazy ("including file " ^ fname));
 286         load_from_absolute ~path:!_path registry fname
 287     | tag, _ ->
 288         raise (Parse_error (fname, ~-1, ~-1,
 289           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 290   in
 291   let end_element tag =
 292     match tag with
 293     | "section" -> pop_path ()
 294     | "key" ->
 295         let key = String.concat "." (List.rev !_path) in
 296         set' registry ~key ~value:!cdata;
 297         cdata := "";
 298         in_key := false;
 299         pop_path ()
 300     | "include" | "helm_registry" -> ()
 301     | _ -> assert false
 302   in
 303   let character_data text =
 304     if !in_key then cdata := !cdata ^ text
 305   in
 306   let callbacks = {
 307     XmlPushParser.default_callbacks with
 308       XmlPushParser.start_element = Some start_element;
 309       XmlPushParser.end_element = Some end_element;
 310       XmlPushParser.character_data = Some character_data;
 311   } in
 312   let xml_parser = XmlPushParser.create_parser callbacks in
 313   let backup = backup_registry registry in
 314 (*   if path = None then Hashtbl.clear registry; *)
 315   try
 316     XmlPushParser.parse xml_parser (`File fname)
 317   with exn ->
 318     restore_registry backup registry;
 319     raise exn
 320
 321 let load_from registry ?path fname =
 322   if Filename.is_relative fname then begin
 323     let no_file_found = ref true in
 324     let path =
 325       match path with
 326       | Some path -> path (* path given as argument *)
 327       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 328     in
 329     List.iter
 330       (fun dir ->
 331         let conffile = dir ^ "/" ^ fname in
 332         if Sys.file_exists conffile then begin
 333           no_file_found := false;
 334           load_from_absolute registry conffile
 335         end)
 336        path;
 337     if !no_file_found then
 338       failwith (sprintf
 339         "Helm_registry.init: no configuration file named %s in [ %s ]"
 340         fname (String.concat "; " path))
 341   end else
 342     load_from_absolute registry fname
 343
 344 let fold registry ?prefix ?(interpolate = true) f init =
 345   let value_of k v =
 346     if interpolate then singleton (get registry k) else strip_blanks v
 347   in
 348   match prefix with
 349   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 350   | Some s ->
 351       let key_matches = starts_with (s ^ ".") in
 352       let rec fold_filter acc = function
 353         | [] -> acc
 354         | (k,v) :: tl when key_matches k ->
 355             fold_filter (f acc k (value_of k v)) tl
 356         | _ :: tl -> fold_filter acc tl
 357       in
 358       fold_filter init (hashtbl_pairs registry)
 359
 360 let iter registry ?prefix ?interpolate f =
 361   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 362 let to_list registry ?prefix ?interpolate () =
 363   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 364
 365 let ls registry prefix =
 366   let prefix = prefix ^ "." in
 367   let prefix_len = String.length prefix in
 368   let key_matches = starts_with prefix in
 369   let matching_keys = (* collect matching keys' _postfixes_ *)
 370     fold registry
 371       (fun acc key _ ->
 372         if key_matches key then
 373           String.sub key prefix_len (String.length key - prefix_len) :: acc
 374         else
 375           acc)
 376       []
 377   in
 378   let (sections, keys) =
 379     List.fold_left
 380       (fun (sections, keys) postfix ->
 381         match Str.split dot_rex postfix with
 382         | [key] -> (sections, key :: keys)
 383         | hd_key :: _ ->  (* length > 1 => nested section found *)
 384             (hd_key :: sections, keys)
 385         | _ -> assert false)
 386       ([], []) matching_keys
 387   in
 388   (list_uniq (List.sort Pervasives.compare sections), keys)
 389
 390 (** {2 API implementation}
 391  * functional methods above are wrapped so that they work on a default
 392  * (imperative) registry*)
 393
 394 let default_registry = Hashtbl.create magic_size
 395
 396 let get key = singleton (get default_registry key)
 397 let set = set' ~replace:true default_registry
 398 let has = has default_registry
 399 let fold ?prefix ?interpolate f init =
 400   fold default_registry ?prefix ?interpolate f init
 401 let iter = iter default_registry
 402 let to_list = to_list default_registry
 403 let ls = ls default_registry
 404 let get_typed unmarshaller = get_typed default_registry unmarshaller
 405 let get_opt unmarshaller = get_opt default_registry unmarshaller
 406 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 407 let get_list unmarshaller = get_list default_registry unmarshaller
 408 let get_pair unmarshaller = get_pair default_registry unmarshaller
 409 let set_typed marshaller = set_typed default_registry marshaller
 410 let set_opt unmarshaller = set_opt default_registry unmarshaller
 411 let set_list marshaller = set_list default_registry marshaller
 412 let unset = unset default_registry
 413 let save_to = save_to default_registry
 414 let load_from = load_from default_registry
 415 let clear () = Hashtbl.clear default_registry
 416
 417 let get_string = get_typed string
 418 let get_int = get_typed int
 419 let get_float = get_typed float
 420 let get_bool = get_typed bool
 421 let set_string = set_typed of_string
 422 let set_int = set_typed of_int
 423 let set_float = set_typed of_float
 424 let set_bool = set_typed of_bool
 425