helm/software/components/acic_content/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33   (* when set to true debugging information, not in sync with input syntax, will
  34    * be added to the output of pp_term.
  35    * set to false if you need, for example, cut and paste from matitac output to
  36    * matitatop *)
  37 let debug_printing = true
  38
  39 let pp_binder = function
  40   | `Lambda -> "lambda"
  41   | `Pi -> "Pi"
  42   | `Exists -> "exists"
  43   | `Forall -> "forall"
  44
  45 let pp_literal =
  46   if debug_printing then
  47     (function (* debugging version *)
  48       | `Symbol s -> sprintf "symbol(%s)" s
  49       | `Keyword s -> sprintf "keyword(%s)" s
  50       | `Number s -> sprintf "number(%s)" s)
  51   else
  52     (function
  53       | `Symbol s
  54       | `Keyword s
  55       | `Number s -> s)
  56
  57 let pp_assoc =
  58   function
  59   | Gramext.NonA -> "NonA"
  60   | Gramext.LeftA -> "LeftA"
  61   | Gramext.RightA -> "RightA"
  62
  63 let pp_pos =
  64   function
  65 (*      `None -> "`None" *)
  66     | `Left -> "`Left"
  67     | `Right -> "`Right"
  68     | `Inner -> "`Inner"
  69
  70 let pp_attribute =
  71   function
  72   | `IdRef id -> sprintf "x(%s)" id
  73   | `XmlAttrs attrs ->
  74       sprintf "X(%s)"
  75         (String.concat ";"
  76           (List.map (fun (_, n, v) -> sprintf "%s=%s" n v) attrs))
  77   | `Level (prec, assoc) -> sprintf "L(%d%s)" prec (pp_assoc assoc)
  78   | `Raw _ -> "R"
  79   | `Loc _ -> "@"
  80   | `ChildPos p -> sprintf "P(%s)" (pp_pos p)
  81
  82 let rec pp_term ?(pp_parens = true) t =
  83   let t_pp =
  84     match t with
  85     | Ast.AttributedTerm (attr, term) when debug_printing ->
  86         sprintf "%s[%s]" (pp_attribute attr) (pp_term ~pp_parens:false term)
  87     | Ast.AttributedTerm (`Raw text, _) -> text
  88     | Ast.AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  89     | Ast.Appl terms ->
  90         sprintf "%s" (String.concat " " (List.map pp_term terms))
  91     | Ast.Binder (`Forall, (Ast.Ident ("_", None), typ), body)
  92     | Ast.Binder (`Pi, (Ast.Ident ("_", None), typ), body) ->
  93         sprintf "%s \\to %s"
  94           (match typ with None -> "?" | Some typ -> pp_term typ)
  95           (pp_term ~pp_parens:true body)
  96     | Ast.Binder (kind, var, body) ->
  97         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable var)
  98           (pp_term ~pp_parens:true body)
  99     | Ast.Case (term, indtype, typ, patterns) ->
 100         sprintf "match %s%s%s with %s"
 101           (pp_term term)
 102           (match indtype with
 103           | None -> ""
 104           | Some (ty, href_opt) ->
 105               sprintf " in %s%s" ty
 106               (match debug_printing, href_opt with
 107               | true, Some uri ->
 108                   sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 109               | _ -> ""))
 110           (match typ with None -> "" | Some t -> sprintf " return %s" (pp_term t))
 111           (pp_patterns patterns)
 112     | Ast.Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term ~pp_parens:true t1) (pp_term ~pp_parens:true t2)
 113     | Ast.LetIn (var, t1, t2) ->
 114         sprintf "let %s \\def %s in %s" (pp_capture_variable var) (pp_term ~pp_parens:true t1)
 115           (pp_term ~pp_parens:true t2)
 116     | Ast.LetRec (kind, definitions, term) ->
 117         let strip i t =
 118            let rec aux i l = function
 119               | Ast.Binder (_, var, body) when i > 0 -> aux (pred i) (var :: l) body
 120               | body                                 -> List.rev l, body
 121            in
 122            aux i [] t
 123         in
 124         let rec get_guard i = function
 125            | []                   -> assert false
 126            | [term, _] when i = 1 -> term
 127            | _ :: tl              -> get_guard (pred i) tl
 128         in
 129         let map (var, body, i) =
 130            let id, vars, typ, body = match var with
 131               | term, Some typ ->
 132                  let pvars, pbody = strip i typ in
 133                  let _, bbody = strip i body in
 134                  term, pvars, pbody, bbody
 135               | _              -> assert false
 136            in
 137            sprintf "%s %s on %s: %s \\def %s"
 138               (pp_term ~pp_parens:false term)
 139               (String.concat " " (List.map pp_capture_variable vars))
 140               (pp_term ~pp_parens:false (get_guard i vars))
 141               (pp_term typ) (pp_term body)
 142         in
 143         sprintf "let %s %s in %s"
 144           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
 145           (String.concat " and " (List.map map definitions))
 146           (pp_term term)
 147     | Ast.Ident (name, Some []) | Ast.Ident (name, None)
 148     | Ast.Uri (name, Some []) | Ast.Uri (name, None) ->
 149         name
 150     | Ast.Ident (name, Some substs)
 151     | Ast.Uri (name, Some substs) ->
 152         sprintf "%s \\subst [%s]" name (pp_substs substs)
 153     | Ast.Implicit -> "?"
 154     | Ast.Meta (index, substs) ->
 155         sprintf "%d[%s]" index
 156           (String.concat "; "
 157             (List.map (function None -> "_" | Some t -> pp_term t) substs))
 158     | Ast.Num (num, _) -> num
 159     | Ast.Sort `Set -> "Set"
 160     | Ast.Sort `Prop -> "Prop"
 161     | Ast.Sort (`Type _) -> "Type"
 162     | Ast.Sort `CProp -> "CProp"
 163     | Ast.Symbol (name, _) -> "'" ^ name
 164
 165     | Ast.UserInput -> ""
 166
 167     | Ast.Literal l -> pp_literal l
 168     | Ast.Layout l -> pp_layout l
 169     | Ast.Magic m -> pp_magic m
 170     | Ast.Variable v -> pp_variable v
 171   in
 172   match pp_parens, t with
 173     | false, _
 174     | true, Ast.Implicit
 175     | true, Ast.Sort _
 176     | true, Ast.Ident (_, Some [])
 177     | true, Ast.Ident (_, None)    -> t_pp
 178     | _                            -> sprintf "(%s)" t_pp
 179
 180 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 181 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 182
 183 and pp_pattern ((head, href, vars), term) =
 184   let head_pp =
 185     head ^
 186     (match debug_printing, href with
 187     | true, Some uri -> sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 188     | _ -> "")
 189   in
 190   sprintf "%s \\Rightarrow %s"
 191     (match vars with
 192     | [] -> head_pp
 193     | _ ->
 194         sprintf "(%s %s)" head_pp
 195           (String.concat " " (List.map pp_capture_variable vars)))
 196     (pp_term term)
 197
 198 and pp_patterns patterns =
 199   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 200
 201 and pp_capture_variable =
 202   function
 203   | term, None -> pp_term ~pp_parens:false term
 204   | term, Some typ -> "(" ^ pp_term ~pp_parens:false term ^ ": " ^ pp_term typ ^ ")"
 205
 206 and pp_box_spec (kind, spacing, indent) =
 207   let int_of_bool b = if b then 1 else 0 in
 208   let kind_string =
 209     match kind with
 210     Ast.H -> "H" | Ast.V -> "V" | Ast.HV -> "HV" | Ast.HOV -> "HOV"
 211   in
 212   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 213
 214 and pp_layout = function
 215   | Ast.Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 216   | Ast.Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 217   | Ast.Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 218   | Ast.Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 219   | Ast.Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 220   | Ast.Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 221   | Ast.Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 222   | Ast.Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 223   | Ast.Root (arg, index) ->
 224       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 225   | Ast.Break -> "\\BREAK"
 226 (*   | Space -> "\\SPACE" *)
 227   | Ast.Box (box_spec, terms) ->
 228       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 229         (String.concat " " (List.map pp_term terms))
 230   | Ast.Group terms ->
 231       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 232
 233 and pp_magic = function
 234   | Ast.List0 (t, sep_opt) ->
 235       sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 236   | Ast.List1 (t, sep_opt) ->
 237       sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 238   | Ast.Opt t -> sprintf "opt %s" (pp_term t)
 239   | Ast.Fold (kind, p_base, names, p_rec) ->
 240       let acc = match names with acc :: _ -> acc | _ -> assert false in
 241       sprintf "fold %s %s rec %s %s"
 242         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 243   | Ast.Default (p_some, p_none) ->
 244       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 245   | Ast.If (p_test, p_true, p_false) ->
 246       sprintf "if %s then %s else %s"
 247         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 248   | Ast.Fail -> "fail"
 249
 250 and pp_fold_kind = function
 251   | `Left -> "left"
 252   | `Right -> "right"
 253
 254 and pp_sep_opt = function
 255   | None -> ""
 256   | Some sep -> sprintf " sep %s" (pp_literal sep)
 257
 258 and pp_variable = function
 259   | Ast.NumVar s -> "number " ^ s
 260   | Ast.IdentVar s -> "ident " ^ s
 261   | Ast.TermVar s -> "term " ^ s
 262   | Ast.Ascription (t, n) -> assert false
 263   | Ast.FreshVar n -> "fresh " ^ n
 264
 265 let _pp_term = ref (pp_term ~pp_parens:false)
 266 let pp_term t = !_pp_term t
 267 let set_pp_term f = _pp_term := f
 268
 269 let pp_params = function
 270   | [] -> ""
 271   | params ->
 272       " " ^
 273       String.concat " "
 274         (List.map
 275           (fun (name, typ) -> sprintf "(%s:%s)" name (pp_term typ))
 276           params)
 277
 278 let pp_flavour = function
 279   | `Definition -> "definition"
 280   | `Fact -> "fact"
 281   | `Goal -> "goal"
 282   | `Lemma -> "lemma"
 283   | `Remark -> "remark"
 284   | `Theorem -> "theorem"
 285   | `Variant -> "variant"
 286   | `Axiom -> "axiom"
 287
 288 let pp_fields fields =
 289   (if fields <> [] then "\n" else "") ^
 290   String.concat ";\n"
 291     (List.map
 292       (fun (name,ty,coercion,arity) ->
 293         " " ^ name ^
 294         if coercion then (":" ^
 295           if arity > 0 then string_of_int arity else "" ^ ">") else ": " ^
 296         pp_term ty) fields)
 297
 298 let pp_obj = function
 299  | Ast.Inductive (params, types) ->
 300     let pp_constructors constructors =
 301       String.concat "\n"
 302         (List.map (fun (name, typ) -> sprintf "| %s: %s" name (pp_term typ))
 303           constructors)
 304     in
 305     let pp_type (name, _, typ, constructors) =
 306       sprintf "\nwith %s: %s \\def\n%s" name (pp_term typ)
 307         (pp_constructors constructors)
 308     in
 309     (match types with
 310     | [] -> assert false
 311     | (name, inductive, typ, constructors) :: tl ->
 312         let fst_typ_pp =
 313           sprintf "%sinductive %s%s: %s \\def\n%s"
 314             (if inductive then "" else "co") name (pp_params params)
 315             (pp_term typ) (pp_constructors constructors)
 316         in
 317         fst_typ_pp ^ String.concat "" (List.map pp_type tl))
 318  | Ast.Theorem (flavour, name, typ, body) ->
 319     sprintf "%s %s:\n %s\n%s"
 320       (pp_flavour flavour)
 321       name
 322       (pp_term typ)
 323       (match body with
 324       | None -> ""
 325       | Some body -> "\\def\n " ^ pp_term body)
 326  | Ast.Record (params,name,ty,fields) ->
 327     "record " ^ name ^ " " ^ pp_params params ^ ": " ^ pp_term ty ^
 328     " \\def {" ^ pp_fields fields ^ "\n}"
 329
 330 let rec pp_value = function
 331   | Env.TermValue t -> sprintf "$%s$" (pp_term t)
 332   | Env.StringValue s -> sprintf "\"%s\"" s
 333   | Env.NumValue n -> n
 334   | Env.OptValue (Some v) -> "Some " ^ pp_value v
 335   | Env.OptValue None -> "None"
 336   | Env.ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 337
 338 let rec pp_value_type =
 339   function
 340   | Env.TermType -> "Term"
 341   | Env.StringType -> "String"
 342   | Env.NumType -> "Number"
 343   | Env.OptType t -> "Maybe " ^ pp_value_type t
 344   | Env.ListType l -> "List " ^ pp_value_type l
 345
 346 let pp_env env =
 347   String.concat "; "
 348     (List.map
 349       (fun (name, (ty, value)) ->
 350         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 351       env)
 352
 353 let rec pp_cic_appl_pattern = function
 354   | Ast.UriPattern uri -> UriManager.string_of_uri uri
 355   | Ast.VarPattern name -> name
 356   | Ast.ImplicitPattern -> "_"
 357   | Ast.ApplPattern aps ->
 358       sprintf "(%s)" (String.concat " " (List.map pp_cic_appl_pattern aps))
 359