helm/software/components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45 module H    = ProceduralHelpers
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    clears: string list;
  55    clears_note: string;
  56    case: int list;
  57    skip_thm_and_qed : bool;
  58 }
  59
  60 let debug = true
  61
  62 (* helpers ******************************************************************)
  63
  64 let split2_last l1 l2 =
  65 try
  66    let n = pred (List.length l1) in
  67    let before1, after1 = HEL.split_nth n l1 in
  68    let before2, after2 = HEL.split_nth n l2 in
  69    before1, before2, List.hd after1, List.hd after2
  70 with Invalid_argument _ -> failwith "A2P.split2_last"
  71
  72 let string_of_head = function
  73    | C.ASort _         -> "sort"
  74    | C.AConst _        -> "const"
  75    | C.AMutInd _       -> "mutind"
  76    | C.AMutConstruct _ -> "mutconstruct"
  77    | C.AVar _          -> "var"
  78    | C.ARel _          -> "rel"
  79    | C.AProd _         -> "prod"
  80    | C.ALambda _       -> "lambda"
  81    | C.ALetIn _        -> "letin"
  82    | C.AFix _          -> "fix"
  83    | C.ACoFix _        -> "cofix"
  84    | C.AAppl _         -> "appl"
  85    | C.ACast _         -> "cast"
  86    | C.AMutCase _      -> "mutcase"
  87    | C.AMeta _         -> "meta"
  88    | C.AImplicit _     -> "implict"
  89
  90 let next st = {st with depth = succ st.depth}
  91
  92 let add st entry = {st with context = entry :: st.context}
  93
  94 let push st = {st with case = 1 :: st.case}
  95
  96 let inc st =
  97    {st with case = match st.case with
  98       | []       -> assert false
  99       | hd :: tl -> succ hd :: tl
 100    }
 101
 102 let case st str =
 103    let case = String.concat "." (List.rev_map string_of_int st.case) in
 104    Printf.sprintf "case %s: %s" case str
 105
 106 let test_depth st =
 107 try
 108    let msg = Printf.sprintf "Depth %u: " st.depth in
 109    match st.max_depth with
 110       | None   -> true, ""
 111       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 112 with Invalid_argument _ -> failwith "A2P.test_depth"
 113
 114 let is_rewrite_right = function
 115    | C.AConst (_, uri, []) ->
 116       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 117    | _                     -> false
 118
 119 let is_rewrite_left = function
 120    | C.AConst (_, uri, []) ->
 121       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 122    | _                     -> false
 123
 124 let is_fwd_rewrite_right hd tl =
 125    if is_rewrite_right hd then match List.nth tl 3 with
 126       | C.ARel _ -> true
 127       | _        -> false
 128    else false
 129
 130 let is_fwd_rewrite_left hd tl =
 131    if is_rewrite_left hd then match List.nth tl 3 with
 132       | C.ARel _ -> true
 133       | _        -> false
 134    else false
 135
 136 let get_inner_types st v =
 137 try
 138    let id = Ut.id_of_annterm v in
 139    try match Hashtbl.find st.types id with
 140       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 141       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 142    with Not_found -> None
 143 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 144 (*
 145 let get_inner_sort st v =
 146 try
 147    let id = Ut.id_of_annterm v in
 148    try Hashtbl.find st.sorts id
 149    with Not_found -> `Type (CicUniv.fresh())
 150 with Invalid_argument _ -> failwith "A2P.get_sort"
 151 *)
 152 let get_type msg st bo =
 153 try
 154    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.oblivion_ugraph in
 155    ty
 156 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 157
 158 let get_entry st id =
 159    let rec aux = function
 160       | []                                        -> assert false
 161       | Some (C.Name name, e) :: _ when name = id -> e
 162       | _ :: tl                                   -> aux tl
 163    in
 164    aux st.context
 165
 166 let get_ind_names uri tno =
 167 try
 168    let ts = match E.get_obj Un.oblivion_ugraph uri with
 169       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 170       | _                                      -> assert false
 171    in
 172    match List.nth ts tno with
 173       | (_, _, _, cs) -> List.map fst cs
 174 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 175
 176 (* proof construction *******************************************************)
 177
 178 let used_premise = C.Name "USED"
 179
 180 let mk_exp_args hd tl classes synth =
 181    let meta id = C.AImplicit (id, None) in
 182    let map v (cl, b) =
 183       if I.overlaps synth cl && b then v else meta ""
 184    in
 185    let rec aux = function
 186       | [] -> []
 187       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 188    in
 189    let args = T.list_rev_map2 map tl classes in
 190    let args = aux args in
 191    if args = [] then hd else C.AAppl ("", hd :: args)
 192
 193 let mk_convert st ?name sty ety note =
 194    let e = Cn.hole "" in
 195    let csty, cety = H.cic sty, H.cic ety in
 196    let script =
 197       if debug then
 198          let sname = match name with None -> "" | Some (id, _) -> id in
 199          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 200             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 201          in
 202          [T.Note note]
 203       else []
 204    in
 205    assert (Ut.is_sober csty);
 206    assert (Ut.is_sober cety);
 207    if Ut.alpha_equivalence csty cety then script else
 208    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 209    match name with
 210       | None         -> T.Change (sty, ety, None, e, "") :: script
 211       | Some (id, i) ->
 212          begin match get_entry st id with
 213             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 214             | C.Decl _ ->
 215                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 216          end
 217
 218 let convert st ?name v =
 219    match get_inner_types st v with
 220       | None            ->
 221          if debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 222       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 223
 224 let convert_elim st ?name t v pattern =
 225    match t, get_inner_types st t, get_inner_types st v with
 226       | _, None, _
 227       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 228       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 229          let where = List.hd (List.rev tl) in
 230          let cty = Cn.elim_inferred_type
 231              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 232          in
 233          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 234       | _, Some _, Some _                                     -> assert false
 235
 236 let get_intro = function
 237    | C.Anonymous -> None
 238    | C.Name s    -> Some s
 239
 240 let mk_preamble st what script =
 241    let clears st script =
 242       if true (* st.clears = [] *) then script else T.Clear (st.clears, st.clears_note) :: script
 243    in
 244    clears st (convert st what @ script)
 245
 246 let mk_arg st = function
 247    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 248    | _                              -> []
 249
 250 let mk_fwd_rewrite st dtext name tl direction v t ity =
 251    let compare premise = function
 252       | None   -> true
 253       | Some s -> s = premise
 254    in
 255    assert (List.length tl = 6);
 256    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 257    let e = Cn.mk_pattern 1 predicate in
 258    if (Cn.does_not_occur e) then st, [] else
 259    match where with
 260       | C.ARel (_, _, i, premise) as w ->
 261 (*         let _script = convert_elim st ~name:(premise, i) v w e in *)
 262          let script name =
 263             let where = Some (premise, name) in
 264             let script = mk_arg st what @ mk_arg st w (* @ script *) in
 265             T.Rewrite (direction, what, where, e, dtext) :: script
 266          in
 267          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 268             {st with context = Cn.clear st.context premise}, script name
 269          else
 270             let br1 = [T.Id ""] in
 271             let br2 = List.rev (T.Apply (w, "assumption") :: script None) in
 272             let text = "non linear rewrite" in
 273             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 274       | _                         -> assert false
 275
 276 let mk_rewrite st dtext where qs tl direction t =
 277    assert (List.length tl = 5);
 278    let predicate = List.nth tl 2 in
 279    let e = Cn.mk_pattern 1 predicate in
 280    let script = [T.Branch (qs, "")] in
 281    if (Cn.does_not_occur e) then script else
 282 (*   let script = convert_elim st t t e in *)
 283    T.Rewrite (direction, where, None, e, dtext) :: script
 284
 285 let rec proc_lambda st what name v t =
 286    let dno = match get_inner_types st t with
 287       | None            -> false
 288       | Some (sty, ety) ->
 289          let sty, ety = H.cic sty, H.cic ety in
 290          DTI.does_not_occur 1 sty && DTI.does_not_occur 1 ety
 291    in
 292    let dno = dno && DTI.does_not_occur 1 (H.cic t) in
 293    let name = match dno, name with
 294       | true, _            -> C.Anonymous
 295       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 296       | false, name        -> name
 297    in
 298    let entry = Some (name, C.Decl (H.cic v)) in
 299    let intro = get_intro name in
 300    let script = proc_proof (add st entry) t in
 301    let script = T.Intros (Some 1, [intro], "") :: script in
 302    mk_preamble st what script
 303
 304 and proc_letin st what name v w t =
 305    let intro = get_intro name in
 306    let proceed, dtext = test_depth st in
 307    let script = if proceed then
 308       let st, hyp, rqv = match get_inner_types st v with
 309          | Some (ity, _) ->
 310             let st, rqv = match v with
 311                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 312                   mk_fwd_rewrite st dtext intro tl true v t ity
 313                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 314                   mk_fwd_rewrite st dtext intro tl false v t ity
 315                | v                                                     ->
 316                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 317                   let ity = H.acic_bc st.context ity in
 318                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 319             in
 320             st, C.Decl (H.cic ity), rqv
 321          | None          ->
 322             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 323       in
 324       let entry = Some (name, hyp) in
 325       let qt = proc_proof (next (add st entry)) t in
 326       List.rev_append rqv qt
 327    else
 328       [T.Apply (what, dtext)]
 329    in
 330    mk_preamble st what script
 331
 332 and proc_rel st what =
 333    let _, dtext = test_depth st in
 334    let text = "assumption" in
 335    let script = [T.Apply (what, dtext ^ text)] in
 336    mk_preamble st what script
 337
 338 and proc_mutconstruct st what =
 339    let _, dtext = test_depth st in
 340    let script = [T.Apply (what, dtext)] in
 341    mk_preamble st what script
 342
 343 and proc_const st what =
 344    let _, dtext = test_depth st in
 345    let script = [T.Apply (what, dtext)] in
 346    mk_preamble st what script
 347
 348 and proc_appl st what hd tl =
 349    let proceed, dtext = test_depth st in
 350    let script = if proceed then
 351       let ty = get_type "TC2" st hd in
 352       let classes, rc = Cl.classify st.context ty in
 353       let goal_arity, goal = match get_inner_types st what with
 354          | None            -> 0, None
 355          | Some (ity, ety) ->
 356            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 357       in
 358       let parsno, argsno = List.length classes, List.length tl in
 359       let decurry = parsno - argsno in
 360       let diff = goal_arity - decurry in
 361       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 362       let classes = Cl.adjust st.context tl ?goal classes in
 363       let rec mk_synth a n =
 364          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 365       in
 366       let synth = mk_synth I.S.empty decurry in
 367       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 368       let script = List.rev (mk_arg st hd) in
 369       match rc with
 370          | Some (i, j, uri, tyno) ->
 371             let classes2, tl2, _, where = split2_last classes tl in
 372             let script2 = List.rev (mk_arg st where) @ script in
 373             let synth2 = I.S.add 1 synth in
 374             let names = get_ind_names uri tyno in
 375             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 376             if List.length qs <> List.length names then
 377                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 378                let hd = mk_exp_args hd tl classes synth in
 379                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 380             else if is_rewrite_right hd then
 381                script2 @ mk_rewrite st dtext where qs tl2 false what
 382             else if is_rewrite_left hd then
 383                script2 @ mk_rewrite st dtext where qs tl2 true what
 384             else
 385                let predicate = List.nth tl2 (parsno - i) in
 386                let e = Cn.mk_pattern j predicate in
 387                let using = Some hd in
 388                (* convert_elim st what what e @ *) script2 @
 389                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 390          | None        ->
 391             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 392             let hd = mk_exp_args hd tl classes synth in
 393             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 394    else
 395       [T.Apply (what, dtext)]
 396    in
 397    mk_preamble st what script
 398
 399 and proc_other st what =
 400    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 401    let script = [T.Note text] in
 402    mk_preamble st what script
 403
 404 and proc_proof st t =
 405    let f st =
 406       let xtypes, note = match get_inner_types st t with
 407          | Some (it, et) -> Some (H.cic it, H.cic et),
 408           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 409           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 410          | None          -> None, "\nNo types"
 411       in
 412       let context, clears = Cn.get_clears st.context (H.cic t) xtypes in
 413       let note = Pp.ppcontext st.context ^ note in
 414       {st with context = context; clears = clears; clears_note = note; }
 415    in
 416    match t with
 417       | C.ALambda (_, name, w, t) as what   -> proc_lambda (f st) what name w t
 418       | C.ALetIn (_, name, v, w, t) as what -> proc_letin (f st) what name v w t
 419       | C.ARel _ as what                    -> proc_rel (f st) what
 420       | C.AMutConstruct _ as what           -> proc_mutconstruct (f st) what
 421       | C.AConst _ as what                  -> proc_const (f st) what
 422       | C.AAppl (_, hd :: tl) as what       -> proc_appl (f st) what hd tl
 423       | what                                -> proc_other (f st) what
 424
 425 and proc_bkd_proofs st synth names classes ts =
 426 try
 427    let get_note =
 428       let names = ref (names, push st) in
 429       fun f ->
 430          match !names with
 431             | [], st       -> fun _ -> f st
 432             | "" :: tl, st -> names := tl, st; fun _ -> f st
 433             | hd :: tl, st ->
 434                let note = case st hd in
 435                names := tl, inc st;
 436                fun b -> if b then T.Note note :: f st else f st
 437    in
 438    let _, dtext = test_depth st in
 439    let aux (inv, _) v =
 440       if I.overlaps synth inv then None else
 441       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 442       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 443    in
 444    let ps = T.list_map2_filter aux classes ts in
 445    let b = List.length ps > 1 in
 446    List.rev_map (fun f -> f b) ps
 447
 448 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 449
 450 (* object costruction *******************************************************)
 451
 452 let is_theorem pars =
 453    pars = [] ||
 454    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 455    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 456
 457 let proc_obj st = function
 458    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 459       let ast = proc_proof st v in
 460       let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 461       let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 462       if st.skip_thm_and_qed then ast
 463       else T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 464    | _                                                               ->
 465       failwith "not a theorem"
 466
 467 (* interface functions ******************************************************)
 468
 469 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 470 ?(skip_thm_and_qed=false) prefix aobj =
 471    let st = {
 472       sorts       = ids_to_inner_sorts;
 473       types       = ids_to_inner_types;
 474       prefix      = prefix;
 475       max_depth   = depth;
 476       depth       = 0;
 477       context     = [];
 478       clears      = [];
 479       clears_note = "";
 480       case        = [];
 481       skip_thm_and_qed = skip_thm_and_qed;
 482    } in
 483    HLog.debug "Procedural: level 2 transformation";
 484    let steps = proc_obj st aobj in
 485    HLog.debug "Procedural: grafite rendering";
 486    List.rev (T.render_steps [] steps)