helm/software/components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41 module NU   = CicNotationUtil
  42
  43 module Cl   = ProceduralClassify
  44 module T    = ProceduralTypes
  45 module Cn   = ProceduralConversion
  46 module H    = ProceduralHelpers
  47
  48 type status = {
  49    sorts : (C.id, A.sort_kind) Hashtbl.t;
  50    types : (C.id, A.anntypes) Hashtbl.t;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    case: int list
  55 }
  56
  57 let debug = false
  58
  59 (* helpers ******************************************************************)
  60
  61 let split2_last l1 l2 =
  62 try
  63    let n = pred (List.length l1) in
  64    let before1, after1 = HEL.split_nth n l1 in
  65    let before2, after2 = HEL.split_nth n l2 in
  66    before1, before2, List.hd after1, List.hd after2
  67 with Invalid_argument _ -> failwith "A2P.split2_last"
  68
  69 let string_of_head = function
  70    | C.ASort _         -> "sort"
  71    | C.AConst _        -> "const"
  72    | C.AMutInd _       -> "mutind"
  73    | C.AMutConstruct _ -> "mutconstruct"
  74    | C.AVar _          -> "var"
  75    | C.ARel _          -> "rel"
  76    | C.AProd _         -> "prod"
  77    | C.ALambda _       -> "lambda"
  78    | C.ALetIn _        -> "letin"
  79    | C.AFix _          -> "fix"
  80    | C.ACoFix _        -> "cofix"
  81    | C.AAppl _         -> "appl"
  82    | C.ACast _         -> "cast"
  83    | C.AMutCase _      -> "mutcase"
  84    | C.AMeta _         -> "meta"
  85    | C.AImplicit _     -> "implict"
  86
  87 let next st = {st with depth = succ st.depth}
  88
  89 let add st entry = {st with context = entry :: st.context}
  90
  91 let push st = {st with case = 1 :: st.case}
  92
  93 let inc st =
  94    {st with case = match st.case with
  95       | []       -> assert false
  96       | hd :: tl -> succ hd :: tl
  97    }
  98
  99 let case st str =
 100    let case = String.concat "." (List.rev_map string_of_int st.case) in
 101    Printf.sprintf "case %s: %s" case str
 102
 103 let test_depth st =
 104 try
 105    let msg = Printf.sprintf "Depth %u: " st.depth in
 106    match st.max_depth with
 107       | None   -> true, ""
 108       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 109 with Invalid_argument _ -> failwith "A2P.test_depth"
 110
 111 let is_rewrite_right = function
 112    | C.AConst (_, uri, []) ->
 113       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 114    | _                     -> false
 115
 116 let is_rewrite_left = function
 117    | C.AConst (_, uri, []) ->
 118       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 119    | _                     -> false
 120
 121 let is_fwd_rewrite_right hd tl =
 122    if is_rewrite_right hd then match List.nth tl 3 with
 123       | C.ARel _ -> true
 124       | _        -> false
 125    else false
 126
 127 let is_fwd_rewrite_left hd tl =
 128    if is_rewrite_left hd then match List.nth tl 3 with
 129       | C.ARel _ -> true
 130       | _        -> false
 131    else false
 132
 133 let get_inner_types st v =
 134 try
 135    let id = Ut.id_of_annterm v in
 136    try match Hashtbl.find st.types id with
 137       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 138       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 139    with Not_found -> None
 140 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 141 (*
 142 let get_inner_sort st v =
 143 try
 144    let id = Ut.id_of_annterm v in
 145    try Hashtbl.find st.sorts id
 146    with Not_found -> `Type (CicUniv.fresh())
 147 with Invalid_argument _ -> failwith "A2P.get_sort"
 148 *)
 149 let get_type msg st bo =
 150 try
 151    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.oblivion_ugraph in
 152    ty
 153 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 154
 155 let get_entry st id =
 156    let rec aux = function
 157       | []                                        -> assert false
 158       | Some (C.Name name, e) :: _ when name = id -> e
 159       | _ :: tl                                   -> aux tl
 160    in
 161    aux st.context
 162
 163 let get_ind_names uri tno =
 164 try
 165    let ts = match E.get_obj Un.oblivion_ugraph uri with
 166       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 167       | _                                      -> assert false
 168    in
 169    match List.nth ts tno with
 170       | (_, _, _, cs) -> List.map fst cs
 171 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 172
 173 let string_of_atomic = function
 174    | C.ARel (_, _, _, s)               -> s
 175    | C.AVar (_, uri, _)                -> H.name_of_uri uri None None
 176    | C.AConst (_, uri, _)              -> H.name_of_uri uri None None
 177    | C.AMutInd (_, uri, i, _)          -> H.name_of_uri uri (Some i) None
 178    | C.AMutConstruct (_, uri, i, j, _) -> H.name_of_uri uri (Some i) (Some j)
 179    | _                                 -> ""
 180
 181 let get_sub_names head l =
 182    let s = string_of_atomic head in
 183    if s = "" then [] else
 184    let map (names, i) _ =
 185       let name = Printf.sprintf "%s_%u" s i in name :: names, succ i
 186    in
 187    let names, _ = List.fold_left map ([], 1) l in
 188    List.rev names
 189
 190 (* proof construction *******************************************************)
 191
 192 let anonymous_premise = C.Name "PREMISE"
 193
 194 let mk_exp_args hd tl classes synth =
 195    let meta id = C.AImplicit (id, None) in
 196    let map v (cl, b) =
 197       if I.overlaps synth cl && b then v else meta ""
 198    in
 199    let rec aux = function
 200       | [] -> []
 201       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 202    in
 203    let args = T.list_rev_map2 map tl classes in
 204    let args = aux args in
 205    if args = [] then hd else C.AAppl ("", hd :: args)
 206
 207 let mk_convert st ?name sty ety note =
 208    let e = Cn.hole "" in
 209    let csty, cety = H.cic sty, H.cic ety in
 210    let script =
 211       if debug then
 212          let sname = match name with None -> "" | Some (id, _) -> id in
 213          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 214             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 215          in
 216          [T.Note note]
 217       else []
 218    in
 219    assert (Ut.is_sober st.context csty);
 220    assert (Ut.is_sober st.context cety);
 221    if Ut.alpha_equivalence csty cety then script else
 222    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 223    match name with
 224       | None         -> T.Change (sty, ety, None, e, "") :: script
 225       | Some (id, i) ->
 226          begin match get_entry st id with
 227             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 228             | C.Decl _ ->
 229                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 230          end
 231
 232 let convert st ?name v =
 233    match get_inner_types st v with
 234       | None            ->
 235          if debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 236       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 237
 238 let convert_elim st ?name t v pattern =
 239    match t, get_inner_types st t, get_inner_types st v with
 240       | _, None, _
 241       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 242       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 243          let where = List.hd (List.rev tl) in
 244          let cty = Cn.elim_inferred_type
 245              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 246          in
 247          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 248       | _, Some _, Some _                                     -> assert false
 249
 250 let get_intro = function
 251    | C.Anonymous -> None
 252    | C.Name s    -> Some s
 253
 254 let mk_preamble st what script =
 255    convert st what @ script
 256
 257 let mk_arg st = function
 258    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 259    | _                              -> []
 260
 261 let mk_fwd_rewrite st dtext name tl direction v t ity =
 262    let compare premise = function
 263       | None   -> true
 264       | Some s -> s = premise
 265    in
 266    assert (List.length tl = 6);
 267    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 268    let e = Cn.mk_pattern 1 predicate in
 269    if (Cn.does_not_occur e) then st, [] else
 270    match where with
 271       | C.ARel (_, _, i, premise) as w ->
 272 (*         let _script = convert_elim st ~name:(premise, i) v w e in *)
 273          let script name =
 274             let where = Some (premise, name) in
 275             let script = mk_arg st what @ mk_arg st w (* @ script *) in
 276             T.Rewrite (direction, what, where, e, dtext) :: script
 277          in
 278          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 279             {st with context = Cn.clear st.context premise}, script name
 280          else begin
 281             assert (Ut.is_sober st.context (H.cic ity));
 282             let ity = H.acic_bc st.context ity in
 283             let br1 = [T.Id ""] in
 284             let br2 = List.rev (T.Apply (w, "assumption") :: script None) in
 285             let text = "non linear rewrite" in
 286             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 287          end
 288       | _                         -> assert false
 289
 290 let mk_rewrite st dtext where qs tl direction t =
 291    assert (List.length tl = 5);
 292    let predicate = List.nth tl 2 in
 293    let e = Cn.mk_pattern 1 predicate in
 294    let script = [T.Branch (qs, "")] in
 295    if (Cn.does_not_occur e) then script else
 296 (*   let script = convert_elim st t t e in *)
 297    T.Rewrite (direction, where, None, e, dtext) :: script
 298
 299 let rec proc_lambda st what name v t =
 300    let name = match name with
 301       | C.Anonymous -> H.mk_fresh_name st.context anonymous_premise
 302       | name        -> name
 303    in
 304    let entry = Some (name, C.Decl (H.cic v)) in
 305    let intro = get_intro name in
 306    let script = proc_proof (add st entry) t in
 307    let script = T.Intros (Some 1, [intro], "") :: script in
 308    mk_preamble st what script
 309
 310 and proc_letin st what name v w t =
 311    let intro = get_intro name in
 312    let proceed, dtext = test_depth st in
 313    let script = if proceed then
 314       let st, hyp, rqv = match get_inner_types st v with
 315          | Some (ity, _) ->
 316             let st, rqv = match v with
 317                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 318                   mk_fwd_rewrite st dtext intro tl true v t ity
 319                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 320                   mk_fwd_rewrite st dtext intro tl false v t ity
 321                | v                                                     ->
 322                   assert (Ut.is_sober st.context (H.cic ity));
 323                   let ity = H.acic_bc st.context ity in
 324                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 325                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 326             in
 327             st, C.Decl (H.cic ity), rqv
 328          | None          ->
 329             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 330       in
 331       let entry = Some (name, hyp) in
 332       let qt = proc_proof (next (add st entry)) t in
 333       List.rev_append rqv qt
 334    else
 335       [T.Apply (what, dtext)]
 336    in
 337    mk_preamble st what script
 338
 339 and proc_rel st what =
 340    let _, dtext = test_depth st in
 341    let text = "assumption" in
 342    let script = [T.Apply (what, dtext ^ text)] in
 343    mk_preamble st what script
 344
 345 and proc_mutconstruct st what =
 346    let _, dtext = test_depth st in
 347    let script = [T.Apply (what, dtext)] in
 348    mk_preamble st what script
 349
 350 and proc_const st what =
 351    let _, dtext = test_depth st in
 352    let script = [T.Apply (what, dtext)] in
 353    mk_preamble st what script
 354
 355 and proc_appl st what hd tl =
 356    let proceed, dtext = test_depth st in
 357    let script = if proceed then
 358       let ty = get_type "TC2" st hd in
 359       let classes, rc = Cl.classify st.context ty in
 360       let goal_arity, goal = match get_inner_types st what with
 361          | None            -> 0, None
 362          | Some (ity, ety) ->
 363            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 364       in
 365       let parsno, argsno = List.length classes, List.length tl in
 366       let decurry = parsno - argsno in
 367       let diff = goal_arity - decurry in
 368       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 369       let classes = Cl.adjust st.context tl ?goal classes in
 370       let rec mk_synth a n =
 371          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 372       in
 373       let synth = mk_synth I.S.empty decurry in
 374       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 375       let script = List.rev (mk_arg st hd) in
 376       match rc with
 377          | Some (i, j, uri, tyno) ->
 378             let classes2, tl2, _, where = split2_last classes tl in
 379             let script2 = List.rev (mk_arg st where) @ script in
 380             let synth2 = I.S.add 1 synth in
 381             let names = get_ind_names uri tyno in
 382             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 383             if List.length qs <> List.length names then
 384                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 385                let hd = mk_exp_args hd tl classes synth in
 386                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 387             else if is_rewrite_right hd then
 388                script2 @ mk_rewrite st dtext where qs tl2 false what
 389             else if is_rewrite_left hd then
 390                script2 @ mk_rewrite st dtext where qs tl2 true what
 391             else
 392                let predicate = List.nth tl2 (parsno - i) in
 393                let e = Cn.mk_pattern j predicate in
 394                let using = Some hd in
 395                (* convert_elim st what what e @ *) script2 @
 396                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 397          | None        ->
 398             let names = get_sub_names hd tl in
 399             let qs = proc_bkd_proofs (next st) synth names classes tl in
 400             let hd = mk_exp_args hd tl classes synth in
 401             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 402    else
 403       [T.Apply (what, dtext)]
 404    in
 405    mk_preamble st what script
 406
 407 and proc_other st what =
 408    let _, dtext = test_depth st in
 409    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 410    let script = [T.Apply (what, dtext ^ text)] in
 411    mk_preamble st what script
 412
 413 and proc_proof st t =
 414    let f st =
 415       let xtypes, note = match get_inner_types st t with
 416          | Some (it, et) -> Some (H.cic it, H.cic et),
 417           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 418           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 419          | None          -> None, "\nNo types"
 420       in
 421       let context, _clears = Cn.get_clears st.context (H.cic t) xtypes in
 422       {st with context = context}
 423    in
 424    match t with
 425       | C.ALambda (_, name, w, t) as what   -> proc_lambda (f st) what name w t
 426       | C.ALetIn (_, name, v, w, t) as what -> proc_letin (f st) what name v w t
 427       | C.ARel _ as what                    -> proc_rel (f st) what
 428       | C.AMutConstruct _ as what           -> proc_mutconstruct (f st) what
 429       | C.AConst _ as what                  -> proc_const (f st) what
 430       | C.AAppl (_, hd :: tl) as what       -> proc_appl (f st) what hd tl
 431       | what                                -> proc_other (f st) what
 432
 433 and proc_bkd_proofs st synth names classes ts =
 434 try
 435    let get_names b = ref (names, if b then push st else st) in
 436    let get_note f b names =
 437       match !names with
 438          | [], st       -> f st
 439          | "" :: tl, st -> names := tl, st; f st
 440          | hd :: tl, st ->
 441             let note = case st hd in
 442             names := tl, inc st;
 443             if b then T.Note note :: f st else f st
 444    in
 445    let _, dtext = test_depth st in
 446    let aux (inv, _) v =
 447       if I.overlaps synth inv then None else
 448       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 449       Some (get_note (fun _ -> [T.Apply (v, dtext ^ "dependent")]))
 450    in
 451    let ps = T.list_map2_filter aux classes ts in
 452    let b = List.length ps > 1 in
 453    let names = get_names b in
 454    List.rev_map (fun f -> f b names) ps
 455
 456 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 457
 458 (* object costruction *******************************************************)
 459
 460 let th_flavours = [`Theorem; `Lemma; `Remark; `Fact]
 461
 462 let def_flavours = [`Definition]
 463
 464 let get_flavour ?flavour attrs =
 465    let rec aux = function
 466       | []               -> List.hd th_flavours
 467       | `Flavour fl :: _ -> fl
 468       | _ :: tl          -> aux tl
 469    in
 470    match flavour with
 471       | Some fl -> fl
 472       | None    -> aux attrs
 473
 474 let proc_obj ?flavour st = function
 475    | C.AConstant (_, _, s, Some v, t, [], attrs)         ->
 476       begin match get_flavour ?flavour attrs with
 477          | flavour when List.mem flavour th_flavours  ->
 478             let ast = proc_proof st v in
 479             let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 480             let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 481             T.Statement (flavour, Some s, t, None, "") :: ast @ [T.Qed text]
 482          | flavour when List.mem flavour def_flavours ->
 483             [T.Statement (flavour, Some s, t, Some v, "")]
 484          | _                                  ->
 485             failwith "not a theorem, definition, axiom or inductive type"
 486       end
 487    | C.AConstant (_, _, s, None, t, [], attrs)           ->
 488       [T.Statement (`Axiom, Some s, t, None, "")]
 489    | C.AInductiveDefinition (_, types, [], lpsno, attrs) ->
 490       [T.Inductive (types, lpsno, "")]
 491    | _                                          ->
 492       failwith "not a theorem, definition, axiom or inductive type"
 493
 494 (* interface functions ******************************************************)
 495
 496 let procedural_of_acic_object ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 497    ?flavour prefix anobj =
 498    let st = {
 499       sorts       = ids_to_inner_sorts;
 500       types       = ids_to_inner_types;
 501       max_depth   = depth;
 502       depth       = 0;
 503       context     = [];
 504       case        = []
 505    } in
 506    HLog.debug "Procedural: level 2 transformation";
 507    let steps = proc_obj st ?flavour anobj in
 508    HLog.debug "Procedural: grafite rendering";
 509    List.rev (T.render_steps [] steps)
 510
 511 let procedural_of_acic_term ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 512    prefix context annterm =
 513    let st = {
 514       sorts       = ids_to_inner_sorts;
 515       types       = ids_to_inner_types;
 516       max_depth   = depth;
 517       depth       = 0;
 518       context     = context;
 519       case        = []
 520    } in
 521    HLog.debug "Procedural: level 2 transformation";
 522    let steps = proc_proof st annterm in
 523    HLog.debug "Procedural: grafite rendering";
 524    List.rev (T.render_steps [] steps)