helm/software/components/acic_content/cicNotationUtil.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module Ast = CicNotationPt
  29
  30 let visit_ast ?(special_k = fun _ -> assert false)
  31   ?(map_xref_option= fun x -> x) ?(map_case_indty= fun x -> x)
  32   ?(map_case_outtype=
  33       fun k x -> match x with None -> None | Some x -> Some (k x))
  34   k
  35 =
  36   let rec aux = function
  37     | Ast.Appl terms -> Ast.Appl (List.map k terms)
  38     | Ast.Binder (kind, var, body) ->
  39         Ast.Binder (kind, aux_capture_variable var, k body)
  40     | Ast.Case (term, indtype, typ, patterns) ->
  41         Ast.Case (k term, map_case_indty indtype, map_case_outtype k typ,
  42           aux_patterns map_xref_option patterns)
  43     | Ast.Cast (t1, t2) -> Ast.Cast (k t1, k t2)
  44     | Ast.LetIn (var, t1, t3) ->
  45         Ast.LetIn (aux_capture_variable var, k t1, k t3)
  46     | Ast.LetRec (kind, definitions, term) ->
  47         let definitions =
  48           List.map
  49             (fun (params, var, ty, decrno) ->
  50               List.map aux_capture_variable params, aux_capture_variable var,
  51               k ty, decrno)
  52             definitions
  53         in
  54         Ast.LetRec (kind, definitions, k term)
  55     | Ast.Ident (name, Some substs) ->
  56         Ast.Ident (name, Some (aux_substs substs))
  57     | Ast.Uri (name, Some substs) -> Ast.Uri (name, Some (aux_substs substs))
  58     | Ast.Meta (index, substs) -> Ast.Meta (index, List.map aux_opt substs)
  59     | (Ast.AttributedTerm _
  60       | Ast.Layout _
  61       | Ast.Literal _
  62       | Ast.Magic _
  63       | Ast.Variable _) as t -> special_k t
  64     | (Ast.Ident _
  65       | Ast.Implicit
  66       | Ast.Num _
  67       | Ast.Sort _
  68       | Ast.Symbol _
  69       | Ast.Uri _
  70       | Ast.UserInput) as t -> t
  71   and aux_opt = function
  72     | None -> None
  73     | Some term -> Some (k term)
  74   and aux_capture_variable (term, typ_opt) = k term, aux_opt typ_opt
  75   and aux_patterns k_xref patterns = List.map (aux_pattern k_xref) patterns
  76   and aux_pattern k_xref =
  77    function
  78       Ast.Pattern (head, hrefs, vars), term ->
  79         Ast.Pattern (head, k_xref hrefs, List.map aux_capture_variable vars), k term
  80     | Ast.Wildcard, term -> Ast.Wildcard, k term
  81   and aux_subst (name, term) = (name, k term)
  82   and aux_substs substs = List.map aux_subst substs
  83   in
  84   aux
  85
  86 let visit_layout k = function
  87   | Ast.Sub (t1, t2) -> Ast.Sub (k t1, k t2)
  88   | Ast.Sup (t1, t2) -> Ast.Sup (k t1, k t2)
  89   | Ast.Below (t1, t2) -> Ast.Below (k t1, k t2)
  90   | Ast.Above (t1, t2) -> Ast.Above (k t1, k t2)
  91   | Ast.Over (t1, t2) -> Ast.Over (k t1, k t2)
  92   | Ast.Atop (t1, t2) -> Ast.Atop (k t1, k t2)
  93   | Ast.Frac (t1, t2) -> Ast.Frac (k t1, k t2)
  94   | Ast.InfRule (t1, t2, t3) -> Ast.InfRule (k t1, k t2, k t3)
  95   | Ast.Sqrt t -> Ast.Sqrt (k t)
  96   | Ast.Root (arg, index) -> Ast.Root (k arg, k index)
  97   | Ast.Break -> Ast.Break
  98   | Ast.Box (kind, terms) -> Ast.Box (kind, List.map k terms)
  99   | Ast.Group terms -> Ast.Group (List.map k terms)
 100   | Ast.Mstyle (l, term) -> Ast.Mstyle (l, List.map k term)
 101   | Ast.Mpadded (l, term) -> Ast.Mpadded (l, List.map k term)
 102   | Ast.Maction terms -> Ast.Maction (List.map k terms)
 103
 104 let visit_magic k = function
 105   | Ast.List0 (t, l) -> Ast.List0 (k t, l)
 106   | Ast.List1 (t, l) -> Ast.List1 (k t, l)
 107   | Ast.Opt t -> Ast.Opt (k t)
 108   | Ast.Fold (kind, t1, names, t2) -> Ast.Fold (kind, k t1, names, k t2)
 109   | Ast.Default (t1, t2) -> Ast.Default (k t1, k t2)
 110   | Ast.If (t1, t2, t3) -> Ast.If (k t1, k t2, k t3)
 111   | Ast.Fail -> Ast.Fail
 112
 113 let visit_variable k = function
 114   | Ast.NumVar _
 115   | Ast.IdentVar _
 116   | Ast.TermVar _
 117   | Ast.FreshVar _ as t -> t
 118   | Ast.Ascription (t, s) -> Ast.Ascription (k t, s)
 119
 120 let variables_of_term t =
 121   let rec vars = ref [] in
 122   let add_variable v =
 123     if List.mem v !vars then ()
 124     else vars := v :: !vars
 125   in
 126   let rec aux = function
 127     | Ast.Magic m -> Ast.Magic (visit_magic aux m)
 128     | Ast.Layout l -> Ast.Layout (visit_layout aux l)
 129     | Ast.Variable v -> Ast.Variable (aux_variable v)
 130     | Ast.Literal _ as t -> t
 131     | Ast.AttributedTerm (_, t) -> aux t
 132     | t -> visit_ast aux t
 133   and aux_variable = function
 134     | (Ast.NumVar _
 135       | Ast.IdentVar _
 136       | Ast.TermVar _) as t ->
 137         add_variable t ;
 138         t
 139     | Ast.FreshVar _ as t -> t
 140     | Ast.Ascription _ -> assert false
 141   in
 142     ignore (aux t) ;
 143     !vars
 144
 145 let names_of_term t =
 146   let aux = function
 147     | Ast.NumVar s
 148     | Ast.IdentVar s
 149     | Ast.TermVar (s,_) -> s
 150     | _ -> assert false
 151   in
 152     List.map aux (variables_of_term t)
 153
 154 let keywords_of_term t =
 155   let rec keywords = ref [] in
 156   let add_keyword k = keywords := k :: !keywords in
 157   let rec aux = function
 158     | Ast.AttributedTerm (_, t) -> aux t
 159     | Ast.Layout l -> Ast.Layout (visit_layout aux l)
 160     | Ast.Literal (`Keyword k) as t ->
 161         add_keyword k;
 162         t
 163     | Ast.Literal _ as t -> t
 164     | Ast.Magic m -> Ast.Magic (visit_magic aux m)
 165     | Ast.Variable _ as v -> v
 166     | t -> visit_ast aux t
 167   in
 168     ignore (aux t) ;
 169     !keywords
 170
 171 let rec strip_attributes t =
 172   let special_k = function
 173     | Ast.AttributedTerm (_, term) -> strip_attributes term
 174     | Ast.Magic m -> Ast.Magic (visit_magic strip_attributes m)
 175     | Ast.Variable _ as t -> t
 176     | t -> assert false
 177   in
 178   visit_ast ~special_k strip_attributes t
 179
 180 let rec get_idrefs =
 181   function
 182   | Ast.AttributedTerm (`IdRef id, t) -> id :: get_idrefs t
 183   | Ast.AttributedTerm (_, t) -> get_idrefs t
 184   | _ -> []
 185
 186 let meta_names_of_term term =
 187   let rec names = ref [] in
 188   let add_name n =
 189     if List.mem n !names then ()
 190     else names := n :: !names
 191   in
 192   let rec aux = function
 193     | Ast.AttributedTerm (_, term) -> aux term
 194     | Ast.Appl terms -> List.iter aux terms
 195     | Ast.Binder (_, _, body) -> aux body
 196     | Ast.Case (term, indty, outty_opt, patterns) ->
 197         aux term ;
 198         aux_opt outty_opt ;
 199         List.iter aux_branch patterns
 200     | Ast.LetIn (_, t1, t3) ->
 201         aux t1 ;
 202         aux t3
 203     | Ast.LetRec (_, definitions, body) ->
 204         List.iter aux_definition definitions ;
 205         aux body
 206     | Ast.Uri (_, Some substs) -> aux_substs substs
 207     | Ast.Ident (_, Some substs) -> aux_substs substs
 208     | Ast.Meta (_, substs) -> aux_meta_substs substs
 209
 210     | Ast.Implicit
 211     | Ast.Ident _
 212     | Ast.Num _
 213     | Ast.Sort _
 214     | Ast.Symbol _
 215     | Ast.Uri _
 216     | Ast.UserInput -> ()
 217
 218     | Ast.Magic magic -> aux_magic magic
 219     | Ast.Variable var -> aux_variable var
 220
 221     | _ -> assert false
 222   and aux_opt = function
 223     | Some term -> aux term
 224     | None -> ()
 225   and aux_capture_var (_, ty_opt) = aux_opt ty_opt
 226   and aux_branch (pattern, term) =
 227     aux_pattern pattern ;
 228     aux term
 229   and aux_pattern =
 230    function
 231       Ast.Pattern (head, _, vars) -> List.iter aux_capture_var vars
 232     | Ast.Wildcard -> ()
 233   and aux_definition (params, var, term, decrno) =
 234     List.iter aux_capture_var params ;
 235     aux_capture_var var ;
 236     aux term
 237   and aux_substs substs = List.iter (fun (_, term) -> aux term) substs
 238   and aux_meta_substs meta_substs = List.iter aux_opt meta_substs
 239   and aux_variable = function
 240     | Ast.NumVar name -> add_name name
 241     | Ast.IdentVar name -> add_name name
 242     | Ast.TermVar (name,_) -> add_name name
 243     | Ast.FreshVar _ -> ()
 244     | Ast.Ascription _ -> assert false
 245   and aux_magic = function
 246     | Ast.Default (t1, t2)
 247     | Ast.Fold (_, t1, _, t2) ->
 248         aux t1 ;
 249         aux t2
 250     | Ast.If (t1, t2, t3) ->
 251         aux t1 ;
 252         aux t2 ;
 253         aux t3
 254     | Ast.Fail -> ()
 255     | _ -> assert false
 256   in
 257   aux term ;
 258   !names
 259
 260 let rectangular matrix =
 261   let columns = Array.length matrix.(0) in
 262   try
 263     Array.iter (fun a -> if Array.length a <> columns then raise Exit) matrix;
 264     true
 265   with Exit -> false
 266
 267 let ncombine ll =
 268   let matrix = Array.of_list (List.map Array.of_list ll) in
 269   assert (rectangular matrix);
 270   let rows = Array.length matrix in
 271   let columns = Array.length matrix.(0) in
 272   let lists = ref [] in
 273   for j = 0 to columns - 1 do
 274     let l = ref [] in
 275     for i = 0 to rows - 1 do
 276       l := matrix.(i).(j) :: !l
 277     done;
 278     lists := List.rev !l :: !lists
 279   done;
 280   List.rev !lists
 281
 282 let string_of_literal = function
 283   | `Symbol s
 284   | `Keyword s
 285   | `Number s -> s
 286
 287 let boxify = function
 288   | [ a ] -> a
 289   | l -> Ast.Layout (Ast.Box ((Ast.H, false, false), l))
 290
 291 let unboxify = function
 292   | Ast.Layout (Ast.Box ((Ast.H, false, false), [ a ])) -> a
 293   | l -> l
 294
 295 let group = function
 296   | [ a ] -> a
 297   | l -> Ast.Layout (Ast.Group l)
 298
 299 let ungroup =
 300   let rec aux acc =
 301     function
 302         [] -> List.rev acc
 303       | Ast.Layout (Ast.Group terms) :: terms' -> aux acc (terms @ terms')
 304       | term :: terms -> aux (term :: acc) terms
 305   in
 306     aux []
 307
 308 let dress ~sep:sauce =
 309   let rec aux =
 310     function
 311       | [] -> []
 312       | [hd] -> [hd]
 313       | hd :: tl -> hd :: sauce :: aux tl
 314   in
 315     aux
 316
 317 let dressn ~sep:sauces =
 318   let rec aux =
 319     function
 320       | [] -> []
 321       | [hd] -> [hd]
 322       | hd :: tl -> hd :: sauces @ aux tl
 323   in
 324     aux
 325
 326 let find_appl_pattern_uris ap =
 327   let rec aux acc =
 328     function
 329     | Ast.UriPattern uri -> uri :: acc
 330     | Ast.ImplicitPattern
 331     | Ast.VarPattern _ -> acc
 332     | Ast.ApplPattern apl -> List.fold_left aux acc apl
 333   in
 334   let uris = aux [] ap in
 335   HExtlib.list_uniq (List.fast_sort UriManager.compare uris)
 336
 337 let rec find_branch =
 338   function
 339       Ast.Magic (Ast.If (_, Ast.Magic Ast.Fail, t)) -> find_branch t
 340     | Ast.Magic (Ast.If (_, t, _)) -> find_branch t
 341     | t -> t
 342
 343 let cic_name_of_name = function
 344   | Ast.Ident ("_", None) -> Cic.Anonymous
 345   | Ast.Ident (name, None) -> Cic.Name name
 346   | _ -> assert false
 347
 348 let name_of_cic_name =
 349 (*   let add_dummy_xref t = Ast.AttributedTerm (`IdRef "", t) in *)
 350   (* ZACK why we used to generate dummy xrefs? *)
 351   let add_dummy_xref t = t in
 352   function
 353   | Cic.Name s -> add_dummy_xref (Ast.Ident (s, None))
 354   | Cic.Anonymous -> add_dummy_xref (Ast.Ident ("_", None))
 355
 356 let fresh_index = ref ~-1
 357
 358 type notation_id = int
 359
 360 let fresh_id () =
 361   incr fresh_index;
 362   !fresh_index
 363
 364   (* TODO ensure that names generated by fresh_var do not clash with user's *)
 365   (* FG: "η" is not an identifier (it is rendered, but not be parsed) *)
 366 let fresh_name () = "eta" ^ string_of_int (fresh_id ())
 367
 368 let rec freshen_term ?(index = ref 0) term =
 369   let freshen_term = freshen_term ~index in
 370   let fresh_instance () = incr index; !index in
 371   let special_k = function
 372     | Ast.AttributedTerm (attr, t) -> Ast.AttributedTerm (attr, freshen_term t)
 373     | Ast.Layout l -> Ast.Layout (visit_layout freshen_term l)
 374     | Ast.Magic m -> Ast.Magic (visit_magic freshen_term m)
 375     | Ast.Variable v -> Ast.Variable (visit_variable freshen_term v)
 376     | Ast.Literal _ as t -> t
 377     | _ -> assert false
 378   in
 379   match term with
 380   | Ast.Symbol (s, instance) -> Ast.Symbol (s, fresh_instance ())
 381   | Ast.Num (s, instance) -> Ast.Num (s, fresh_instance ())
 382   | t -> visit_ast ~special_k freshen_term t
 383
 384 let freshen_obj obj =
 385   let index = ref 0 in
 386   let freshen_term = freshen_term ~index in
 387   let freshen_name_ty = List.map (fun (n, t) -> (n, freshen_term t)) in
 388   let freshen_name_ty_b = List.map (fun (n,t,b,i) -> (n,freshen_term t,b,i)) in
 389   let freshen_capture_variables =
 390    List.map (fun (n,t) -> (freshen_term n, HExtlib.map_option freshen_term t))
 391   in
 392   match obj with
 393   | CicNotationPt.Inductive (params, indtypes) ->
 394       let indtypes =
 395         List.map
 396           (fun (n, co, ty, ctors) -> (n, co, ty, freshen_name_ty ctors))
 397           indtypes
 398       in
 399       CicNotationPt.Inductive (freshen_capture_variables params, indtypes)
 400   | CicNotationPt.Theorem (flav, n, t, ty_opt) ->
 401       let ty_opt =
 402         match ty_opt with None -> None | Some ty -> Some (freshen_term ty)
 403       in
 404       CicNotationPt.Theorem (flav, n, freshen_term t, ty_opt)
 405   | CicNotationPt.Record (params, n, ty, fields) ->
 406       CicNotationPt.Record (freshen_capture_variables params, n,
 407         freshen_term ty, freshen_name_ty_b fields)
 408
 409 let freshen_term = freshen_term ?index:None
 410