helm/software/components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41 module NU   = CicNotationUtil
  42
  43 module Cl   = ProceduralClassify
  44 module T    = ProceduralTypes
  45 module Cn   = ProceduralConversion
  46 module H    = ProceduralHelpers
  47
  48 type status = {
  49    sorts : (C.id, A.sort_kind) Hashtbl.t;
  50    types : (C.id, A.anntypes) Hashtbl.t;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    case: int list
  55 }
  56
  57 let debug = false
  58
  59 (* helpers ******************************************************************)
  60
  61 let split2_last l1 l2 =
  62 try
  63    let n = pred (List.length l1) in
  64    let before1, after1 = HEL.split_nth n l1 in
  65    let before2, after2 = HEL.split_nth n l2 in
  66    before1, before2, List.hd after1, List.hd after2
  67 with Invalid_argument _ -> failwith "A2P.split2_last"
  68
  69 let string_of_head = function
  70    | C.ASort _         -> "sort"
  71    | C.AConst _        -> "const"
  72    | C.AMutInd _       -> "mutind"
  73    | C.AMutConstruct _ -> "mutconstruct"
  74    | C.AVar _          -> "var"
  75    | C.ARel _          -> "rel"
  76    | C.AProd _         -> "prod"
  77    | C.ALambda _       -> "lambda"
  78    | C.ALetIn _        -> "letin"
  79    | C.AFix _          -> "fix"
  80    | C.ACoFix _        -> "cofix"
  81    | C.AAppl _         -> "appl"
  82    | C.ACast _         -> "cast"
  83    | C.AMutCase _      -> "mutcase"
  84    | C.AMeta _         -> "meta"
  85    | C.AImplicit _     -> "implict"
  86
  87 let next st = {st with depth = succ st.depth}
  88
  89 let add st entry = {st with context = entry :: st.context}
  90
  91 let push st = {st with case = 1 :: st.case}
  92
  93 let inc st =
  94    {st with case = match st.case with
  95       | []       -> []
  96       | hd :: tl -> succ hd :: tl
  97    }
  98
  99 let case st str =
 100    let case = String.concat "." (List.rev_map string_of_int st.case) in
 101    Printf.sprintf "case %s: %s" case str
 102
 103 let test_depth st =
 104 try
 105    let msg = Printf.sprintf "Depth %u: " st.depth in
 106    match st.max_depth with
 107       | None   -> true, ""
 108       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 109 with Invalid_argument _ -> failwith "A2P.test_depth"
 110
 111 let is_rewrite_right = function
 112    | C.AConst (_, uri, []) ->
 113       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 114    | _                     -> false
 115
 116 let is_rewrite_left = function
 117    | C.AConst (_, uri, []) ->
 118       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 119    | _                     -> false
 120
 121 let is_fwd_rewrite_right hd tl =
 122    if is_rewrite_right hd then match List.nth tl 3 with
 123       | C.ARel _ -> true
 124       | _        -> false
 125    else false
 126
 127 let is_fwd_rewrite_left hd tl =
 128    if is_rewrite_left hd then match List.nth tl 3 with
 129       | C.ARel _ -> true
 130       | _        -> false
 131    else false
 132
 133 let get_inner_types st v =
 134 try
 135    let id = Ut.id_of_annterm v in
 136    try match Hashtbl.find st.types id with
 137       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 138       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 139    with Not_found -> None
 140 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 141 (*
 142 let get_inner_sort st v =
 143 try
 144    let id = Ut.id_of_annterm v in
 145    try Hashtbl.find st.sorts id
 146    with Not_found -> `Type (CicUniv.fresh())
 147 with Invalid_argument _ -> failwith "A2P.get_sort"
 148 *)
 149 let get_entry st id =
 150    let rec aux = function
 151       | []                                        -> assert false
 152       | Some (C.Name name, e) :: _ when name = id -> e
 153       | _ :: tl                                   -> aux tl
 154    in
 155    aux st.context
 156
 157 let string_of_atomic = function
 158    | C.ARel (_, _, _, s)               -> s
 159    | C.AVar (_, uri, _)                -> H.name_of_uri uri None None
 160    | C.AConst (_, uri, _)              -> H.name_of_uri uri None None
 161    | C.AMutInd (_, uri, i, _)          -> H.name_of_uri uri (Some i) None
 162    | C.AMutConstruct (_, uri, i, j, _) -> H.name_of_uri uri (Some i) (Some j)
 163    | _                                 -> ""
 164
 165 let get_sub_names head l =
 166    let s = string_of_atomic head in
 167    if s = "" then [] else
 168    let map (names, i) _ =
 169       let name = Printf.sprintf "%s_%u" s i in name :: names, succ i
 170    in
 171    let names, _ = List.fold_left map ([], 1) l in
 172    List.rev names
 173
 174 let get_type msg st t = H.get_type msg st.context (H.cic t)
 175
 176 (* proof construction *******************************************************)
 177
 178 let anonymous_premise = C.Name "PREMISE"
 179
 180 let mk_exp_args hd tl classes synth =
 181    let meta id = C.AImplicit (id, None) in
 182    let map v (cl, b) =
 183       if I.overlaps synth cl && b then v else meta ""
 184    in
 185    let rec aux = function
 186       | [] -> []
 187       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 188    in
 189    let args = T.list_rev_map2 map tl classes in
 190    let args = aux args in
 191    if args = [] then hd else C.AAppl ("", hd :: args)
 192
 193 let mk_convert st ?name sty ety note =
 194    let e = Cn.hole "" in
 195    let csty, cety = H.cic sty, H.cic ety in
 196    let script =
 197       if debug then
 198          let sname = match name with None -> "" | Some (id, _) -> id in
 199          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 200             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 201          in
 202          [T.Note note]
 203       else []
 204    in
 205    assert (Ut.is_sober st.context csty);
 206    assert (Ut.is_sober st.context cety);
 207    if Ut.alpha_equivalence csty cety then script else
 208    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 209    match name with
 210       | None         -> T.Change (sty, ety, None, e, "") :: script
 211       | Some (id, i) ->
 212          begin match get_entry st id with
 213             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 214             | C.Decl _ ->
 215                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 216          end
 217
 218 let convert st ?name v =
 219    match get_inner_types st v with
 220       | None            ->
 221          if debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 222       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 223
 224 let convert_elim st ?name t v pattern =
 225    match t, get_inner_types st t, get_inner_types st v with
 226       | _, None, _
 227       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 228       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 229          let where = List.hd (List.rev tl) in
 230          let cty = Cn.elim_inferred_type
 231              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 232          in
 233          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 234       | _, Some _, Some _                                     -> assert false
 235
 236 let get_intro = function
 237    | C.Anonymous -> None
 238    | C.Name s    -> Some s
 239
 240 let mk_preamble st what script =
 241    convert st what @ script
 242
 243 let mk_arg st = function
 244    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 245    | _                              -> []
 246
 247 let mk_fwd_rewrite st dtext name tl direction v t ity =
 248    let compare premise = function
 249       | None   -> true
 250       | Some s -> s = premise
 251    in
 252    assert (List.length tl = 6);
 253    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 254    let e = Cn.mk_pattern 1 predicate in
 255    if (Cn.does_not_occur e) then st, [] else
 256    match where with
 257       | C.ARel (_, _, i, premise) as w ->
 258 (*         let _script = convert_elim st ~name:(premise, i) v w e in *)
 259          let script name =
 260             let where = Some (premise, name) in
 261             let script = mk_arg st what @ mk_arg st w (* @ script *) in
 262             T.Rewrite (direction, what, where, e, dtext) :: script
 263          in
 264          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 265             {st with context = Cn.clear st.context premise}, script name
 266          else begin
 267             assert (Ut.is_sober st.context (H.cic ity));
 268             let ity = H.acic_bc st.context ity in
 269             let br1 = [T.Id ""] in
 270             let br2 = List.rev (T.Apply (w, "assumption") :: script None) in
 271             let text = "non linear rewrite" in
 272             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 273          end
 274       | _                         -> assert false
 275
 276 let mk_rewrite st dtext where qs tl direction t =
 277    assert (List.length tl = 5);
 278    let predicate = List.nth tl 2 in
 279    let e = Cn.mk_pattern 1 predicate in
 280    let script = [T.Branch (qs, "")] in
 281    if (Cn.does_not_occur e) then script else
 282 (*   let script = convert_elim st t t e in *)
 283    T.Rewrite (direction, where, None, e, dtext) :: script
 284
 285 let rec proc_lambda st what name v t =
 286    let name = match name with
 287       | C.Anonymous -> H.mk_fresh_name st.context anonymous_premise
 288       | name        -> name
 289    in
 290    let entry = Some (name, C.Decl (H.cic v)) in
 291    let intro = get_intro name in
 292    let script = proc_proof (add st entry) t in
 293    let script = T.Intros (Some 1, [intro], "") :: script in
 294    mk_preamble st what script
 295
 296 and proc_letin st what name v w t =
 297    let intro = get_intro name in
 298    let proceed, dtext = test_depth st in
 299    let script = if proceed then
 300       let st, hyp, rqv = match get_inner_types st v with
 301          | Some (ity, _) ->
 302             let st, rqv = match v with
 303                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 304                   mk_fwd_rewrite st dtext intro tl true v t ity
 305                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 306                   mk_fwd_rewrite st dtext intro tl false v t ity
 307                | v                                                     ->
 308                   assert (Ut.is_sober st.context (H.cic ity));
 309                   let ity = H.acic_bc st.context ity in
 310                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 311                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 312             in
 313             st, C.Decl (H.cic ity), rqv
 314          | None          ->
 315             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 316       in
 317       let entry = Some (name, hyp) in
 318       let qt = proc_proof (next (add st entry)) t in
 319       List.rev_append rqv qt
 320    else
 321       [T.Apply (what, dtext)]
 322    in
 323    mk_preamble st what script
 324
 325 and proc_rel st what =
 326    let _, dtext = test_depth st in
 327    let text = "assumption" in
 328    let script = [T.Apply (what, dtext ^ text)] in
 329    mk_preamble st what script
 330
 331 and proc_mutconstruct st what =
 332    let _, dtext = test_depth st in
 333    let script = [T.Apply (what, dtext)] in
 334    mk_preamble st what script
 335
 336 and proc_const st what =
 337    let _, dtext = test_depth st in
 338    let script = [T.Apply (what, dtext)] in
 339    mk_preamble st what script
 340
 341 and proc_appl st what hd tl =
 342    let proceed, dtext = test_depth st in
 343    let script = if proceed then
 344       let ty = get_type "TC2" st hd in
 345       let classes, rc = Cl.classify st.context ty in
 346       let goal_arity, goal = match get_inner_types st what with
 347          | None            -> 0, None
 348          | Some (ity, ety) ->
 349            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 350       in
 351       let parsno, argsno = List.length classes, List.length tl in
 352       let decurry = parsno - argsno in
 353       let diff = goal_arity - decurry in
 354       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 355       let classes = Cl.adjust st.context tl ?goal classes in
 356       let rec mk_synth a n =
 357          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 358       in
 359       let synth = mk_synth I.S.empty decurry in
 360       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 361       let script = List.rev (mk_arg st hd) in
 362       match rc with
 363          | Some (i, j, uri, tyno) ->
 364             let classes2, tl2, _, where = split2_last classes tl in
 365             let script2 = List.rev (mk_arg st where) @ script in
 366             let synth2 = I.S.add 1 synth in
 367             let names = H.get_ind_names uri tyno in
 368             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 369             if List.length qs <> List.length names then
 370                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 371                let hd = mk_exp_args hd tl classes synth in
 372                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 373             else if is_rewrite_right hd then
 374                script2 @ mk_rewrite st dtext where qs tl2 false what
 375             else if is_rewrite_left hd then
 376                script2 @ mk_rewrite st dtext where qs tl2 true what
 377             else
 378                let predicate = List.nth tl2 (parsno - i) in
 379                let e = Cn.mk_pattern j predicate in
 380                let using = Some hd in
 381                (* convert_elim st what what e @ *) script2 @
 382                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 383          | None        ->
 384             let names = get_sub_names hd tl in
 385             let qs = proc_bkd_proofs (next st) synth names classes tl in
 386             let hd = mk_exp_args hd tl classes synth in
 387             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 388    else
 389       [T.Apply (what, dtext)]
 390    in
 391    mk_preamble st what script
 392
 393 and proc_other st what =
 394    let _, dtext = test_depth st in
 395    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 396    let script = [T.Apply (what, dtext ^ text)] in
 397    mk_preamble st what script
 398
 399 and proc_proof st t =
 400    let f st =
 401       let xtypes, note = match get_inner_types st t with
 402          | Some (it, et) -> Some (H.cic it, H.cic et),
 403           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 404           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 405          | None          -> None, "\nNo types"
 406       in
 407       let context, _clears = Cn.get_clears st.context (H.cic t) xtypes in
 408       {st with context = context}
 409    in
 410    match t with
 411       | C.ALambda (_, name, w, t) as what   -> proc_lambda (f st) what name w t
 412       | C.ALetIn (_, name, v, w, t) as what -> proc_letin (f st) what name v w t
 413       | C.ARel _ as what                    -> proc_rel (f st) what
 414       | C.AMutConstruct _ as what           -> proc_mutconstruct (f st) what
 415       | C.AConst _ as what                  -> proc_const (f st) what
 416       | C.AAppl (_, hd :: tl) as what       -> proc_appl (f st) what hd tl
 417       | what                                -> proc_other (f st) what
 418
 419 and proc_bkd_proofs st synth names classes ts =
 420 try
 421    let get_names b = ref (names, if b then push st else st) in
 422    let get_note f b names =
 423       match !names with
 424          | [], st       -> f st
 425          | "" :: tl, st -> names := tl, st; f st
 426          | hd :: tl, st ->
 427             let note = case st hd in
 428             names := tl, inc st;
 429             if b then T.Note note :: f st else f st
 430    in
 431    let _, dtext = test_depth st in
 432    let aux (inv, _) v =
 433       if I.overlaps synth inv then None else
 434       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 435       Some (get_note (fun _ -> [T.Apply (v, dtext ^ "dependent")]))
 436    in
 437    let ps = T.list_map2_filter aux classes ts in
 438    let b = List.length ps > 1 in
 439    let names = get_names b in
 440    List.rev_map (fun f -> f b names) ps
 441
 442 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 443
 444 (* object costruction *******************************************************)
 445
 446 let th_flavours = [`Theorem; `Lemma; `Remark; `Fact]
 447
 448 let def_flavours = [`Definition]
 449
 450 let get_flavour ?flavour attrs =
 451    let rec aux = function
 452       | []               -> List.hd th_flavours
 453       | `Flavour fl :: _ -> fl
 454       | _ :: tl          -> aux tl
 455    in
 456    match flavour with
 457       | Some fl -> fl
 458       | None    -> aux attrs
 459
 460 let proc_obj ?flavour st = function
 461    | C.AConstant (_, _, s, Some v, t, [], attrs)         ->
 462       begin match get_flavour ?flavour attrs with
 463          | flavour when List.mem flavour th_flavours  ->
 464             let ast = proc_proof st v in
 465             let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 466             let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 467             T.Statement (flavour, Some s, t, None, "") :: ast @ [T.Qed text]
 468          | flavour when List.mem flavour def_flavours ->
 469             [T.Statement (flavour, Some s, t, Some v, "")]
 470          | _                                  ->
 471             failwith "not a theorem, definition, axiom or inductive type"
 472       end
 473    | C.AConstant (_, _, s, None, t, [], attrs)           ->
 474       [T.Statement (`Axiom, Some s, t, None, "")]
 475    | C.AInductiveDefinition (_, types, [], lpsno, attrs) ->
 476       [T.Inductive (types, lpsno, "")]
 477    | _                                          ->
 478       failwith "not a theorem, definition, axiom or inductive type"
 479
 480 (* interface functions ******************************************************)
 481
 482 let procedural_of_acic_object ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 483    ?flavour prefix anobj =
 484    let st = {
 485       sorts       = ids_to_inner_sorts;
 486       types       = ids_to_inner_types;
 487       max_depth   = depth;
 488       depth       = 0;
 489       context     = [];
 490       case        = []
 491    } in
 492    H.print_times "LEVEL 2";
 493    HLog.debug "Procedural: level 2 transformation";
 494    let steps = proc_obj st ?flavour anobj in
 495    H.print_times "RENDERING";
 496    HLog.debug "Procedural: grafite rendering";
 497    let r = List.rev (T.render_steps [] steps) in
 498    H.print_times "DONE     "; r
 499
 500 let procedural_of_acic_term ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 501    prefix context annterm =
 502    let st = {
 503       sorts       = ids_to_inner_sorts;
 504       types       = ids_to_inner_types;
 505       max_depth   = depth;
 506       depth       = 0;
 507       context     = context;
 508       case        = []
 509    } in
 510    HLog.debug "Procedural: level 2 transformation";
 511    let steps = proc_proof st annterm in
 512    HLog.debug "Procedural: grafite rendering";
 513    List.rev (T.render_steps [] steps)