helm/software/components/acic_content/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33   (* when set to true debugging information, not in sync with input syntax, will
  34    * be added to the output of pp_term.
  35    * set to false if you need, for example, cut and paste from matitac output to
  36    * matitatop *)
  37 let debug_printing = false
  38
  39 let pp_binder = function
  40   | `Lambda -> "lambda"
  41   | `Pi -> "Pi"
  42   | `Exists -> "exists"
  43   | `Forall -> "forall"
  44
  45 let pp_literal =
  46   if debug_printing then
  47     (function (* debugging version *)
  48       | `Symbol s -> sprintf "symbol(%s)" s
  49       | `Keyword s -> sprintf "keyword(%s)" s
  50       | `Number s -> sprintf "number(%s)" s)
  51   else
  52     (function
  53       | `Symbol s
  54       | `Keyword s
  55       | `Number s -> s)
  56
  57 let pp_pos =
  58   function
  59 (*      `None -> "`None" *)
  60     | `Left -> "`Left"
  61     | `Right -> "`Right"
  62     | `Inner -> "`Inner"
  63
  64 let pp_attribute =
  65   function
  66   | `IdRef id -> sprintf "x(%s)" id
  67   | `XmlAttrs attrs ->
  68       sprintf "X(%s)"
  69         (String.concat ";"
  70           (List.map (fun (_, n, v) -> sprintf "%s=%s" n v) attrs))
  71   | `Level (prec) -> sprintf "L(%d)" prec
  72   | `Raw _ -> "R"
  73   | `Loc _ -> "@"
  74   | `ChildPos p -> sprintf "P(%s)" (pp_pos p)
  75
  76 let pp_capture_variable pp_term =
  77   function
  78   | term, None -> pp_term (* ~pp_parens:false *) term
  79   | term, Some typ -> "(" ^ pp_term (* ~pp_parens:false *) term ^ ": " ^ pp_term typ ^ ")"
  80
  81 let rec pp_term ?(pp_parens = true) t =
  82   let t_pp =
  83     match t with
  84     | Ast.AttributedTerm (attr, term) when debug_printing ->
  85         sprintf "%s[%s]" (pp_attribute attr) (pp_term ~pp_parens:false term)
  86     | Ast.AttributedTerm (`Raw text, _) -> text
  87     | Ast.AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  88     | Ast.Appl terms ->
  89         sprintf "%s" (String.concat " " (List.map pp_term terms))
  90     | Ast.Binder (`Forall, (Ast.Ident ("_", None), typ), body)
  91     | Ast.Binder (`Pi, (Ast.Ident ("_", None), typ), body) ->
  92         sprintf "%s \\to %s"
  93           (match typ with None -> "?" | Some typ -> pp_term typ)
  94           (pp_term ~pp_parens:true body)
  95     | Ast.Binder (kind, var, body) ->
  96         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable pp_term var)
  97           (pp_term ~pp_parens:true body)
  98     | Ast.Case (term, indtype, typ, patterns) ->
  99         sprintf "match %s%s%s with %s"
 100           (pp_term term)
 101           (match indtype with
 102           | None -> ""
 103           | Some (ty, href_opt) ->
 104               sprintf " in %s%s" ty
 105               (match debug_printing, href_opt with
 106               | true, Some uri ->
 107                   sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 108               | _ -> ""))
 109           (match typ with None -> "" | Some t -> sprintf " return %s" (pp_term t))
 110           (pp_patterns patterns)
 111     | Ast.Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term ~pp_parens:true t1) (pp_term ~pp_parens:true t2)
 112     | Ast.LetIn ((var,t2), t1, t3) ->
 113 (*       let t2 = match t2 with None -> Ast.Implicit | Some t -> t in *)
 114         sprintf "let %s \\def %s in %s" (pp_term var)
 115 (*           (pp_term ~pp_parens:true t2) *)
 116           (pp_term ~pp_parens:true t1)
 117           (pp_term ~pp_parens:true t3)
 118     | Ast.LetRec (kind, definitions, term) ->
 119         let rec get_guard i = function
 120            | []                   -> (*assert false*) Ast.Implicit `JustOne
 121            | [term, _] when i = 1 -> term
 122            | _ :: tl              -> get_guard (pred i) tl
 123         in
 124         let map (params, (id,typ), body, i) =
 125          let typ =
 126           match typ with
 127              None -> Ast.Implicit `JustOne
 128            | Some typ -> typ
 129          in
 130            sprintf "%s %s on %s: %s \\def %s"
 131               (pp_term ~pp_parens:false term)
 132               (String.concat " " (List.map (pp_capture_variable pp_term) params))
 133               (pp_term ~pp_parens:false (get_guard i params))
 134               (pp_term typ) (pp_term body)
 135         in
 136         sprintf "let %s %s in %s"
 137           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
 138           (String.concat " and " (List.map map definitions))
 139           (pp_term term)
 140     | Ast.Ident (name, Some []) | Ast.Ident (name, None)
 141     | Ast.Uri (name, Some []) | Ast.Uri (name, None) -> name
 142     | Ast.NRef nref -> NReference.string_of_reference nref
 143     | Ast.Ident (name, Some substs)
 144     | Ast.Uri (name, Some substs) ->
 145         sprintf "%s \\subst [%s]" name (pp_substs substs)
 146     | Ast.Implicit `Vector -> "?"
 147     | Ast.Implicit `JustOne -> "…"
 148     | Ast.Meta (index, substs) ->
 149         sprintf "%d[%s]" index
 150           (String.concat "; "
 151             (List.map (function None -> "?" | Some t -> pp_term t) substs))
 152     | Ast.Num (num, _) -> num
 153     | Ast.Sort `Set -> "Set"
 154     | Ast.Sort `Prop -> "Prop"
 155     | Ast.Sort (`Type _) -> "Type"
 156     | Ast.Sort (`CProp _)-> "CProp"
 157     | Ast.Sort (`NType s)-> "Type[" ^ s ^ "]"
 158     | Ast.Sort (`NCProp s)-> "CProp[" ^ s ^ "]"
 159     | Ast.Symbol (name, _) -> "'" ^ name
 160
 161     | Ast.UserInput -> ""
 162
 163     | Ast.Literal l -> pp_literal l
 164     | Ast.Layout l -> pp_layout l
 165     | Ast.Magic m -> pp_magic m
 166     | Ast.Variable v -> pp_variable v
 167   in
 168   match pp_parens, t with
 169     | false, _
 170     | true, Ast.Implicit _
 171     | true, Ast.Sort _
 172     | true, Ast.Ident (_, Some [])
 173     | true, Ast.Ident (_, None)    -> t_pp
 174     | _                            -> sprintf "(%s)" t_pp
 175
 176 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 177 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 178
 179 and pp_pattern =
 180  function
 181     Ast.Pattern (head, href, vars), term ->
 182      let head_pp =
 183        head ^
 184        (match debug_printing, href with
 185        | true, Some uri -> sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 186        | _ -> "")
 187      in
 188      sprintf "%s \\Rightarrow %s"
 189        (match vars with
 190        | [] -> head_pp
 191        | _ ->
 192            sprintf "(%s %s)" head_pp
 193              (String.concat " " (List.map (pp_capture_variable pp_term) vars)))
 194        (pp_term term)
 195   | Ast.Wildcard, term ->
 196      sprintf "_ \\Rightarrow %s" (pp_term term)
 197
 198 and pp_patterns patterns =
 199   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 200
 201 and pp_box_spec (kind, spacing, indent) =
 202   let int_of_bool b = if b then 1 else 0 in
 203   let kind_string =
 204     match kind with
 205     Ast.H -> "H" | Ast.V -> "V" | Ast.HV -> "HV" | Ast.HOV -> "HOV"
 206   in
 207   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 208
 209 and pp_layout = function
 210   | Ast.Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 211   | Ast.Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 212   | Ast.Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 213   | Ast.Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 214   | Ast.Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 215   | Ast.Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 216   | Ast.Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 217   | Ast.InfRule (t1, t2, t3) -> sprintf "\\INFRULE %s %s %s" (pp_term t1)
 218   (pp_term t2) (pp_term t3)
 219   | Ast.Maction l -> sprintf "\\MACTION (%s)"
 220      (String.concat "," (List.map pp_term l))
 221   | Ast.Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 222   | Ast.Root (arg, index) ->
 223       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 224   | Ast.Break -> "\\BREAK"
 225 (*   | Space -> "\\SPACE" *)
 226   | Ast.Box (box_spec, terms) ->
 227       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 228         (String.concat " " (List.map pp_term terms))
 229   | Ast.Group terms ->
 230       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 231   | Ast.Mstyle (l,terms) ->
 232       sprintf "\\MSTYLE %s [%s]"
 233         (String.concat " " (List.map (fun (k,v) -> k^"="^v) l))
 234         (String.concat " " (List.map pp_term terms))
 235   | Ast.Mpadded (l,terms) ->
 236       sprintf "\\MSTYLE %s [%s]"
 237         (String.concat " " (List.map (fun (k,v) -> k^"="^v) l))
 238         (String.concat " " (List.map pp_term terms))
 239
 240 and pp_magic = function
 241   | Ast.List0 (t, sep_opt) ->
 242       sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 243   | Ast.List1 (t, sep_opt) ->
 244       sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 245   | Ast.Opt t -> sprintf "opt %s" (pp_term t)
 246   | Ast.Fold (kind, p_base, names, p_rec) ->
 247       let acc = match names with acc :: _ -> acc | _ -> assert false in
 248       sprintf "fold %s %s rec %s %s"
 249         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 250   | Ast.Default (p_some, p_none) ->
 251       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 252   | Ast.If (p_test, p_true, p_false) ->
 253       sprintf "if %s then %s else %s"
 254         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 255   | Ast.Fail -> "fail"
 256
 257 and pp_fold_kind = function
 258   | `Left -> "left"
 259   | `Right -> "right"
 260
 261 and pp_sep_opt = function
 262   | None -> ""
 263   | Some sep -> sprintf " sep %s" (pp_literal sep)
 264
 265 and pp_variable = function
 266   | Ast.NumVar s -> "number " ^ s
 267   | Ast.IdentVar s -> "ident " ^ s
 268   | Ast.TermVar (s,Ast.Self _) -> s
 269   | Ast.TermVar (s,Ast.Level l) -> "term " ^string_of_int l
 270   | Ast.Ascription (t, n) -> assert false
 271   | Ast.FreshVar n -> "fresh " ^ n
 272
 273 let _pp_term = ref (pp_term ~pp_parens:false)
 274 let pp_term t = !_pp_term t
 275 let set_pp_term f = _pp_term := f
 276
 277 let pp_params pp_term = function
 278   | [] -> ""
 279   | params -> " " ^ String.concat " " (List.map (pp_capture_variable pp_term) params)
 280
 281 let pp_flavour = function
 282   | `Definition -> "definition"
 283   | `MutualDefinition -> assert false
 284   | `Fact -> "fact"
 285   | `Goal -> "goal"
 286   | `Lemma -> "lemma"
 287   | `Remark -> "remark"
 288   | `Theorem -> "theorem"
 289   | `Variant -> "variant"
 290   | `Axiom -> "axiom"
 291
 292 let pp_fields pp_term fields =
 293   (if fields <> [] then "\n" else "") ^
 294   String.concat ";\n"
 295     (List.map
 296       (fun (name,ty,coercion,arity) ->
 297         " " ^ name ^
 298         (if coercion then
 299           (":" ^ (if arity > 0 then string_of_int arity else "") ^ "> ")
 300         else ": ") ^
 301       pp_term ty)
 302     fields)
 303
 304 let pp_obj pp_term = function
 305  | Ast.Inductive (params, types) ->
 306     let pp_constructors constructors =
 307       String.concat "\n"
 308         (List.map (fun (name, typ) -> sprintf "| %s: %s" name (pp_term typ))
 309           constructors)
 310     in
 311     let pp_type (name, _, typ, constructors) =
 312       sprintf "\nwith %s: %s \\def\n%s" name (pp_term typ)
 313         (pp_constructors constructors)
 314     in
 315     (match types with
 316     | [] -> assert false
 317     | (name, inductive, typ, constructors) :: tl ->
 318         let fst_typ_pp =
 319           sprintf "%sinductive %s%s: %s \\def\n%s"
 320             (if inductive then "" else "co") name (pp_params pp_term params)
 321             (pp_term typ) (pp_constructors constructors)
 322         in
 323         fst_typ_pp ^ String.concat "" (List.map pp_type tl))
 324  | Ast.Theorem (`MutualDefinition, name, typ, body) ->
 325     sprintf "<<pretty printing of mutual definitions not implemented yet>>"
 326  | Ast.Theorem (flavour, name, typ, body) ->
 327     sprintf "%s %s:\n %s\n%s"
 328       (pp_flavour flavour)
 329       name
 330       (pp_term typ)
 331       (match body with
 332       | None -> ""
 333       | Some body -> "\\def\n " ^ pp_term body)
 334  | Ast.Record (params,name,ty,fields) ->
 335     "record " ^ name ^ " " ^ pp_params pp_term params ^ ": " ^ pp_term ty ^
 336     " \\def {" ^ pp_fields pp_term fields ^ "\n}"
 337
 338 let rec pp_value = function
 339   | Env.TermValue t -> sprintf "$%s$" (pp_term t)
 340   | Env.StringValue s -> sprintf "\"%s\"" s
 341   | Env.NumValue n -> n
 342   | Env.OptValue (Some v) -> "Some " ^ pp_value v
 343   | Env.OptValue None -> "None"
 344   | Env.ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 345
 346 let rec pp_value_type =
 347   function
 348   | Env.TermType l -> "Term "^string_of_int l
 349   | Env.StringType -> "String"
 350   | Env.NumType -> "Number"
 351   | Env.OptType t -> "Maybe " ^ pp_value_type t
 352   | Env.ListType l -> "List " ^ pp_value_type l
 353
 354 let pp_env env =
 355   String.concat "; "
 356     (List.map
 357       (fun (name, (ty, value)) ->
 358         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 359       env)
 360
 361 let rec pp_cic_appl_pattern = function
 362   | Ast.UriPattern uri -> UriManager.string_of_uri uri
 363   | Ast.NRefPattern nref -> NReference.string_of_reference nref
 364   | Ast.VarPattern name -> name
 365   | Ast.ImplicitPattern -> "?"
 366   | Ast.ApplPattern aps ->
 367       sprintf "(%s)" (String.concat " " (List.map pp_cic_appl_pattern aps))
 368