helm/software/components/acic_procedural/procedural2.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module R    = CicReduction
  30 module TC   = CicTypeChecker
  31 module Un   = CicUniv
  32 module UM   = UriManager
  33 module Obj  = LibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41 module NU   = CicNotationUtil
  42 module L    = Librarian
  43 module G    = GrafiteAst
  44
  45 module Cl   = ProceduralClassify
  46 module T    = ProceduralTypes
  47 module Cn   = ProceduralConversion
  48 module H    = ProceduralHelpers
  49
  50 type status = {
  51    sorts    : (C.id, A.sort_kind) Hashtbl.t;
  52    types    : (C.id, A.anntypes) Hashtbl.t;
  53    params   : G.inline_param list;
  54    max_depth: int option;
  55    depth    : int;
  56    defaults : bool;
  57    cr       : bool;
  58    context  : C.context;
  59    case     : int list
  60 }
  61
  62 let debug = ref false
  63
  64 (* helpers ******************************************************************)
  65
  66 let split2_last l1 l2 =
  67 try
  68    let n = pred (List.length l1) in
  69    let before1, after1 = HEL.split_nth n l1 in
  70    let before2, after2 = HEL.split_nth n l2 in
  71    before1, before2, List.hd after1, List.hd after2
  72 with Invalid_argument _ -> failwith "A2P.split2_last"
  73
  74 let string_of_head = function
  75    | C.ASort _         -> "sort"
  76    | C.AConst _        -> "const"
  77    | C.AMutInd _       -> "mutind"
  78    | C.AMutConstruct _ -> "mutconstruct"
  79    | C.AVar _          -> "var"
  80    | C.ARel _          -> "rel"
  81    | C.AProd _         -> "prod"
  82    | C.ALambda _       -> "lambda"
  83    | C.ALetIn _        -> "letin"
  84    | C.AFix _          -> "fix"
  85    | C.ACoFix _        -> "cofix"
  86    | C.AAppl _         -> "appl"
  87    | C.ACast _         -> "cast"
  88    | C.AMutCase _      -> "mutcase"
  89    | C.AMeta _         -> "meta"
  90    | C.AImplicit _     -> "implict"
  91
  92 let next st = {st with depth = succ st.depth}
  93
  94 let add st entry = {st with context = entry :: st.context}
  95
  96 let push st = {st with case = 1 :: st.case}
  97
  98 let inc st =
  99    {st with case = match st.case with
 100       | []       -> []
 101       | hd :: tl -> succ hd :: tl
 102    }
 103
 104 let case st str =
 105    let case = String.concat "." (List.rev_map string_of_int st.case) in
 106    Printf.sprintf "case %s: %s" case str
 107
 108 let test_depth st =
 109 try
 110    let msg = Printf.sprintf "Depth %u: " st.depth in
 111    match st.max_depth with
 112       | None   -> true, ""
 113       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 114 with Invalid_argument _ -> failwith "A2P.test_depth"
 115
 116 let is_rewrite_right st = function
 117    | C.AConst (_, uri, []) -> st.defaults && Obj.is_eq_ind_r_URI uri
 118    | _                     -> false
 119
 120 let is_rewrite_left st = function
 121    | C.AConst (_, uri, []) -> st.defaults && Obj.is_eq_ind_URI uri
 122    | _                     -> false
 123
 124 let is_fwd_rewrite_right st hd tl =
 125    if is_rewrite_right st hd then match List.nth tl 3 with
 126       | C.ARel _ -> true
 127       | _        -> false
 128    else false
 129
 130 let is_fwd_rewrite_left st hd tl =
 131    if is_rewrite_left st hd then match List.nth tl 3 with
 132       | C.ARel _ -> true
 133       | _        -> false
 134    else false
 135
 136 let get_inner_types st v =
 137 try
 138    let id = Ut.id_of_annterm v in
 139    try match Hashtbl.find st.types id with
 140       | {A.annsynthesized = ity; A.annexpected = Some ety} -> Some (ity, ety)
 141       | {A.annsynthesized = ity; A.annexpected = None}     -> Some (ity, ity)
 142    with Not_found -> None
 143 with Invalid_argument _ -> failwith "P2.get_inner_types"
 144
 145 let get_entry st id =
 146    let rec aux = function
 147       | []                                        -> assert false
 148       | Some (C.Name name, e) :: _ when name = id -> e
 149       | _ :: tl                                   -> aux tl
 150    in
 151    aux st.context
 152
 153 let string_of_atomic = function
 154    | C.ARel (_, _, _, s)               -> s
 155    | C.AVar (_, uri, _)                -> H.name_of_uri uri None None
 156    | C.AConst (_, uri, _)              -> H.name_of_uri uri None None
 157    | C.AMutInd (_, uri, i, _)          -> H.name_of_uri uri (Some i) None
 158    | C.AMutConstruct (_, uri, i, j, _) -> H.name_of_uri uri (Some i) (Some j)
 159    | _                                 -> ""
 160
 161 let get_sub_names head l =
 162    let s = string_of_atomic head in
 163    if s = "" then [] else
 164    let map (names, i) _ =
 165       let name = Printf.sprintf "%s_%u" s i in name :: names, succ i
 166    in
 167    let names, _ = List.fold_left map ([], 1) l in
 168    List.rev names
 169
 170 let get_type msg st t = H.get_type msg st.context (H.cic t)
 171
 172 let get_uri_of_head = function
 173    | C.AConst (_, u, _)                                 ->
 174       Some (u, 0, 0, 0)
 175    | C.AAppl (_, C.AConst (_, u, _) :: vs)              ->
 176       Some (u, 0, 0, List.length vs)
 177    | C.AMutInd (_, u, i, _)                             ->
 178       Some (u, succ i, 0, 0)
 179    | C.AAppl (_, C.AMutInd (_, u, i, _) :: vs)          ->
 180       Some (u, succ i, 0, List.length vs)
 181    | C.AMutConstruct (_, u, i, j, _)                    ->
 182       Some (u, succ i, j, 0)
 183    | C.AAppl (_, C.AMutConstruct (_, u, i, j, _) :: vs) ->
 184       Some (u, succ i, j, List.length vs)
 185    | _                                                  ->
 186       None
 187
 188 let get_uri_of_apply = function
 189    | T.Exact (t, _)
 190    | T.Apply (t, _) -> get_uri_of_head t
 191    | _              -> None
 192
 193 let is_reflexivity st step =
 194    match get_uri_of_apply step with
 195       | None                -> false
 196       | Some (uri, i, j, n) ->
 197          st.defaults && Obj.is_eq_URI uri && i = 1 && j = 1 && n = 0
 198
 199 let is_ho_reflexivity st step =
 200    match get_uri_of_apply step with
 201       | None                -> false
 202       | Some (uri, i, j, n) ->
 203          st.defaults && Obj.is_eq_URI uri && i = 1 && j = 1 && n > 0
 204
 205 let are_convertible st pred sx dx =
 206    let pred, sx, dx = H.cic pred, H.cic sx, H.cic dx in
 207    let sx, dx = C.Appl [pred; sx], C.Appl [pred; dx] in
 208    fst (R.are_convertible st.context sx dx Un.default_ugraph)
 209
 210 (* proof construction *******************************************************)
 211
 212 let anonymous_premise = C.Name "UNNAMED"
 213
 214 let mk_exp_args hd tl classes synth qs =
 215    let exp = ref 0 in
 216    let meta id = C.AImplicit (id, None) in
 217    let map v (cl, b) =
 218       if I.overlaps synth cl
 219          then if b then v, v else meta "", v
 220          else meta "", meta ""
 221    in
 222    let rec rev a = function
 223       | []       -> a
 224       | hd :: tl ->
 225          if snd hd <> meta "" then incr exp;
 226          rev (snd hd :: a) tl
 227    in
 228    let rec aux = function
 229       | []       -> []
 230       | hd :: tl ->
 231          if fst hd = meta "" then aux tl else rev [] (hd :: tl)
 232    in
 233    let args = T.list_rev_map2 map tl classes in
 234    let args = aux args in
 235    let part = !exp < List.length tl in
 236    if args = [] then part, hd, qs else part, C.AAppl ("", hd :: args), qs
 237
 238 let mk_convert st ?name sty ety note =
 239    let ppterm t =
 240       let a = ref "" in Ut.pp_term (fun s -> a := !a ^ s) [] st.context t; !a
 241    in
 242    let e = Cn.hole "" in
 243    let csty, cety = H.cic sty, H.cic ety in
 244    let note =
 245       if !debug then
 246          let sname = match name with None -> "" | Some (id, _) -> id in
 247          Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 248             note sname (ppterm csty) (ppterm cety)
 249       else ""
 250    in
 251    if H.alpha ~flatten:true st.context csty cety then [T.Note note] else
 252    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 253    match name with
 254       | None         -> [T.Change (sty, ety, None, e, note)]
 255       | Some (id, i) ->
 256          begin match get_entry st id with
 257             | C.Def _  ->
 258                [T.Change (ety, sty, Some (id, Some id), e, note);
 259                 T.ClearBody (id, "")
 260                ]
 261             | C.Decl _ ->
 262                [T.Change (ety, sty, Some (id, Some id), e, note)]
 263          end
 264
 265 let convert st ?name v =
 266    match get_inner_types st v with
 267       | None            ->
 268          if !debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 269       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 270
 271 let get_intro = function
 272    | C.Anonymous -> None
 273    | C.Name s    -> Some s
 274
 275 let mk_preamble st what script = match script with
 276    | step :: script when is_reflexivity st step ->
 277       T.Reflexivity (T.note_of_step step) :: script
 278    | step :: script when is_ho_reflexivity st step ->
 279       convert st what @ T.Reflexivity (T.note_of_step step) :: script
 280    | T.Exact _ :: _ -> script
 281    | _              -> convert st what @ script
 282
 283 let mk_arg st = function
 284    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 285    | _                              -> []
 286
 287 let mk_fwd_rewrite st dtext name tl direction v t ity ety =
 288    let compare premise = function
 289       | None   -> true
 290       | Some s -> s = premise
 291    in
 292    assert (List.length tl = 6);
 293    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 294    let e = Cn.mk_pattern 1 ety predicate in
 295    if (Cn.does_not_occur e) then st, [] else
 296    match where with
 297       | C.ARel (_, _, i, premise) as w ->
 298          let script name =
 299             let where = Some (premise, name) in
 300             let script = mk_arg st what @ mk_arg st w in
 301             T.Rewrite (direction, what, where, e, dtext) :: script
 302          in
 303          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 304             {st with context = Cn.clear st.context premise}, script name
 305          else begin
 306             assert (Ut.is_sober st.context (H.cic ity));
 307             let ity = H.acic_bc st.context ity in
 308             let br1 = [T.Id ""] in
 309             let br2 = List.rev (T.Exact (w, "assumption") :: script None) in
 310             let text = "non-linear rewrite" in
 311             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 312          end
 313       | _                         -> assert false
 314
 315 let mk_rewrite st dtext where qs tl direction t ity =
 316    let ppterm t =
 317       let a = ref "" in Ut.pp_term (fun s -> a := !a ^ s) [] st.context t; !a
 318    in
 319    assert (List.length tl = 5);
 320    let pred, sx, dx = List.nth tl 2, List.nth tl 1, List.nth tl 4 in
 321    let dtext = if !debug then dtext ^ ppterm (H.cic pred) else dtext in
 322    let e = Cn.mk_pattern 1 ity pred in
 323    let script = [T.Branch (qs, "")] in
 324    if Cn.does_not_occur e then script else
 325    if st.cr && are_convertible st pred sx dx then
 326       let dtext = "convertible rewrite" ^ dtext in
 327       let ity, ety, e = Cn.beta sx pred, Cn.beta dx pred, Cn.hole "" in
 328       let city, cety = H.cic ity, H.cic ety in
 329       if H.alpha ~flatten:true st.context city cety then script else
 330       T.Change (ity, ety, None, e, dtext) :: script
 331    else
 332    T.Rewrite (direction, where, None, e, dtext) :: script
 333
 334 let rec proc_lambda st what name v t =
 335    let dtext = if !debug then CicPp.ppcontext st.context else "" in
 336    let name = match name with
 337       | C.Anonymous -> H.mk_fresh_name true st.context anonymous_premise
 338       | name        -> name
 339    in
 340    let entry = Some (name, C.Decl (H.cic v)) in
 341    let intro = get_intro name in
 342    let script = proc_proof (add st entry) t in
 343    let script = T.Intros (Some 1, [intro], dtext) :: script in
 344    mk_preamble st what script
 345
 346 and proc_letin st what name v w t =
 347    let intro = get_intro name in
 348    let proceed, dtext = test_depth st in
 349    let script = if proceed then
 350       let st, hyp, rqv = match get_inner_types st what, get_inner_types st v with
 351          | Some (C.ALetIn (_, _, iv, iw, _), _), _ when
 352             H.alpha ~flatten:true st.context (H.cic v) (H.cic iv) &&
 353             H.alpha ~flatten:true st.context (H.cic w) (H.cic iw)
 354                                                    ->
 355             st, C.Def (H.cic v, H.cic w), [T.Intros (Some 1, [intro], dtext)]
 356          | _, Some (ity, ety)                      ->
 357             let st, rqv = match v with
 358                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right st hd tl ->
 359                   mk_fwd_rewrite st dtext intro tl true v t ity ety
 360                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left st hd tl  ->
 361                   mk_fwd_rewrite st dtext intro tl false v t ity ety
 362                | v                                                        ->
 363                   assert (Ut.is_sober st.context (H.cic ety));
 364                   let ety = H.acic_bc st.context ety in
 365                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 366                   st, [T.Branch (qs, ""); T.Cut (intro, ety, dtext)]
 367             in
 368             st, C.Decl (H.cic ity), rqv
 369          | _, None                 ->
 370             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 371       in
 372       let entry = Some (name, hyp) in
 373       let qt = proc_proof (next (add st entry)) t in
 374       List.rev_append rqv qt
 375    else
 376       [T.Exact (what, dtext)]
 377    in
 378    mk_preamble st what script
 379
 380 and proc_rel st what =
 381    let _, dtext = test_depth st in
 382    let text = "assumption" in
 383    let script = [T.Exact (what, dtext ^ text)] in
 384    mk_preamble st what script
 385
 386 and proc_mutconstruct st what =
 387    let _, dtext = test_depth st in
 388    let script = [T.Exact (what, dtext)] in
 389    mk_preamble st what script
 390
 391 and proc_const st what =
 392    let _, dtext = test_depth st in
 393    let script = [T.Exact (what, dtext)] in
 394    mk_preamble st what script
 395
 396 and proc_appl st what hd tl =
 397    let proceed, dtext = test_depth st in
 398    let script = if proceed then
 399       let ty = match get_inner_types st hd with
 400          | Some (ity, _) -> H.cic ity
 401          | None          -> get_type "TC2" st hd
 402       in
 403       let classes, rc = Cl.classify st.context ty in
 404       let goal_arity, goal = match get_inner_types st what with
 405          | None          -> 0, None
 406          | Some (ity, _) ->
 407            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ity)
 408       in
 409       let parsno, argsno = List.length classes, List.length tl in
 410       let decurry = parsno - argsno in
 411       let diff = goal_arity - decurry in
 412       if diff < 0 then
 413          let text = Printf.sprintf "partial application: %i" diff in
 414          prerr_endline ("Procedural 2: " ^ text);
 415          [T.Exact (what, dtext ^ text)]
 416       else
 417       let classes = Cl.adjust st.context tl ?goal classes in
 418       let rec mk_synth a n =
 419          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 420       in
 421       let synth = mk_synth I.S.empty decurry in
 422       let text = if !debug
 423          then Printf.sprintf "%u %s" parsno (Cl.to_string synth (classes, rc))
 424          else ""
 425       in
 426       let script = List.rev (mk_arg st hd) in
 427       let tactic b t n = if b then T.Apply (t, n) else T.Exact (t, n) in
 428       match rc with
 429          | Some (i, j, uri, tyno) when decurry = 0 ->
 430             let classes2, tl2, _, where = split2_last classes tl in
 431             let script2 = List.rev (mk_arg st where) @ script in
 432             let synth2 = I.S.add 1 synth in
 433             let names = H.get_ind_names uri tyno in
 434             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 435             let ity = match get_inner_types st what with
 436                 | Some (ity, _) -> ity
 437                 | None          ->
 438                    Cn.fake_annotate "" st.context (get_type "TC3" st what)
 439             in
 440             if List.length qs <> List.length names then
 441                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 442                let b, hd, qs = mk_exp_args hd tl classes synth qs in
 443                script @ [tactic b hd (dtext ^ text); T.Branch (qs, "")]
 444             else if is_rewrite_right st hd then
 445                script2 @ mk_rewrite st dtext where qs tl2 false what ity
 446             else if is_rewrite_left st hd then
 447                script2 @ mk_rewrite st dtext where qs tl2 true what ity
 448             else
 449                let predicate = List.nth tl2 (parsno - i) in
 450                let e = Cn.mk_pattern j ity predicate in
 451                let using = Some hd in
 452                script2 @
 453                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 454          | _                                       ->
 455             let names = get_sub_names hd tl in
 456             let qs = proc_bkd_proofs (next st) synth names classes tl in
 457             let b, hd, qs = mk_exp_args hd tl classes synth qs in
 458             script @ [tactic b hd (dtext ^ text); T.Branch (qs, "")]
 459    else
 460       [T.Exact (what, dtext)]
 461    in
 462    mk_preamble st what script
 463
 464 and proc_case st what uri tyno u v ts =
 465    let proceed, dtext = test_depth st in
 466    let script = if proceed then
 467       let synth, classes = I.S.empty, Cl.make ts in
 468       let names = H.get_ind_names uri tyno in
 469       let qs = proc_bkd_proofs (next st) synth names classes ts in
 470       let lpsno, _ = H.get_ind_type uri tyno in
 471       let ps, _ = H.get_ind_parameters st.context (H.cic v) in
 472       let _, rps = HEL.split_nth lpsno ps in
 473       let rpsno = List.length rps in
 474       let ity = match get_inner_types st what with
 475          | Some (ity, _) -> ity
 476          | None          ->
 477             Cn.fake_annotate "" st.context (get_type "TC4" st what)
 478       in
 479       let e = Cn.mk_pattern rpsno ity u in
 480       let text = "" in
 481       let script = List.rev (mk_arg st v) in
 482       script @ [T.Cases (v, e, dtext ^ text); T.Branch (qs, "")]
 483    else
 484       [T.Exact (what, dtext)]
 485    in
 486    mk_preamble st what script
 487
 488 and proc_other st what =
 489    let _, dtext = test_depth st in
 490    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 491    let script = [T.Exact (what, dtext ^ text)] in
 492    mk_preamble st what script
 493
 494 and proc_proof st t =
 495    let f st =
 496 (*
 497       let xtypes, note = match get_inner_types st t with
 498          | Some (it, et) -> Some (H.cic it, H.cic et),
 499           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 500           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 501          | None          -> None, "\nNo types"
 502       in
 503       let context, clears = Cn.get_clears st.context (H.cic t) xtypes in
 504       {st with context = context}
 505 *)
 506       st
 507    in
 508    match t with
 509       | C.ALambda (_, name, w, t) as what        -> proc_lambda (f st) what name w t
 510       | C.ALetIn (_, name, v, w, t) as what      -> proc_letin (f st) what name v w t
 511       | C.ARel _ as what                         -> proc_rel (f st) what
 512       | C.AMutConstruct _ as what                -> proc_mutconstruct (f st) what
 513       | C.AConst _ as what                       -> proc_const (f st) what
 514       | C.AAppl (_, hd :: tl) as what            -> proc_appl (f st) what hd tl
 515 (* FG: we deactivate the tactic "cases" because it does not work properly
 516       | C.AMutCase (_, uri, i, u, v, ts) as what -> proc_case (f st) what uri i u v ts
 517 *)
 518       | what                                     -> proc_other (f st) what
 519
 520 and proc_bkd_proofs st synth names classes ts =
 521 try
 522    let get_names b = ref (names, if b then push st else st) in
 523    let get_note f b names =
 524       match !names with
 525          | [], st       -> f st
 526          | "" :: tl, st -> names := tl, st; f st
 527          | hd :: tl, st ->
 528             let note = case st hd in
 529             names := tl, inc st;
 530             if b then T.Note note :: f st else f st
 531    in
 532    let _, dtext = test_depth st in
 533    let aux (inv, _) v =
 534       if I.overlaps synth inv then None else
 535       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 536       Some (get_note (fun _ -> [T.Exact (v, dtext ^ "dependent")]))
 537    in
 538    let ps = T.list_map2_filter aux classes ts in
 539    let b = List.length ps > 1 in
 540    let names = get_names b in
 541    List.rev_map (fun f -> f b names) ps
 542
 543 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 544
 545 (* initialization ***********************************************************)
 546
 547 let init ~ids_to_inner_sorts ~ids_to_inner_types params context =
 548    let depth_map x y = match x, y with
 549       | None, G.IPDepth depth -> Some depth
 550       | _                     -> x
 551    in
 552    {
 553       sorts       = ids_to_inner_sorts;
 554       types       = ids_to_inner_types;
 555       params      = params;
 556       max_depth   = List.fold_left depth_map None params;
 557       depth       = 0;
 558       defaults    = not (List.mem G.IPNoDefaults params);
 559       cr          = List.mem G.IPCR params;
 560       context     = context;
 561       case        = []
 562    }