helm/software/components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45 module H    = ProceduralHelpers
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    intros: string option list;
  55    clears: string list;
  56    clears_note: string;
  57    case: int list;
  58    skip_thm_and_qed : bool;
  59 }
  60
  61 let debug = true
  62
  63 (* helpers ******************************************************************)
  64
  65 let split2_last l1 l2 =
  66 try
  67    let n = pred (List.length l1) in
  68    let before1, after1 = HEL.split_nth n l1 in
  69    let before2, after2 = HEL.split_nth n l2 in
  70    before1, before2, List.hd after1, List.hd after2
  71 with Invalid_argument _ -> failwith "A2P.split2_last"
  72
  73 let string_of_head = function
  74    | C.ASort _         -> "sort"
  75    | C.AConst _        -> "const"
  76    | C.AMutInd _       -> "mutind"
  77    | C.AMutConstruct _ -> "mutconstruct"
  78    | C.AVar _          -> "var"
  79    | C.ARel _          -> "rel"
  80    | C.AProd _         -> "prod"
  81    | C.ALambda _       -> "lambda"
  82    | C.ALetIn _        -> "letin"
  83    | C.AFix _          -> "fix"
  84    | C.ACoFix _        -> "cofix"
  85    | C.AAppl _         -> "appl"
  86    | C.ACast _         -> "cast"
  87    | C.AMutCase _      -> "mutcase"
  88    | C.AMeta _         -> "meta"
  89    | C.AImplicit _     -> "implict"
  90
  91 let clear st = {st with intros = []}
  92
  93 let next st = {(clear st) with depth = succ st.depth}
  94
  95 let add st entry intro =
  96    {st with context = entry :: st.context; intros = intro :: st.intros}
  97
  98 let push st = {st with case = 1 :: st.case}
  99
 100 let inc st =
 101    {st with case = match st.case with
 102       | []       -> assert false
 103       | hd :: tl -> succ hd :: tl
 104    }
 105
 106 let case st str =
 107    let case = String.concat "." (List.rev_map string_of_int st.case) in
 108    Printf.sprintf "case %s: %s" case str
 109
 110 let test_depth st =
 111 try
 112    let msg = Printf.sprintf "Depth %u: " st.depth in
 113    match st.max_depth with
 114       | None   -> true, ""
 115       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 116 with Invalid_argument _ -> failwith "A2P.test_depth"
 117
 118 let is_rewrite_right = function
 119    | C.AConst (_, uri, []) ->
 120       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 121    | _                     -> false
 122
 123 let is_rewrite_left = function
 124    | C.AConst (_, uri, []) ->
 125       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 126    | _                     -> false
 127
 128 let is_fwd_rewrite_right hd tl =
 129    if is_rewrite_right hd then match List.nth tl 3 with
 130       | C.ARel _ -> true
 131       | _        -> false
 132    else false
 133
 134 let is_fwd_rewrite_left hd tl =
 135    if is_rewrite_left hd then match List.nth tl 3 with
 136       | C.ARel _ -> true
 137       | _        -> false
 138    else false
 139
 140 let get_inner_types st v =
 141 try
 142    let id = Ut.id_of_annterm v in
 143    try match Hashtbl.find st.types id with
 144       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 145       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 146    with Not_found -> None
 147 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 148 (*
 149 let get_inner_sort st v =
 150 try
 151    let id = Ut.id_of_annterm v in
 152    try Hashtbl.find st.sorts id
 153    with Not_found -> `Type (CicUniv.fresh())
 154 with Invalid_argument _ -> failwith "A2P.get_sort"
 155 *)
 156 let get_type msg st bo =
 157 try
 158    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.oblivion_ugraph in
 159    ty
 160 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 161
 162 let get_entry st id =
 163    let rec aux = function
 164       | []                                        -> assert false
 165       | Some (C.Name name, e) :: _ when name = id -> e
 166       | _ :: tl                                   -> aux tl
 167    in
 168    aux st.context
 169
 170 let get_ind_names uri tno =
 171 try
 172    let ts = match E.get_obj Un.oblivion_ugraph uri with
 173       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 174       | _                                      -> assert false
 175    in
 176    match List.nth ts tno with
 177       | (_, _, _, cs) -> List.map fst cs
 178 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 179
 180 (* proof construction *******************************************************)
 181
 182 let used_premise = C.Name "USED"
 183
 184 let mk_exp_args hd tl classes synth =
 185    let meta id = C.AImplicit (id, None) in
 186    let map v (cl, b) =
 187       if I.overlaps synth cl && b then v else meta ""
 188    in
 189    let rec aux = function
 190       | [] -> []
 191       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 192    in
 193    let args = T.list_rev_map2 map tl classes in
 194    let args = aux args in
 195    if args = [] then hd else C.AAppl ("", hd :: args)
 196
 197 let mk_convert st ?name sty ety note =
 198    let e = Cn.hole "" in
 199    let csty, cety = H.cic sty, H.cic ety in
 200    let script =
 201       if debug then
 202          let sname = match name with None -> "" | Some (id, _) -> id in
 203          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 204             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 205          in
 206          [T.Note note]
 207       else []
 208    in
 209    assert (Ut.is_sober csty);
 210    assert (Ut.is_sober cety);
 211    if Ut.alpha_equivalence csty cety then script else
 212    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 213    match name with
 214       | None         -> T.Change (sty, ety, None, e, "") :: script
 215       | Some (id, i) ->
 216          begin match get_entry st id with
 217             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 218             | C.Decl _ ->
 219                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 220          end
 221
 222 let convert st ?name v =
 223    match get_inner_types st v with
 224       | None            ->
 225          if debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 226       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 227
 228 let convert_elim st ?name t v pattern =
 229    match t, get_inner_types st t, get_inner_types st v with
 230       | _, None, _
 231       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 232       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 233          let where = List.hd (List.rev tl) in
 234          let cty = Cn.elim_inferred_type
 235              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 236          in
 237          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 238       | _, Some _, Some _                                     -> assert false
 239
 240 let get_intro = function
 241    | C.Anonymous -> None
 242    | C.Name s    -> Some s
 243
 244 let mk_intros st what script =
 245    let intros st script =
 246       if st.intros = [] then script else
 247       let count = List.length st.intros in
 248       T.Intros (Some count, List.rev st.intros, "") :: script
 249    in
 250    let clears st script =
 251       if true (* st.clears = [] *) then script else T.Clear (st.clears, st.clears_note) :: script
 252    in
 253    intros st (clears st (convert st what @ script))
 254
 255 let mk_arg st = function
 256    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 257    | _                              -> []
 258
 259 let mk_fwd_rewrite st dtext name tl direction v t ity =
 260    let compare premise = function
 261       | None   -> true
 262       | Some s -> s = premise
 263    in
 264    assert (List.length tl = 6);
 265    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 266    let e = Cn.mk_pattern 1 predicate in
 267    match where with
 268       | C.ARel (_, _, i, premise) as w ->
 269 (*         let _script = convert_elim st ~name:(premise, i) v w e in *)
 270          let script name =
 271             let where = Some (premise, name) in
 272             let script = mk_arg st what @ mk_arg st w (* @ script *) in
 273             T.Rewrite (direction, what, where, e, dtext) :: script
 274          in
 275          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 276             {st with context = Cn.clear st.context premise}, script name
 277          else
 278             let br1 = [T.Id ""] in
 279             let br2 = List.rev (T.Apply (w, "assumption") :: script None) in
 280             let text = "non linear rewrite" in
 281             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 282       | _                         -> assert false
 283
 284 let mk_rewrite st dtext where qs tl direction t =
 285    assert (List.length tl = 5);
 286    let predicate = List.nth tl 2 in
 287    let e = Cn.mk_pattern 1 predicate in
 288    let script = [] (* convert_elim st t t e *) in
 289    script @ [T.Rewrite (direction, where, None, e, dtext); T.Branch (qs, "")]
 290
 291 let rec proc_lambda st what name v t =
 292    let dno, ae = match get_inner_types st t with
 293       | None            -> false, true
 294       | Some (sty, ety) ->
 295          let sty, ety = H.cic sty, H.cic ety in
 296          DTI.does_not_occur 1 sty && DTI.does_not_occur 1 ety,
 297          Ut.alpha_equivalence sty ety
 298    in
 299    let dno = dno && DTI.does_not_occur 1 (H.cic t) in
 300    let name = match dno, name with
 301       | true, _            -> C.Anonymous
 302       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 303       | false, name        -> name
 304    in
 305    let entry = Some (name, C.Decl (H.cic v)) in
 306    let intro = get_intro name in
 307    let st = (add st entry intro) in
 308    if ae then proc_proof st t else
 309    let script = proc_proof (clear st) t in
 310    mk_intros st t script
 311
 312 and proc_letin st what name v w t =
 313    let intro = get_intro name in
 314    let proceed, dtext = test_depth st in
 315    let script = if proceed then
 316       let st, hyp, rqv = match get_inner_types st v with
 317          | Some (ity, _) ->
 318             let st, rqv = match v with
 319                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 320                   mk_fwd_rewrite st dtext intro tl true v t ity
 321                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 322                   mk_fwd_rewrite st dtext intro tl false v t ity
 323                | v                                                     ->
 324                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 325                   let ity = H.acic_bc st.context ity in
 326                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 327             in
 328             st, C.Decl (H.cic ity), rqv
 329          | None          ->
 330             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 331       in
 332       let entry = Some (name, hyp) in
 333       let qt = proc_proof (next (add st entry intro)) t in
 334       List.rev_append rqv qt
 335    else
 336       [T.Apply (what, dtext)]
 337    in
 338    mk_intros st what script
 339
 340 and proc_rel st what =
 341    let _, dtext = test_depth st in
 342    let text = "assumption" in
 343    let script = [T.Apply (what, dtext ^ text)] in
 344    mk_intros st what script
 345
 346 and proc_mutconstruct st what =
 347    let _, dtext = test_depth st in
 348    let script = [T.Apply (what, dtext)] in
 349    mk_intros st what script
 350
 351 and proc_const st what =
 352    let _, dtext = test_depth st in
 353    let script = [T.Apply (what, dtext)] in
 354    mk_intros st what script
 355
 356 and proc_appl st what hd tl =
 357    let proceed, dtext = test_depth st in
 358    let script = if proceed then
 359       let ty = get_type "TC2" st hd in
 360       let classes, rc = Cl.classify st.context ty in
 361       let goal_arity, goal = match get_inner_types st what with
 362          | None            -> 0, None
 363          | Some (ity, ety) ->
 364            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 365       in
 366       let parsno, argsno = List.length classes, List.length tl in
 367       let decurry = parsno - argsno in
 368       let diff = goal_arity - decurry in
 369       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 370       let classes = Cl.adjust st.context tl ?goal classes in
 371       let rec mk_synth a n =
 372          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 373       in
 374       let synth = mk_synth I.S.empty decurry in
 375       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 376       let script = List.rev (mk_arg st hd) in
 377       match rc with
 378          | Some (i, j, uri, tyno) ->
 379             let classes2, tl2, _, where = split2_last classes tl in
 380             let script2 = List.rev (mk_arg st where) @ script in
 381             let synth2 = I.S.add 1 synth in
 382             let names = get_ind_names uri tyno in
 383             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 384             if List.length qs <> List.length names then
 385                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 386                let hd = mk_exp_args hd tl classes synth in
 387                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 388             else if is_rewrite_right hd then
 389                script2 @ mk_rewrite st dtext where qs tl2 false what
 390             else if is_rewrite_left hd then
 391                script2 @ mk_rewrite st dtext where qs tl2 true what
 392             else
 393                let predicate = List.nth tl2 (parsno - i) in
 394                let e = Cn.mk_pattern j predicate in
 395                let using = Some hd in
 396                (* convert_elim st what what e @ *) script2 @
 397                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 398          | None        ->
 399             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 400             let hd = mk_exp_args hd tl classes synth in
 401             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 402    else
 403       [T.Apply (what, dtext)]
 404    in
 405    mk_intros st what script
 406
 407 and proc_other st what =
 408    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 409    let script = [T.Note text] in
 410    mk_intros st what script
 411
 412 and proc_proof st t =
 413    let f st =
 414       let xtypes, note = match get_inner_types st t with
 415          | Some (it, et) -> Some (H.cic it, H.cic et),
 416           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 417           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 418          | None          -> None, "\nNo types"
 419       in
 420       let context, clears = Cn.get_clears st.context (H.cic t) xtypes in
 421       let note = Pp.ppcontext st.context ^ note in
 422       {st with context = context; clears = clears; clears_note = note; }
 423    in
 424    match t with
 425       | C.ALambda (_, name, w, t) as what   -> proc_lambda (f st) what name w t
 426       | C.ALetIn (_, name, v, w, t) as what -> proc_letin (f st) what name v w t
 427       | C.ARel _ as what                    -> proc_rel (f st) what
 428       | C.AMutConstruct _ as what           -> proc_mutconstruct (f st) what
 429       | C.AConst _ as what                  -> proc_const (f st) what
 430       | C.AAppl (_, hd :: tl) as what       -> proc_appl (f st) what hd tl
 431       | what                                -> proc_other (f st) what
 432
 433 and proc_bkd_proofs st synth names classes ts =
 434 try
 435    let get_note =
 436       let names = ref (names, push st) in
 437       fun f ->
 438          match !names with
 439             | [], st       -> fun _ -> f st
 440             | "" :: tl, st -> names := tl, st; fun _ -> f st
 441             | hd :: tl, st ->
 442                let note = case st hd in
 443                names := tl, inc st;
 444                fun b -> if b then T.Note note :: f st else f st
 445    in
 446    let _, dtext = test_depth st in
 447    let aux (inv, _) v =
 448       if I.overlaps synth inv then None else
 449       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 450       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 451    in
 452    let ps = T.list_map2_filter aux classes ts in
 453    let b = List.length ps > 1 in
 454    List.rev_map (fun f -> f b) ps
 455
 456 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 457
 458 (* object costruction *******************************************************)
 459
 460 let is_theorem pars =
 461    pars = [] ||
 462    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 463    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 464
 465 let proc_obj st = function
 466    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 467       let ast = proc_proof st v in
 468       let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 469       let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 470       if st.skip_thm_and_qed then ast
 471       else T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 472    | _                                                               ->
 473       failwith "not a theorem"
 474
 475 (* interface functions ******************************************************)
 476
 477 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 478 ?(skip_thm_and_qed=false) prefix aobj =
 479    let st = {
 480       sorts       = ids_to_inner_sorts;
 481       types       = ids_to_inner_types;
 482       prefix      = prefix;
 483       max_depth   = depth;
 484       depth       = 0;
 485       context     = [];
 486       intros      = [];
 487       clears      = [];
 488       clears_note = "";
 489       case        = [];
 490       skip_thm_and_qed = skip_thm_and_qed;
 491    } in
 492    HLog.debug "Procedural: level 2 transformation";
 493    let steps = proc_obj st aobj in
 494    HLog.debug "Procedural: grafite rendering";
 495    List.rev (T.render_steps [] steps)