helm/software/components/acic_procedural/procedural1.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41 module NU   = CicNotationUtil
  42 module L    = Librarian
  43
  44 module Cl   = ProceduralClassify
  45 module T    = ProceduralTypes
  46 module Cn   = ProceduralConversion
  47 module H    = ProceduralHelpers
  48
  49 type status = {
  50    sorts : (C.id, A.sort_kind) Hashtbl.t;
  51    types : (C.id, A.anntypes) Hashtbl.t;
  52    max_depth: int option;
  53    depth: int;
  54    context: C.context;
  55    case: int list
  56 }
  57
  58 let debug = ref false
  59
  60 (* helpers ******************************************************************)
  61
  62 let split2_last l1 l2 =
  63 try
  64    let n = pred (List.length l1) in
  65    let before1, after1 = HEL.split_nth n l1 in
  66    let before2, after2 = HEL.split_nth n l2 in
  67    before1, before2, List.hd after1, List.hd after2
  68 with Invalid_argument _ -> failwith "A2P.split2_last"
  69
  70 let string_of_head = function
  71    | C.ASort _         -> "sort"
  72    | C.AConst _        -> "const"
  73    | C.AMutInd _       -> "mutind"
  74    | C.AMutConstruct _ -> "mutconstruct"
  75    | C.AVar _          -> "var"
  76    | C.ARel _          -> "rel"
  77    | C.AProd _         -> "prod"
  78    | C.ALambda _       -> "lambda"
  79    | C.ALetIn _        -> "letin"
  80    | C.AFix _          -> "fix"
  81    | C.ACoFix _        -> "cofix"
  82    | C.AAppl _         -> "appl"
  83    | C.ACast _         -> "cast"
  84    | C.AMutCase _      -> "mutcase"
  85    | C.AMeta _         -> "meta"
  86    | C.AImplicit _     -> "implict"
  87
  88 let next st = {st with depth = succ st.depth}
  89
  90 let add st entry = {st with context = entry :: st.context}
  91
  92 let push st = {st with case = 1 :: st.case}
  93
  94 let inc st =
  95    {st with case = match st.case with
  96       | []       -> []
  97       | hd :: tl -> succ hd :: tl
  98    }
  99
 100 let case st str =
 101    let case = String.concat "." (List.rev_map string_of_int st.case) in
 102    Printf.sprintf "case %s: %s" case str
 103
 104 let test_depth st =
 105 try
 106    let msg = Printf.sprintf "Depth %u: " st.depth in
 107    match st.max_depth with
 108       | None   -> true, ""
 109       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 110 with Invalid_argument _ -> failwith "A2P.test_depth"
 111
 112 let is_rewrite_right = function
 113    | C.AConst (_, uri, []) ->
 114       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 115    | _                     -> false
 116
 117 let is_rewrite_left = function
 118    | C.AConst (_, uri, []) ->
 119       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 120    | _                     -> false
 121
 122 let is_fwd_rewrite_right hd tl =
 123    if is_rewrite_right hd then match List.nth tl 3 with
 124       | C.ARel _ -> true
 125       | _        -> false
 126    else false
 127
 128 let is_fwd_rewrite_left hd tl =
 129    if is_rewrite_left hd then match List.nth tl 3 with
 130       | C.ARel _ -> true
 131       | _        -> false
 132    else false
 133
 134 let get_inner_types st v =
 135 try
 136    let id = Ut.id_of_annterm v in
 137    try match Hashtbl.find st.types id with
 138       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 139       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 140    with Not_found -> None
 141 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 142
 143 let is_proof st v =
 144 try
 145    let id = Ut.id_of_annterm v in
 146    try match Hashtbl.find st.sorts id with
 147       | `Prop -> true
 148       | _     -> false
 149    with Not_found -> H.is_proof st.context (H.cic v)
 150 with Invalid_argument _ -> failwith "P1.is_proof"
 151
 152 let get_entry st id =
 153    let rec aux = function
 154       | []                                        -> assert false
 155       | Some (C.Name name, e) :: _ when name = id -> e
 156       | _ :: tl                                   -> aux tl
 157    in
 158    aux st.context
 159
 160 let string_of_atomic = function
 161    | C.ARel (_, _, _, s)               -> s
 162    | C.AVar (_, uri, _)                -> H.name_of_uri uri None None
 163    | C.AConst (_, uri, _)              -> H.name_of_uri uri None None
 164    | C.AMutInd (_, uri, i, _)          -> H.name_of_uri uri (Some i) None
 165    | C.AMutConstruct (_, uri, i, j, _) -> H.name_of_uri uri (Some i) (Some j)
 166    | _                                 -> ""
 167
 168 let get_sub_names head l =
 169    let s = string_of_atomic head in
 170    if s = "" then [] else
 171    let map (names, i) _ =
 172       let name = Printf.sprintf "%s_%u" s i in name :: names, succ i
 173    in
 174    let names, _ = List.fold_left map ([], 1) l in
 175    List.rev names
 176
 177 let get_type msg st t = H.get_type msg st.context (H.cic t)
 178
 179 let clear_absts m =
 180    let rec aux k n = function
 181       | C.ALambda (id, s, v, t) when k > 0 ->
 182          C.ALambda (id, s, v, aux (pred k) n t)
 183       | C.ALambda (_, _, _, t) when n > 0 ->
 184          aux 0 (pred n) (Cn.lift 1 (-1) t)
 185       | t                  when n > 0 ->
 186          Printf.eprintf "A2P.clear_absts: %u %s\n" n (Pp.ppterm (H.cic t));
 187          assert false
 188       | t                             -> t
 189    in
 190    aux m
 191
 192 (* proof construction *******************************************************)
 193
 194 let anonymous_premise = C.Name "UNNAMED"
 195
 196 let mk_exp_args hd tl classes synth =
 197    let meta id = C.AImplicit (id, None) in
 198    let map v (cl, b) =
 199       if I.overlaps synth cl && b then v else meta ""
 200    in
 201    let rec aux = function
 202       | [] -> []
 203       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 204    in
 205    let args = T.list_rev_map2 map tl classes in
 206    let args = aux args in
 207    if args = [] then hd else C.AAppl ("", hd :: args)
 208
 209 let mk_convert st ?name sty ety note =
 210    let e = Cn.hole "" in
 211    let csty, cety = H.cic sty, H.cic ety in
 212    let script =
 213       if !debug then
 214          let sname = match name with None -> "" | Some (id, _) -> id in
 215          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 216             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 217          in
 218          [T.Note note]
 219       else []
 220    in
 221    assert (Ut.is_sober st.context csty);
 222    assert (Ut.is_sober st.context cety);
 223    if Ut.alpha_equivalence csty cety then script else
 224    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 225    match name with
 226       | None         -> T.Change (sty, ety, None, e, "") :: script
 227       | Some (id, i) ->
 228          begin match get_entry st id with
 229             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 230             | C.Decl _ ->
 231                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 232          end
 233
 234 let convert st ?name v =
 235    match get_inner_types st v with
 236       | None            ->
 237          if !debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 238       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 239
 240 let get_intro = function
 241    | C.Anonymous -> None
 242    | C.Name s    -> Some s
 243
 244 let mk_preamble st what script =
 245    convert st what @ script
 246
 247 let mk_arg st = function
 248    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 249    | _                              -> []
 250
 251 let mk_fwd_rewrite st dtext name tl direction v t ity =
 252    let compare premise = function
 253       | None   -> true
 254       | Some s -> s = premise
 255    in
 256    assert (List.length tl = 6);
 257    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 258    let e = Cn.mk_pattern 1 predicate in
 259    if (Cn.does_not_occur e) then st, [] else
 260    match where with
 261       | C.ARel (_, _, i, premise) as w ->
 262          let script name =
 263             let where = Some (premise, name) in
 264             let script = mk_arg st what @ mk_arg st w in
 265             T.Rewrite (direction, what, where, e, dtext) :: script
 266          in
 267          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 268             {st with context = Cn.clear st.context premise}, script name
 269          else begin
 270             assert (Ut.is_sober st.context (H.cic ity));
 271             let ity = H.acic_bc st.context ity in
 272             let br1 = [T.Id ""] in
 273             let br2 = List.rev (T.Apply (w, "assumption") :: script None) in
 274             let text = "non-linear rewrite" in
 275             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 276          end
 277       | _                         -> assert false
 278
 279 let mk_rewrite st dtext where qs tl direction t =
 280    assert (List.length tl = 5);
 281    let predicate = List.nth tl 2 in
 282    let e = Cn.mk_pattern 1 predicate in
 283    let script = [T.Branch (qs, "")] in
 284    if (Cn.does_not_occur e) then script else
 285    T.Rewrite (direction, where, None, e, dtext) :: script
 286
 287 let rec proc_lambda st what name v t =
 288    let name = match name with
 289       | C.Anonymous -> H.mk_fresh_name st.context anonymous_premise
 290       | name        -> name
 291    in
 292    let entry = Some (name, C.Decl (H.cic v)) in
 293    let intro = get_intro name in
 294    let script = proc_proof (add st entry) t in
 295    let script = T.Intros (Some 1, [intro], "") :: script in
 296    mk_preamble st what script
 297
 298 and proc_letin st what name v w t =
 299    let intro = get_intro name in
 300    let proceed, dtext = test_depth st in
 301    let script = if proceed then
 302       let st, hyp, rqv = match get_inner_types st v with
 303          | Some (ity, _) ->
 304             let st, rqv = match v with
 305                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 306                   mk_fwd_rewrite st dtext intro tl true v t ity
 307                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 308                   mk_fwd_rewrite st dtext intro tl false v t ity
 309                | v                                                     ->
 310                   assert (Ut.is_sober st.context (H.cic ity));
 311                   let ity = H.acic_bc st.context ity in
 312                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 313                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 314             in
 315             st, C.Decl (H.cic ity), rqv
 316          | None          ->
 317             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 318       in
 319       let entry = Some (name, hyp) in
 320       let qt = proc_proof (next (add st entry)) t in
 321       List.rev_append rqv qt
 322    else
 323       [T.Apply (what, dtext)]
 324    in
 325    mk_preamble st what script
 326
 327 and proc_rel st what =
 328    let _, dtext = test_depth st in
 329    let text = "assumption" in
 330    let script = [T.Apply (what, dtext ^ text)] in
 331    mk_preamble st what script
 332
 333 and proc_mutconstruct st what =
 334    let _, dtext = test_depth st in
 335    let script = [T.Apply (what, dtext)] in
 336    mk_preamble st what script
 337
 338 and proc_const st what =
 339    let _, dtext = test_depth st in
 340    let script = [T.Apply (what, dtext)] in
 341    mk_preamble st what script
 342
 343 and proc_appl st what hd tl =
 344    let proceed, dtext = test_depth st in
 345    let script = if proceed then
 346       let ty = match get_inner_types st hd with
 347          | Some (ity, _) -> H.cic ity
 348          | None          -> get_type "TC2" st hd
 349       in
 350       let classes, rc = Cl.classify st.context ty in
 351       let goal_arity, goal = match get_inner_types st what with
 352          | None            -> 0, None
 353          | Some (ity, ety) ->
 354            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 355       in
 356       let parsno, argsno = List.length classes, List.length tl in
 357       let decurry = parsno - argsno in
 358       let diff = goal_arity - decurry in
 359       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 360       let classes = Cl.adjust st.context tl ?goal classes in
 361       let rec mk_synth a n =
 362          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 363       in
 364       let synth = mk_synth I.S.empty decurry in
 365       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 366       let script = List.rev (mk_arg st hd) in
 367       match rc with
 368          | Some (i, j, uri, tyno) ->
 369             let classes2, tl2, _, where = split2_last classes tl in
 370             let script2 = List.rev (mk_arg st where) @ script in
 371             let synth2 = I.S.add 1 synth in
 372             let names = H.get_ind_names uri tyno in
 373             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 374             if List.length qs <> List.length names then
 375                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 376                let hd = mk_exp_args hd tl classes synth in
 377                script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 378             else if is_rewrite_right hd then
 379                script2 @ mk_rewrite st dtext where qs tl2 false what
 380             else if is_rewrite_left hd then
 381                script2 @ mk_rewrite st dtext where qs tl2 true what
 382             else
 383                let predicate = List.nth tl2 (parsno - i) in
 384                let e = Cn.mk_pattern j predicate in
 385                let using = Some hd in
 386                script2 @
 387                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 388          | None        ->
 389             let names = get_sub_names hd tl in
 390             let qs = proc_bkd_proofs (next st) synth names classes tl in
 391             let hd = mk_exp_args hd tl classes synth in
 392             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 393    else
 394       [T.Apply (what, dtext)]
 395    in
 396    mk_preamble st what script
 397
 398 and proc_case st what uri tyno u v ts =
 399    let proceed, dtext = test_depth st in
 400    let script = if proceed then
 401       let synth, classes = I.S.empty, Cl.make ts in
 402       let names = H.get_ind_names uri tyno in
 403       let qs = proc_bkd_proofs (next st) synth names classes ts in
 404       let lpsno, _ = H.get_ind_type uri tyno in
 405       let ps, sort_disp = H.get_ind_parameters st.context (H.cic v) in
 406       let _, rps = HEL.split_nth lpsno ps in
 407       let rpsno = List.length rps in
 408       let predicate = clear_absts rpsno (1 - sort_disp) u in
 409       let e = Cn.mk_pattern rpsno predicate in
 410       let text = "" in
 411       let script = List.rev (mk_arg st v) in
 412       script @ [T.Cases (v, e, dtext ^ text); T.Branch (qs, "")]
 413    else
 414       [T.Apply (what, dtext)]
 415    in
 416    mk_preamble st what script
 417
 418 and proc_other st what =
 419    let _, dtext = test_depth st in
 420    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 421    let script = [T.Apply (what, dtext ^ text)] in
 422    mk_preamble st what script
 423
 424 and proc_proof st t =
 425    let f st =
 426       let xtypes, note = match get_inner_types st t with
 427          | Some (it, et) -> Some (H.cic it, H.cic et),
 428           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 429           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 430          | None          -> None, "\nNo types"
 431       in
 432       let context, _clears = Cn.get_clears st.context (H.cic t) xtypes in
 433       {st with context = context}
 434    in
 435    match t with
 436       | C.ALambda (_, name, w, t) as what        -> proc_lambda (f st) what name w t
 437       | C.ALetIn (_, name, v, w, t) as what      -> proc_letin (f st) what name v w t
 438       | C.ARel _ as what                         -> proc_rel (f st) what
 439       | C.AMutConstruct _ as what                -> proc_mutconstruct (f st) what
 440       | C.AConst _ as what                       -> proc_const (f st) what
 441       | C.AAppl (_, hd :: tl) as what            -> proc_appl (f st) what hd tl
 442       | C.AMutCase (_, uri, i, u, v, ts) as what -> proc_case (f st) what uri i u v ts
 443       | what                                     -> proc_other (f st) what
 444
 445 and proc_bkd_proofs st synth names classes ts =
 446 try
 447    let get_names b = ref (names, if b then push st else st) in
 448    let get_note f b names =
 449       match !names with
 450          | [], st       -> f st
 451          | "" :: tl, st -> names := tl, st; f st
 452          | hd :: tl, st ->
 453             let note = case st hd in
 454             names := tl, inc st;
 455             if b then T.Note note :: f st else f st
 456    in
 457    let _, dtext = test_depth st in
 458    let aux (inv, _) v =
 459       if I.overlaps synth inv then None else
 460       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 461       Some (get_note (fun _ -> [T.Apply (v, dtext ^ "dependent")]))
 462    in
 463    let ps = T.list_map2_filter aux classes ts in
 464    let b = List.length ps > 1 in
 465    let names = get_names b in
 466    List.rev_map (fun f -> f b names) ps
 467
 468 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 469
 470 (* object costruction *******************************************************)
 471
 472 let th_flavours = [`Theorem; `Lemma; `Remark; `Fact]
 473
 474 let def_flavours = [`Definition]
 475
 476 let get_flavour ?flavour st v attrs =
 477    let rec aux = function
 478       | []               ->
 479          if is_proof st v then List.hd th_flavours else List.hd def_flavours
 480       | `Flavour fl :: _ -> fl
 481       | _ :: tl          -> aux tl
 482    in
 483    match flavour with
 484       | Some fl -> fl
 485       | None    -> aux attrs
 486
 487 let proc_obj ?flavour ?(info="") st = function
 488    | C.AConstant (_, _, s, Some v, t, [], attrs)         ->
 489       begin match get_flavour ?flavour st v attrs with
 490          | flavour when List.mem flavour th_flavours  ->
 491             let ast = proc_proof st v in
 492             let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 493             let text = Printf.sprintf "%s\n%s%s: %u\n%s: %u\n%s"
 494                "COMMENTS" info "Tactics" steps "Final nodes" nodes "END"
 495             in
 496             T.Statement (flavour, Some s, t, None, "") :: ast @ [T.Qed text]
 497          | flavour when List.mem flavour def_flavours ->
 498             [T.Statement (flavour, Some s, t, Some v, "")]
 499          | _                                  ->
 500             failwith "not a theorem, definition, axiom or inductive type"
 501       end
 502    | C.AConstant (_, _, s, None, t, [], attrs)           ->
 503       [T.Statement (`Axiom, Some s, t, None, "")]
 504    | C.AInductiveDefinition (_, types, [], lpsno, attrs) ->
 505       [T.Inductive (types, lpsno, "")]
 506    | _                                          ->
 507       failwith "not a theorem, definition, axiom or inductive type"
 508
 509 let init ~ids_to_inner_sorts ~ids_to_inner_types ?depth context =
 510    {
 511       sorts       = ids_to_inner_sorts;
 512       types       = ids_to_inner_types;
 513       max_depth   = depth;
 514       depth       = 0;
 515       context     = context;
 516       case        = []
 517    }