helm/software/components/acic_procedural/proceduralHelpers.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module Rf   = CicRefine
  28 module Un   = CicUniv
  29 module Pp   = CicPp
  30 module TC   = CicTypeChecker
  31 module PEH  = ProofEngineHelpers
  32 module E    = CicEnvironment
  33 module UM   = UriManager
  34 module D    = Deannotate
  35 module PER  = ProofEngineReduction
  36 module Ut   = CicUtil
  37
  38 (* fresh name generator *****************************************************)
  39
  40 let split name =
  41    let rec aux i =
  42       if i <= 0 then assert false else
  43       let c = name.[pred i] in
  44       if c >= '0' && c <= '9' then aux (pred i)
  45       else Str.string_before name i, Str.string_after name i
  46    in
  47    let before, after = aux (String.length name) in
  48    let i = if after = "" then -1 else int_of_string after in
  49    before, i
  50
  51 let join (s, i) =
  52    C.Name (if i < 0 then s else s ^ string_of_int i)
  53
  54 let mk_fresh_name context (name, k) =
  55    let rec aux i = function
  56       | []                            -> name, i
  57       | Some (C.Name s, _) :: entries ->
  58          let m, j = split s in
  59          if m = name && j >= i then aux (succ j) entries else aux i entries
  60       | _ :: entries                  -> aux i entries
  61    in
  62    join (aux k context)
  63
  64 let mk_fresh_name context = function
  65    | C.Anonymous -> C.Anonymous
  66    | C.Name s    -> mk_fresh_name context (split s)
  67
  68 (* helper functions *********************************************************)
  69
  70 let rec list_map_cps g map = function
  71    | []       -> g []
  72    | hd :: tl ->
  73       let h hd =
  74          let g tl = g (hd :: tl) in
  75          list_map_cps g map tl
  76       in
  77       map h hd
  78
  79 let identity x = x
  80
  81 let compose f g x = f (g x)
  82
  83 let fst3 (x, _, _) = x
  84
  85 let refine c t =
  86    try let t, _, _, _ = Rf.type_of_aux' [] c t Un.oblivion_ugraph in t
  87    with e ->
  88       Printf.eprintf "REFINE EROR: %s\n" (Printexc.to_string e);
  89       Printf.eprintf "Ref: context: %s\n" (Pp.ppcontext c);
  90       Printf.eprintf "Ref: term   : %s\n" (Pp.ppterm t);
  91       raise e
  92
  93 let get_type c t =
  94    try let ty, _ = TC.type_of_aux' [] c t Un.oblivion_ugraph in ty
  95    with e ->
  96       Printf.eprintf "TC: context: %s\n" (Pp.ppcontext c);
  97       Printf.eprintf "TC: term   : %s\n" (Pp.ppterm t);
  98       raise e
  99
 100 let get_tail c t =
 101    match PEH.split_with_whd (c, t) with
 102       | (_, hd) :: _, _ -> hd
 103       | _               -> assert false
 104
 105 let is_proof c t =
 106    match get_tail c (get_type c (get_type c t)) with
 107       | C.Sort C.Prop -> true
 108       | C.Sort _      -> false
 109       | _             -> assert false
 110
 111 let is_sort = function
 112    | C.Sort _ -> true
 113    | _        -> false
 114
 115 let is_unsafe h (c, t) = true
 116
 117 let is_not_atomic = function
 118    | C.Sort _
 119    | C.Rel _
 120    | C.Const _
 121    | C.Var _
 122    | C.MutInd _
 123    | C.MutConstruct _ -> false
 124    | _                -> true
 125
 126 let is_atomic t = not (is_not_atomic t)
 127
 128 let get_ind_type uri tyno =
 129    match E.get_obj Un.oblivion_ugraph uri with
 130       | C.InductiveDefinition (tys, _, lpsno, _), _ -> lpsno, List.nth tys tyno
 131       | _                                           -> assert false
 132
 133 let get_default_eliminator context uri tyno ty =
 134    let _, (name, _, _, _) = get_ind_type uri tyno in
 135    let ext = match get_tail context (get_type context ty) with
 136       | C.Sort C.Prop     -> "_ind"
 137       | C.Sort C.Set      -> "_rec"
 138       | C.Sort (C.CProp _)   -> "_rect"
 139       | C.Sort (C.Type _) -> "_rect"
 140       | t                 ->
 141          Printf.eprintf "CicPPP get_default_eliminator: %s\n" (Pp.ppterm t);
 142          assert false
 143    in
 144    let buri = UM.buri_of_uri uri in
 145    let uri = UM.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con") in
 146    C.Const (uri, [])
 147
 148 let get_ind_parameters c t =
 149    let ty = get_type c t in
 150    let ps = match get_tail c ty with
 151       | C.MutInd _                  -> []
 152       | C.Appl (C.MutInd _ :: args) -> args
 153       | _                           -> assert false
 154    in
 155    let disp = match get_tail c (get_type c ty) with
 156       | C.Sort C.Prop -> 0
 157       | C.Sort _      -> 1
 158       | _             -> assert false
 159    in
 160    ps, disp
 161
 162 let cic = D.deannotate_term
 163
 164 let occurs c ~what ~where =
 165    let result = ref false in
 166    let equality c t1 t2 =
 167       let r = Ut.alpha_equivalence t1 t2 in
 168       result := !result || r; r
 169    in
 170    let context, what, with_what = c, [what], [C.Rel 0] in
 171    let _ = PER.replace_lifting ~equality ~context ~what ~with_what ~where in
 172    !result
 173
 174 (* Ensuring Barendregt convenction ******************************************)
 175
 176 let rec add_entries map c = function
 177    | []       -> c
 178    | hd :: tl ->
 179       let sname, w = map hd in
 180       let entry = Some (Cic.Name sname, C.Decl w) in
 181       add_entries map (entry :: c) tl
 182
 183 let get_sname c i =
 184    try match List.nth c (pred i) with
 185       | Some (Cic.Name sname, _) -> sname
 186       | _                        -> assert false
 187    with
 188       | Failure _          -> assert false
 189       | Invalid_argument _ -> assert false
 190
 191 let cic_bc c t =
 192    let get_fix_decl (sname, i, w, v) = sname, w in
 193    let get_cofix_decl (sname, w, v) = sname, w in
 194    let rec bc c = function
 195       | C.LetIn (name, v, ty, t) ->
 196          let name = mk_fresh_name c name in
 197          let entry = Some (name, C.Def (v, ty)) in
 198          let v, ty, t = bc c v, bc c ty, bc (entry :: c) t in
 199          C.LetIn (name, v, ty, t)
 200       | C.Lambda (name, w, t) ->
 201          let name = mk_fresh_name c name in
 202          let entry = Some (name, C.Decl w) in
 203          let w, t = bc c w, bc (entry :: c) t in
 204          C.Lambda (name, w, t)
 205       | C.Prod (name, w, t) ->
 206          let name = mk_fresh_name c name in
 207          let entry = Some (name, C.Decl w) in
 208          let w, t = bc c w, bc (entry :: c) t in
 209          C.Prod (name, w, t)
 210       | C.Appl vs ->
 211          let vs = List.map (bc c) vs in
 212          C.Appl vs
 213       | C.MutCase (uri, tyno, u, v, ts) ->
 214          let u, v, ts = bc c u, bc c v, List.map (bc c) ts in
 215          C.MutCase (uri, tyno, u, v, ts)
 216       | C.Cast (t, u) ->
 217          let t, u = bc c t, bc c u in
 218          C.Cast (t, u)
 219       | C.Fix (i, fixes) ->
 220          let d = add_entries get_fix_decl c fixes in
 221          let bc_fix (sname, i, w, v) = (sname, i, bc c w, bc d v) in
 222          let fixes = List.map bc_fix fixes in
 223          C.Fix (i, fixes)
 224       | C.CoFix (i, cofixes) ->
 225          let d = add_entries get_cofix_decl c cofixes in
 226          let bc_cofix (sname, w, v) = (sname, bc c w, bc d v) in
 227          let cofixes = List.map bc_cofix cofixes in
 228          C.CoFix (i, cofixes)
 229       | t -> t
 230    in
 231    bc c t
 232
 233 let acic_bc c t =
 234    let get_fix_decl (id, sname, i, w, v) = sname, cic w in
 235    let get_cofix_decl (id, sname, w, v) = sname, cic w in
 236    let rec bc c = function
 237       | C.ALetIn (id, name, v, ty, t) ->
 238          let name = mk_fresh_name c name in
 239          let entry = Some (name, C.Def (cic v, cic ty)) in
 240          let v, ty, t = bc c v, bc c ty, bc (entry :: c) t in
 241          C.ALetIn (id, name, v, ty, t)
 242       | C.ALambda (id, name, w, t) ->
 243          let name = mk_fresh_name c name in
 244          let entry = Some (name, C.Decl (cic w)) in
 245          let w, t = bc c w, bc (entry :: c) t in
 246          C.ALambda (id, name, w, t)
 247       | C.AProd (id, name, w, t) ->
 248          let name = mk_fresh_name c name in
 249          let entry = Some (name, C.Decl (cic w)) in
 250          let w, t = bc c w, bc (entry :: c) t in
 251          C.AProd (id, name, w, t)
 252       | C.AAppl (id, vs) ->
 253          let vs = List.map (bc c) vs in
 254          C.AAppl (id, vs)
 255       | C.AMutCase (id, uri, tyno, u, v, ts) ->
 256          let u, v, ts = bc c u, bc c v, List.map (bc c) ts in
 257          C.AMutCase (id, uri, tyno, u, v, ts)
 258       | C.ACast (id, t, u) ->
 259          let t, u = bc c t, bc c u in
 260          C.ACast (id, t, u)
 261       | C.AFix (id, i, fixes) ->
 262          let d = add_entries get_fix_decl c fixes in
 263          let bc_fix (id, sname, i, w, v) = (id, sname, i, bc c w, bc d v) in
 264          let fixes = List.map bc_fix fixes in
 265          C.AFix (id, i, fixes)
 266       | C.ACoFix (id, i, cofixes) ->
 267          let d = add_entries get_cofix_decl c cofixes in
 268          let bc_cofix (id, sname, w, v) = (id, sname, bc c w, bc d v) in
 269          let cofixes = List.map bc_cofix cofixes in
 270          C.ACoFix (id, i, cofixes)
 271       | C.ARel (id1, id2, i, sname) ->
 272          let sname = get_sname c i in
 273          C.ARel (id1, id2, i, sname)
 274       | t -> t
 275    in
 276    bc c t