helm/searchEngine/searchEngine.ml

   1 (* Copyright (C) 2002-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 open Printf
  27
  28 let debug = true
  29 let debug_print s = if debug then prerr_endline s
  30 let _ = Http_common.debug := false
  31
  32 exception Chat_unfinished
  33 exception Unbound_identifier of string
  34 exception Invalid_action of string  (* invalid action for "/search" method *)
  35
  36   (** raised by elim when a MutInd is required but not found *)
  37 exception Not_a_MutInd
  38
  39 let daemon_name = "Whelp"
  40 let configuration_file = "/projects/helm/etc/whelp.conf.xml"
  41
  42 let placeholders = [
  43   "ACTION"; "ADVANCED"; "ADVANCED_CHECKED"; "CHOICES"; "CURRENT_CHOICES";
  44   "EXPRESSION"; "ID"; "IDEN"; "ID_TO_URIS"; "INTERPRETATIONS";
  45   "INTERPRETATIONS_LABELS"; "MSG"; "NEW_ALIASES"; "NEXT_LINK"; "NO_CHOICES";
  46   "PAGE"; "PAGES"; "PAGELIST"; "PREV_LINK"; "QUERY_KIND"; "QUERY_SUMMARY"; "RESULTS";
  47   "SEARCH_ENGINE_URL"; "SIMPLE_CHECKED"; "TITLE";
  48 ]
  49
  50 let tag =
  51   let regexps = Hashtbl.create 25 in
  52   List.iter
  53     (fun tag -> Hashtbl.add regexps tag (Pcre.regexp (sprintf "@%s@" tag)))
  54     placeholders;
  55   fun name ->
  56     try
  57       Hashtbl.find regexps name
  58     with Not_found -> assert false
  59
  60   (* First of all we load the configuration *)
  61 let _ = Helm_registry.load_from configuration_file
  62 let port = Helm_registry.get_int "search_engine.port"
  63 let pages_dir = Helm_registry.get "search_engine.html_dir"
  64
  65 let moogle_TPL = pages_dir ^ "/moogle.html"
  66 let choices_TPL = pages_dir ^ "/moogle_chat.html"
  67
  68 let my_own_url =
  69  let ic = Unix.open_process_in "hostname -f" in
  70  let hostname = input_line ic in
  71  ignore (Unix.close_process_in ic);
  72  sprintf "http://%s:%d" hostname port
  73 let _ = Helm_registry.set "search_engine.my_own_url" my_own_url
  74
  75 let bad_request body outchan =
  76   Http_daemon.respond_error ~code:(`Status (`Client_error `Bad_request)) ~body
  77     outchan
  78
  79   (** chain application of Pcre substitutions *)
  80 let rec apply_substs substs line =
  81   match substs with
  82   | [] -> line
  83   | (rex, templ) :: rest -> apply_substs rest (Pcre.replace ~rex ~templ line)
  84   (** fold like function on files *)
  85 let fold_file f init fname =
  86   let inchan = open_in fname in
  87   let rec fold_lines' value =
  88     try
  89       let line = input_line inchan in
  90       fold_lines' (f value line)
  91     with End_of_file -> value
  92   in
  93   let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  94   close_in inchan;
  95   res
  96   (** iter like function on files *)
  97 let iter_file f = fold_file (fun _ line -> f line) ()
  98 let javascript_quote s =
  99  let rex = Pcre.regexp "'" in
 100  let rex' = Pcre.regexp "\"" in
 101   Pcre.replace ~rex ~templ:"\\'"
 102    (Pcre.replace ~rex:rex' ~templ:"\\\"" s)
 103 let string_tail s =
 104   let len = String.length s in
 105   String.sub s 1 (len-1)
 106 let nonvar s =
 107   let len = String.length s in
 108   let suffix = String.sub s (len-4) 4 in
 109   not (suffix  = ".var")
 110
 111 let add_param_substs params =
 112   List.map
 113     (fun (key,value) ->
 114       let key' = (Pcre.extract ~pat:"param\\.(.*)" key).(1) in
 115       Pcre.regexp ("@" ^ key' ^ "@"), value)
 116     (List.filter
 117       (fun ((key,_) as p) -> Pcre.pmatch ~pat:"^param\\." key)
 118       params)
 119
 120 let page_RE = Pcre.regexp "&param\\.page=\\d+"
 121 let identifier_RE = Pcre.regexp "^\\s*(\\w|')+\\s*$"
 122 let qualified_mutind_RE =
 123  Pcre.regexp "^\\s*cic:(/(\\w|')+)+\\.ind#xpointer\\(1/\\d+\\)\\s*$"
 124
 125 let query_kind_of_req (req: Http_types.request) =
 126   match req#path with
 127   | "/match" -> "Match"
 128   | "/hint" -> "Hint"
 129   | "/locate" -> "Locate"
 130   | "/elim" -> "Elim"
 131   | "/instance" -> "Instance"
 132   | _ -> ""
 133
 134   (* given a uri with a query part in input try to find in it a string
 135    * "&param_name=..." (where param_name is given). If found its value will be
 136    * set to param_value. If not, a trailing "&param_name=param_value" (where
 137    * both are given) is added to the input string *)
 138 let patch_param param_name param_value url =
 139   let rex = Pcre.regexp (sprintf "&%s=[^&]*" (Pcre.quote param_name)) in
 140   if Pcre.pmatch ~rex url then
 141     Pcre.replace ~rex ~templ:(sprintf "%s=%s" param_name param_value) url
 142   else
 143     sprintf "%s&%s=%s" url param_name param_value
 144
 145   (** HTML encoding, e.g.: "<" -> "&lt;" *)
 146 let html_encode = Netencoding.Html.encode_from_latin1
 147
 148 let fold_n_to_m f n m acc =
 149  let rec aux acc =
 150   function
 151      i when i <= m -> aux (f i acc) (i + 1)
 152    | _ -> acc
 153  in
 154   aux acc n
 155
 156 let send_results results
 157   ?(id_to_uris = CicTextualParser2.EnvironmentP3.of_string "")
 158    (req: Http_types.request) outchan
 159   =
 160   let query_kind = query_kind_of_req req in
 161   let interp = try req#param "interp" with Http_types.Param_not_found _ -> "" in
 162   let page_link anchor page =
 163     try
 164       let this = req#param "this" in
 165       let target =
 166         (patch_param "param.interp" interp
 167            (patch_param "param.page" (string_of_int page)
 168               this))
 169       in
 170       let target = Pcre.replace ~pat:"&" ~templ:"&amp;" target in
 171       sprintf "<a href=\"%s\">%s</a>" target anchor
 172     with Http_types.Param_not_found _ -> ""
 173   in
 174   Http_daemon.send_basic_headers ~code:(`Code 200) outchan ;
 175   Http_daemon.send_header "Content-Type" "text/xml" outchan;
 176   Http_daemon.send_CRLF outchan ;
 177   let subst =
 178     match results with
 179     | `Results results ->
 180         let page = try int_of_string (req#param "page") with _ -> 1 in
 181         let results_no = List.length results in
 182         let results_per_page =
 183           Helm_registry.get_int "search_engine.results_per_page"
 184         in
 185         let pages =
 186           if results_no mod results_per_page = 0 then
 187             results_no / results_per_page
 188           else
 189             results_no / results_per_page + 1
 190         in
 191         let pages = if pages = 0 then 1 else pages in
 192         let additional_pages = 3 in
 193         let (summary, results) = MooglePp.theory_of_result page results in
 194         [ tag "PAGE", string_of_int page;
 195           tag "PAGES", string_of_int pages ^ " Pages";
 196           tag "PAGELIST",
 197           (let inf = page - additional_pages in
 198            let sup = page + additional_pages in
 199            let superinf = inf - (sup - pages) in
 200            let supersup = sup + (1 - inf) in
 201            let n,m =
 202             if inf >= 1 && sup <= pages then
 203              inf,sup
 204             else if inf < 1 then
 205              1, (if supersup <= pages then supersup else pages)
 206             else (* sup > pages *)
 207              (if superinf >= 1 then superinf else 1),pages
 208            in
 209             fold_n_to_m
 210              (fun n acc -> acc ^ " " ^
 211                           (if n = page then string_of_int n
 212                            else page_link (string_of_int n) n))
 213              n m "");
 214           tag "PREV_LINK", (if page > 1 then page_link "Prev" (page-1) else "");
 215           tag "NEXT_LINK",
 216             (if page < pages then page_link "Next" (page+1) else "");
 217           tag "QUERY_KIND", query_kind;
 218           tag "QUERY_SUMMARY", summary;
 219           tag "RESULTS", results ]
 220     | `Error msg ->
 221         [ tag "PAGE", "1";
 222           tag "PAGES", "1 Page";
 223           tag "PAGELIST", "";
 224           tag "PREV_LINK", "";
 225           tag "NEXT_LINK", "";
 226           tag "QUERY_KIND", query_kind;
 227           tag "QUERY_SUMMARY", "error";
 228           tag "RESULTS", msg ]
 229   in
 230   let advanced =
 231     try
 232       req#param "advanced"
 233     with Http_types.Param_not_found _ -> "no"
 234   in
 235   let subst =
 236     (tag "SEARCH_ENGINE_URL", my_own_url) ::
 237     (tag "ADVANCED", advanced) ::
 238     (tag "EXPRESSION", html_encode (req#param "expression")) ::
 239     add_param_substs req#params @
 240     (if advanced = "no" then
 241       [ tag "SIMPLE_CHECKED", "checked='true'";
 242         tag "ADVANCED_CHECKED", "" ]
 243     else
 244       [ tag "SIMPLE_CHECKED", "";
 245         tag "ADVANCED_CHECKED", "checked='true'" ]) @
 246     subst
 247   in
 248   iter_file
 249     (fun line ->
 250       let new_aliases =
 251         CicTextualParser2.EnvironmentP3.to_string id_to_uris
 252       in
 253       let processed_line =
 254         apply_substs
 255           (* CSC: Bug here: this is a string, not an array! *)
 256           ((tag "NEW_ALIASES", "'" ^ javascript_quote new_aliases ^ "'") ::
 257             subst)
 258           line
 259       in
 260       output_string outchan (processed_line ^ "\n"))
 261     moogle_TPL
 262
 263 let exec_action dbd (req: Http_types.request) outchan =
 264   let term_str = req#param "expression" in
 265   try
 266     if req#path = "/elim" &&
 267      not (Pcre.pmatch ~rex:identifier_RE term_str ||
 268           Pcre.pmatch ~rex:qualified_mutind_RE term_str) then
 269       raise Not_a_MutInd;
 270     let (context, metasenv) = ([], []) in
 271     let id_to_uris_raw =
 272       try req#param "aliases"
 273       with Http_types.Param_not_found _ -> ""
 274     in
 275     let parse_interpretation_choices choices =
 276       List.map int_of_string (Pcre.split ~pat:" " choices) in
 277     let parse_choices choices_raw =
 278       let choices = Pcre.split ~pat:";" choices_raw in
 279       List.fold_left
 280         (fun f x ->
 281            match Pcre.split ~pat:"\\s" x with
 282              | ""::id::tail
 283              | id::tail when id<>"" ->
 284                  (fun id' ->
 285                     if id = id' then
 286                       Some (List.map (fun u -> Netencoding.Url.decode u) tail)
 287                     else
 288                       f id')
 289              | _ -> failwith "Can't parse choices")
 290         (fun _ -> None)
 291         choices
 292     in
 293     let id_to_uris = CicTextualParser2.EnvironmentP3.of_string id_to_uris_raw in
 294     let id_to_choices =
 295       try
 296         parse_choices (req#param "choices")
 297       with Http_types.Param_not_found _ -> (fun _ -> None)
 298     in
 299     let interpretation_choices =
 300       try
 301         let choices_raw = req#param "interpretation_choices" in
 302         if choices_raw = "" then None
 303         else Some (parse_interpretation_choices choices_raw)
 304       with Http_types.Param_not_found _ -> None
 305     in
 306     let module Chat: DisambiguateTypes.Callbacks =
 307       struct
 308         let interactive_user_uri_choice ~selection_mode ?ok
 309           ?enable_button_for_non_vars ~(title: string) ~(msg: string)
 310           ~(id: string) (choices: string list)
 311         =
 312           match id_to_choices id with
 313           | Some choices -> choices
 314           | None -> List.filter nonvar choices
 315
 316         let interactive_interpretation_choice interpretations =
 317           match interpretation_choices with
 318           | Some l -> l
 319           | None ->
 320               let html_interpretations =
 321                 MooglePp.html_of_interpretations interpretations
 322               in
 323               Http_daemon.send_basic_headers ~code:(`Code 200) outchan ;
 324               Http_daemon.send_CRLF outchan ;
 325               let advanced =
 326                 try
 327                   req#param "advanced"
 328                 with Http_types.Param_not_found _ -> "no"
 329               in
 330               let query_kind = query_kind_of_req req in
 331               iter_file
 332                 (fun line ->
 333                    let processed_line =
 334                      apply_substs
 335                        [ tag "SEARCH_ENGINE_URL", my_own_url;
 336                          tag "ADVANCED", advanced;
 337                          tag "INTERPRETATIONS", html_interpretations;
 338                          tag "CURRENT_CHOICES", req#param "choices";
 339                          tag "EXPRESSION", html_encode (req#param "expression");
 340                          tag "QUERY_KIND", query_kind;
 341                          tag "QUERY_SUMMARY", "disambiguation";
 342                          tag "ACTION", string_tail req#path ]
 343                        line
 344                    in
 345                    output_string outchan (processed_line ^ "\n"))
 346                 choices_TPL;
 347               raise Chat_unfinished
 348
 349         let input_or_locate_uri ~title ?id () =
 350           match id with
 351           | Some id -> raise (Unbound_identifier id)
 352           | None -> assert false
 353       end
 354     in
 355     let module Disambiguate' = Disambiguate.Make(Chat) in
 356     let ast = CicTextualParser2.parse_term (Stream.of_string term_str) in
 357     let (id_to_uris, metasenv, term) =
 358       match
 359         Disambiguate'.disambiguate_term ~dbd ~context ~metasenv
 360           ~aliases:id_to_uris ast
 361       with
 362       | [id_to_uris,metasenv,term,_] -> id_to_uris,metasenv,term
 363       | _ -> assert false
 364     in
 365     let uris =
 366       match req#path with
 367       | "/match" -> MetadataQuery.match_term ~dbd term
 368       | "/instance" -> MetadataQuery.instance ~dbd term
 369       | "/hint" ->
 370           let status = ProofEngineTypes.initial_status term metasenv in
 371           let intros = PrimitiveTactics.intros_tac () in
 372           let subgoals = ProofEngineTypes.apply_tactic intros status in
 373           (match subgoals with
 374           | proof, [goal] ->
 375               let (uri,metasenv,bo,ty) = proof in
 376               List.map fst (MetadataQuery.experimental_hint ~dbd (proof, goal))
 377           | _ -> assert false)
 378       | "/elim" ->
 379           let uri =
 380             match term with
 381             | Cic.MutInd (uri, typeno, _) ->
 382                 UriManager.string_of_uriref (uri, [typeno])
 383             | _ -> raise Not_a_MutInd
 384           in
 385           MetadataQuery.elim ~dbd uri
 386       | _ -> assert false
 387     in
 388     send_results ~id_to_uris (`Results uris) req outchan
 389   with
 390   | Not_a_MutInd ->
 391       send_results (`Error (MooglePp.pp_error "Not an inductive type"
 392         ("elim requires as input an identifier corresponding to an inductive"
 393          ^ " type")))
 394         req outchan
 395
 396 let callback dbd (req: Http_types.request) outchan =
 397   try
 398     debug_print (sprintf "Received request: %s" req#path);
 399     (match req#path with
 400     | "/getpage" ->
 401           (* TODO implement "is_permitted" *)
 402         (let is_permitted page = not (Pcre.pmatch ~pat:"/" page) in
 403         let page = req#param "url" in
 404         let fname = sprintf "%s/%s" pages_dir page in
 405         let preprocess =
 406           (try
 407             bool_of_string (req#param "preprocess")
 408           with Invalid_argument _ | Http_types.Param_not_found _ -> false)
 409         in
 410         (match page with
 411         | page when is_permitted page && Sys.file_exists fname ->
 412             Http_daemon.send_basic_headers ~code:(`Code 200) outchan;
 413             Http_daemon.send_header "Content-Type" "text/html" outchan;
 414             Http_daemon.send_CRLF outchan;
 415             if preprocess then begin
 416               iter_file
 417                 (fun line ->
 418                   output_string outchan
 419                     ((apply_substs
 420                        ((tag "SEARCH_ENGINE_URL", my_own_url) ::
 421                         (tag "ADVANCED", "no") ::
 422                         (tag "RESULTS", "") ::
 423                         add_param_substs req#params)
 424                        line) ^
 425                     "\n"))
 426                 fname
 427             end else
 428               Http_daemon.send_file ~src:(Http_types.FileSrc fname) outchan
 429         | page -> Http_daemon.respond_forbidden ~url:page outchan))
 430     | "/help" -> Http_daemon.respond ~body:daemon_name outchan
 431     | "/locate" ->
 432         let initial_expression =
 433           try req#param "expression" with Http_types.Param_not_found _ -> ""
 434         in
 435         let expression =
 436           Pcre.replace ~pat:"\\s*$"
 437             (Pcre.replace ~pat:"^\\s*" initial_expression)
 438         in
 439         if expression = "" then
 440           send_results (`Results []) req outchan
 441         else begin
 442           let results = MetadataQuery.locate ~dbd expression in
 443           send_results (`Results results) req outchan
 444         end
 445     | "/hint"
 446     | "/elim"
 447     | "/instance"
 448     | "/match" -> exec_action dbd req outchan
 449     | invalid_request ->
 450         Http_daemon.respond_error ~code:(`Status (`Client_error `Bad_request))
 451           outchan);
 452     debug_print (sprintf "%s done!" req#path)
 453   with
 454   | Chat_unfinished -> ()
 455   | Http_types.Param_not_found attr_name ->
 456       bad_request (sprintf "Parameter '%s' is missing" attr_name) outchan
 457   | CicTextualParser2.Parse_error (_, msg) ->
 458       send_results (`Error (MooglePp.pp_error "Parse error" msg)) req outchan
 459   | Unbound_identifier id ->
 460       send_results (`Error (MooglePp.pp_error "Unbound identifier" id)) req
 461         outchan
 462   | exn ->
 463       let exn_string = Printexc.to_string exn in
 464       debug_print exn_string;
 465       let msg = MooglePp.pp_error "Uncaught exception" exn_string in
 466       send_results (`Error msg) req outchan
 467
 468 let restore_environment () =
 469   match
 470     Helm_registry.get_opt Helm_registry.string "search_engine.environment_dump"
 471   with
 472   | None -> ()
 473   | Some fname ->
 474       printf "Restoring Cic environment from %s ... " fname; flush stdout;
 475       let ic = open_in fname in
 476       CicEnvironment.restore_from_channel ic;
 477       close_in ic;
 478       printf "done!\n"; flush stdout
 479
 480 let _ =
 481   printf "%s started and listening on port %d\n" daemon_name port;
 482   printf "Current directory is %s\n" (Sys.getcwd ());
 483   printf "HTML directory is %s\n" pages_dir;
 484   flush stdout;
 485   Unix.putenv "http_proxy" "";
 486   let dbd =
 487     Mysql.quick_connect
 488       ~host:(Helm_registry.get "db.host")
 489       ~database:(Helm_registry.get "db.database")
 490       ~user:(Helm_registry.get "db.user")
 491       ()
 492   in
 493   restore_environment ();
 494   Http_daemon.start' ~port (callback dbd);
 495   printf "%s is terminating, bye!\n" daemon_name
 496