helm/ocaml/xml/xmlPushParser.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let gzip_bufsize = 10240
  27
  28 type callbacks = {
  29   start_element: (string -> (string * string) list -> unit) option;
  30   end_element: (string -> unit) option;
  31   character_data: (string -> unit) option;
  32   processing_instruction: (string -> string -> unit) option;
  33   comment: (string -> unit) option;
  34 }
  35
  36 let default_callbacks = {
  37   start_element = None;
  38   end_element = None;
  39   character_data = None;
  40   processing_instruction = None;
  41   comment = None;
  42 }
  43
  44 type xml_source =
  45   [ `Channel of in_channel
  46   | `File of string
  47   | `Gzip_channel of Gzip.in_channel
  48   | `Gzip_file of string
  49   | `String of string
  50   ]
  51
  52 type position = int * int
  53
  54 type xml_parser = Expat.expat_parser
  55
  56 exception Parse_error of string
  57
  58 let create_parser callbacks =
  59   let expat_parser = Expat.parser_create ~encoding:None in
  60   (match callbacks.start_element with
  61   | Some f -> Expat.set_start_element_handler expat_parser f
  62   | _ -> ());
  63   (match callbacks.end_element with
  64   | Some f -> Expat.set_end_element_handler expat_parser f
  65   | _ -> ());
  66   (match callbacks.character_data with
  67   | Some f -> Expat.set_character_data_handler expat_parser f
  68   | _ -> ());
  69   (match callbacks.processing_instruction with
  70   | Some f -> Expat.set_processing_instruction_handler expat_parser f
  71   | _ -> ());
  72   (match callbacks.comment with
  73   | Some f -> Expat.set_comment_handler expat_parser f
  74   | _ -> ());
  75   expat_parser
  76
  77 let final = Expat.final
  78
  79 let get_position expat_parser =
  80   (Expat.get_current_line_number expat_parser,
  81    Expat.get_current_column_number expat_parser)
  82
  83 let parse expat_parser =
  84   let parse_fun = Expat.parse expat_parser in
  85   let rec aux = function
  86     | `Channel ic ->
  87         (try
  88           while true do parse_fun (input_line ic ^ "\n") done
  89         with End_of_file -> final expat_parser)
  90     | `File fname ->
  91         let ic = open_in fname in
  92         aux (`Channel ic);
  93         close_in ic
  94     | `Gzip_channel ic ->
  95         let buf = String.create gzip_bufsize in
  96         (try
  97           while true do
  98             let bytes = Gzip.input ic buf 0 gzip_bufsize in
  99             if bytes = 0 then raise End_of_file;
 100             parse_fun (String.sub buf 0 bytes)
 101           done
 102         with End_of_file -> final expat_parser)
 103     | `Gzip_file fname ->
 104         let ic = Gzip.open_in fname in
 105         aux (`Gzip_channel ic);
 106         Gzip.close_in ic
 107     | `String s -> parse_fun s
 108   in
 109   aux
 110
 111 let parse expat_parser xml_source =
 112   try
 113     parse expat_parser xml_source
 114   with Expat.Expat_error xml_error ->
 115     raise (Parse_error (Expat.xml_error_to_string xml_error))
 116