helm/software/components/acic_procedural/proceduralConversion.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module E    = CicEnvironment
  28 module Un   = CicUniv
  29 module TC   = CicTypeChecker
  30 module UM   = UriManager
  31 module Rd   = CicReduction
  32 module PEH  = ProofEngineHelpers
  33 module PT   = PrimitiveTactics
  34 module DTI  = DoubleTypeInference
  35
  36 module H    = ProceduralHelpers
  37
  38 (* helpers ******************************************************************)
  39
  40 let rec list_sub start length = function
  41    | _  :: tl when start  > 0 -> list_sub (pred start) length tl
  42    | hd :: tl when length > 0 -> hd :: list_sub start (pred length) tl
  43    | _                        -> []
  44
  45 (* proof construction *******************************************************)
  46
  47 let lift k n =
  48    let rec lift_xns k (uri, t) = uri, lift_term k t
  49    and lift_ms k = function
  50       | None   -> None
  51       | Some t -> Some (lift_term k t)
  52    and lift_fix len k (id, name, i, ty, bo) =
  53       id, name, i, lift_term k ty, lift_term (k + len) bo
  54    and lift_cofix len k (id, name, ty, bo) =
  55       id, name, lift_term k ty, lift_term (k + len) bo
  56    and lift_term k = function
  57       | C.ASort _ as t -> t
  58       | C.AImplicit _ as t -> t
  59       | C.ARel (id, rid, m, b) as t ->
  60          if m < k then t else
  61          if m + n > 0 then C.ARel (id, rid, m + n, b) else
  62          assert false
  63       | C.AConst (id, uri, xnss) -> C.AConst (id, uri, List.map (lift_xns k) xnss)
  64       | C.AVar (id, uri, xnss) -> C.AVar (id, uri, List.map (lift_xns k) xnss)
  65       | C.AMutInd (id, uri, tyno, xnss) -> C.AMutInd (id, uri, tyno, List.map (lift_xns k) xnss)
  66       | C.AMutConstruct (id, uri, tyno, consno, xnss) -> C.AMutConstruct (id, uri,tyno,consno, List.map (lift_xns k) xnss)
  67       | C.AMeta (id, i, mss) -> C.AMeta(id, i, List.map (lift_ms k) mss)
  68       | C.AAppl (id, ts) -> C.AAppl (id, List.map (lift_term k) ts)
  69       | C.ACast (id, te, ty) -> C.ACast (id, lift_term k te, lift_term k ty)
  70       | C.AMutCase (id, sp, i, outty, t, pl) -> C.AMutCase (id, sp, i, lift_term k outty, lift_term k t, List.map (lift_term k) pl)
  71       | C.AProd (id, n, s, t) -> C.AProd (id, n, lift_term k s, lift_term (succ k) t)
  72       | C.ALambda (id, n, s, t) -> C.ALambda (id, n, lift_term k s, lift_term (succ k) t)
  73       | C.ALetIn (id, n, ty, s, t) -> C.ALetIn (id, n, lift_term k ty, lift_term k s, lift_term (succ k) t)
  74       | C.AFix (id, i, fl) -> C.AFix (id, i, List.map (lift_fix (List.length fl) k) fl)
  75       | C.ACoFix (id, i, fl) -> C.ACoFix (id, i, List.map (lift_cofix (List.length fl) k) fl)
  76    in
  77    lift_term k
  78
  79    let fake_annotate id c =
  80       let get_binder c m =
  81          try match List.nth c (pred m) with
  82             | Some (C.Name s, _) -> s
  83             | _ -> assert false
  84          with
  85             | Invalid_argument _ -> assert false
  86       in
  87       let mk_decl n v = Some (n, C.Decl v) in
  88       let mk_def n v ty = Some (n, C.Def (v, ty)) in
  89       let mk_fix (name, _, ty, bo) = mk_def (C.Name name) bo ty in
  90       let mk_cofix (name, ty, bo) = mk_def (C.Name name) bo ty in
  91       let rec ann_xns c (uri, t) = uri, ann_term c t
  92       and ann_ms c = function
  93          | None -> None
  94          | Some t -> Some (ann_term c t)
  95       and ann_fix newc c (name, i, ty, bo) =
  96          id, name, i, ann_term c ty, ann_term (List.rev_append newc c) bo
  97       and ann_cofix newc c (name, ty, bo) =
  98          id, name, ann_term c ty, ann_term (List.rev_append newc c) bo
  99       and ann_term c = function
 100          | C.Sort sort -> C.ASort (id, sort)
 101          | C.Implicit ann -> C.AImplicit (id, ann)
 102          | C.Rel m -> C.ARel (id, id, m, get_binder c m)
 103          | C.Const (uri, xnss) -> C.AConst (id, uri, List.map (ann_xns c) xnss)
 104          | C.Var (uri, xnss) -> C.AVar (id, uri, List.map (ann_xns c) xnss)
 105          | C.MutInd (uri, tyno, xnss) -> C.AMutInd (id, uri, tyno, List.map (ann_xns c) xnss)
 106          | C.MutConstruct (uri, tyno, consno, xnss) -> C.AMutConstruct (id, uri,tyno,consno, List.map (ann_xns c) xnss)
 107          | C.Meta (i, mss) -> C.AMeta(id, i, List.map (ann_ms c) mss)
 108          | C.Appl ts -> C.AAppl (id, List.map (ann_term c) ts)
 109          | C.Cast (te, ty) -> C.ACast (id, ann_term c te, ann_term c ty)
 110          | C.MutCase (sp, i, outty, t, pl) -> C.AMutCase (id, sp, i, ann_term c outty, ann_term c t, List.map (ann_term c) pl)
 111          | C.Prod (n, s, t) -> C.AProd (id, n, ann_term c s, ann_term (mk_decl n s :: c) t)
 112          | C.Lambda (n, s, t) -> C.ALambda (id, n, ann_term c s, ann_term (mk_decl n s :: c) t)
 113          | C.LetIn (n, s, ty, t) -> C.ALetIn (id, n, ann_term c s, ann_term c ty, ann_term (mk_def n s ty :: c) t)
 114          | C.Fix (i, fl) -> C.AFix (id, i, List.map (ann_fix (List.rev_map mk_fix fl) c) fl)
 115          | C.CoFix (i, fl) -> C.ACoFix (id, i, List.map (ann_cofix (List.rev_map mk_cofix fl) c) fl)
 116       in
 117       ann_term c
 118
 119 let clear_absts m =
 120    let rec aux k n = function
 121       | C.AImplicit (_, None) as t         -> t
 122       | C.ALambda (id, s, v, t) when k > 0 ->
 123          C.ALambda (id, s, v, aux (pred k) n t)
 124       | C.ALambda (_, _, _, t) when n > 0  ->
 125          aux 0 (pred n) (lift 1 (-1) t)
 126       | t                      when n > 0  ->
 127             Printf.eprintf "CLEAR: %u %s\n" n (CicPp.ppterm (H.cic t));
 128             assert false
 129       | t                                  -> t
 130    in
 131    aux m
 132
 133 let hole id = C.AImplicit (id, Some `Hole)
 134
 135 let meta id = C.AImplicit (id, None)
 136
 137 let anon = C.Anonymous
 138
 139 let generalize n =
 140    let is_meta =
 141       let map b = function
 142          | C.AImplicit (_, None) when b -> b
 143          | _                            -> false
 144       in
 145       List.fold_left map true
 146    in
 147    let rec gen_fix len k (id, name, i, ty, bo) =
 148       id, name, i, gen_term k ty, gen_term (k + len) bo
 149    and gen_cofix len k (id, name, ty, bo) =
 150       id, name, gen_term k ty, gen_term (k + len) bo
 151    and gen_term k = function
 152       | C.ASort (id, _)
 153       | C.AImplicit (id, _)
 154       | C.AConst (id, _, _)
 155       | C.AVar (id, _, _)
 156       | C.AMutInd (id, _, _, _)
 157       | C.AMutConstruct (id, _, _, _, _)
 158       | C.AMeta (id, _, _) -> meta id
 159       | C.ARel (id, _, m, _) ->
 160          if succ (k - n) <= m && m <= k then hole id else meta id
 161       | C.AAppl (id, ts) ->
 162          let ts = List.map (gen_term k) ts in
 163          if is_meta ts then meta id else C.AAppl (id, ts)
 164       | C.ACast (id, te, ty) ->
 165          let te, ty = gen_term k te, gen_term k ty in
 166          if is_meta [te; ty] then meta id else C.ACast (id, te, ty)
 167       | C.AMutCase (id, sp, i, outty, t, pl) ->
 168          let outty, t, pl = gen_term k outty, gen_term k t, List.map (gen_term k) pl in
 169          if is_meta (outty :: t :: pl) then meta id else hole id (* C.AMutCase (id, sp, i, outty, t, pl) *)
 170       | C.AProd (id, _, s, t) ->
 171          let s, t = gen_term k s, gen_term (succ k) t in
 172          if is_meta [s; t] then meta id else C.AProd (id, anon, s, t)
 173       | C.ALambda (id, _, s, t) ->
 174          let s, t = gen_term k s, gen_term (succ k) t in
 175          if is_meta [s; t] then meta id else C.ALambda (id, anon, s, t)
 176       | C.ALetIn (id, _, s, ty, t) ->
 177          let s, ty, t = gen_term k s, gen_term k ty, gen_term (succ k) t in
 178          if is_meta [s; t] then meta id else C.ALetIn (id, anon, s, ty, t)
 179       | C.AFix (id, i, fl) -> C.AFix (id, i, List.map (gen_fix (List.length fl) k) fl)
 180       | C.ACoFix (id, i, fl) -> C.ACoFix (id, i, List.map (gen_cofix (List.length fl) k) fl)
 181    in
 182    gen_term 0
 183
 184 let mk_pattern psno predicate =
 185    let body = generalize psno predicate in
 186    clear_absts 0 psno body
 187
 188 let get_clears c p xtypes =
 189    let meta = C.Implicit None in
 190    let rec aux c names p it et = function
 191       | []                                                ->
 192          List.rev c, List.rev names
 193       | Some (C.Name name as n, C.Decl v) as hd :: tl     ->
 194          let hd, names, v =
 195             if DTI.does_not_occur 1 p && DTI.does_not_occur 1 it && DTI.does_not_occur 1 et then
 196                Some (C.Anonymous, C.Decl v), name :: names, meta
 197             else
 198                hd, names, v
 199          in
 200          let p = C.Lambda (n, v, p) in
 201          let it = C.Prod (n, v, it) in
 202          let et = C.Prod (n, v, et) in
 203          aux (hd :: c) names p it et tl
 204       | Some (C.Name name as n, C.Def (v, x)) as hd :: tl ->
 205          let hd, names, v =
 206             if DTI.does_not_occur 1 p && DTI.does_not_occur 1 it && DTI.does_not_occur 1 et then
 207                Some (C.Anonymous, C.Def (v, x)), name :: names, meta
 208             else
 209                hd, names, v
 210          in
 211          let p = C.LetIn (n, v, x, p) in
 212          let it = C.LetIn (n, v, x, it) in
 213          let et = C.LetIn (n, v, x, et) in
 214          aux (hd :: c) names p it et tl
 215       | Some (C.Anonymous as n, C.Decl v) as hd :: tl     ->
 216          let p = C.Lambda (n, meta, p) in
 217          let it = C.Lambda (n, meta, it) in
 218          let et = C.Lambda (n, meta, et) in
 219          aux (hd :: c) names p it et tl
 220       | Some (C.Anonymous as n, C.Def (v, _)) as hd :: tl ->
 221          let p = C.LetIn (n, meta, meta, p) in
 222          let it = C.LetIn (n, meta, meta, it) in
 223          let et = C.LetIn (n, meta, meta, et) in
 224          aux (hd :: c) names p it et tl
 225       | None :: tl                                        -> assert false
 226    in
 227    match xtypes with
 228       | Some (it, et) -> aux [] [] p it et c
 229       | None          -> c, []
 230
 231 let clear c hyp =
 232    let rec aux c = function
 233       | []            -> List.rev c
 234       | Some (C.Name name, entry) :: tail when name = hyp ->
 235          aux (Some (C.Anonymous, entry) :: c) tail
 236       | entry :: tail -> aux (entry :: c) tail
 237    in
 238    aux [] c
 239
 240 let elim_inferred_type context goal arg using cpattern =
 241    let metasenv, ugraph = [], Un.default_ugraph in
 242    let ety = H.get_type "elim_inferred_type" context using in
 243    let _splits, args_no = PEH.split_with_whd (context, ety) in
 244    let _metasenv, predicate, _arg, actual_args = PT.mk_predicate_for_elim
 245       ~context ~metasenv ~ugraph ~goal ~arg ~using ~cpattern ~args_no
 246    in
 247    let ty = C.Appl (predicate :: actual_args) in
 248    let upto = List.length actual_args in
 249    Rd.head_beta_reduce ~delta:false ~upto ty
 250
 251 let does_not_occur = function
 252    | C.AImplicit (_, None) -> true
 253    | _                     -> false