helm/software/components/acic_content/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33   (* when set to true debugging information, not in sync with input syntax, will
  34    * be added to the output of pp_term.
  35    * set to false if you need, for example, cut and paste from matitac output to
  36    * matitatop *)
  37 let debug_printing = true
  38
  39 let pp_binder = function
  40   | `Lambda -> "lambda"
  41   | `Pi -> "Pi"
  42   | `Exists -> "exists"
  43   | `Forall -> "forall"
  44
  45 let pp_literal =
  46   if debug_printing then
  47     (function (* debugging version *)
  48       | `Symbol s -> sprintf "symbol(%s)" s
  49       | `Keyword s -> sprintf "keyword(%s)" s
  50       | `Number s -> sprintf "number(%s)" s)
  51   else
  52     (function
  53       | `Symbol s
  54       | `Keyword s
  55       | `Number s -> s)
  56
  57 let pp_assoc =
  58   function
  59   | Gramext.NonA -> "NonA"
  60   | Gramext.LeftA -> "LeftA"
  61   | Gramext.RightA -> "RightA"
  62
  63 let pp_pos =
  64   function
  65 (*      `None -> "`None" *)
  66     | `Left -> "`Left"
  67     | `Right -> "`Right"
  68     | `Inner -> "`Inner"
  69
  70 let pp_attribute =
  71   function
  72   | `IdRef id -> sprintf "x(%s)" id
  73   | `XmlAttrs attrs ->
  74       sprintf "X(%s)"
  75         (String.concat ";"
  76           (List.map (fun (_, n, v) -> sprintf "%s=%s" n v) attrs))
  77   | `Level (prec, assoc) -> sprintf "L(%d%s)" prec (pp_assoc assoc)
  78   | `Raw _ -> "R"
  79   | `Loc _ -> "@"
  80   | `ChildPos p -> sprintf "P(%s)" (pp_pos p)
  81
  82 let pp_capture_variable pp_term =
  83   function
  84   | term, None -> pp_term (* ~pp_parens:false *) term
  85   | term, Some typ -> "(" ^ pp_term (* ~pp_parens:false *) term ^ ": " ^ pp_term typ ^ ")"
  86
  87 let rec pp_term ?(pp_parens = true) t =
  88   let t_pp =
  89     match t with
  90     | Ast.AttributedTerm (attr, term) when debug_printing ->
  91         sprintf "%s[%s]" (pp_attribute attr) (pp_term ~pp_parens:false term)
  92     | Ast.AttributedTerm (`Raw text, _) -> text
  93     | Ast.AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  94     | Ast.Appl terms ->
  95         sprintf "%s" (String.concat " " (List.map pp_term terms))
  96     | Ast.Binder (`Forall, (Ast.Ident ("_", None), typ), body)
  97     | Ast.Binder (`Pi, (Ast.Ident ("_", None), typ), body) ->
  98         sprintf "%s \\to %s"
  99           (match typ with None -> "?" | Some typ -> pp_term typ)
 100           (pp_term ~pp_parens:true body)
 101     | Ast.Binder (kind, var, body) ->
 102         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable pp_term var)
 103           (pp_term ~pp_parens:true body)
 104     | Ast.Case (term, indtype, typ, patterns) ->
 105         sprintf "match %s%s%s with %s"
 106           (pp_term term)
 107           (match indtype with
 108           | None -> ""
 109           | Some (ty, href_opt) ->
 110               sprintf " in %s%s" ty
 111               (match debug_printing, href_opt with
 112               | true, Some uri ->
 113                   sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 114               | _ -> ""))
 115           (match typ with None -> "" | Some t -> sprintf " return %s" (pp_term t))
 116           (pp_patterns patterns)
 117     | Ast.Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term ~pp_parens:true t1) (pp_term ~pp_parens:true t2)
 118     | Ast.LetIn (var, t1, t2) ->
 119         sprintf "let %s \\def %s in %s" (pp_capture_variable pp_term var) (pp_term ~pp_parens:true t1)
 120           (pp_term ~pp_parens:true t2)
 121     | Ast.LetRec (kind, definitions, term) ->
 122         let rec get_guard i = function
 123            | []                   -> (*assert false*) Ast.Implicit
 124            | [term, _] when i = 1 -> term
 125            | _ :: tl              -> get_guard (pred i) tl
 126         in
 127         let map (params, (id,typ), body, i) =
 128          let typ =
 129           match typ with
 130              None -> Ast.Implicit
 131            | Some typ -> typ
 132          in
 133            sprintf "%s %s on %s: %s \\def %s"
 134               (pp_term ~pp_parens:false term)
 135               (String.concat " " (List.map (pp_capture_variable pp_term) params))
 136               (pp_term ~pp_parens:false (get_guard i params))
 137               (pp_term typ) (pp_term body)
 138         in
 139         sprintf "let %s %s in %s"
 140           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
 141           (String.concat " and " (List.map map definitions))
 142           (pp_term term)
 143     | Ast.Ident (name, Some []) | Ast.Ident (name, None)
 144     | Ast.Uri (name, Some []) | Ast.Uri (name, None) ->
 145         name
 146     | Ast.Ident (name, Some substs)
 147     | Ast.Uri (name, Some substs) ->
 148         sprintf "%s \\subst [%s]" name (pp_substs substs)
 149     | Ast.Implicit -> "?"
 150     | Ast.Meta (index, substs) ->
 151         sprintf "%d[%s]" index
 152           (String.concat "; "
 153             (List.map (function None -> "_" | Some t -> pp_term t) substs))
 154     | Ast.Num (num, _) -> num
 155     | Ast.Sort `Set -> "Set"
 156     | Ast.Sort `Prop -> "Prop"
 157     | Ast.Sort (`Type _) -> "Type"
 158     | Ast.Sort `CProp -> "CProp"
 159     | Ast.Symbol (name, _) -> "'" ^ name
 160
 161     | Ast.UserInput -> ""
 162
 163     | Ast.Literal l -> pp_literal l
 164     | Ast.Layout l -> pp_layout l
 165     | Ast.Magic m -> pp_magic m
 166     | Ast.Variable v -> pp_variable v
 167   in
 168   match pp_parens, t with
 169     | false, _
 170     | true, Ast.Implicit
 171     | true, Ast.Sort _
 172     | true, Ast.Ident (_, Some [])
 173     | true, Ast.Ident (_, None)    -> t_pp
 174     | _                            -> sprintf "(%s)" t_pp
 175
 176 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 177 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 178
 179 and pp_pattern ((head, href, vars), term) =
 180   let head_pp =
 181     head ^
 182     (match debug_printing, href with
 183     | true, Some uri -> sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 184     | _ -> "")
 185   in
 186   sprintf "%s \\Rightarrow %s"
 187     (match vars with
 188     | [] -> head_pp
 189     | _ ->
 190         sprintf "(%s %s)" head_pp
 191           (String.concat " " (List.map (pp_capture_variable pp_term) vars)))
 192     (pp_term term)
 193
 194 and pp_patterns patterns =
 195   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 196
 197 and pp_box_spec (kind, spacing, indent) =
 198   let int_of_bool b = if b then 1 else 0 in
 199   let kind_string =
 200     match kind with
 201     Ast.H -> "H" | Ast.V -> "V" | Ast.HV -> "HV" | Ast.HOV -> "HOV"
 202   in
 203   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 204
 205 and pp_layout = function
 206   | Ast.Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 207   | Ast.Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 208   | Ast.Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 209   | Ast.Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 210   | Ast.Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 211   | Ast.Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 212   | Ast.Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 213   | Ast.Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 214   | Ast.Root (arg, index) ->
 215       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 216   | Ast.Break -> "\\BREAK"
 217 (*   | Space -> "\\SPACE" *)
 218   | Ast.Box (box_spec, terms) ->
 219       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 220         (String.concat " " (List.map pp_term terms))
 221   | Ast.Group terms ->
 222       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 223
 224 and pp_magic = function
 225   | Ast.List0 (t, sep_opt) ->
 226       sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 227   | Ast.List1 (t, sep_opt) ->
 228       sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 229   | Ast.Opt t -> sprintf "opt %s" (pp_term t)
 230   | Ast.Fold (kind, p_base, names, p_rec) ->
 231       let acc = match names with acc :: _ -> acc | _ -> assert false in
 232       sprintf "fold %s %s rec %s %s"
 233         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 234   | Ast.Default (p_some, p_none) ->
 235       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 236   | Ast.If (p_test, p_true, p_false) ->
 237       sprintf "if %s then %s else %s"
 238         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 239   | Ast.Fail -> "fail"
 240
 241 and pp_fold_kind = function
 242   | `Left -> "left"
 243   | `Right -> "right"
 244
 245 and pp_sep_opt = function
 246   | None -> ""
 247   | Some sep -> sprintf " sep %s" (pp_literal sep)
 248
 249 and pp_variable = function
 250   | Ast.NumVar s -> "number " ^ s
 251   | Ast.IdentVar s -> "ident " ^ s
 252   | Ast.TermVar s -> "term " ^ s
 253   | Ast.Ascription (t, n) -> assert false
 254   | Ast.FreshVar n -> "fresh " ^ n
 255
 256 let _pp_term = ref (pp_term ~pp_parens:false)
 257 let pp_term t = !_pp_term t
 258 let set_pp_term f = _pp_term := f
 259
 260 let pp_params pp_term = function
 261   | [] -> ""
 262   | params -> " " ^ String.concat " " (List.map (pp_capture_variable pp_term) params)
 263
 264 let pp_flavour = function
 265   | `Definition -> "definition"
 266   | `MutualDefinition -> assert false
 267   | `Fact -> "fact"
 268   | `Goal -> "goal"
 269   | `Lemma -> "lemma"
 270   | `Remark -> "remark"
 271   | `Theorem -> "theorem"
 272   | `Variant -> "variant"
 273   | `Axiom -> "axiom"
 274
 275 let pp_fields pp_term fields =
 276   (if fields <> [] then "\n" else "") ^
 277   String.concat ";\n"
 278     (List.map
 279       (fun (name,ty,coercion,arity) ->
 280         " " ^ name ^
 281         if coercion then (":" ^
 282           if arity > 0 then string_of_int arity else "" ^ ">") else ": " ^
 283         pp_term ty) fields)
 284
 285 let pp_obj pp_term = function
 286  | Ast.Inductive (params, types) ->
 287     let pp_constructors constructors =
 288       String.concat "\n"
 289         (List.map (fun (name, typ) -> sprintf "| %s: %s" name (pp_term typ))
 290           constructors)
 291     in
 292     let pp_type (name, _, typ, constructors) =
 293       sprintf "\nwith %s: %s \\def\n%s" name (pp_term typ)
 294         (pp_constructors constructors)
 295     in
 296     (match types with
 297     | [] -> assert false
 298     | (name, inductive, typ, constructors) :: tl ->
 299         let fst_typ_pp =
 300           sprintf "%sinductive %s%s: %s \\def\n%s"
 301             (if inductive then "" else "co") name (pp_params pp_term params)
 302             (pp_term typ) (pp_constructors constructors)
 303         in
 304         fst_typ_pp ^ String.concat "" (List.map pp_type tl))
 305  | Ast.Theorem (`MutualDefinition, name, typ, body) ->
 306     sprintf "<<pretty printing of mutual definitions not implemented yet>>"
 307  | Ast.Theorem (flavour, name, typ, body) ->
 308     sprintf "%s %s:\n %s\n%s"
 309       (pp_flavour flavour)
 310       name
 311       (pp_term typ)
 312       (match body with
 313       | None -> ""
 314       | Some body -> "\\def\n " ^ pp_term body)
 315  | Ast.Record (params,name,ty,fields) ->
 316     "record " ^ name ^ " " ^ pp_params pp_term params ^ ": " ^ pp_term ty ^
 317     " \\def {" ^ pp_fields pp_term fields ^ "\n}"
 318
 319 let rec pp_value = function
 320   | Env.TermValue t -> sprintf "$%s$" (pp_term t)
 321   | Env.StringValue s -> sprintf "\"%s\"" s
 322   | Env.NumValue n -> n
 323   | Env.OptValue (Some v) -> "Some " ^ pp_value v
 324   | Env.OptValue None -> "None"
 325   | Env.ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 326
 327 let rec pp_value_type =
 328   function
 329   | Env.TermType -> "Term"
 330   | Env.StringType -> "String"
 331   | Env.NumType -> "Number"
 332   | Env.OptType t -> "Maybe " ^ pp_value_type t
 333   | Env.ListType l -> "List " ^ pp_value_type l
 334
 335 let pp_env env =
 336   String.concat "; "
 337     (List.map
 338       (fun (name, (ty, value)) ->
 339         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 340       env)
 341
 342 let rec pp_cic_appl_pattern = function
 343   | Ast.UriPattern uri -> UriManager.string_of_uri uri
 344   | Ast.VarPattern name -> name
 345   | Ast.ImplicitPattern -> "_"
 346   | Ast.ApplPattern aps ->
 347       sprintf "(%s)" (String.concat " " (List.map pp_cic_appl_pattern aps))
 348