helm/software/components/acic_procedural/procedural2.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41 module NU   = CicNotationUtil
  42 module L    = Librarian
  43
  44 module Cl   = ProceduralClassify
  45 module T    = ProceduralTypes
  46 module Cn   = ProceduralConversion
  47 module H    = ProceduralHelpers
  48
  49 type status = {
  50    sorts : (C.id, A.sort_kind) Hashtbl.t;
  51    types : (C.id, A.anntypes) Hashtbl.t;
  52    max_depth: int option;
  53    depth: int;
  54    context: C.context;
  55    case: int list
  56 }
  57
  58 let debug = ref false
  59
  60 (* helpers ******************************************************************)
  61
  62 let split2_last l1 l2 =
  63 try
  64    let n = pred (List.length l1) in
  65    let before1, after1 = HEL.split_nth n l1 in
  66    let before2, after2 = HEL.split_nth n l2 in
  67    before1, before2, List.hd after1, List.hd after2
  68 with Invalid_argument _ -> failwith "A2P.split2_last"
  69
  70 let string_of_head = function
  71    | C.ASort _         -> "sort"
  72    | C.AConst _        -> "const"
  73    | C.AMutInd _       -> "mutind"
  74    | C.AMutConstruct _ -> "mutconstruct"
  75    | C.AVar _          -> "var"
  76    | C.ARel _          -> "rel"
  77    | C.AProd _         -> "prod"
  78    | C.ALambda _       -> "lambda"
  79    | C.ALetIn _        -> "letin"
  80    | C.AFix _          -> "fix"
  81    | C.ACoFix _        -> "cofix"
  82    | C.AAppl _         -> "appl"
  83    | C.ACast _         -> "cast"
  84    | C.AMutCase _      -> "mutcase"
  85    | C.AMeta _         -> "meta"
  86    | C.AImplicit _     -> "implict"
  87
  88 let next st = {st with depth = succ st.depth}
  89
  90 let add st entry = {st with context = entry :: st.context}
  91
  92 let push st = {st with case = 1 :: st.case}
  93
  94 let inc st =
  95    {st with case = match st.case with
  96       | []       -> []
  97       | hd :: tl -> succ hd :: tl
  98    }
  99
 100 let case st str =
 101    let case = String.concat "." (List.rev_map string_of_int st.case) in
 102    Printf.sprintf "case %s: %s" case str
 103
 104 let test_depth st =
 105 try
 106    let msg = Printf.sprintf "Depth %u: " st.depth in
 107    match st.max_depth with
 108       | None   -> true, ""
 109       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 110 with Invalid_argument _ -> failwith "A2P.test_depth"
 111
 112 let is_rewrite_right = function
 113    | C.AConst (_, uri, []) ->
 114       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 115    | _                     -> false
 116
 117 let is_rewrite_left = function
 118    | C.AConst (_, uri, []) ->
 119       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 120    | _                     -> false
 121
 122 let is_fwd_rewrite_right hd tl =
 123    if is_rewrite_right hd then match List.nth tl 3 with
 124       | C.ARel _ -> true
 125       | _        -> false
 126    else false
 127
 128 let is_fwd_rewrite_left hd tl =
 129    if is_rewrite_left hd then match List.nth tl 3 with
 130       | C.ARel _ -> true
 131       | _        -> false
 132    else false
 133
 134 let get_inner_types st v =
 135 try
 136    let id = Ut.id_of_annterm v in
 137    try match Hashtbl.find st.types id with
 138       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 139       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 140    with Not_found -> None
 141 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 142
 143 let is_proof st v =
 144 try
 145    let id = Ut.id_of_annterm v in
 146    try match Hashtbl.find st.sorts id with
 147       | `Prop -> true
 148       | _     -> false
 149    with Not_found -> H.is_proof st.context (H.cic v)
 150 with Invalid_argument _ -> failwith "P1.is_proof"
 151
 152 let get_entry st id =
 153    let rec aux = function
 154       | []                                        -> assert false
 155       | Some (C.Name name, e) :: _ when name = id -> e
 156       | _ :: tl                                   -> aux tl
 157    in
 158    aux st.context
 159
 160 let string_of_atomic = function
 161    | C.ARel (_, _, _, s)               -> s
 162    | C.AVar (_, uri, _)                -> H.name_of_uri uri None None
 163    | C.AConst (_, uri, _)              -> H.name_of_uri uri None None
 164    | C.AMutInd (_, uri, i, _)          -> H.name_of_uri uri (Some i) None
 165    | C.AMutConstruct (_, uri, i, j, _) -> H.name_of_uri uri (Some i) (Some j)
 166    | _                                 -> ""
 167
 168 let get_sub_names head l =
 169    let s = string_of_atomic head in
 170    if s = "" then [] else
 171    let map (names, i) _ =
 172       let name = Printf.sprintf "%s_%u" s i in name :: names, succ i
 173    in
 174    let names, _ = List.fold_left map ([], 1) l in
 175    List.rev names
 176
 177 let get_type msg st t = H.get_type msg st.context (H.cic t)
 178
 179 (* proof construction *******************************************************)
 180
 181 let anonymous_premise = C.Name "UNNAMED"
 182
 183 let mk_exp_args hd tl classes synth =
 184    let meta id = C.AImplicit (id, None) in
 185    let map v (cl, b) =
 186       if I.overlaps synth cl && b then v else meta ""
 187    in
 188    let rec aux b = function
 189       | [] -> b, []
 190       | hd :: tl ->
 191          if hd = meta "" then aux true tl else b, List.rev (hd :: tl)
 192    in
 193    let args = T.list_rev_map2 map tl classes in
 194    let b, args = aux false args in
 195    if args = [] then b, hd else b, C.AAppl ("", hd :: args)
 196
 197 let mk_convert st ?name sty ety note =
 198    let e = Cn.hole "" in
 199    let csty, cety = H.cic sty, H.cic ety in
 200    let script =
 201       if !debug then
 202          let sname = match name with None -> "" | Some (id, _) -> id in
 203          let note = Printf.sprintf "%s: %s\nSINTH: %s\nEXP: %s"
 204             note sname (Pp.ppterm csty) (Pp.ppterm cety)
 205          in
 206          [T.Note note]
 207       else []
 208    in
 209    assert (Ut.is_sober st.context csty);
 210    assert (Ut.is_sober st.context cety);
 211    if Ut.alpha_equivalence csty cety then script else
 212    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 213    match name with
 214       | None         -> T.Change (sty, ety, None, e, "") :: script
 215       | Some (id, i) ->
 216          begin match get_entry st id with
 217             | C.Def _  -> assert false (* T.ClearBody (id, "") :: script *)
 218             | C.Decl _ ->
 219                T.Change (ety, sty, Some (id, Some id), e, "") :: script
 220          end
 221
 222 let convert st ?name v =
 223    match get_inner_types st v with
 224       | None            ->
 225          if !debug then [T.Note "NORMAL: NO INNER TYPES"] else []
 226       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 227
 228 let get_intro = function
 229    | C.Anonymous -> None
 230    | C.Name s    -> Some s
 231
 232 let mk_preamble st what script = match script with
 233    | T.Exact _ :: _ -> script
 234    | _              -> convert st what @ script
 235
 236 let mk_arg st = function
 237    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 238    | _                              -> []
 239
 240 let mk_fwd_rewrite st dtext name tl direction v t ity =
 241    let compare premise = function
 242       | None   -> true
 243       | Some s -> s = premise
 244    in
 245    assert (List.length tl = 6);
 246    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 247    let e = Cn.mk_pattern 1 predicate in
 248    if (Cn.does_not_occur e) then st, [] else
 249    match where with
 250       | C.ARel (_, _, i, premise) as w ->
 251          let script name =
 252             let where = Some (premise, name) in
 253             let script = mk_arg st what @ mk_arg st w in
 254             T.Rewrite (direction, what, where, e, dtext) :: script
 255          in
 256          if DTI.does_not_occur (succ i) (H.cic t) || compare premise name then
 257             {st with context = Cn.clear st.context premise}, script name
 258          else begin
 259             assert (Ut.is_sober st.context (H.cic ity));
 260             let ity = H.acic_bc st.context ity in
 261             let br1 = [T.Id ""] in
 262             let br2 = List.rev (T.Exact (w, "assumption") :: script None) in
 263             let text = "non-linear rewrite" in
 264             st, [T.Branch ([br2; br1], ""); T.Cut (name, ity, text)]
 265          end
 266       | _                         -> assert false
 267
 268 let mk_rewrite st dtext where qs tl direction t =
 269    assert (List.length tl = 5);
 270    let predicate = List.nth tl 2 in
 271    let e = Cn.mk_pattern 1 predicate in
 272    let script = [T.Branch (qs, "")] in
 273    if (Cn.does_not_occur e) then script else
 274    T.Rewrite (direction, where, None, e, dtext) :: script
 275
 276 let rec proc_lambda st what name v t =
 277    let name = match name with
 278       | C.Anonymous -> H.mk_fresh_name true st.context anonymous_premise
 279       | name        -> name
 280    in
 281    let entry = Some (name, C.Decl (H.cic v)) in
 282    let intro = get_intro name in
 283    let script = proc_proof (add st entry) t in
 284    let script = T.Intros (Some 1, [intro], "") :: script in
 285    mk_preamble st what script
 286
 287 and proc_letin st what name v w t =
 288    let intro = get_intro name in
 289    let proceed, dtext = test_depth st in
 290    let script = if proceed then
 291       let st, hyp, rqv = match get_inner_types st v with
 292          | Some (ity, _) ->
 293             let st, rqv = match v with
 294                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 295                   mk_fwd_rewrite st dtext intro tl true v t ity
 296                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 297                   mk_fwd_rewrite st dtext intro tl false v t ity
 298                | v                                                     ->
 299                   assert (Ut.is_sober st.context (H.cic ity));
 300                   let ity = H.acic_bc st.context ity in
 301                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 302                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 303             in
 304             st, C.Decl (H.cic ity), rqv
 305          | None          ->
 306             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 307       in
 308       let entry = Some (name, hyp) in
 309       let qt = proc_proof (next (add st entry)) t in
 310       List.rev_append rqv qt
 311    else
 312       [T.Exact (what, dtext)]
 313    in
 314    mk_preamble st what script
 315
 316 and proc_rel st what =
 317    let _, dtext = test_depth st in
 318    let text = "assumption" in
 319    let script = [T.Exact (what, dtext ^ text)] in
 320    mk_preamble st what script
 321
 322 and proc_mutconstruct st what =
 323    let _, dtext = test_depth st in
 324    let script = [T.Exact (what, dtext)] in
 325    mk_preamble st what script
 326
 327 and proc_const st what =
 328    let _, dtext = test_depth st in
 329    let script = [T.Exact (what, dtext)] in
 330    mk_preamble st what script
 331
 332 and proc_appl st what hd tl =
 333    let proceed, dtext = test_depth st in
 334    let script = if proceed then
 335       let ty = match get_inner_types st hd with
 336          | Some (ity, _) -> H.cic ity
 337          | None          -> get_type "TC2" st hd
 338       in
 339       let classes, rc = Cl.classify st.context ty in
 340       let goal_arity, goal = match get_inner_types st what with
 341          | None            -> 0, None
 342          | Some (ity, ety) ->
 343            snd (PEH.split_with_whd (st.context, H.cic ity)), Some (H.cic ety)
 344       in
 345       let parsno, argsno = List.length classes, List.length tl in
 346       let decurry = parsno - argsno in
 347       let diff = goal_arity - decurry in
 348       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 349       let classes = Cl.adjust st.context tl ?goal classes in
 350       let rec mk_synth a n =
 351          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 352       in
 353       let synth = mk_synth I.S.empty decurry in
 354       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 355       let script = List.rev (mk_arg st hd) in
 356       let tactic b t n = if b then T.Apply (t, n) else T.Exact (t, n) in
 357       match rc with
 358          | Some (i, j, uri, tyno) ->
 359             let classes2, tl2, _, where = split2_last classes tl in
 360             let script2 = List.rev (mk_arg st where) @ script in
 361             let synth2 = I.S.add 1 synth in
 362             let names = H.get_ind_names uri tyno in
 363             let qs = proc_bkd_proofs (next st) synth2 names classes2 tl2 in
 364             if List.length qs <> List.length names then
 365                let qs = proc_bkd_proofs (next st) synth [] classes tl in
 366                let b, hd = mk_exp_args hd tl classes synth in
 367                script @ [tactic b hd (dtext ^ text); T.Branch (qs, "")]
 368             else if is_rewrite_right hd then
 369                script2 @ mk_rewrite st dtext where qs tl2 false what
 370             else if is_rewrite_left hd then
 371                script2 @ mk_rewrite st dtext where qs tl2 true what
 372             else
 373                let predicate = List.nth tl2 (parsno - i) in
 374                let e = Cn.mk_pattern j predicate in
 375                let using = Some hd in
 376                script2 @
 377                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 378          | None        ->
 379             let names = get_sub_names hd tl in
 380             let qs = proc_bkd_proofs (next st) synth names classes tl in
 381             let b, hd = mk_exp_args hd tl classes synth in
 382             script @ [tactic b hd (dtext ^ text); T.Branch (qs, "")]
 383    else
 384       [T.Exact (what, dtext)]
 385    in
 386    mk_preamble st what script
 387
 388 and proc_case st what uri tyno u v ts =
 389    let proceed, dtext = test_depth st in
 390    let script = if proceed then
 391       let synth, classes = I.S.empty, Cl.make ts in
 392       let names = H.get_ind_names uri tyno in
 393       let qs = proc_bkd_proofs (next st) synth names classes ts in
 394       let lpsno, _ = H.get_ind_type uri tyno in
 395       let ps, _ = H.get_ind_parameters st.context (H.cic v) in
 396       let _, rps = HEL.split_nth lpsno ps in
 397       let rpsno = List.length rps in
 398       let e = Cn.mk_pattern rpsno u in
 399       let text = "" in
 400       let script = List.rev (mk_arg st v) in
 401       script @ [T.Cases (v, e, dtext ^ text); T.Branch (qs, "")]
 402    else
 403       [T.Exact (what, dtext)]
 404    in
 405    mk_preamble st what script
 406
 407 and proc_other st what =
 408    let _, dtext = test_depth st in
 409    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 410    let script = [T.Exact (what, dtext ^ text)] in
 411    mk_preamble st what script
 412
 413 and proc_proof st t =
 414    let f st =
 415       let xtypes, note = match get_inner_types st t with
 416          | Some (it, et) -> Some (H.cic it, H.cic et),
 417           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 418           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 419          | None          -> None, "\nNo types"
 420       in
 421       let context, _clears = Cn.get_clears st.context (H.cic t) xtypes in
 422       {st with context = context}
 423    in
 424    match t with
 425       | C.ALambda (_, name, w, t) as what        -> proc_lambda (f st) what name w t
 426       | C.ALetIn (_, name, v, w, t) as what      -> proc_letin (f st) what name v w t
 427       | C.ARel _ as what                         -> proc_rel (f st) what
 428       | C.AMutConstruct _ as what                -> proc_mutconstruct (f st) what
 429       | C.AConst _ as what                       -> proc_const (f st) what
 430       | C.AAppl (_, hd :: tl) as what            -> proc_appl (f st) what hd tl
 431 (* FG: we deactivate the tactic "cases" because it does not work properly
 432       | C.AMutCase (_, uri, i, u, v, ts) as what -> proc_case (f st) what uri i u v ts
 433 *)
 434       | what                                     -> proc_other (f st) what
 435
 436 and proc_bkd_proofs st synth names classes ts =
 437 try
 438    let get_names b = ref (names, if b then push st else st) in
 439    let get_note f b names =
 440       match !names with
 441          | [], st       -> f st
 442          | "" :: tl, st -> names := tl, st; f st
 443          | hd :: tl, st ->
 444             let note = case st hd in
 445             names := tl, inc st;
 446             if b then T.Note note :: f st else f st
 447    in
 448    let _, dtext = test_depth st in
 449    let aux (inv, _) v =
 450       if I.overlaps synth inv then None else
 451       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 452       Some (get_note (fun _ -> [T.Exact (v, dtext ^ "dependent")]))
 453    in
 454    let ps = T.list_map2_filter aux classes ts in
 455    let b = List.length ps > 1 in
 456    let names = get_names b in
 457    List.rev_map (fun f -> f b names) ps
 458
 459 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 460
 461 (* object costruction *******************************************************)
 462
 463 let th_flavours = [`Theorem; `Lemma; `Remark; `Fact]
 464
 465 let def_flavours = [`Definition]
 466
 467 let get_flavour ?flavour st v attrs =
 468    let rec aux = function
 469       | []               ->
 470          if is_proof st v then List.hd th_flavours else List.hd def_flavours
 471       | `Flavour fl :: _ -> fl
 472       | _ :: tl          -> aux tl
 473    in
 474    match flavour with
 475       | Some fl -> fl
 476       | None    -> aux attrs
 477
 478 let proc_obj ?flavour ?(info="") st = function
 479    | C.AConstant (_, _, s, Some v, t, [], attrs)         ->
 480       begin match get_flavour ?flavour st v attrs with
 481          | flavour when List.mem flavour th_flavours  ->
 482             let ast = proc_proof st v in
 483             let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 484             let text = Printf.sprintf "%s\n%s%s: %u\n%s: %u\n%s"
 485                "COMMENTS" info "Tactics" steps "Final nodes" nodes "END"
 486             in
 487             T.Statement (flavour, Some s, t, None, "") :: ast @ [T.Qed text]
 488          | flavour when List.mem flavour def_flavours ->
 489             [T.Statement (flavour, Some s, t, Some v, "")]
 490          | _                                  ->
 491             failwith "not a theorem, definition, axiom or inductive type"
 492       end
 493    | C.AConstant (_, _, s, None, t, [], attrs)           ->
 494       [T.Statement (`Axiom, Some s, t, None, "")]
 495    | C.AInductiveDefinition (_, types, [], lpsno, attrs) ->
 496       [T.Inductive (types, lpsno, "")]
 497    | _                                          ->
 498       failwith "not a theorem, definition, axiom or inductive type"
 499
 500 let init ~ids_to_inner_sorts ~ids_to_inner_types ?depth context =
 501    {
 502       sorts       = ids_to_inner_sorts;
 503       types       = ids_to_inner_types;
 504       max_depth   = depth;
 505       depth       = 0;
 506       context     = context;
 507       case        = []
 508    }