helm/software/components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45 module H    = ProceduralHelpers
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    intros: string option list;
  55    clears: string list;
  56    clears_note: string;
  57    case: int list;
  58    skip_thm_and_qed : bool;
  59 }
  60
  61 let debug = true
  62
  63 (* helpers ******************************************************************)
  64
  65 let split2_last l1 l2 =
  66 try
  67    let n = pred (List.length l1) in
  68    let before1, after1 = HEL.split_nth n l1 in
  69    let before2, after2 = HEL.split_nth n l2 in
  70    before1, before2, List.hd after1, List.hd after2
  71 with Invalid_argument _ -> failwith "A2P.split2_last"
  72
  73 let string_of_head = function
  74    | C.ASort _         -> "sort"
  75    | C.AConst _        -> "const"
  76    | C.AMutInd _       -> "mutind"
  77    | C.AMutConstruct _ -> "mutconstruct"
  78    | C.AVar _          -> "var"
  79    | C.ARel _          -> "rel"
  80    | C.AProd _         -> "prod"
  81    | C.ALambda _       -> "lambda"
  82    | C.ALetIn _        -> "letin"
  83    | C.AFix _          -> "fix"
  84    | C.ACoFix _        -> "cofix"
  85    | C.AAppl _         -> "appl"
  86    | C.ACast _         -> "cast"
  87    | C.AMutCase _      -> "mutcase"
  88    | C.AMeta _         -> "meta"
  89    | C.AImplicit _     -> "implict"
  90
  91 let clear st = {st with intros = []}
  92
  93 let next st = {(clear st) with depth = succ st.depth}
  94
  95 let add st entry intro =
  96    {st with context = entry :: st.context; intros = intro :: st.intros}
  97
  98 let push st = {st with case = 1 :: st.case}
  99
 100 let inc st =
 101    {st with case = match st.case with
 102       | []       -> assert false
 103       | hd :: tl -> succ hd :: tl
 104    }
 105
 106 let case st str =
 107    let case = String.concat "." (List.rev_map string_of_int st.case) in
 108    Printf.sprintf "case %s: %s" case str
 109
 110 let test_depth st =
 111 try
 112    let msg = Printf.sprintf "Depth %u: " st.depth in
 113    match st.max_depth with
 114       | None   -> true, ""
 115       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 116 with Invalid_argument _ -> failwith "A2P.test_depth"
 117
 118 let is_rewrite_right = function
 119    | C.AConst (_, uri, []) ->
 120       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 121    | _                     -> false
 122
 123 let is_rewrite_left = function
 124    | C.AConst (_, uri, []) ->
 125       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 126    | _                     -> false
 127
 128 let is_fwd_rewrite_right hd tl =
 129    if is_rewrite_right hd then match List.nth tl 3 with
 130       | C.ARel _ -> true
 131       | _        -> false
 132    else false
 133
 134 let is_fwd_rewrite_left hd tl =
 135    if is_rewrite_left hd then match List.nth tl 3 with
 136       | C.ARel _ -> true
 137       | _        -> false
 138    else false
 139
 140 let get_inner_types st v =
 141 try
 142    let id = Ut.id_of_annterm v in
 143    try match Hashtbl.find st.types id with
 144       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 145       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 146    with Not_found -> None
 147 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 148 (*
 149 let get_inner_sort st v =
 150 try
 151    let id = Ut.id_of_annterm v in
 152    try Hashtbl.find st.sorts id
 153    with Not_found -> `Type (CicUniv.fresh())
 154 with Invalid_argument _ -> failwith "A2P.get_sort"
 155 *)
 156 let get_type msg st bo =
 157 try
 158    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.oblivion_ugraph in
 159    ty
 160 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 161
 162 let get_entry st id =
 163    let rec aux = function
 164       | []                                        -> assert false
 165       | Some (C.Name name, e) :: _ when name = id -> e
 166       | _ :: tl                                   -> aux tl
 167    in
 168    aux st.context
 169
 170 let get_ind_names uri tno =
 171 try
 172    let ts = match E.get_obj Un.oblivion_ugraph uri with
 173       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 174       | _                                      -> assert false
 175    in
 176    match List.nth ts tno with
 177       | (_, _, _, cs) -> List.map fst cs
 178 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 179
 180 (* proof construction *******************************************************)
 181
 182 let used_premise = C.Name "USED"
 183
 184 let mk_exp_args hd tl classes synth =
 185    let meta id = C.AImplicit (id, None) in
 186    let map v (cl, b) =
 187       if I.overlaps synth cl && b then v else meta ""
 188    in
 189    let rec aux = function
 190       | [] -> []
 191       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 192    in
 193    let args = T.list_rev_map2 map tl classes in
 194    let args = aux args in
 195    if args = [] then hd else C.AAppl ("", hd :: args)
 196
 197 let mk_convert st ?name sty ety note =
 198    let e = Cn.hole "" in
 199    let csty, cety = H.cic sty, H.cic ety in
 200    let script =
 201       if debug then
 202          let sname = match name with None -> "" | Some (id, _) -> id in
 203          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 204             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 205          in
 206          [T.Note note]
 207       else []
 208    in
 209    assert (Ut.is_sober csty);
 210    assert (Ut.is_sober cety);
 211    if Ut.alpha_equivalence csty cety then script else
 212    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 213    match name with
 214       | None         -> T.Change (sty, ety, None, e, "") :: script
 215       | Some (id, i) ->
 216          begin match get_entry st id with
 217             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 218             | C.Decl _ ->
 219                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 220          end
 221
 222 let convert st ?name v =
 223    match get_inner_types st v with
 224       | None            ->
 225          if debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 226       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 227
 228 let convert_elim st ?name t v pattern =
 229    match t, get_inner_types st t, get_inner_types st v with
 230       | _, None, _
 231       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 232       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 233          let where = List.hd (List.rev tl) in
 234          let cty = Cn.elim_inferred_type
 235              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 236          in
 237          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 238       | _, Some _, Some _                                     -> assert false
 239
 240 let get_intro = function
 241    | C.Anonymous -> None
 242    | C.Name s    -> Some s
 243
 244 let mk_intros st what script =
 245    let intros st script =
 246       if st.intros = [] then script else
 247       let count = List.length st.intros in
 248       T.Intros (Some count, List.rev st.intros, "") :: script
 249    in
 250    let clears st script =
 251       if true (* st.clears = [] *) then script else T.Clear (st.clears, st.clears_note) :: script
 252    in
 253    intros st (clears st (convert st what @ script))
 254
 255 let mk_arg st = function
 256    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 257    | _                              -> []
 258
 259 let mk_fwd_rewrite st dtext name tl direction t =
 260    assert (List.length tl = 6);
 261    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 262    let e = Cn.mk_pattern 1 predicate in
 263    match where with
 264       | C.ARel (_, _, i, premise) as v ->
 265          let where = Some (premise, name) in
 266 (*         let _script = convert_elim st ~name:(premise, i) t v e in *)
 267          let script = mk_arg st what @ mk_arg st v (* @ script *) in
 268          let st = {st with context = Cn.clear st.context premise} in
 269          st, T.Rewrite (direction, what, where, e, dtext) :: script
 270       | _                         -> assert false
 271
 272 let mk_rewrite st dtext where qs tl direction t =
 273    assert (List.length tl = 5);
 274    let predicate = List.nth tl 2 in
 275    let e = Cn.mk_pattern 1 predicate in
 276    let script = [] (* convert_elim st t t e *) in
 277    script @ [T.Rewrite (direction, where, None, e, dtext); T.Branch (qs, "")]
 278
 279 let rec proc_lambda st name v t =
 280    let dno = DTI.does_not_occur 1 (H.cic t) in
 281    let dno = dno && match get_inner_types st t with
 282       | None          -> false
 283       | Some (it, et) ->
 284          DTI.does_not_occur 1 (H.cic it) && DTI.does_not_occur 1 (H.cic et)
 285    in
 286    let name = match dno, name with
 287       | true, _            -> C.Anonymous
 288       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 289       | false, name        -> name
 290    in
 291    let entry = Some (name, C.Decl (H.cic v)) in
 292    let intro = get_intro name in
 293    proc_proof (add st entry intro) t
 294
 295 and proc_letin st what name v w t =
 296    let intro = get_intro name in
 297    let proceed, dtext = test_depth st in
 298    let script = if proceed then
 299       let st, hyp, rqv = match get_inner_types st v with
 300          | Some (ity, _) ->
 301             let st, rqv = match v with
 302                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 303                   mk_fwd_rewrite st dtext intro tl true v
 304                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 305                   mk_fwd_rewrite st dtext intro tl false v
 306                | v                                                     ->
 307                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 308                   let ity = H.acic_bc st.context ity in
 309                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 310             in
 311             st, C.Decl (H.cic ity), rqv
 312          | None          ->
 313             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 314       in
 315       let entry = Some (name, hyp) in
 316       let qt = proc_proof (next (add st entry intro)) t in
 317       List.rev_append rqv qt
 318    else
 319       [T.Apply (what, dtext)]
 320    in
 321    mk_intros st what script
 322
 323 and proc_rel st what =
 324    let _, dtext = test_depth st in
 325    let text = "assumption" in
 326    let script = [T.Apply (what, dtext ^ text)] in
 327    mk_intros st what script
 328
 329 and proc_mutconstruct st what =
 330    let _, dtext = test_depth st in
 331    let script = [T.Apply (what, dtext)] in
 332    mk_intros st what script
 333
 334 and proc_const st what =
 335    let _, dtext = test_depth st in
 336    let script = [T.Apply (what, dtext)] in
 337    mk_intros st what script
 338
 339 and proc_appl st what hd tl =
 340    let proceed, dtext = test_depth st in
 341    let script = if proceed then
 342       let ty = get_type "TC2" st hd in
 343       let classes, rc = Cl.classify st.context ty in
 344       let goal_arity, goal = match get_inner_types st what with
 345          | None            -> 0, None
 346          | Some (ity, ety) ->
 347            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 348       in
 349       let parsno, argsno = List.length classes, List.length tl in
 350       let decurry = parsno - argsno in
 351       let diff = goal_arity - decurry in
 352       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 353       let classes = Cl.adjust st.context tl ?goal classes in
 354       let rec mk_synth a n =
 355          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 356       in
 357       let synth = mk_synth I.S.empty decurry in
 358       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 359       let script = List.rev (mk_arg st hd) in
 360       match rc with
 361          | Some (i, j, uri, tyno) ->
 362             let classes2, tl2, _, where = split2_last classes tl in
 363             let script2 = List.rev (mk_arg st where) @ script in
 364             let synth2 = I.S.add 1 synth in
 365             let names = get_ind_names uri tyno in
 366             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 367             if List.length qs <> List.length names then
 368                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 369                let hd = mk_exp_args hd tl classes synth in
 370                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 371             else if is_rewrite_right hd then
 372                script2 @ mk_rewrite st dtext where qs tl2 false what
 373             else if is_rewrite_left hd then
 374                script2 @ mk_rewrite st dtext where qs tl2 true what
 375             else
 376                let predicate = List.nth tl2 (parsno - i) in
 377                let e = Cn.mk_pattern j predicate in
 378                let using = Some hd in
 379                (* convert_elim st what what e @ *) script2 @
 380                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 381          | None        ->
 382             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 383             let hd = mk_exp_args hd tl classes synth in
 384             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 385    else
 386       [T.Apply (what, dtext)]
 387    in
 388    mk_intros st what script
 389
 390 and proc_other st what =
 391    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 392    let script = [T.Note text] in
 393    mk_intros st what script
 394
 395 and proc_proof st t =
 396    let f st =
 397       let xtypes, note = match get_inner_types st t with
 398          | Some (it, et) -> Some (H.cic it, H.cic et),
 399           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 400           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 401          | None          -> None, "\nNo types"
 402       in
 403       let context, clears = Cn.get_clears st.context (H.cic t) xtypes in
 404       let note = Pp.ppcontext st.context ^ note in
 405       {st with context = context; clears = clears; clears_note = note; }
 406    in
 407    match t with
 408       | C.ALambda (_, name, w, t)           -> proc_lambda st name w t
 409       | C.ALetIn (_, name, v, w, t) as what -> proc_letin (f st) what name v w t
 410       | C.ARel _ as what                    -> proc_rel (f st) what
 411       | C.AMutConstruct _ as what           -> proc_mutconstruct (f st) what
 412       | C.AConst _ as what                  -> proc_const (f st) what
 413       | C.AAppl (_, hd :: tl) as what       -> proc_appl (f st) what hd tl
 414       | what                                -> proc_other (f st) what
 415
 416 and proc_bkd_proofs st synth names classes ts =
 417 try
 418    let get_note =
 419       let names = ref (names, push st) in
 420       fun f ->
 421          match !names with
 422             | [], st       -> fun _ -> f st
 423             | "" :: tl, st -> names := tl, st; fun _ -> f st
 424             | hd :: tl, st ->
 425                let note = case st hd in
 426                names := tl, inc st;
 427                fun b -> if b then T.Note note :: f st else f st
 428    in
 429    let _, dtext = test_depth st in
 430    let aux (inv, _) v =
 431       if I.overlaps synth inv then None else
 432       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 433       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 434    in
 435    let ps = T.list_map2_filter aux classes ts in
 436    let b = List.length ps > 1 in
 437    List.rev_map (fun f -> f b) ps
 438
 439 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 440
 441 (* object costruction *******************************************************)
 442
 443 let is_theorem pars =
 444    pars = [] ||
 445    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 446    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 447
 448 let proc_obj st = function
 449    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 450       let ast = proc_proof st v in
 451       let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 452       let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 453       if st.skip_thm_and_qed then ast
 454       else T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 455    | _                                                               ->
 456       failwith "not a theorem"
 457
 458 (* interface functions ******************************************************)
 459
 460 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 461 ?(skip_thm_and_qed=false) prefix aobj =
 462    let st = {
 463       sorts       = ids_to_inner_sorts;
 464       types       = ids_to_inner_types;
 465       prefix      = prefix;
 466       max_depth   = depth;
 467       depth       = 0;
 468       context     = [];
 469       intros      = [];
 470       clears      = [];
 471       clears_note = "";
 472       case        = [];
 473       skip_thm_and_qed = skip_thm_and_qed;
 474    } in
 475    HLog.debug "Procedural: level 2 transformation";
 476    let steps = proc_obj st aobj in
 477    HLog.debug "Procedural: grafite rendering";
 478    List.rev (T.render_steps [] steps)