helm/ocaml/tactics/primitiveTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 open ProofEngineHelpers
  27 open ProofEngineTypes
  28
  29 exception NotAnInductiveTypeToEliminate
  30 exception NotTheRightEliminatorShape
  31 exception NoHypothesesFound
  32 exception WrongUriToVariable of string
  33
  34 (* lambda_abstract newmeta ty *)
  35 (* returns a triple [bo],[context],[ty'] where              *)
  36 (* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
  37 (* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
  38 (* So, lambda_abstract is the core of the implementation of *)
  39 (* the Intros tactic.                                       *)
  40 let lambda_abstract context newmeta ty mk_fresh_name =
  41  let module C = Cic in
  42   let rec collect_context context =
  43    function
  44       C.Cast (te,_)   -> collect_context context te
  45     | C.Prod (n,s,t)  ->
  46        let n' = mk_fresh_name context n ~typ:s in
  47         let (context',ty,bo) =
  48          collect_context ((Some (n',(C.Decl s)))::context) t
  49         in
  50          (context',ty,C.Lambda(n',s,bo))
  51     | C.LetIn (n,s,t) ->
  52        let (context',ty,bo) =
  53         collect_context ((Some (n,(C.Def (s,None))))::context) t
  54        in
  55         (context',ty,C.LetIn(n,s,bo))
  56     | _ as t ->
  57       let irl = identity_relocation_list_for_metavariable context in
  58        context, t, (C.Meta (newmeta,irl))
  59   in
  60    collect_context context ty
  61
  62 let eta_expand metasenv context t arg =
  63  let module T = CicTypeChecker in
  64  let module S = CicSubstitution in
  65  let module C = Cic in
  66   let rec aux n =
  67    function
  68       t' when t' = S.lift n arg -> C.Rel (1 + n)
  69     | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
  70     | C.Var (uri,exp_named_subst) ->
  71        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  72         C.Var (uri,exp_named_subst')
  73     | C.Meta _
  74     | C.Sort _
  75     | C.Implicit as t -> t
  76     | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
  77     | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
  78     | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
  79     | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
  80     | C.Appl l -> C.Appl (List.map (aux n) l)
  81     | C.Const (uri,exp_named_subst) ->
  82        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  83         C.Const (uri,exp_named_subst')
  84     | C.MutInd (uri,i,exp_named_subst) ->
  85        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  86         C.MutInd (uri,i,exp_named_subst')
  87     | C.MutConstruct (uri,i,j,exp_named_subst) ->
  88        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  89         C.MutConstruct (uri,i,j,exp_named_subst')
  90     | C.MutCase (sp,i,outt,t,pl) ->
  91        C.MutCase (sp,i,aux n outt, aux n t,
  92         List.map (aux n) pl)
  93     | C.Fix (i,fl) ->
  94        let tylen = List.length fl in
  95         let substitutedfl =
  96          List.map
  97           (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
  98            fl
  99         in
 100          C.Fix (i, substitutedfl)
 101     | C.CoFix (i,fl) ->
 102        let tylen = List.length fl in
 103         let substitutedfl =
 104          List.map
 105           (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
 106            fl
 107         in
 108          C.CoFix (i, substitutedfl)
 109   and aux_exp_named_subst n =
 110    List.map (function uri,t -> uri,aux n t)
 111   in
 112    let argty =
 113     T.type_of_aux' metasenv context arg
 114    in
 115     let fresh_name =
 116      ProofEngineHelpers.mk_fresh_name context (Cic.Name "Heta") ~typ:argty
 117     in
 118      (C.Appl [C.Lambda (fresh_name,argty,aux 0 t) ; arg])
 119
 120 (*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
 121 let classify_metas newmeta in_subst_domain subst_in metasenv =
 122  List.fold_right
 123   (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
 124     if in_subst_domain i then
 125      old_uninst,new_uninst
 126     else
 127      let ty' = subst_in canonical_context ty in
 128       let canonical_context' =
 129        List.fold_right
 130         (fun entry canonical_context' ->
 131           let entry' =
 132            match entry with
 133               Some (n,Cic.Decl s) ->
 134                Some (n,Cic.Decl (subst_in canonical_context' s))
 135             | Some (n,Cic.Def (s,None)) ->
 136                Some (n,Cic.Def ((subst_in canonical_context' s),None))
 137             | None -> None
 138             | Some (_,Cic.Def (_,Some _)) -> assert false
 139           in
 140            entry'::canonical_context'
 141         ) canonical_context []
 142      in
 143       if i < newmeta then
 144        ((i,canonical_context',ty')::old_uninst),new_uninst
 145       else
 146        old_uninst,((i,canonical_context',ty')::new_uninst)
 147   ) metasenv ([],[])
 148
 149 (* Auxiliary function for apply: given a type (a backbone), it returns its   *)
 150 (* head, a META environment in which there is new a META for each hypothesis,*)
 151 (* a list of arguments for the new applications and the indexes of the first *)
 152 (* and last new METAs introduced. The nth argument in the list of arguments  *)
 153 (* is just the nth new META.                                                 *)
 154 let new_metasenv_for_apply newmeta proof context ty =
 155  let module C = Cic in
 156  let module S = CicSubstitution in
 157   let rec aux newmeta =
 158    function
 159       C.Cast (he,_) -> aux newmeta he
 160     | C.Prod (name,s,t) ->
 161        let irl = identity_relocation_list_for_metavariable context in
 162         let newargument = C.Meta (newmeta,irl) in
 163          let (res,newmetasenv,arguments,lastmeta) =
 164           aux (newmeta + 1) (S.subst newargument t)
 165          in
 166           res,(newmeta,context,s)::newmetasenv,newargument::arguments,lastmeta
 167     | t -> t,[],[],newmeta
 168   in
 169    (* WARNING: here we are using the invariant that above the most *)
 170    (* recente new_meta() there are no used metas.                  *)
 171    let (res,newmetasenv,arguments,lastmeta) = aux newmeta ty in
 172     res,newmetasenv,arguments,lastmeta
 173
 174 (* Useful only inside apply_tac *)
 175 let
 176  generalize_exp_named_subst_with_fresh_metas context newmeta uri exp_named_subst
 177 =
 178  let module C = Cic in
 179   let params =
 180    match CicEnvironment.get_obj uri with
 181       C.Constant (_,_,_,params)
 182     | C.CurrentProof (_,_,_,_,params)
 183     | C.Variable (_,_,_,params)
 184     | C.InductiveDefinition (_,params,_) -> params
 185   in
 186    let exp_named_subst_diff,new_fresh_meta,newmetasenvfragment,exp_named_subst'=
 187     let next_fresh_meta = ref newmeta in
 188     let newmetasenvfragment = ref [] in
 189     let exp_named_subst_diff = ref [] in
 190      let rec aux =
 191       function
 192          [],[] -> []
 193        | uri::tl,[] ->
 194           let ty =
 195            match CicEnvironment.get_obj uri with
 196               C.Variable (_,_,ty,_) ->
 197                CicSubstitution.subst_vars !exp_named_subst_diff ty
 198             | _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
 199           in
 200            let irl = identity_relocation_list_for_metavariable context in
 201            let subst_item = uri,C.Meta (!next_fresh_meta,irl) in
 202             newmetasenvfragment :=
 203              (!next_fresh_meta,context,ty)::!newmetasenvfragment ;
 204             exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 205             incr next_fresh_meta ;
 206             subst_item::(aux (tl,[]))
 207        | uri::tl1,((uri',_) as s)::tl2 ->
 208           assert (UriManager.eq uri uri') ;
 209           s::(aux (tl1,tl2))
 210        | [],_ -> assert false
 211      in
 212       let exp_named_subst' = aux (params,exp_named_subst) in
 213        !exp_named_subst_diff,!next_fresh_meta,
 214         List.rev !newmetasenvfragment, exp_named_subst'
 215    in
 216 prerr_endline ("@@@ " ^ CicPp.ppterm (Cic.Var (uri,exp_named_subst)) ^ " |--> " ^ CicPp.ppterm (Cic.Var (uri,exp_named_subst'))) ;
 217     new_fresh_meta,newmetasenvfragment,exp_named_subst',exp_named_subst_diff
 218 ;;
 219
 220 let apply_tac ~term ~status:(proof, goal) =
 221   (* Assumption: The term "term" must be closed in the current context *)
 222  let module T = CicTypeChecker in
 223  let module R = CicReduction in
 224  let module C = Cic in
 225   let (_,metasenv,_,_) = proof in
 226   let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 227   let newmeta = new_meta ~proof in
 228    let exp_named_subst_diff,newmeta',newmetasenvfragment,term' =
 229     match term with
 230        C.Var (uri,exp_named_subst) ->
 231         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 232          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 233           exp_named_subst
 234         in
 235          exp_named_subst_diff,newmeta',newmetasenvfragment,
 236           C.Var (uri,exp_named_subst')
 237      | C.Const (uri,exp_named_subst) ->
 238         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 239          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 240           exp_named_subst
 241         in
 242          exp_named_subst_diff,newmeta',newmetasenvfragment,
 243           C.Const (uri,exp_named_subst')
 244      | C.MutInd (uri,tyno,exp_named_subst) ->
 245         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 246          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 247           exp_named_subst
 248         in
 249          exp_named_subst_diff,newmeta',newmetasenvfragment,
 250           C.MutInd (uri,tyno,exp_named_subst')
 251      | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
 252         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 253          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 254           exp_named_subst
 255         in
 256          exp_named_subst_diff,newmeta',newmetasenvfragment,
 257           C.MutConstruct (uri,tyno,consno,exp_named_subst')
 258      | _ -> [],newmeta,[],term
 259    in
 260    let metasenv' = metasenv@newmetasenvfragment in
 261 prerr_endline ("^^^^^TERM': " ^ CicPp.ppterm term') ;
 262    let termty =
 263     CicSubstitution.subst_vars exp_named_subst_diff
 264      (CicTypeChecker.type_of_aux' metasenv' context term)
 265    in
 266 prerr_endline ("^^^^^TERMTY: " ^ CicPp.ppterm termty) ;
 267     (* newmeta is the lowest index of the new metas introduced *)
 268     let (consthead,newmetas,arguments,_) =
 269      new_metasenv_for_apply newmeta' proof context termty
 270     in
 271      let newmetasenv = metasenv'@newmetas in
 272       let subst,newmetasenv' =
 273        CicUnification.fo_unif newmetasenv context consthead ty
 274       in
 275        let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
 276        let apply_subst = CicUnification.apply_subst subst in
 277         let old_uninstantiatedmetas,new_uninstantiatedmetas =
 278          (* subst_in doesn't need the context. Hence the underscore. *)
 279          let subst_in _ = CicUnification.apply_subst subst in
 280           classify_metas newmeta in_subst_domain subst_in newmetasenv'
 281         in
 282          let bo' =
 283           apply_subst
 284            (if List.length newmetas = 0 then
 285              term'
 286             else
 287              Cic.Appl (term'::arguments)
 288            )
 289          in
 290 prerr_endline ("XXXX " ^ CicPp.ppterm (if List.length newmetas = 0 then term' else Cic.Appl (term'::arguments)) ^ " |>>> " ^ CicPp.ppterm bo') ;
 291           let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
 292           let (newproof, newmetasenv''') =
 293            let subst_in = CicUnification.apply_subst ((metano,bo')::subst) in
 294             subst_meta_and_metasenv_in_proof
 295               proof metano subst_in newmetasenv''
 296           in
 297            (newproof, List.map (function (i,_,_) -> i) new_uninstantiatedmetas)
 298
 299   (* TODO per implementare i tatticali e' necessario che tutte le tattiche
 300   sollevino _solamente_ Fail *)
 301 let apply_tac ~term ~status =
 302   try
 303     apply_tac ~term ~status
 304       (* TODO cacciare anche altre eccezioni? *)
 305   with CicUnification.UnificationFailed as e ->
 306     raise (Fail (Printexc.to_string e))
 307
 308 let intros_tac
 309  ?(mk_fresh_name_callback = ProofEngineHelpers.mk_fresh_name) ()
 310  ~status:(proof, goal)
 311 =
 312  let module C = Cic in
 313  let module R = CicReduction in
 314   let (_,metasenv,_,_) = proof in
 315   let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 316    let newmeta = new_meta ~proof in
 317     let (context',ty',bo') =
 318      lambda_abstract context newmeta ty mk_fresh_name_callback
 319     in
 320      let (newproof, _) =
 321        subst_meta_in_proof proof metano bo' [newmeta,context',ty']
 322      in
 323       (newproof, [newmeta])
 324
 325 let cut_tac
 326  ?(mk_fresh_name_callback = ProofEngineHelpers.mk_fresh_name)
 327  term ~status:(proof, goal)
 328 =
 329  let module C = Cic in
 330   let curi,metasenv,pbo,pty = proof in
 331   let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 332    let newmeta1 = new_meta ~proof in
 333    let newmeta2 = newmeta1 + 1 in
 334    let fresh_name =
 335     mk_fresh_name_callback context (Cic.Name "Hcut") ~typ:term in
 336    let context_for_newmeta1 =
 337     (Some (fresh_name,C.Decl term))::context in
 338    let irl1 =
 339     identity_relocation_list_for_metavariable context_for_newmeta1 in
 340    let irl2 = identity_relocation_list_for_metavariable context in
 341     let newmeta1ty = CicSubstitution.lift 1 ty in
 342     let bo' =
 343      C.Appl
 344       [C.Lambda (fresh_name,term,C.Meta (newmeta1,irl1)) ;
 345        C.Meta (newmeta2,irl2)]
 346     in
 347      let (newproof, _) =
 348       subst_meta_in_proof proof metano bo'
 349        [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
 350      in
 351       (newproof, [newmeta1 ; newmeta2])
 352
 353 let letin_tac
 354  ?(mk_fresh_name_callback = ProofEngineHelpers.mk_fresh_name)
 355  term ~status:(proof, goal)
 356 =
 357  let module C = Cic in
 358   let curi,metasenv,pbo,pty = proof in
 359   let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 360    let _ = CicTypeChecker.type_of_aux' metasenv context term in
 361     let newmeta = new_meta ~proof in
 362     let fresh_name =
 363      mk_fresh_name_callback context (Cic.Name "Hletin") ~typ:term in
 364     let context_for_newmeta =
 365      (Some (fresh_name,C.Def (term,None)))::context in
 366     let irl =
 367      identity_relocation_list_for_metavariable context_for_newmeta in
 368      let newmetaty = CicSubstitution.lift 1 ty in
 369      let bo' = C.LetIn (fresh_name,term,C.Meta (newmeta,irl)) in
 370       let (newproof, _) =
 371         subst_meta_in_proof
 372           proof metano bo'[newmeta,context_for_newmeta,newmetaty]
 373       in
 374        (newproof, [newmeta])
 375
 376   (** functional part of the "exact" tactic *)
 377 let exact_tac ~term ~status:(proof, goal) =
 378  (* Assumption: the term bo must be closed in the current context *)
 379  let (_,metasenv,_,_) = proof in
 380  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 381  let module T = CicTypeChecker in
 382  let module R = CicReduction in
 383  if R.are_convertible context (T.type_of_aux' metasenv context term) ty then
 384   begin
 385    let (newproof, metasenv') =
 386      subst_meta_in_proof proof metano term [] in
 387    (newproof, [])
 388   end
 389  else
 390   raise (Fail "The type of the provided term is not the one expected.")
 391
 392
 393 (* not really "primitive" tactics .... *)
 394
 395 let elim_tac ~term ~status:(proof, goal) =
 396  let module T = CicTypeChecker in
 397  let module U = UriManager in
 398  let module R = CicReduction in
 399  let module C = Cic in
 400   let (curi,metasenv,_,_) = proof in
 401   let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 402    let termty = T.type_of_aux' metasenv context term in
 403    let uri,exp_named_subst,typeno,args =
 404     match termty with
 405        C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 406      | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 407          (uri,exp_named_subst,typeno,args)
 408      | _ -> raise NotAnInductiveTypeToEliminate
 409    in
 410     let eliminator_uri =
 411      let buri = U.buri_of_uri uri in
 412      let name =
 413       match CicEnvironment.get_obj uri with
 414          C.InductiveDefinition (tys,_,_) ->
 415           let (name,_,_,_) = List.nth tys typeno in
 416            name
 417        | _ -> assert false
 418      in
 419      let ext =
 420       match T.type_of_aux' metasenv context ty with
 421          C.Sort C.Prop -> "_ind"
 422        | C.Sort C.Set  -> "_rec"
 423        | C.Sort C.Type -> "_rect"
 424        | _ -> assert false
 425      in
 426       U.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
 427     in
 428      let eliminator_ref = C.Const (eliminator_uri,exp_named_subst) in
 429       let ety = T.type_of_aux' metasenv context eliminator_ref in
 430       let newmeta = new_meta ~proof in
 431        let (econclusion,newmetas,arguments,lastmeta) =
 432          new_metasenv_for_apply newmeta proof context ety
 433        in
 434         (* Here we assume that we have only one inductive hypothesis to *)
 435         (* eliminate and that it is the last hypothesis of the theorem. *)
 436         (* A better approach would be fingering the hypotheses in some  *)
 437         (* way.                                                         *)
 438         let meta_of_corpse =
 439          let (_,canonical_context,_) =
 440           List.find (function (m,_,_) -> m=(lastmeta - 1)) newmetas
 441          in
 442           let irl =
 443            identity_relocation_list_for_metavariable canonical_context
 444           in
 445            Cic.Meta (lastmeta - 1, irl)
 446         in
 447         let newmetasenv = newmetas @ metasenv in
 448         let subst1,newmetasenv' =
 449          CicUnification.fo_unif newmetasenv context term meta_of_corpse
 450         in
 451          let ueconclusion = CicUnification.apply_subst subst1 econclusion in
 452           (* The conclusion of our elimination principle is *)
 453           (*  (?i farg1 ... fargn)                         *)
 454           (* The conclusion of our goal is ty. So, we can   *)
 455           (* eta-expand ty w.r.t. farg1 .... fargn to get   *)
 456           (* a new ty equal to (P farg1 ... fargn). Now     *)
 457           (* ?i can be instantiated with P and we are ready *)
 458           (* to refine the term.                            *)
 459           let emeta, fargs =
 460            match ueconclusion with
 461               C.Appl ((C.Meta (emeta,_))::fargs) -> emeta,fargs
 462             | C.Meta (emeta,_) -> emeta,[]
 463             | _ -> raise NotTheRightEliminatorShape
 464           in
 465            let ty' = CicUnification.apply_subst subst1 ty in
 466            let eta_expanded_ty =
 467 (*CSC: newmetasenv' era metasenv ??????????? *)
 468             List.fold_left (eta_expand newmetasenv' context) ty' fargs
 469            in
 470             let subst2,newmetasenv'' =
 471 (*CSC: passo newmetasenv', ma alcune variabili sono gia' state sostituite
 472 da subst1!!!! Dovrei rimuoverle o sono innocue?*)
 473              CicUnification.fo_unif
 474               newmetasenv' context ueconclusion eta_expanded_ty
 475             in
 476              let in_subst_domain i =
 477               let eq_to_i = function (j,_) -> i=j in
 478                List.exists eq_to_i subst1 ||
 479                List.exists eq_to_i subst2
 480              in
 481               (* When unwinding the META that corresponds to the elimination *)
 482               (* predicate (which is emeta), we must also perform one-step   *)
 483               (* beta-reduction. apply_subst doesn't need the context. Hence *)
 484               (* the underscore.                                             *)
 485               let apply_subst _ t =
 486                let t' = CicUnification.apply_subst subst1 t in
 487                 CicUnification.apply_subst_reducing
 488                  subst2 (Some (emeta,List.length fargs)) t'
 489               in
 490                 let old_uninstantiatedmetas,new_uninstantiatedmetas =
 491                  classify_metas newmeta in_subst_domain apply_subst
 492                   newmetasenv''
 493                 in
 494                  let arguments' = List.map (apply_subst context) arguments in
 495                   let bo' = Cic.Appl (eliminator_ref::arguments') in
 496                    let newmetasenv''' =
 497                     new_uninstantiatedmetas@old_uninstantiatedmetas
 498                    in
 499                     let (newproof, newmetasenv'''') =
 500                      (* When unwinding the META that corresponds to the *)
 501                      (* elimination predicate (which is emeta), we must *)
 502                      (* also perform one-step beta-reduction.           *)
 503                      (* The only difference w.r.t. apply_subst is that  *)
 504                      (* we also substitute metano with bo'.             *)
 505                      (*CSC: Nota: sostituire nuovamente subst1 e' superfluo, *)
 506                      (*CSC: no?                                              *)
 507                      let apply_subst' t =
 508                       let t' = CicUnification.apply_subst subst1 t in
 509                        CicUnification.apply_subst_reducing
 510                         ((metano,bo')::subst2)
 511                         (Some (emeta,List.length fargs)) t'
 512                      in
 513                       subst_meta_and_metasenv_in_proof
 514                         proof metano apply_subst' newmetasenv'''
 515                     in
 516                      (newproof,
 517                       List.map (function (i,_,_) -> i) new_uninstantiatedmetas)
 518 ;;
 519
 520 (* The simplification is performed only on the conclusion *)
 521 let elim_intros_simpl_tac ~term =
 522  Tacticals.then_ ~start:(elim_tac ~term)
 523   ~continuation:
 524    (Tacticals.thens
 525      ~start:(intros_tac ())
 526      ~continuations:
 527        [ReductionTactics.simpl_tac ~also_in_hypotheses:false ~terms:None])
 528 ;;
 529
 530 exception NotConvertible
 531
 532 (*CSC: Bug (or feature?). [with_what] is parsed in the context of the goal,  *)
 533 (*CSC: while [what] can have a richer context (because of binders)           *)
 534 (*CSC: So it is _NOT_ possible to use those binders in the [with_what] term. *)
 535 (*CSC: Is that evident? Is that right? Or should it be changed?              *)
 536 let change_tac ~what ~with_what ~status:(proof, goal) =
 537  let curi,metasenv,pbo,pty = proof in
 538  let metano,context,ty = List.find (function (m,_,_) -> m=goal) metasenv in
 539   (* are_convertible works only on well-typed terms *)
 540   ignore (CicTypeChecker.type_of_aux' metasenv context with_what) ;
 541   if CicReduction.are_convertible context what with_what then
 542    begin
 543     let replace =
 544      ProofEngineReduction.replace
 545       ~equality:(==) ~what:[what] ~with_what:[with_what]
 546     in
 547     let ty' = replace ty in
 548     let context' =
 549      List.map
 550       (function
 551           Some (name,Cic.Def (t,None)) -> Some (name,Cic.Def ((replace t),None))
 552         | Some (name,Cic.Decl t) -> Some (name,Cic.Decl (replace t))
 553         | None -> None
 554         | Some (_,Cic.Def (_,Some _)) -> assert false
 555       ) context
 556     in
 557      let metasenv' =
 558       List.map
 559        (function
 560            (n,_,_) when n = metano -> (metano,context',ty')
 561          | _ as t -> t
 562        ) metasenv
 563      in
 564       (curi,metasenv',pbo,pty), [metano]
 565    end
 566   else
 567    raise (ProofEngineTypes.Fail "Not convertible")