helm/software/components/acic_procedural/proceduralConversion.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module E    = CicEnvironment
  28 module Un   = CicUniv
  29 module TC   = CicTypeChecker
  30 module UM   = UriManager
  31 module Rd   = CicReduction
  32 module PEH  = ProofEngineHelpers
  33 module PT   = PrimitiveTactics
  34 module DTI  = DoubleTypeInference
  35
  36 module H    = ProceduralHelpers
  37
  38 (* helpers ******************************************************************)
  39
  40 let rec list_sub start length = function
  41    | _  :: tl when start  > 0 -> list_sub (pred start) length tl
  42    | hd :: tl when length > 0 -> hd :: list_sub start (pred length) tl
  43    | _                        -> []
  44
  45 (* proof construction *******************************************************)
  46
  47 let lift k n =
  48    let rec lift_xns k (uri, t) = uri, lift_term k t
  49    and lift_ms k = function
  50       | None   -> None
  51       | Some t -> Some (lift_term k t)
  52    and lift_fix len k (id, name, i, ty, bo) =
  53       id, name, i, lift_term k ty, lift_term (k + len) bo
  54    and lift_cofix len k (id, name, ty, bo) =
  55       id, name, lift_term k ty, lift_term (k + len) bo
  56    and lift_term k = function
  57       | C.ASort _ as t -> t
  58       | C.AImplicit _ as t -> t
  59       | C.ARel (id, rid, m, b) as t ->
  60          if m < k then t else
  61          if m + n > 0 then C.ARel (id, rid, m + n, b) else
  62          begin
  63             HLog.error (Printf.sprintf "ProceduralConversion.lift: %i %i" m n);
  64             assert false
  65          end
  66       | C.AConst (id, uri, xnss) -> C.AConst (id, uri, List.map (lift_xns k) xnss)
  67       | C.AVar (id, uri, xnss) -> C.AVar (id, uri, List.map (lift_xns k) xnss)
  68       | C.AMutInd (id, uri, tyno, xnss) -> C.AMutInd (id, uri, tyno, List.map (lift_xns k) xnss)
  69       | C.AMutConstruct (id, uri, tyno, consno, xnss) -> C.AMutConstruct (id, uri,tyno,consno, List.map (lift_xns k) xnss)
  70       | C.AMeta (id, i, mss) -> C.AMeta(id, i, List.map (lift_ms k) mss)
  71       | C.AAppl (id, ts) -> C.AAppl (id, List.map (lift_term k) ts)
  72       | C.ACast (id, te, ty) -> C.ACast (id, lift_term k te, lift_term k ty)
  73       | C.AMutCase (id, sp, i, outty, t, pl) -> C.AMutCase (id, sp, i, lift_term k outty, lift_term k t, List.map (lift_term k) pl)
  74       | C.AProd (id, n, s, t) -> C.AProd (id, n, lift_term k s, lift_term (succ k) t)
  75       | C.ALambda (id, n, s, t) -> C.ALambda (id, n, lift_term k s, lift_term (succ k) t)
  76       | C.ALetIn (id, n, ty, s, t) -> C.ALetIn (id, n, lift_term k ty, lift_term k s, lift_term (succ k) t)
  77       | C.AFix (id, i, fl) -> C.AFix (id, i, List.map (lift_fix (List.length fl) k) fl)
  78       | C.ACoFix (id, i, fl) -> C.ACoFix (id, i, List.map (lift_cofix (List.length fl) k) fl)
  79    in
  80    lift_term k
  81
  82    let fake_annotate id c =
  83       let get_binder c m =
  84          try match List.nth c (pred m) with
  85             | Some (C.Name s, _) -> s
  86             | _ -> assert false
  87          with
  88             | Invalid_argument _ -> assert false
  89       in
  90       let mk_decl n v = Some (n, C.Decl v) in
  91       let mk_def n v ty = Some (n, C.Def (v, ty)) in
  92       let mk_fix (name, _, ty, bo) = mk_def (C.Name name) bo ty in
  93       let mk_cofix (name, ty, bo) = mk_def (C.Name name) bo ty in
  94       let rec ann_xns c (uri, t) = uri, ann_term c t
  95       and ann_ms c = function
  96          | None -> None
  97          | Some t -> Some (ann_term c t)
  98       and ann_fix newc c (name, i, ty, bo) =
  99          id, name, i, ann_term c ty, ann_term (List.rev_append newc c) bo
 100       and ann_cofix newc c (name, ty, bo) =
 101          id, name, ann_term c ty, ann_term (List.rev_append newc c) bo
 102       and ann_term c = function
 103          | C.Sort sort -> C.ASort (id, sort)
 104          | C.Implicit ann -> C.AImplicit (id, ann)
 105          | C.Rel m -> C.ARel (id, id, m, get_binder c m)
 106          | C.Const (uri, xnss) -> C.AConst (id, uri, List.map (ann_xns c) xnss)
 107          | C.Var (uri, xnss) -> C.AVar (id, uri, List.map (ann_xns c) xnss)
 108          | C.MutInd (uri, tyno, xnss) -> C.AMutInd (id, uri, tyno, List.map (ann_xns c) xnss)
 109          | C.MutConstruct (uri, tyno, consno, xnss) -> C.AMutConstruct (id, uri,tyno,consno, List.map (ann_xns c) xnss)
 110          | C.Meta (i, mss) -> C.AMeta(id, i, List.map (ann_ms c) mss)
 111          | C.Appl ts -> C.AAppl (id, List.map (ann_term c) ts)
 112          | C.Cast (te, ty) -> C.ACast (id, ann_term c te, ann_term c ty)
 113          | C.MutCase (sp, i, outty, t, pl) -> C.AMutCase (id, sp, i, ann_term c outty, ann_term c t, List.map (ann_term c) pl)
 114          | C.Prod (n, s, t) -> C.AProd (id, n, ann_term c s, ann_term (mk_decl n s :: c) t)
 115          | C.Lambda (n, s, t) -> C.ALambda (id, n, ann_term c s, ann_term (mk_decl n s :: c) t)
 116          | C.LetIn (n, s, ty, t) -> C.ALetIn (id, n, ann_term c s, ann_term c ty, ann_term (mk_def n s ty :: c) t)
 117          | C.Fix (i, fl) -> C.AFix (id, i, List.map (ann_fix (List.rev_map mk_fix fl) c) fl)
 118          | C.CoFix (i, fl) -> C.ACoFix (id, i, List.map (ann_cofix (List.rev_map mk_cofix fl) c) fl)
 119       in
 120       ann_term c
 121
 122 let clear_absts m =
 123    let rec aux k n = function
 124       | C.AImplicit (_, None) as t         -> t
 125       | C.ALambda (id, s, v, t) when k > 0 ->
 126          C.ALambda (id, s, v, aux (pred k) n t)
 127       | C.ALambda (_, _, _, t) when n > 0  ->
 128          aux 0 (pred n) (lift 1 (-1) t)
 129       | t                      when n > 0  ->
 130             Printf.eprintf "CLEAR: %u %s\n" n (CicPp.ppterm (H.cic t));
 131             assert false
 132       | t                                  -> t
 133    in
 134    aux m
 135
 136 let hole id = C.AImplicit (id, Some `Hole)
 137
 138 let meta id = C.AImplicit (id, None)
 139
 140 let anon = C.Anonymous
 141
 142 let generalize n =
 143    let is_meta =
 144       let map b = function
 145          | C.AImplicit (_, None) when b -> b
 146          | _                            -> false
 147       in
 148       List.fold_left map true
 149    in
 150    let rec gen_fix len k (id, name, i, ty, bo) =
 151       id, name, i, gen_term k ty, gen_term (k + len) bo
 152    and gen_cofix len k (id, name, ty, bo) =
 153       id, name, gen_term k ty, gen_term (k + len) bo
 154    and gen_term k = function
 155       | C.ASort (id, _)
 156       | C.AImplicit (id, _)
 157       | C.AConst (id, _, _)
 158       | C.AVar (id, _, _)
 159       | C.AMutInd (id, _, _, _)
 160       | C.AMutConstruct (id, _, _, _, _)
 161       | C.AMeta (id, _, _) -> meta id
 162       | C.ARel (id, _, m, _) ->
 163          if succ (k - n) <= m && m <= k then hole id else meta id
 164       | C.AAppl (id, ts) ->
 165          let ts = List.map (gen_term k) ts in
 166          if is_meta ts then meta id else C.AAppl (id, ts)
 167       | C.ACast (id, te, ty) ->
 168          let te, ty = gen_term k te, gen_term k ty in
 169          if is_meta [te; ty] then meta id else C.ACast (id, te, ty)
 170       | C.AMutCase (id, sp, i, outty, t, pl) ->
 171          let outty, t, pl = gen_term k outty, gen_term k t, List.map (gen_term k) pl in
 172          if is_meta (outty :: t :: pl) then meta id else hole id (* C.AMutCase (id, sp, i, outty, t, pl) *)
 173       | C.AProd (id, _, s, t) ->
 174          let s, t = gen_term k s, gen_term (succ k) t in
 175          if is_meta [s; t] then meta id else C.AProd (id, anon, s, t)
 176       | C.ALambda (id, _, s, t) ->
 177          let s, t = gen_term k s, gen_term (succ k) t in
 178          if is_meta [s; t] then meta id else C.ALambda (id, anon, s, t)
 179       | C.ALetIn (id, _, s, ty, t) ->
 180          let s, ty, t = gen_term k s, gen_term k ty, gen_term (succ k) t in
 181          if is_meta [s; t] then meta id else C.ALetIn (id, anon, s, ty, t)
 182       | C.AFix (id, i, fl) -> C.AFix (id, i, List.map (gen_fix (List.length fl) k) fl)
 183       | C.ACoFix (id, i, fl) -> C.ACoFix (id, i, List.map (gen_cofix (List.length fl) k) fl)
 184    in
 185    gen_term 0
 186
 187 let mk_pattern psno predicate =
 188    let body = generalize psno predicate in
 189    clear_absts 0 psno body
 190
 191 let get_clears c p xtypes =
 192    let meta = C.Implicit None in
 193    let rec aux c names p it et = function
 194       | []                                                ->
 195          List.rev c, List.rev names
 196       | Some (C.Name name as n, C.Decl v) as hd :: tl     ->
 197          let hd, names, v =
 198             if DTI.does_not_occur 1 p && DTI.does_not_occur 1 it && DTI.does_not_occur 1 et then
 199                Some (C.Anonymous, C.Decl v), name :: names, meta
 200             else
 201                hd, names, v
 202          in
 203          let p = C.Lambda (n, v, p) in
 204          let it = C.Prod (n, v, it) in
 205          let et = C.Prod (n, v, et) in
 206          aux (hd :: c) names p it et tl
 207       | Some (C.Name name as n, C.Def (v, x)) as hd :: tl ->
 208          let hd, names, v =
 209             if DTI.does_not_occur 1 p && DTI.does_not_occur 1 it && DTI.does_not_occur 1 et then
 210                Some (C.Anonymous, C.Def (v, x)), name :: names, meta
 211             else
 212                hd, names, v
 213          in
 214          let p = C.LetIn (n, v, x, p) in
 215          let it = C.LetIn (n, v, x, it) in
 216          let et = C.LetIn (n, v, x, et) in
 217          aux (hd :: c) names p it et tl
 218       | Some (C.Anonymous as n, C.Decl v) as hd :: tl     ->
 219          let p = C.Lambda (n, meta, p) in
 220          let it = C.Lambda (n, meta, it) in
 221          let et = C.Lambda (n, meta, et) in
 222          aux (hd :: c) names p it et tl
 223       | Some (C.Anonymous as n, C.Def (v, _)) as hd :: tl ->
 224          let p = C.LetIn (n, meta, meta, p) in
 225          let it = C.LetIn (n, meta, meta, it) in
 226          let et = C.LetIn (n, meta, meta, et) in
 227          aux (hd :: c) names p it et tl
 228       | None :: tl                                        -> assert false
 229    in
 230    match xtypes with
 231       | Some (it, et) -> aux [] [] p it et c
 232       | None          -> c, []
 233
 234 let clear c hyp =
 235    let rec aux c = function
 236       | []            -> List.rev c
 237       | Some (C.Name name, entry) :: tail when name = hyp ->
 238          aux (Some (C.Anonymous, entry) :: c) tail
 239       | entry :: tail -> aux (entry :: c) tail
 240    in
 241    aux [] c
 242
 243 let elim_inferred_type context goal arg using cpattern =
 244    let metasenv, ugraph = [], Un.default_ugraph in
 245    let ety = H.get_type "elim_inferred_type" context using in
 246    let _splits, args_no = PEH.split_with_whd (context, ety) in
 247    let _metasenv, _subst, predicate, _arg, actual_args =
 248      PT.mk_predicate_for_elim
 249      ~context ~metasenv ~subst:[] ~ugraph ~goal ~arg ~using ~cpattern ~args_no
 250    in
 251    let ty = C.Appl (predicate :: actual_args) in
 252    let upto = List.length actual_args in
 253    Rd.head_beta_reduce ~delta:false ~upto ty
 254
 255 let does_not_occur = function
 256    | C.AImplicit (_, None) -> true
 257    | _                     -> false