helm/software/components/acic_content/cicNotationUtil.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module Ast = CicNotationPt
  29
  30 let visit_ast ?(special_k = fun _ -> assert false) k =
  31   let rec aux = function
  32     | Ast.Appl terms -> Ast.Appl (List.map k terms)
  33     | Ast.Binder (kind, var, body) ->
  34         Ast.Binder (kind, aux_capture_variable var, k body)
  35     | Ast.Case (term, indtype, typ, patterns) ->
  36         Ast.Case (k term, indtype, aux_opt typ, aux_patterns patterns)
  37     | Ast.Cast (t1, t2) -> Ast.Cast (k t1, k t2)
  38     | Ast.LetIn (var, t1, t3) ->
  39         Ast.LetIn (aux_capture_variable var, k t1, k t3)
  40     | Ast.LetRec (kind, definitions, term) ->
  41         let definitions =
  42           List.map
  43             (fun (params, var, ty, decrno) ->
  44               List.map aux_capture_variable params, aux_capture_variable var,
  45               k ty, decrno)
  46             definitions
  47         in
  48         Ast.LetRec (kind, definitions, k term)
  49     | Ast.Ident (name, Some substs) ->
  50         Ast.Ident (name, Some (aux_substs substs))
  51     | Ast.Uri (name, Some substs) -> Ast.Uri (name, Some (aux_substs substs))
  52     | Ast.Meta (index, substs) -> Ast.Meta (index, List.map aux_opt substs)
  53     | (Ast.AttributedTerm _
  54       | Ast.Layout _
  55       | Ast.Literal _
  56       | Ast.Magic _
  57       | Ast.Variable _) as t -> special_k t
  58     | (Ast.Ident _
  59       | Ast.Implicit
  60       | Ast.Num _
  61       | Ast.Sort _
  62       | Ast.Symbol _
  63       | Ast.Uri _
  64       | Ast.UserInput) as t -> t
  65   and aux_opt = function
  66     | None -> None
  67     | Some term -> Some (k term)
  68   and aux_capture_variable (term, typ_opt) = k term, aux_opt typ_opt
  69   and aux_patterns patterns = List.map aux_pattern patterns
  70   and aux_pattern =
  71    function
  72       Ast.Pattern (head, hrefs, vars), term ->
  73         Ast.Pattern (head, hrefs, List.map aux_capture_variable vars), k term
  74     | Ast.Wildcard, term -> Ast.Wildcard, k term
  75   and aux_subst (name, term) = (name, k term)
  76   and aux_substs substs = List.map aux_subst substs
  77   in
  78   aux
  79
  80 let visit_layout k = function
  81   | Ast.Sub (t1, t2) -> Ast.Sub (k t1, k t2)
  82   | Ast.Sup (t1, t2) -> Ast.Sup (k t1, k t2)
  83   | Ast.Below (t1, t2) -> Ast.Below (k t1, k t2)
  84   | Ast.Above (t1, t2) -> Ast.Above (k t1, k t2)
  85   | Ast.Over (t1, t2) -> Ast.Over (k t1, k t2)
  86   | Ast.Atop (t1, t2) -> Ast.Atop (k t1, k t2)
  87   | Ast.Frac (t1, t2) -> Ast.Frac (k t1, k t2)
  88   | Ast.InfRule (t1, t2, t3) -> Ast.InfRule (k t1, k t2, k t3)
  89   | Ast.Sqrt t -> Ast.Sqrt (k t)
  90   | Ast.Root (arg, index) -> Ast.Root (k arg, k index)
  91   | Ast.Break -> Ast.Break
  92   | Ast.Box (kind, terms) -> Ast.Box (kind, List.map k terms)
  93   | Ast.Group terms -> Ast.Group (List.map k terms)
  94   | Ast.Mstyle (l, term) -> Ast.Mstyle (l, List.map k term)
  95   | Ast.Mpadded (l, term) -> Ast.Mpadded (l, List.map k term)
  96
  97 let visit_magic k = function
  98   | Ast.List0 (t, l) -> Ast.List0 (k t, l)
  99   | Ast.List1 (t, l) -> Ast.List1 (k t, l)
 100   | Ast.Opt t -> Ast.Opt (k t)
 101   | Ast.Fold (kind, t1, names, t2) -> Ast.Fold (kind, k t1, names, k t2)
 102   | Ast.Default (t1, t2) -> Ast.Default (k t1, k t2)
 103   | Ast.If (t1, t2, t3) -> Ast.If (k t1, k t2, k t3)
 104   | Ast.Fail -> Ast.Fail
 105
 106 let visit_variable k = function
 107   | Ast.NumVar _
 108   | Ast.IdentVar _
 109   | Ast.TermVar _
 110   | Ast.FreshVar _ as t -> t
 111   | Ast.Ascription (t, s) -> Ast.Ascription (k t, s)
 112
 113 let variables_of_term t =
 114   let rec vars = ref [] in
 115   let add_variable v =
 116     if List.mem v !vars then ()
 117     else vars := v :: !vars
 118   in
 119   let rec aux = function
 120     | Ast.Magic m -> Ast.Magic (visit_magic aux m)
 121     | Ast.Layout l -> Ast.Layout (visit_layout aux l)
 122     | Ast.Variable v -> Ast.Variable (aux_variable v)
 123     | Ast.Literal _ as t -> t
 124     | Ast.AttributedTerm (_, t) -> aux t
 125     | t -> visit_ast aux t
 126   and aux_variable = function
 127     | (Ast.NumVar _
 128       | Ast.IdentVar _
 129       | Ast.TermVar _) as t ->
 130         add_variable t ;
 131         t
 132     | Ast.FreshVar _ as t -> t
 133     | Ast.Ascription _ -> assert false
 134   in
 135     ignore (aux t) ;
 136     !vars
 137
 138 let names_of_term t =
 139   let aux = function
 140     | Ast.NumVar s
 141     | Ast.IdentVar s
 142     | Ast.TermVar (s,_) -> s
 143     | _ -> assert false
 144   in
 145     List.map aux (variables_of_term t)
 146
 147 let keywords_of_term t =
 148   let rec keywords = ref [] in
 149   let add_keyword k = keywords := k :: !keywords in
 150   let rec aux = function
 151     | Ast.AttributedTerm (_, t) -> aux t
 152     | Ast.Layout l -> Ast.Layout (visit_layout aux l)
 153     | Ast.Literal (`Keyword k) as t ->
 154         add_keyword k;
 155         t
 156     | Ast.Literal _ as t -> t
 157     | Ast.Magic m -> Ast.Magic (visit_magic aux m)
 158     | Ast.Variable _ as v -> v
 159     | t -> visit_ast aux t
 160   in
 161     ignore (aux t) ;
 162     !keywords
 163
 164 let rec strip_attributes t =
 165   let special_k = function
 166     | Ast.AttributedTerm (_, term) -> strip_attributes term
 167     | Ast.Magic m -> Ast.Magic (visit_magic strip_attributes m)
 168     | Ast.Variable _ as t -> t
 169     | t -> assert false
 170   in
 171   visit_ast ~special_k strip_attributes t
 172
 173 let rec get_idrefs =
 174   function
 175   | Ast.AttributedTerm (`IdRef id, t) -> id :: get_idrefs t
 176   | Ast.AttributedTerm (_, t) -> get_idrefs t
 177   | _ -> []
 178
 179 let meta_names_of_term term =
 180   let rec names = ref [] in
 181   let add_name n =
 182     if List.mem n !names then ()
 183     else names := n :: !names
 184   in
 185   let rec aux = function
 186     | Ast.AttributedTerm (_, term) -> aux term
 187     | Ast.Appl terms -> List.iter aux terms
 188     | Ast.Binder (_, _, body) -> aux body
 189     | Ast.Case (term, indty, outty_opt, patterns) ->
 190         aux term ;
 191         aux_opt outty_opt ;
 192         List.iter aux_branch patterns
 193     | Ast.LetIn (_, t1, t3) ->
 194         aux t1 ;
 195         aux t3
 196     | Ast.LetRec (_, definitions, body) ->
 197         List.iter aux_definition definitions ;
 198         aux body
 199     | Ast.Uri (_, Some substs) -> aux_substs substs
 200     | Ast.Ident (_, Some substs) -> aux_substs substs
 201     | Ast.Meta (_, substs) -> aux_meta_substs substs
 202
 203     | Ast.Implicit
 204     | Ast.Ident _
 205     | Ast.Num _
 206     | Ast.Sort _
 207     | Ast.Symbol _
 208     | Ast.Uri _
 209     | Ast.UserInput -> ()
 210
 211     | Ast.Magic magic -> aux_magic magic
 212     | Ast.Variable var -> aux_variable var
 213
 214     | _ -> assert false
 215   and aux_opt = function
 216     | Some term -> aux term
 217     | None -> ()
 218   and aux_capture_var (_, ty_opt) = aux_opt ty_opt
 219   and aux_branch (pattern, term) =
 220     aux_pattern pattern ;
 221     aux term
 222   and aux_pattern =
 223    function
 224       Ast.Pattern (head, _, vars) -> List.iter aux_capture_var vars
 225     | Ast.Wildcard -> ()
 226   and aux_definition (params, var, term, decrno) =
 227     List.iter aux_capture_var params ;
 228     aux_capture_var var ;
 229     aux term
 230   and aux_substs substs = List.iter (fun (_, term) -> aux term) substs
 231   and aux_meta_substs meta_substs = List.iter aux_opt meta_substs
 232   and aux_variable = function
 233     | Ast.NumVar name -> add_name name
 234     | Ast.IdentVar name -> add_name name
 235     | Ast.TermVar (name,_) -> add_name name
 236     | Ast.FreshVar _ -> ()
 237     | Ast.Ascription _ -> assert false
 238   and aux_magic = function
 239     | Ast.Default (t1, t2)
 240     | Ast.Fold (_, t1, _, t2) ->
 241         aux t1 ;
 242         aux t2
 243     | Ast.If (t1, t2, t3) ->
 244         aux t1 ;
 245         aux t2 ;
 246         aux t3
 247     | Ast.Fail -> ()
 248     | _ -> assert false
 249   in
 250   aux term ;
 251   !names
 252
 253 let rectangular matrix =
 254   let columns = Array.length matrix.(0) in
 255   try
 256     Array.iter (fun a -> if Array.length a <> columns then raise Exit) matrix;
 257     true
 258   with Exit -> false
 259
 260 let ncombine ll =
 261   let matrix = Array.of_list (List.map Array.of_list ll) in
 262   assert (rectangular matrix);
 263   let rows = Array.length matrix in
 264   let columns = Array.length matrix.(0) in
 265   let lists = ref [] in
 266   for j = 0 to columns - 1 do
 267     let l = ref [] in
 268     for i = 0 to rows - 1 do
 269       l := matrix.(i).(j) :: !l
 270     done;
 271     lists := List.rev !l :: !lists
 272   done;
 273   List.rev !lists
 274
 275 let string_of_literal = function
 276   | `Symbol s
 277   | `Keyword s
 278   | `Number s -> s
 279
 280 let boxify = function
 281   | [ a ] -> a
 282   | l -> Ast.Layout (Ast.Box ((Ast.H, false, false), l))
 283
 284 let unboxify = function
 285   | Ast.Layout (Ast.Box ((Ast.H, false, false), [ a ])) -> a
 286   | l -> l
 287
 288 let group = function
 289   | [ a ] -> a
 290   | l -> Ast.Layout (Ast.Group l)
 291
 292 let ungroup =
 293   let rec aux acc =
 294     function
 295         [] -> List.rev acc
 296       | Ast.Layout (Ast.Group terms) :: terms' -> aux acc (terms @ terms')
 297       | term :: terms -> aux (term :: acc) terms
 298   in
 299     aux []
 300
 301 let dress ~sep:sauce =
 302   let rec aux =
 303     function
 304       | [] -> []
 305       | [hd] -> [hd]
 306       | hd :: tl -> hd :: sauce :: aux tl
 307   in
 308     aux
 309
 310 let dressn ~sep:sauces =
 311   let rec aux =
 312     function
 313       | [] -> []
 314       | [hd] -> [hd]
 315       | hd :: tl -> hd :: sauces @ aux tl
 316   in
 317     aux
 318
 319 let find_appl_pattern_uris ap =
 320   let rec aux acc =
 321     function
 322     | Ast.UriPattern uri -> uri :: acc
 323     | Ast.ImplicitPattern
 324     | Ast.VarPattern _ -> acc
 325     | Ast.ApplPattern apl -> List.fold_left aux acc apl
 326   in
 327   let uris = aux [] ap in
 328   HExtlib.list_uniq (List.fast_sort UriManager.compare uris)
 329
 330 let rec find_branch =
 331   function
 332       Ast.Magic (Ast.If (_, Ast.Magic Ast.Fail, t)) -> find_branch t
 333     | Ast.Magic (Ast.If (_, t, _)) -> find_branch t
 334     | t -> t
 335
 336 let cic_name_of_name = function
 337   | Ast.Ident ("_", None) -> Cic.Anonymous
 338   | Ast.Ident (name, None) -> Cic.Name name
 339   | _ -> assert false
 340
 341 let name_of_cic_name =
 342 (*   let add_dummy_xref t = Ast.AttributedTerm (`IdRef "", t) in *)
 343   (* ZACK why we used to generate dummy xrefs? *)
 344   let add_dummy_xref t = t in
 345   function
 346   | Cic.Name s -> add_dummy_xref (Ast.Ident (s, None))
 347   | Cic.Anonymous -> add_dummy_xref (Ast.Ident ("_", None))
 348
 349 let fresh_index = ref ~-1
 350
 351 type notation_id = int
 352
 353 let fresh_id () =
 354   incr fresh_index;
 355   !fresh_index
 356
 357   (* TODO ensure that names generated by fresh_var do not clash with user's *)
 358 let fresh_name () = "fresh" ^ string_of_int (fresh_id ())
 359
 360 let rec freshen_term ?(index = ref 0) term =
 361   let freshen_term = freshen_term ~index in
 362   let fresh_instance () = incr index; !index in
 363   let special_k = function
 364     | Ast.AttributedTerm (attr, t) -> Ast.AttributedTerm (attr, freshen_term t)
 365     | Ast.Layout l -> Ast.Layout (visit_layout freshen_term l)
 366     | Ast.Magic m -> Ast.Magic (visit_magic freshen_term m)
 367     | Ast.Variable v -> Ast.Variable (visit_variable freshen_term v)
 368     | Ast.Literal _ as t -> t
 369     | _ -> assert false
 370   in
 371   match term with
 372   | Ast.Symbol (s, instance) -> Ast.Symbol (s, fresh_instance ())
 373   | Ast.Num (s, instance) -> Ast.Num (s, fresh_instance ())
 374   | t -> visit_ast ~special_k freshen_term t
 375
 376 let freshen_obj obj =
 377   let index = ref 0 in
 378   let freshen_term = freshen_term ~index in
 379   let freshen_name_ty = List.map (fun (n, t) -> (n, freshen_term t)) in
 380   let freshen_name_ty_b = List.map (fun (n,t,b,i) -> (n,freshen_term t,b,i)) in
 381   let freshen_capture_variables =
 382    List.map (fun (n,t) -> (freshen_term n, HExtlib.map_option freshen_term t))
 383   in
 384   match obj with
 385   | CicNotationPt.Inductive (params, indtypes) ->
 386       let indtypes =
 387         List.map
 388           (fun (n, co, ty, ctors) -> (n, co, ty, freshen_name_ty ctors))
 389           indtypes
 390       in
 391       CicNotationPt.Inductive (freshen_capture_variables params, indtypes)
 392   | CicNotationPt.Theorem (flav, n, t, ty_opt) ->
 393       let ty_opt =
 394         match ty_opt with None -> None | Some ty -> Some (freshen_term ty)
 395       in
 396       CicNotationPt.Theorem (flav, n, freshen_term t, ty_opt)
 397   | CicNotationPt.Record (params, n, ty, fields) ->
 398       CicNotationPt.Record (freshen_capture_variables params, n,
 399         freshen_term ty, freshen_name_ty_b fields)
 400
 401 let freshen_term = freshen_term ?index:None
 402