helm/software/components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41 module NU   = CicNotationUtil
  42 module L    = Librarian
  43
  44 module Cl   = ProceduralClassify
  45 module T    = ProceduralTypes
  46 module Cn   = ProceduralConversion
  47 module H    = ProceduralHelpers
  48
  49 type status = {
  50    sorts : (C.id, A.sort_kind) Hashtbl.t;
  51    types : (C.id, A.anntypes) Hashtbl.t;
  52    max_depth: int option;
  53    depth: int;
  54    context: C.context;
  55    case: int list
  56 }
  57
  58 let debug = ref false
  59
  60 (* helpers ******************************************************************)
  61
  62 let split2_last l1 l2 =
  63 try
  64    let n = pred (List.length l1) in
  65    let before1, after1 = HEL.split_nth n l1 in
  66    let before2, after2 = HEL.split_nth n l2 in
  67    before1, before2, List.hd after1, List.hd after2
  68 with Invalid_argument _ -> failwith "A2P.split2_last"
  69
  70 let string_of_head = function
  71    | C.ASort _         -> "sort"
  72    | C.AConst _        -> "const"
  73    | C.AMutInd _       -> "mutind"
  74    | C.AMutConstruct _ -> "mutconstruct"
  75    | C.AVar _          -> "var"
  76    | C.ARel _          -> "rel"
  77    | C.AProd _         -> "prod"
  78    | C.ALambda _       -> "lambda"
  79    | C.ALetIn _        -> "letin"
  80    | C.AFix _          -> "fix"
  81    | C.ACoFix _        -> "cofix"
  82    | C.AAppl _         -> "appl"
  83    | C.ACast _         -> "cast"
  84    | C.AMutCase _      -> "mutcase"
  85    | C.AMeta _         -> "meta"
  86    | C.AImplicit _     -> "implict"
  87
  88 let next st = {st with depth = succ st.depth}
  89
  90 let add st entry = {st with context = entry :: st.context}
  91
  92 let push st = {st with case = 1 :: st.case}
  93
  94 let inc st =
  95    {st with case = match st.case with
  96       | []       -> []
  97       | hd :: tl -> succ hd :: tl
  98    }
  99
 100 let case st str =
 101    let case = String.concat "." (List.rev_map string_of_int st.case) in
 102    Printf.sprintf "case %s: %s" case str
 103
 104 let test_depth st =
 105 try
 106    let msg = Printf.sprintf "Depth %u: " st.depth in
 107    match st.max_depth with
 108       | None   -> true, ""
 109       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 110 with Invalid_argument _ -> failwith "A2P.test_depth"
 111
 112 let is_rewrite_right = function
 113    | C.AConst (_, uri, []) ->
 114       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 115    | _                     -> false
 116
 117 let is_rewrite_left = function
 118    | C.AConst (_, uri, []) ->
 119       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 120    | _                     -> false
 121
 122 let is_fwd_rewrite_right hd tl =
 123    if is_rewrite_right hd then match List.nth tl 3 with
 124       | C.ARel _ -> true
 125       | _        -> false
 126    else false
 127
 128 let is_fwd_rewrite_left hd tl =
 129    if is_rewrite_left hd then match List.nth tl 3 with
 130       | C.ARel _ -> true
 131       | _        -> false
 132    else false
 133
 134 let get_inner_types st v =
 135 try
 136    let id = Ut.id_of_annterm v in
 137    try match Hashtbl.find st.types id with
 138       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 139       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 140    with Not_found -> None
 141 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 142 (*
 143 let get_inner_sort st v =
 144 try
 145    let id = Ut.id_of_annterm v in
 146    try Hashtbl.find st.sorts id
 147    with Not_found -> `Type (CicUniv.fresh())
 148 with Invalid_argument _ -> failwith "A2P.get_sort"
 149 *)
 150 let get_entry st id =
 151    let rec aux = function
 152       | []                                        -> assert false
 153       | Some (C.Name name, e) :: _ when name = id -> e
 154       | _ :: tl                                   -> aux tl
 155    in
 156    aux st.context
 157
 158 let string_of_atomic = function
 159    | C.ARel (_, _, _, s)               -> s
 160    | C.AVar (_, uri, _)                -> H.name_of_uri uri None None
 161    | C.AConst (_, uri, _)              -> H.name_of_uri uri None None
 162    | C.AMutInd (_, uri, i, _)          -> H.name_of_uri uri (Some i) None
 163    | C.AMutConstruct (_, uri, i, j, _) -> H.name_of_uri uri (Some i) (Some j)
 164    | _                                 -> ""
 165
 166 let get_sub_names head l =
 167    let s = string_of_atomic head in
 168    if s = "" then [] else
 169    let map (names, i) _ =
 170       let name = Printf.sprintf "%s_%u" s i in name :: names, succ i
 171    in
 172    let names, _ = List.fold_left map ([], 1) l in
 173    List.rev names
 174
 175 let get_type msg st t = H.get_type msg st.context (H.cic t)
 176
 177 let clear_absts m =
 178    let rec aux k n = function
 179       | C.ALambda (id, s, v, t) when k > 0 ->
 180          C.ALambda (id, s, v, aux (pred k) n t)
 181       | C.ALambda (_, _, _, t) when n > 0 ->
 182          aux 0 (pred n) (Cn.lift 1 (-1) t)
 183       | t                  when n > 0 ->
 184          Printf.eprintf "A2P.clear_absts: %u %s\n" n (Pp.ppterm (H.cic t));
 185          assert false
 186       | t                             -> t
 187    in
 188    aux m
 189
 190 (* proof construction *******************************************************)
 191
 192 let anonymous_premise = C.Name "UNNAMED"
 193
 194 let mk_exp_args hd tl classes synth =
 195    let meta id = C.AImplicit (id, None) in
 196    let map v (cl, b) =
 197       if I.overlaps synth cl && b then v else meta ""
 198    in
 199    let rec aux = function
 200       | [] -> []
 201       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 202    in
 203    let args = T.list_rev_map2 map tl classes in
 204    let args = aux args in
 205    if args = [] then hd else C.AAppl ("", hd :: args)
 206
 207 let mk_convert st ?name sty ety note =
 208    let e = Cn.hole "" in
 209    let csty, cety = H.cic sty, H.cic ety in
 210    let script =
 211       if !debug then
 212          let sname = match name with None -> "" | Some (id, _) -> id in
 213          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 214             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 215          in
 216          [T.Note note]
 217       else []
 218    in
 219    assert (Ut.is_sober st.context csty);
 220    assert (Ut.is_sober st.context cety);
 221    if Ut.alpha_equivalence csty cety then script else
 222    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 223    match name with
 224       | None         -> T.Change (sty, ety, None, e, "") :: script
 225       | Some (id, i) ->
 226          begin match get_entry st id with
 227             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 228             | C.Decl _ ->
 229                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 230          end
 231
 232 let convert st ?name v =
 233    match get_inner_types st v with
 234       | None            ->
 235          if !debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 236       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 237
 238 let get_intro = function
 239    | C.Anonymous -> None
 240    | C.Name s    -> Some s
 241
 242 let mk_preamble st what script =
 243    convert st what @ script
 244
 245 let mk_arg st = function
 246    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 247    | _                              -> []
 248
 249 let mk_fwd_rewrite st dtext name tl direction v t ity =
 250    let compare premise = function
 251       | None   -> true
 252       | Some s -> s = premise
 253    in
 254    assert (List.length tl = 6);
 255    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 256    let e = Cn.mk_pattern 1 predicate in
 257    if (Cn.does_not_occur e) then st, [] else
 258    match where with
 259       | C.ARel (_, _, i, premise) as w ->
 260          let script name =
 261             let where = Some (premise, name) in
 262             let script = mk_arg st what @ mk_arg st w in
 263             T.Rewrite (direction, what, where, e, dtext) :: script
 264          in
 265          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 266             {st with context = Cn.clear st.context premise}, script name
 267          else begin
 268             assert (Ut.is_sober st.context (H.cic ity));
 269             let ity = H.acic_bc st.context ity in
 270             let br1 = [T.Id ""] in
 271             let br2 = List.rev (T.Apply (w, "assumption") :: script None) in
 272             let text = "non-linear rewrite" in
 273             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 274          end
 275       | _                         -> assert false
 276
 277 let mk_rewrite st dtext where qs tl direction t =
 278    assert (List.length tl = 5);
 279    let predicate = List.nth tl 2 in
 280    let e = Cn.mk_pattern 1 predicate in
 281    let script = [T.Branch (qs, "")] in
 282    if (Cn.does_not_occur e) then script else
 283    T.Rewrite (direction, where, None, e, dtext) :: script
 284
 285 let rec proc_lambda st what name v t =
 286    let name = match name with
 287       | C.Anonymous -> H.mk_fresh_name st.context anonymous_premise
 288       | name        -> name
 289    in
 290    let entry = Some (name, C.Decl (H.cic v)) in
 291    let intro = get_intro name in
 292    let script = proc_proof (add st entry) t in
 293    let script = T.Intros (Some 1, [intro], "") :: script in
 294    mk_preamble st what script
 295
 296 and proc_letin st what name v w t =
 297    let intro = get_intro name in
 298    let proceed, dtext = test_depth st in
 299    let script = if proceed then
 300       let st, hyp, rqv = match get_inner_types st v with
 301          | Some (ity, _) ->
 302             let st, rqv = match v with
 303                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 304                   mk_fwd_rewrite st dtext intro tl true v t ity
 305                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 306                   mk_fwd_rewrite st dtext intro tl false v t ity
 307                | v                                                     ->
 308                   assert (Ut.is_sober st.context (H.cic ity));
 309                   let ity = H.acic_bc st.context ity in
 310                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 311                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 312             in
 313             st, C.Decl (H.cic ity), rqv
 314          | None          ->
 315             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 316       in
 317       let entry = Some (name, hyp) in
 318       let qt = proc_proof (next (add st entry)) t in
 319       List.rev_append rqv qt
 320    else
 321       [T.Apply (what, dtext)]
 322    in
 323    mk_preamble st what script
 324
 325 and proc_rel st what =
 326    let _, dtext = test_depth st in
 327    let text = "assumption" in
 328    let script = [T.Apply (what, dtext ^ text)] in
 329    mk_preamble st what script
 330
 331 and proc_mutconstruct st what =
 332    let _, dtext = test_depth st in
 333    let script = [T.Apply (what, dtext)] in
 334    mk_preamble st what script
 335
 336 and proc_const st what =
 337    let _, dtext = test_depth st in
 338    let script = [T.Apply (what, dtext)] in
 339    mk_preamble st what script
 340
 341 and proc_appl st what hd tl =
 342    let proceed, dtext = test_depth st in
 343    let script = if proceed then
 344       let ty = match get_inner_types st hd with
 345          | Some (ity, _) -> H.cic ity
 346          | None          -> get_type "TC2" st hd
 347       in
 348       let classes, rc = Cl.classify st.context ty in
 349       let goal_arity, goal = match get_inner_types st what with
 350          | None            -> 0, None
 351          | Some (ity, ety) ->
 352            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 353       in
 354       let parsno, argsno = List.length classes, List.length tl in
 355       let decurry = parsno - argsno in
 356       let diff = goal_arity - decurry in
 357       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 358       let classes = Cl.adjust st.context tl ?goal classes in
 359       let rec mk_synth a n =
 360          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 361       in
 362       let synth = mk_synth I.S.empty decurry in
 363       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 364       let script = List.rev (mk_arg st hd) in
 365       match rc with
 366          | Some (i, j, uri, tyno) ->
 367             let classes2, tl2, _, where = split2_last classes tl in
 368             let script2 = List.rev (mk_arg st where) @ script in
 369             let synth2 = I.S.add 1 synth in
 370             let names = H.get_ind_names uri tyno in
 371             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 372             if List.length qs <> List.length names then
 373                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 374                let hd = mk_exp_args hd tl classes synth in
 375                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 376             else if is_rewrite_right hd then
 377                script2 @ mk_rewrite st dtext where qs tl2 false what
 378             else if is_rewrite_left hd then
 379                script2 @ mk_rewrite st dtext where qs tl2 true what
 380             else
 381                let predicate = List.nth tl2 (parsno - i) in
 382                let e = Cn.mk_pattern j predicate in
 383                let using = Some hd in
 384                script2 @
 385                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 386          | None        ->
 387             let names = get_sub_names hd tl in
 388             let qs = proc_bkd_proofs (next st) synth names classes tl in
 389             let hd = mk_exp_args hd tl classes synth in
 390             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 391    else
 392       [T.Apply (what, dtext)]
 393    in
 394    mk_preamble st what script
 395
 396 and proc_case st what uri tyno u v ts =
 397    let proceed, dtext = test_depth st in
 398    let script = if proceed then
 399       let synth, classes = I.S.empty, Cl.make ts in
 400       let names = H.get_ind_names uri tyno in
 401       let qs = proc_bkd_proofs (next st) synth names classes ts in
 402       let lpsno, _ = H.get_ind_type uri tyno in
 403       let ps, sort_disp = H.get_ind_parameters st.context (H.cic v) in
 404       let _, rps = HEL.split_nth lpsno ps in
 405       let rpsno = List.length rps in
 406       let predicate = clear_absts rpsno (1 - sort_disp) u in
 407       let e = Cn.mk_pattern rpsno predicate in
 408       let text = "" in
 409       let script = List.rev (mk_arg st v) in
 410       script @ [T.Cases (v, e, dtext ^ text); T.Branch (qs, "")]
 411    else
 412       [T.Apply (what, dtext)]
 413    in
 414    mk_preamble st what script
 415
 416 and proc_other st what =
 417    let _, dtext = test_depth st in
 418    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 419    let script = [T.Apply (what, dtext ^ text)] in
 420    mk_preamble st what script
 421
 422 and proc_proof st t =
 423    let f st =
 424       let xtypes, note = match get_inner_types st t with
 425          | Some (it, et) -> Some (H.cic it, H.cic et),
 426           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 427           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 428          | None          -> None, "\nNo types"
 429       in
 430       let context, _clears = Cn.get_clears st.context (H.cic t) xtypes in
 431       {st with context = context}
 432    in
 433    match t with
 434       | C.ALambda (_, name, w, t) as what        -> proc_lambda (f st) what name w t
 435       | C.ALetIn (_, name, v, w, t) as what      -> proc_letin (f st) what name v w t
 436       | C.ARel _ as what                         -> proc_rel (f st) what
 437       | C.AMutConstruct _ as what                -> proc_mutconstruct (f st) what
 438       | C.AConst _ as what                       -> proc_const (f st) what
 439       | C.AAppl (_, hd :: tl) as what            -> proc_appl (f st) what hd tl
 440       | C.AMutCase (_, uri, i, u, v, ts) as what -> proc_case (f st) what uri i u v ts
 441       | what                                     -> proc_other (f st) what
 442
 443 and proc_bkd_proofs st synth names classes ts =
 444 try
 445    let get_names b = ref (names, if b then push st else st) in
 446    let get_note f b names =
 447       match !names with
 448          | [], st       -> f st
 449          | "" :: tl, st -> names := tl, st; f st
 450          | hd :: tl, st ->
 451             let note = case st hd in
 452             names := tl, inc st;
 453             if b then T.Note note :: f st else f st
 454    in
 455    let _, dtext = test_depth st in
 456    let aux (inv, _) v =
 457       if I.overlaps synth inv then None else
 458       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 459       Some (get_note (fun _ -> [T.Apply (v, dtext ^ "dependent")]))
 460    in
 461    let ps = T.list_map2_filter aux classes ts in
 462    let b = List.length ps > 1 in
 463    let names = get_names b in
 464    List.rev_map (fun f -> f b names) ps
 465
 466 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 467
 468 (* object costruction *******************************************************)
 469
 470 let th_flavours = [`Theorem; `Lemma; `Remark; `Fact]
 471
 472 let def_flavours = [`Definition]
 473
 474 let get_flavour ?flavour attrs =
 475    let rec aux = function
 476       | []               -> List.hd th_flavours
 477       | `Flavour fl :: _ -> fl
 478       | _ :: tl          -> aux tl
 479    in
 480    match flavour with
 481       | Some fl -> fl
 482       | None    -> aux attrs
 483
 484 let proc_obj ?flavour ?(info="") st = function
 485    | C.AConstant (_, _, s, Some v, t, [], attrs)         ->
 486       begin match get_flavour ?flavour attrs with
 487          | flavour when List.mem flavour th_flavours  ->
 488             let ast = proc_proof st v in
 489             let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 490             let text = Printf.sprintf "%s\n%s%s: %u\n%s: %u\n%s"
 491                "COMMENTS" info "Tactics" steps "Final nodes" nodes "END"
 492             in
 493             T.Statement (flavour, Some s, t, None, "") :: ast @ [T.Qed text]
 494          | flavour when List.mem flavour def_flavours ->
 495             [T.Statement (flavour, Some s, t, Some v, "")]
 496          | _                                  ->
 497             failwith "not a theorem, definition, axiom or inductive type"
 498       end
 499    | C.AConstant (_, _, s, None, t, [], attrs)           ->
 500       [T.Statement (`Axiom, Some s, t, None, "")]
 501    | C.AInductiveDefinition (_, types, [], lpsno, attrs) ->
 502       [T.Inductive (types, lpsno, "")]
 503    | _                                          ->
 504       failwith "not a theorem, definition, axiom or inductive type"
 505
 506 (* interface functions ******************************************************)
 507
 508 let procedural_of_acic_object ~ids_to_inner_sorts ~ids_to_inner_types
 509    ?info ?depth ?flavour prefix anobj =
 510    let st = {
 511       sorts       = ids_to_inner_sorts;
 512       types       = ids_to_inner_types;
 513       max_depth   = depth;
 514       depth       = 0;
 515       context     = [];
 516       case        = []
 517    } in
 518    L.time_stamp "P : LEVEL 2  ";
 519    HLog.debug "Procedural: level 2 transformation";
 520    let steps = proc_obj st ?flavour ?info anobj in
 521    L.time_stamp "P : RENDERING";
 522    HLog.debug "Procedural: grafite rendering";
 523    let r = List.rev (T.render_steps [] steps) in
 524    L.time_stamp "P : DONE     "; r
 525
 526 let procedural_of_acic_term ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 527    prefix context annterm =
 528    let st = {
 529       sorts       = ids_to_inner_sorts;
 530       types       = ids_to_inner_types;
 531       max_depth   = depth;
 532       depth       = 0;
 533       context     = context;
 534       case        = []
 535    } in
 536    HLog.debug "Procedural: level 2 transformation";
 537    let steps = proc_proof st annterm in
 538    HLog.debug "Procedural: grafite rendering";
 539    List.rev (T.render_steps [] steps)