]> matita.cs.unibo.it Git - helm.git/blob - helm/software/components/acic_content/acic2content.ml
- renamed ocaml/ to components/
[helm.git] / helm / software / components / acic_content / acic2content.ml
1 (* Copyright (C) 2000, HELM Team.
2  * 
3  * This file is part of HELM, an Hypertextual, Electronic
4  * Library of Mathematics, developed at the Computer Science
5  * Department, University of Bologna, Italy.
6  * 
7  * HELM is free software; you can redistribute it and/or
8  * modify it under the terms of the GNU General Public License
9  * as published by the Free Software Foundation; either version 2
10  * of the License, or (at your option) any later version.
11  * 
12  * HELM is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU General Public License for more details.
16  *
17  * You should have received a copy of the GNU General Public License
18  * along with HELM; if not, write to the Free Software
19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
20  * MA  02111-1307, USA.
21  * 
22  * For details, see the HELM World-Wide-Web page,
23  * http://cs.unibo.it/helm/.
24  *)
25
26 (**************************************************************************)
27 (*                                                                        *)
28 (*                           PROJECT HELM                                 *)
29 (*                                                                        *)
30 (*                Andrea Asperti <asperti@cs.unibo.it>                    *)
31 (*                             16/6/2003                                   *)
32 (*                                                                        *)
33 (**************************************************************************)
34
35 (* $Id$ *)
36
37 let object_prefix = "obj:";;
38 let declaration_prefix = "decl:";;
39 let definition_prefix = "def:";;
40 let inductive_prefix = "ind:";;
41 let joint_prefix = "joint:";;
42 let proof_prefix = "proof:";;
43 let conclude_prefix = "concl:";;
44 let premise_prefix = "prem:";;
45 let lemma_prefix = "lemma:";;
46
47 (* e se mettessi la conversione di BY nell'apply_context ? *)
48 (* sarebbe carino avere l'invariante che la proof2pres
49 generasse sempre prove con contesto vuoto *)
50  
51 let gen_id prefix seed =
52  let res = prefix ^ string_of_int !seed in
53   incr seed ;
54   res
55 ;;
56
57 let name_of = function
58     Cic.Anonymous -> None
59   | Cic.Name b -> Some b;;
60  
61 exception Not_a_proof;;
62 exception NotImplemented;;
63 exception NotApplicable;;
64    
65 (* we do not care for positivity, here, that in any case is enforced by
66    well typing. Just a brutal search *)
67
68 let rec occur uri = 
69   let module C = Cic in
70   function
71       C.Rel _ -> false
72     | C.Var _ -> false
73     | C.Meta _ -> false
74     | C.Sort _ -> false
75     | C.Implicit _ -> assert false
76     | C.Prod (_,s,t) -> (occur uri s) or (occur uri t)
77     | C.Cast (te,ty) -> (occur uri te)
78     | C.Lambda (_,s,t) -> (occur uri s) or (occur uri t) (* or false ?? *)
79     | C.LetIn (_,s,t) -> (occur uri s) or (occur uri t)
80     | C.Appl l -> 
81         List.fold_left 
82           (fun b a -> 
83              if b then b  
84              else (occur uri a)) false l
85     | C.Const (_,_) -> false
86     | C.MutInd (uri1,_,_) -> if uri = uri1 then true else false
87     | C.MutConstruct (_,_,_,_) -> false
88     | C.MutCase _ -> false (* presuming too much?? *)
89     | C.Fix _ -> false (* presuming too much?? *)
90     | C.CoFix (_,_) -> false (* presuming too much?? *)
91 ;;
92
93 let get_id = 
94   let module C = Cic in
95   function
96       C.ARel (id,_,_,_) -> id
97     | C.AVar (id,_,_) -> id
98     | C.AMeta (id,_,_) -> id
99     | C.ASort (id,_) -> id
100     | C.AImplicit _ -> raise NotImplemented
101     | C.AProd (id,_,_,_) -> id
102     | C.ACast (id,_,_) -> id
103     | C.ALambda (id,_,_,_) -> id
104     | C.ALetIn (id,_,_,_) -> id
105     | C.AAppl (id,_) -> id
106     | C.AConst (id,_,_) -> id
107     | C.AMutInd (id,_,_,_) -> id
108     | C.AMutConstruct (id,_,_,_,_) -> id
109     | C.AMutCase (id,_,_,_,_,_) -> id
110     | C.AFix (id,_,_) -> id
111     | C.ACoFix (id,_,_) -> id
112 ;;
113
114 let test_for_lifting ~ids_to_inner_types ~ids_to_inner_sorts= 
115   let module C = Cic in
116   let module C2A = Cic2acic in
117   (* atomic terms are never lifted, according to my policy *)
118   function
119       C.ARel (id,_,_,_) -> false
120     | C.AVar (id,_,_) -> 
121          (try 
122             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
123             true;
124           with Not_found -> false) 
125     | C.AMeta (id,_,_) -> 
126          (try 
127             Hashtbl.find ids_to_inner_sorts id = `Prop
128           with Not_found -> assert false)
129     | C.ASort (id,_) -> false
130     | C.AImplicit _ -> raise NotImplemented
131     | C.AProd (id,_,_,_) -> false
132     | C.ACast (id,_,_) -> 
133          (try 
134             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
135             true;
136           with Not_found -> false)
137     | C.ALambda (id,_,_,_) -> 
138          (try 
139             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
140             true;
141           with Not_found -> false)
142     | C.ALetIn (id,_,_,_) -> 
143          (try 
144             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
145             true;
146           with Not_found -> false)
147     | C.AAppl (id,_) ->
148          (try 
149             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
150             true;
151           with Not_found -> false) 
152     | C.AConst (id,_,_) -> 
153          (try 
154             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
155             true;
156           with Not_found -> false) 
157     | C.AMutInd (id,_,_,_) -> false
158     | C.AMutConstruct (id,_,_,_,_) -> 
159        (try 
160             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
161             true;
162           with Not_found -> false)
163         (* oppure: false *)
164     | C.AMutCase (id,_,_,_,_,_) ->
165          (try 
166             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
167             true;
168           with Not_found -> false)
169     | C.AFix (id,_,_) ->
170           (try 
171             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
172             true;
173           with Not_found -> false)
174     | C.ACoFix (id,_,_) ->
175          (try 
176             ignore (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized;
177             true;
178           with Not_found -> false)
179 ;;
180
181 (* transform a proof p into a proof list, concatenating the last 
182 conclude element to the apply_context list, in case context is
183 empty. Otherwise, it just returns [p] *)
184
185 let flat seed p = 
186  let module K = Content in
187   if (p.K.proof_context = []) then
188     if p.K.proof_apply_context = [] then [p]
189     else 
190       let p1 =
191         { p with
192           K.proof_context = []; 
193           K.proof_apply_context = []
194         } in
195       p.K.proof_apply_context@[p1]
196   else 
197     [p]
198 ;;
199
200 let rec serialize seed = 
201   function 
202     [] -> []
203   | a::l -> (flat seed a)@(serialize seed l) 
204 ;;
205
206 (* top_down = true if the term is a LAMBDA or a decl *)
207 let generate_conversion seed top_down id inner_proof ~ids_to_inner_types =
208  let module C2A = Cic2acic in
209  let module K = Content in
210  let exp = (try ((Hashtbl.find ids_to_inner_types id).C2A.annexpected)
211             with Not_found -> None)
212  in
213  match exp with
214      None -> inner_proof
215    | Some expty ->
216        if inner_proof.K.proof_conclude.K.conclude_method = "Intros+LetTac" then
217          { K.proof_name = inner_proof.K.proof_name;
218             K.proof_id   = gen_id proof_prefix seed;
219             K.proof_context = [] ;
220             K.proof_apply_context = [];
221             K.proof_conclude = 
222               { K.conclude_id = gen_id conclude_prefix seed; 
223                 K.conclude_aref = id;
224                 K.conclude_method = "TD_Conversion";
225                 K.conclude_args = 
226                   [K.ArgProof {inner_proof with K.proof_name = None}];
227                 K.conclude_conclusion = Some expty
228               };
229           }
230         else
231           { K.proof_name =  inner_proof.K.proof_name;
232             K.proof_id   = gen_id proof_prefix seed;
233             K.proof_context = [] ;
234             K.proof_apply_context = [{inner_proof with K.proof_name = None}];
235             K.proof_conclude = 
236               { K.conclude_id = gen_id conclude_prefix seed; 
237                 K.conclude_aref = id;
238                 K.conclude_method = "BU_Conversion";
239                 K.conclude_args =  
240                  [K.Premise 
241                   { K.premise_id = gen_id premise_prefix seed;
242                     K.premise_xref = inner_proof.K.proof_id; 
243                     K.premise_binder = None;
244                     K.premise_n = None
245                   } 
246                  ]; 
247                 K.conclude_conclusion = Some expty
248               };
249           }
250 ;;
251
252 let generate_exact seed t id name ~ids_to_inner_types =
253   let module C2A = Cic2acic in
254   let module K = Content in
255     { K.proof_name = name;
256       K.proof_id   = gen_id proof_prefix seed ;
257       K.proof_context = [] ;
258       K.proof_apply_context = [];
259       K.proof_conclude = 
260         { K.conclude_id = gen_id conclude_prefix seed; 
261           K.conclude_aref = id;
262           K.conclude_method = "Exact";
263           K.conclude_args = [K.Term t];
264           K.conclude_conclusion = 
265               try Some (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
266               with Not_found -> None
267         };
268     }
269 ;;
270
271 let generate_intros_let_tac seed id n s is_intro inner_proof name ~ids_to_inner_types =
272   let module C2A = Cic2acic in
273   let module C = Cic in
274   let module K = Content in
275     { K.proof_name = name;
276       K.proof_id  = gen_id proof_prefix seed ;
277       K.proof_context = [] ;
278       K.proof_apply_context = [];
279       K.proof_conclude = 
280         { K.conclude_id = gen_id conclude_prefix seed; 
281           K.conclude_aref = id;
282           K.conclude_method = "Intros+LetTac";
283           K.conclude_args = [K.ArgProof inner_proof];
284           K.conclude_conclusion = 
285             try Some 
286              (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
287             with Not_found -> 
288               (match inner_proof.K.proof_conclude.K.conclude_conclusion with
289                  None -> None
290               | Some t -> 
291                   if is_intro then Some (C.AProd ("gen"^id,n,s,t))
292                   else Some (C.ALetIn ("gen"^id,n,s,t)))
293         };
294     }
295 ;;
296
297 let build_decl_item seed id n s ~ids_to_inner_sorts =
298  let module K = Content in
299  let sort =
300    try
301     Some (Hashtbl.find ids_to_inner_sorts (Cic2acic.source_id_of_id id))
302    with Not_found -> None
303  in
304  match sort with
305  | Some `Prop ->
306     `Hypothesis
307       { K.dec_name = name_of n;
308         K.dec_id = gen_id declaration_prefix seed; 
309         K.dec_inductive = false;
310         K.dec_aref = id;
311         K.dec_type = s
312       }
313  | _ ->
314     `Declaration
315       { K.dec_name = name_of n;
316         K.dec_id = gen_id declaration_prefix seed; 
317         K.dec_inductive = false;
318         K.dec_aref = id;
319         K.dec_type = s
320       }
321 ;;
322
323 let rec build_subproofs_and_args seed l ~ids_to_inner_types ~ids_to_inner_sorts =
324   let module C = Cic in
325   let module K = Content in
326   let rec aux =
327     function
328       [] -> [],[]
329     | t::l1 -> 
330        let subproofs,args = aux l1 in
331         if (test_for_lifting t ~ids_to_inner_types ~ids_to_inner_sorts) then
332           let new_subproof = 
333             acic2content 
334               seed ~name:"H" ~ids_to_inner_types ~ids_to_inner_sorts t in
335           let new_arg = 
336             K.Premise
337               { K.premise_id = gen_id premise_prefix seed;
338                 K.premise_xref = new_subproof.K.proof_id;
339                 K.premise_binder = new_subproof.K.proof_name;
340                 K.premise_n = None
341               } in
342           new_subproof::subproofs,new_arg::args
343         else 
344           let hd = 
345             (match t with 
346                C.ARel (idr,idref,n,b) ->
347                  let sort = 
348                    (try
349                      Hashtbl.find ids_to_inner_sorts idr 
350                     with Not_found -> `Type (CicUniv.fresh())) in 
351                  if sort = `Prop then 
352                     K.Premise 
353                       { K.premise_id = gen_id premise_prefix seed;
354                         K.premise_xref = idr;
355                         K.premise_binder = Some b;
356                         K.premise_n = Some n
357                       }
358                  else (K.Term t)
359              | C.AConst(id,uri,[]) ->
360                  let sort = 
361                    (try
362                      Hashtbl.find ids_to_inner_sorts id 
363                     with Not_found -> `Type (CicUniv.fresh())) in 
364                  if sort = `Prop then 
365                     K.Lemma 
366                       { K.lemma_id = gen_id lemma_prefix seed;
367                         K.lemma_name = UriManager.name_of_uri uri;
368                         K.lemma_uri = UriManager.string_of_uri uri
369                       }
370                  else (K.Term t)
371              | C.AMutConstruct(id,uri,tyno,consno,[]) ->
372                  let sort = 
373                    (try
374                      Hashtbl.find ids_to_inner_sorts id 
375                     with Not_found -> `Type (CicUniv.fresh())) in 
376                  if sort = `Prop then 
377                     let inductive_types =
378                       (let o,_ = 
379                          CicEnvironment.get_obj CicUniv.empty_ugraph uri
380                        in
381                          match o with 
382                            | Cic.InductiveDefinition (l,_,_,_) -> l 
383                            | _ -> assert false
384                       ) in
385                     let (_,_,_,constructors) = 
386                       List.nth inductive_types tyno in 
387                     let name,_ = List.nth constructors (consno - 1) in
388                     K.Lemma 
389                       { K.lemma_id = gen_id lemma_prefix seed;
390                         K.lemma_name = name;
391                         K.lemma_uri = 
392                           UriManager.string_of_uri uri ^ "#xpointer(1/" ^
393                           string_of_int (tyno+1) ^ "/" ^ string_of_int consno ^
394                           ")"
395                       }
396                  else (K.Term t) 
397              | _ -> (K.Term t)) in
398           subproofs,hd::args
399   in 
400   match (aux l) with
401     [p],args -> 
402       [{p with K.proof_name = None}], 
403         List.map 
404           (function 
405               K.Premise prem when prem.K.premise_xref = p.K.proof_id ->
406                K.Premise {prem with K.premise_binder = None}
407             | i -> i) args
408   | p,a as c -> c
409
410 and
411
412 build_def_item seed id n t ~ids_to_inner_sorts ~ids_to_inner_types =
413  let module K = Content in
414   try
415    let sort = Hashtbl.find ids_to_inner_sorts id in
416    if sort = `Prop then
417        (let p = 
418         (acic2content seed ?name:(name_of n) ~ids_to_inner_sorts  ~ids_to_inner_types t)
419        in 
420         `Proof p;)
421    else 
422       `Definition
423         { K.def_name = name_of n;
424           K.def_id = gen_id definition_prefix seed; 
425           K.def_aref = id;
426           K.def_term = t
427         }
428   with
429    Not_found -> assert false
430
431 (* the following function must be called with an object of sort
432 Prop. For debugging purposes this is tested again, possibly raising an 
433 Not_a_proof exception *)
434
435 and acic2content seed ?name ~ids_to_inner_sorts ~ids_to_inner_types t =
436   let rec aux ?name t =
437   let module C = Cic in
438   let module K = Content in
439   let module C2A = Cic2acic in
440   let t1 =
441     match t with 
442       C.ARel (id,idref,n,b) as t ->
443         let sort = Hashtbl.find ids_to_inner_sorts id in
444         if sort = `Prop then
445           generate_exact seed t id name ~ids_to_inner_types 
446         else raise Not_a_proof
447     | C.AVar (id,uri,exp_named_subst) as t ->
448         let sort = Hashtbl.find ids_to_inner_sorts id in
449         if sort = `Prop then
450           generate_exact seed t id name ~ids_to_inner_types 
451         else raise Not_a_proof
452     | C.AMeta (id,n,l) as t ->
453         let sort = Hashtbl.find ids_to_inner_sorts id in
454         if sort = `Prop then
455           generate_exact seed t id name ~ids_to_inner_types 
456         else raise Not_a_proof
457     | C.ASort (id,s) -> raise Not_a_proof
458     | C.AImplicit _ -> raise NotImplemented
459     | C.AProd (_,_,_,_) -> raise Not_a_proof
460     | C.ACast (id,v,t) -> aux v
461     | C.ALambda (id,n,s,t) -> 
462         let sort = Hashtbl.find ids_to_inner_sorts id in
463         if sort = `Prop then 
464           let proof = aux t in
465           let proof' = 
466             if proof.K.proof_conclude.K.conclude_method = "Intros+LetTac" then
467                match proof.K.proof_conclude.K.conclude_args with
468                  [K.ArgProof p] -> p
469                | _ -> assert false                  
470             else proof in
471           let proof'' =
472             { proof' with
473               K.proof_name = None;
474               K.proof_context = 
475                 (build_decl_item seed id n s ids_to_inner_sorts)::
476                   proof'.K.proof_context
477             }
478           in
479           generate_intros_let_tac seed id n s true proof'' name ~ids_to_inner_types
480         else raise Not_a_proof 
481     | C.ALetIn (id,n,s,t) ->
482         let sort = Hashtbl.find ids_to_inner_sorts id in
483         if sort = `Prop then
484           let proof = aux t in
485           let proof' = 
486             if proof.K.proof_conclude.K.conclude_method = "Intros+LetTac" then
487                match proof.K.proof_conclude.K.conclude_args with
488                  [K.ArgProof p] -> p
489                | _ -> assert false                  
490             else proof in
491           let proof'' =
492             { proof' with
493                K.proof_name = None;
494                K.proof_context = 
495                  ((build_def_item seed id n s ids_to_inner_sorts 
496                    ids_to_inner_types):> Cic.annterm K.in_proof_context_element)
497                  ::proof'.K.proof_context;
498             }
499           in
500           generate_intros_let_tac seed id n s false proof'' name ~ids_to_inner_types
501         else raise Not_a_proof 
502     | C.AAppl (id,li) ->
503         (try rewrite 
504            seed name id li ~ids_to_inner_types ~ids_to_inner_sorts
505          with NotApplicable ->
506          try inductive 
507           seed name id li ~ids_to_inner_types ~ids_to_inner_sorts
508          with NotApplicable ->
509           let subproofs, args =
510             build_subproofs_and_args 
511               seed li ~ids_to_inner_types ~ids_to_inner_sorts in
512 (*            
513           let args_to_lift = 
514             List.filter (test_for_lifting ~ids_to_inner_types) li in
515           let subproofs = 
516             match args_to_lift with
517                 [_] -> List.map aux args_to_lift 
518             | _ -> List.map (aux ~name:"H") args_to_lift in
519           let args = build_args seed li subproofs 
520                  ~ids_to_inner_types ~ids_to_inner_sorts in *)
521             { K.proof_name = name;
522               K.proof_id   = gen_id proof_prefix seed;
523               K.proof_context = [];
524               K.proof_apply_context = serialize seed subproofs;
525               K.proof_conclude = 
526                 { K.conclude_id = gen_id conclude_prefix seed;
527                   K.conclude_aref = id;
528                   K.conclude_method = "Apply";
529                   K.conclude_args = args;
530                   K.conclude_conclusion = 
531                      try Some 
532                        (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
533                      with Not_found -> None
534                  };
535             })
536     | C.AConst (id,uri,exp_named_subst) as t ->
537         let sort = Hashtbl.find ids_to_inner_sorts id in
538         if sort = `Prop then
539           generate_exact seed t id name ~ids_to_inner_types
540         else raise Not_a_proof
541     | C.AMutInd (id,uri,i,exp_named_subst) -> raise Not_a_proof
542     | C.AMutConstruct (id,uri,i,j,exp_named_subst) as t ->
543         let sort = Hashtbl.find ids_to_inner_sorts id in
544         if sort = `Prop then 
545           generate_exact seed t id name ~ids_to_inner_types
546         else raise Not_a_proof
547     | C.AMutCase (id,uri,typeno,ty,te,patterns) ->
548         let inductive_types,noparams =
549           (let o, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
550              match o with
551                  Cic.Constant _ -> assert false
552                | Cic.Variable _ -> assert false
553                | Cic.CurrentProof _ -> assert false
554                | Cic.InductiveDefinition (l,_,n,_) -> l,n 
555           ) in
556         let (_,_,_,constructors) = List.nth inductive_types typeno in
557         let name_and_arities = 
558           let rec count_prods =
559             function 
560                C.Prod (_,_,t) -> 1 + count_prods t
561              | _ -> 0 in
562           List.map 
563             (function (n,t) -> Some n,((count_prods t) - noparams)) constructors in
564         let pp = 
565           let build_proof p (name,arity) =
566             let rec make_context_and_body c p n =
567               if n = 0 then c,(aux p)
568               else 
569                 (match p with
570                    Cic.ALambda(idl,vname,s1,t1) ->
571                      let ce = 
572                        build_decl_item seed idl vname s1 ~ids_to_inner_sorts in
573                      make_context_and_body (ce::c) t1 (n-1)
574                    | _ -> assert false) in
575              let context,body = make_context_and_body [] p arity in
576                K.ArgProof
577                 {body with K.proof_name = name; K.proof_context=context} in
578           List.map2 build_proof patterns name_and_arities in
579         let context,term =
580           (match 
581              build_subproofs_and_args 
582                seed ~ids_to_inner_types ~ids_to_inner_sorts [te]
583            with
584              l,[t] -> l,t
585            | _ -> assert false) in
586         { K.proof_name = name;
587           K.proof_id   = gen_id proof_prefix seed;
588           K.proof_context = []; 
589           K.proof_apply_context = serialize seed context;
590           K.proof_conclude = 
591             { K.conclude_id = gen_id conclude_prefix seed; 
592               K.conclude_aref = id;
593               K.conclude_method = "Case";
594               K.conclude_args = 
595                 (K.Aux (UriManager.string_of_uri uri))::
596                 (K.Aux (string_of_int typeno))::(K.Term ty)::term::pp;
597               K.conclude_conclusion = 
598                 try Some 
599                   (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
600                 with Not_found -> None  
601              }
602         }
603     | C.AFix (id, no, funs) -> 
604         let proofs = 
605           List.map 
606             (function (_,name,_,_,bo) -> `Proof (aux ~name bo)) funs in
607         let fun_name = 
608           List.nth (List.map (fun (_,name,_,_,_) -> name) funs) no 
609         in
610         let decreasing_args = 
611           List.map (function (_,_,n,_,_) -> n) funs in
612         let jo = 
613           { K.joint_id = gen_id joint_prefix seed;
614             K.joint_kind = `Recursive decreasing_args;
615             K.joint_defs = proofs
616           } 
617         in
618           { K.proof_name = name;
619             K.proof_id  = gen_id proof_prefix seed;
620             K.proof_context = [`Joint jo]; 
621             K.proof_apply_context = [];
622             K.proof_conclude = 
623               { K.conclude_id = gen_id conclude_prefix seed; 
624                 K.conclude_aref = id;
625                 K.conclude_method = "Exact";
626                 K.conclude_args =
627                 [ K.Premise
628                   { K.premise_id = gen_id premise_prefix seed; 
629                     K.premise_xref = jo.K.joint_id;
630                     K.premise_binder = Some fun_name;
631                     K.premise_n = Some no;
632                   }
633                 ];
634                 K.conclude_conclusion =
635                    try Some 
636                      (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
637                    with Not_found -> None
638               }
639         } 
640     | C.ACoFix (id,no,funs) -> 
641         let proofs = 
642           List.map 
643             (function (_,name,_,bo) -> `Proof (aux ~name bo)) funs in
644         let jo = 
645           { K.joint_id = gen_id joint_prefix seed;
646             K.joint_kind = `CoRecursive;
647             K.joint_defs = proofs
648           } 
649         in
650           { K.proof_name = name;
651             K.proof_id   = gen_id proof_prefix seed;
652             K.proof_context = [`Joint jo]; 
653             K.proof_apply_context = [];
654             K.proof_conclude = 
655               { K.conclude_id = gen_id conclude_prefix seed; 
656                 K.conclude_aref = id;
657                 K.conclude_method = "Exact";
658                 K.conclude_args =
659                 [ K.Premise
660                   { K.premise_id = gen_id premise_prefix seed; 
661                     K.premise_xref = jo.K.joint_id;
662                     K.premise_binder = Some "tiralo fuori";
663                     K.premise_n = Some no;
664                   }
665                 ];
666                 K.conclude_conclusion =
667                   try Some 
668                     (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
669                   with Not_found -> None
670               };
671         } 
672      in 
673      let id = get_id t in
674      generate_conversion seed false id t1 ~ids_to_inner_types
675 in aux ?name t
676
677 and inductive seed name id li ~ids_to_inner_types ~ids_to_inner_sorts =
678   let aux ?name = acic2content seed  ~ids_to_inner_types ~ids_to_inner_sorts in
679   let module C2A = Cic2acic in
680   let module K = Content in
681   let module C = Cic in
682   match li with 
683     C.AConst (idc,uri,exp_named_subst)::args ->
684       let uri_str = UriManager.string_of_uri uri in
685       let suffix = Str.regexp_string "_ind.con" in
686       let len = String.length uri_str in 
687       let n = (try (Str.search_backward suffix uri_str len)
688                with Not_found -> -1) in
689       if n<0 then raise NotApplicable
690       else 
691         let method_name =
692           if UriManager.eq uri HelmLibraryObjects.Logic.ex_ind_URI then "Exists"
693           else if UriManager.eq uri HelmLibraryObjects.Logic.and_ind_URI then "AndInd"
694           else if UriManager.eq uri HelmLibraryObjects.Logic.false_ind_URI then "FalseInd"
695           else "ByInduction" in
696         let prefix = String.sub uri_str 0 n in
697         let ind_str = (prefix ^ ".ind") in 
698         let ind_uri = UriManager.uri_of_string ind_str in
699         let inductive_types,noparams =
700           (let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph ind_uri in
701              match o with
702                | Cic.InductiveDefinition (l,_,n,_) -> (l,n) 
703                | _ -> assert false
704           ) in
705         let rec split n l =
706           if n = 0 then ([],l) else
707           let p,a = split (n-1) (List.tl l) in
708           ((List.hd l::p),a) in
709         let params_and_IP,tail_args = split (noparams+1) args in
710         let constructors = 
711             (match inductive_types with
712               [(_,_,_,l)] -> l
713             | _ -> raise NotApplicable) (* don't care for mutual ind *) in
714         let constructors1 = 
715           let rec clean_up n t =
716              if n = 0 then t else
717              (match t with
718                 (label,Cic.Prod (_,_,t)) -> clean_up (n-1) (label,t)
719               | _ -> assert false) in
720           List.map (clean_up noparams) constructors in
721         let no_constructors= List.length constructors in
722         let args_for_cases, other_args = 
723           split no_constructors tail_args in
724         let subproofs,other_method_args =
725           build_subproofs_and_args seed other_args
726              ~ids_to_inner_types ~ids_to_inner_sorts in
727         let method_args=
728           let rec build_method_args =
729             function
730                 [],_-> [] (* extra args are ignored ???? *)
731               | (name,ty)::tlc,arg::tla ->
732                   let idarg = get_id arg in
733                   let sortarg = 
734                     (try (Hashtbl.find ids_to_inner_sorts idarg)
735                      with Not_found -> `Type (CicUniv.fresh())) in
736                   let hdarg = 
737                     if sortarg = `Prop then
738                       let (co,bo) = 
739                         let rec bc = 
740                           function 
741                             Cic.Prod (_,s,t),Cic.ALambda(idl,n,s1,t1) ->
742                               let ce = 
743                                 build_decl_item 
744                                   seed idl n s1 ~ids_to_inner_sorts in
745                               if (occur ind_uri s) then
746                                 ( match t1 with
747                                    Cic.ALambda(id2,n2,s2,t2) ->
748                                      let inductive_hyp =
749                                        `Hypothesis
750                                          { K.dec_name = name_of n2;
751                                            K.dec_id =
752                                             gen_id declaration_prefix seed; 
753                                            K.dec_inductive = true;
754                                            K.dec_aref = id2;
755                                            K.dec_type = s2
756                                          } in
757                                      let (context,body) = bc (t,t2) in
758                                      (ce::inductive_hyp::context,body)
759                                  | _ -> assert false)
760                               else 
761                                 ( 
762                                 let (context,body) = bc (t,t1) in
763                                 (ce::context,body))
764                             | _ , t -> ([],aux t) in
765                         bc (ty,arg) in
766                       K.ArgProof
767                        { bo with
768                          K.proof_name = Some name;
769                          K.proof_context = co; 
770                        };
771                     else (K.Term arg) in
772                   hdarg::(build_method_args (tlc,tla))
773               | _ -> assert false in
774           build_method_args (constructors1,args_for_cases) in
775           { K.proof_name = name;
776             K.proof_id   = gen_id proof_prefix seed;
777             K.proof_context = []; 
778             K.proof_apply_context = serialize seed subproofs;
779             K.proof_conclude = 
780               { K.conclude_id = gen_id conclude_prefix seed; 
781                 K.conclude_aref = id;
782                 K.conclude_method = method_name;
783                 K.conclude_args =
784                   K.Aux (string_of_int no_constructors) 
785                   ::K.Term (C.AAppl(id,((C.AConst(idc,uri,exp_named_subst))::params_and_IP)))
786                   ::method_args@other_method_args;
787                 K.conclude_conclusion = 
788                    try Some 
789                      (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
790                    with Not_found -> None  
791               }
792           } 
793   | _ -> raise NotApplicable
794
795 and rewrite seed name id li ~ids_to_inner_types ~ids_to_inner_sorts =
796   let aux ?name = acic2content seed ~ids_to_inner_types ~ids_to_inner_sorts in
797   let module C2A = Cic2acic in
798   let module K = Content in
799   let module C = Cic in
800   match li with 
801     C.AConst (sid,uri,exp_named_subst)::args ->
802       if UriManager.eq uri HelmLibraryObjects.Logic.eq_ind_URI or
803          UriManager.eq uri HelmLibraryObjects.Logic.eq_ind_r_URI or
804          LibraryObjects.is_eq_ind_URI uri or
805          LibraryObjects.is_eq_ind_r_URI uri then 
806         let subproofs,arg = 
807           (match 
808              build_subproofs_and_args 
809                seed ~ids_to_inner_types ~ids_to_inner_sorts [List.nth args 3]
810            with 
811              l,[p] -> l,p
812            | _,_ -> assert false) in 
813         let method_args =
814           let rec ma_aux n = function
815               [] -> []
816             | a::tl -> 
817                 let hd = 
818                   if n = 0 then arg
819                   else 
820                     let aid = get_id a in
821                     let asort = (try (Hashtbl.find ids_to_inner_sorts aid)
822                       with Not_found -> `Type (CicUniv.fresh())) in
823                     if asort = `Prop then
824                       K.ArgProof (aux a)
825                     else K.Term a in
826                 hd::(ma_aux (n-1) tl) in
827           (ma_aux 3 args) in 
828           { K.proof_name = name;
829             K.proof_id  = gen_id proof_prefix seed;
830             K.proof_context = []; 
831             K.proof_apply_context = serialize seed subproofs;
832             K.proof_conclude = 
833               { K.conclude_id = gen_id conclude_prefix seed; 
834                 K.conclude_aref = id;
835                 K.conclude_method = "Rewrite";
836                 K.conclude_args = 
837                   K.Term (C.AConst (sid,uri,exp_named_subst))::method_args;
838                 K.conclude_conclusion = 
839                    try Some 
840                      (Hashtbl.find ids_to_inner_types id).C2A.annsynthesized
841                    with Not_found -> None
842               }
843           } 
844       else raise NotApplicable
845   | _ -> raise NotApplicable
846 ;; 
847
848 let map_conjectures
849  seed ~ids_to_inner_sorts ~ids_to_inner_types (id,n,context,ty)
850 =
851  let module K = Content in
852  let context' =
853   List.map
854    (function
855        (id,None) -> None
856      | (id,Some (name,Cic.ADecl t)) ->
857          Some
858           (* We should call build_decl_item, but we have not computed *)
859           (* the inner-types ==> we always produce a declaration      *)
860           (`Declaration
861             { K.dec_name = name_of name;
862               K.dec_id = gen_id declaration_prefix seed; 
863               K.dec_inductive = false;
864               K.dec_aref = get_id t;
865               K.dec_type = t
866             })
867      | (id,Some (name,Cic.ADef t)) ->
868          Some
869           (* We should call build_def_item, but we have not computed *)
870           (* the inner-types ==> we always produce a declaration     *)
871           (`Definition
872              { K.def_name = name_of name;
873                K.def_id = gen_id definition_prefix seed; 
874                K.def_aref = get_id t;
875                K.def_term = t
876              })
877    ) context
878  in
879   (id,n,context',ty)
880 ;;
881
882 (* map_sequent is similar to map_conjectures, but the for the hid
883 of the hypothesis, which are preserved instead of generating
884 fresh ones. We shall have to adopt a uniform policy, soon or later *)
885
886 let map_sequent ((id,n,context,ty):Cic.annconjecture) =
887  let module K = Content in
888  let context' =
889   List.map
890    (function
891        (id,None) -> None
892      | (id,Some (name,Cic.ADecl t)) ->
893          Some
894           (* We should call build_decl_item, but we have not computed *)
895           (* the inner-types ==> we always produce a declaration      *)
896           (`Declaration
897             { K.dec_name = name_of name;
898               K.dec_id = id; 
899               K.dec_inductive = false;
900               K.dec_aref = get_id t;
901               K.dec_type = t
902             })
903      | (id,Some (name,Cic.ADef t)) ->
904          Some
905           (* We should call build_def_item, but we have not computed *)
906           (* the inner-types ==> we always produce a declaration     *)
907           (`Definition
908              { K.def_name = name_of name;
909                K.def_id = id; 
910                K.def_aref = get_id t;
911                K.def_term = t
912              })
913    ) context
914  in
915   (id,n,context',ty)
916 ;;
917
918 let rec annobj2content ~ids_to_inner_sorts ~ids_to_inner_types = 
919   let module C = Cic in
920   let module K = Content in
921   let module C2A = Cic2acic in
922   let seed = ref 0 in
923   function
924       C.ACurrentProof (_,_,n,conjectures,bo,ty,params,_) ->
925         (gen_id object_prefix seed, params,
926           Some
927            (List.map
928              (map_conjectures seed ~ids_to_inner_sorts ~ids_to_inner_types)
929              conjectures),
930           `Def (K.Const,ty,
931             build_def_item seed (get_id bo) (C.Name n) bo 
932              ~ids_to_inner_sorts ~ids_to_inner_types))
933     | C.AConstant (_,_,n,Some bo,ty,params,_) ->
934          (gen_id object_prefix seed, params, None,
935            `Def (K.Const,ty,
936              build_def_item seed (get_id bo) (C.Name n) bo 
937                ~ids_to_inner_sorts ~ids_to_inner_types))
938     | C.AConstant (id,_,n,None,ty,params,_) ->
939          (gen_id object_prefix seed, params, None,
940            `Decl (K.Const,
941              build_decl_item seed id (C.Name n) ty 
942                ~ids_to_inner_sorts))
943     | C.AVariable (_,n,Some bo,ty,params,_) ->
944          (gen_id object_prefix seed, params, None,
945            `Def (K.Var,ty,
946              build_def_item seed (get_id bo) (C.Name n) bo
947                ~ids_to_inner_sorts ~ids_to_inner_types))
948     | C.AVariable (id,n,None,ty,params,_) ->
949          (gen_id object_prefix seed, params, None,
950            `Decl (K.Var,
951              build_decl_item seed id (C.Name n) ty
952               ~ids_to_inner_sorts))
953     | C.AInductiveDefinition (id,l,params,nparams,_) ->
954          (gen_id object_prefix seed, params, None,
955             `Joint
956               { K.joint_id = gen_id joint_prefix seed;
957                 K.joint_kind = `Inductive nparams;
958                 K.joint_defs = List.map (build_inductive seed) l
959               }) 
960
961 and
962     build_inductive seed = 
963      let module K = Content in
964       fun (_,n,b,ty,l) ->
965         `Inductive
966           { K.inductive_id = gen_id inductive_prefix seed;
967             K.inductive_name = n;
968             K.inductive_kind = b;
969             K.inductive_type = ty;
970             K.inductive_constructors = build_constructors seed l
971            }
972
973 and 
974     build_constructors seed l =
975      let module K = Content in
976       List.map 
977        (fun (n,t) ->
978            { K.dec_name = Some n;
979              K.dec_id = gen_id declaration_prefix seed;
980              K.dec_inductive = false;
981              K.dec_aref = "";
982              K.dec_type = t
983            }) l
984 ;;
985    
986 (* 
987 and 'term cinductiveType = 
988  id * string * bool * 'term *                (* typename, inductive, arity *)
989    'term cconstructor list                   (*  constructors        *)
990
991 and 'term cconstructor =
992  string * 'term    
993 *)
994
995