helm/software/components/acic_procedural/proceduralOptimizer.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module UM   = UriManager
  27 module C    = Cic
  28 module Pp   = CicPp
  29 module I    = CicInspect
  30 module E    = CicEnvironment
  31 module S    = CicSubstitution
  32 module DTI  = DoubleTypeInference
  33 module HEL  = HExtlib
  34 module PEH  = ProofEngineHelpers
  35 module TC   = CicTypeChecker
  36 module Un   = CicUniv
  37 module L    = Librarian
  38 module Ut   = CicUtil
  39
  40 module H    = ProceduralHelpers
  41 module Cl   = ProceduralClassify
  42
  43 (* debugging ****************************************************************)
  44
  45 let debug = ref false
  46
  47 (* term optimization ********************************************************)
  48
  49 let critical = ref true
  50
  51 type status = {
  52    dummy: unit;
  53    info: string
  54 }
  55
  56 let info st str = {st with info = st.info ^ str ^ "\n"}
  57
  58 let defined_premise = "LOCAL"
  59
  60 let define c v =
  61    let name = C.Name defined_premise in
  62    let ty = H.get_type "define" c v in
  63    C.LetIn (name, v, ty, C.Rel 1)
  64
  65 let clear_absts m =
  66    let rec aux k n = function
  67       | C.Lambda (s, v, t) when k > 0 ->
  68          C.Lambda (s, v, aux (pred k) n t)
  69       | C.Lambda (_, _, t) when n > 0 ->
  70          aux 0 (pred n) (S.lift (-1) t)
  71       | t                  when n > 0 ->
  72          Printf.eprintf "PO.clear_absts: %u %s\n" n (Pp.ppterm t);
  73          assert false
  74       | t                             -> t
  75    in
  76    aux m
  77
  78 let rec add_abst k = function
  79    | C.Lambda (s, v, t) when k > 0 -> C.Lambda (s, v, add_abst (pred k) t)
  80    | t when k > 0 -> assert false
  81    | t -> C.Lambda (C.Anonymous, C.Implicit None, S.lift 1 t)
  82
  83 let rec opt_letin g st es c name v w t =
  84    let name = H.mk_fresh_name c name in
  85    let entry = Some (name, C.Def (v, w)) in
  86    let g st t =
  87       if DTI.does_not_occur 1 t then
  88          let x = S.lift (-1) t in
  89          opt_proof g (info st "Optimizer: remove 1") true c x
  90       else
  91       let g st = function
  92          | C.LetIn (nname, vv, ww, tt) when H.is_proof c v ->
  93             let eentry = Some (nname, C.Def (vv, ww)) in
  94             let ttw = H.get_type "opt_letin 1" (eentry :: c) tt in
  95             let x = C.LetIn (nname, vv, ww,
  96              C.LetIn (name, tt, ttw, S.lift_from 2 1 t))
  97             in
  98             opt_proof g (info st "Optimizer: swap 1") true c x
  99          | v when H.is_proof c v && H.is_atomic v          ->
 100             let x = S.subst v t in
 101             opt_proof g (info st "Optimizer: remove 5") true c x
 102          | v                                               ->
 103             g st (C.LetIn (name, v, w, t))
 104       in
 105       if es then opt_term g st es c v else g st v
 106    in
 107    if es then opt_proof g st es (entry :: c) t else g st t
 108
 109 and opt_lambda g st es c name w t =
 110    let name = H.mk_fresh_name c name in
 111    let entry = Some (name, C.Decl w) in
 112    let g st t = g st (C.Lambda (name, w, t)) in
 113    if es then opt_proof g st es (entry :: c) t else g st t
 114
 115 and opt_appl g st es c t vs =
 116    let g (st, vs) =
 117       let g st = function
 118          | C.LetIn (mame, vv, tyty, tt) ->
 119             let vs = List.map (S.lift 1) vs in
 120             let x = C.LetIn (mame, vv, tyty, C.Appl (tt :: vs)) in
 121             opt_proof g (info st "Optimizer: swap 2") true c x
 122          | C.Lambda (name, ww, tt) ->
 123             let v, vs = List.hd vs, List.tl vs in
 124             let w = H.get_type "opt_appl 1" c v in
 125             let x = C.Appl (C.LetIn (name, v, w, tt) :: vs) in
 126             opt_proof g (info st "Optimizer: remove 2") true c x
 127          | C.Appl vvs              ->
 128             let x = C.Appl (vvs @ vs) in
 129             opt_proof g (info st "Optimizer: nested application") true c x
 130          | t                       ->
 131 (*
 132             let rec aux st d rvs = function
 133                | [], _                   ->
 134                   let x = C.Appl (t :: List.rev rvs) in
 135                   if d then opt_proof g st true c x else g st x
 136                | v :: vs, (cc, bb) :: cs ->
 137                   if H.is_not_atomic v && I.S.mem 0 cc && bb then
 138                      aux (st info "Optimizer: anticipate 1") true
 139                       (define c v :: rvs) (vs, cs)
 140                   else
 141                      aux st d (v :: rvs) (vs, cs)
 142                | _, []                   -> assert false
 143             in
 144 *)
 145             let h st =
 146                let classes, conclusion = Cl.classify c (H.get_type "opt_appl 3" c t) in
 147                let csno, vsno = List.length classes, List.length vs in
 148                if csno < vsno then
 149                   let vvs, vs = HEL.split_nth csno vs in
 150                   let x = C.Appl (define c (C.Appl (t :: vvs)) :: vs) in
 151                   opt_proof g (info st "Optimizer: anticipate 2") true c x
 152                else match conclusion, List.rev vs with
 153                   | Some _, rv :: rvs when csno = vsno && H.is_not_atomic rv ->
 154                      let x = C.Appl (t :: List.rev rvs @ [define c rv]) in
 155                      opt_proof g (info st "Optimizer: anticipate 3";) true c x
 156                   | _ (* Some _, _ *)                                             ->
 157                      g st (C.Appl (t :: vs))
 158 (*                | None, _                                                ->
 159                      aux false [] (vs, classes)
 160 *)          in
 161             let rec aux h st prev = function
 162                | C.LetIn (name, vv, tyty, tt) :: vs ->
 163                   let t = S.lift 1 t in
 164                   let prev = List.map (S.lift 1) prev in
 165                   let vs = List.map (S.lift 1) vs in
 166                   let y = C.Appl (t :: List.rev prev @ tt :: vs) in
 167                   let ww = H.get_type "opt_appl 2" c vv in
 168                   let x = C.LetIn (name, vv, ww, y) in
 169                   opt_proof g (info st "Optimizer: swap 3") true c x
 170                | v :: vs                      -> aux h st (v :: prev) vs
 171                | []                           -> h st
 172             in
 173             aux h st [] vs
 174       in
 175       if es then opt_proof g st es c t else g st t
 176    in
 177    let map h v (st, vs) =
 178       let h st vv = h (st, vv :: vs) in opt_term h st es c v
 179    in
 180    if es then H.list_fold_right_cps g map vs (st, []) else g (st, vs)
 181
 182 and opt_mutcase_critical g st es c uri tyno outty arg cases =
 183    let eliminator = H.get_default_eliminator c uri tyno outty in
 184    let lpsno, (_, _, _, constructors) = H.get_ind_type uri tyno in
 185    let ps, sort_disp = H.get_ind_parameters c arg in
 186    let lps, rps = HEL.split_nth lpsno ps in
 187    let rpsno = List.length rps in
 188    let predicate = clear_absts rpsno (1 - sort_disp) outty in
 189    let is_recursive t =
 190       I.S.mem tyno (I.get_mutinds_of_uri uri t)
 191    in
 192    let map2 case (_, cty) =
 193       let map (h, case, k) (_, premise) =
 194          if h > 0 then pred h, case, k else
 195          if is_recursive premise then
 196             0, add_abst k case, k + 2
 197          else
 198             0, case, succ k
 199       in
 200       let premises, _ = PEH.split_with_whd (c, cty) in
 201       let _, lifted_case, _ =
 202          List.fold_left map (lpsno, case, 1) (List.rev (List.tl premises))
 203       in
 204       lifted_case
 205    in
 206    let lifted_cases = List.map2 map2 cases constructors in
 207    let args = eliminator :: lps @ predicate :: lifted_cases @ rps @ [arg] in
 208    let x = H.refine c (C.Appl args) in
 209    opt_proof g (info st "Optimizer: remove 3") es c x
 210
 211 and opt_mutcase_plain g st es c uri tyno outty arg cases =
 212    let g st v =
 213       let g (st, ts) = g st (C.MutCase (uri, tyno, outty, v, ts)) in
 214       let map h v (st, vs) =
 215          let h st vv = h (st, vv :: vs) in opt_proof h st es c v
 216       in
 217       if es then H.list_fold_right_cps g map cases (st, []) else g (st, cases)
 218    in
 219    if es then opt_proof g st es c arg else g st arg
 220
 221 and opt_mutcase g =
 222    if !critical then opt_mutcase_critical g else opt_mutcase_plain g
 223
 224 and opt_cast g st es c t w =
 225    let g st t = g (info st "Optimizer: remove 4") t in
 226    if es then opt_proof g st es c t else g st t
 227
 228 and opt_other g st es c t = g st t
 229
 230 and opt_proof g st es c = function
 231    | C.LetIn (name, v, ty, t)   -> opt_letin g st es c name v ty t
 232    | C.Lambda (name, w, t)      -> opt_lambda g st es c name w t
 233    | C.Appl (t :: v :: vs)      -> opt_appl g st es c t (v :: vs)
 234    | C.Appl [t]                 -> opt_proof g st es c t
 235    | C.MutCase (u, n, t, v, ws) -> opt_mutcase g st es c u n t v ws
 236    | C.Cast (t, w)              -> opt_cast g st es c t w
 237    | t                          -> opt_other g st es c t
 238
 239 and opt_term g st es c t =
 240    if H.is_proof c t then opt_proof g st es c t else g st t
 241
 242 (* object optimization ******************************************************)
 243
 244 let wrap g st c bo =
 245    try opt_term g st true c bo
 246    with
 247       | E.Object_not_found uri ->
 248          let msg = "optimize_obj: object not found: " ^ UM.string_of_uri uri in
 249          failwith msg
 250       | e                      ->
 251          let msg = "optimize_obj: " ^ Printexc.to_string e in
 252          failwith msg
 253
 254 let optimize_obj = function
 255    | C.Constant (name, Some bo, ty, pars, attrs) ->
 256       let st, c = {info = ""; dummy = ()}, [] in
 257       let bo, ty = H.cic_bc c bo, H.cic_bc c ty in
 258       let g st bo =
 259          if !debug then begin
 260             Printf.eprintf "Optimized : %s\n" (Pp.ppterm bo);
 261             prerr_string "Ut.pp_term : ";
 262             Ut.pp_term prerr_string [] c bo; prerr_newline ()
 263          end;
 264 (*       let _ = H.get_type "opt" [] (C.Cast (bo, ty)) in *)
 265          let nodes = Printf.sprintf "Optimized nodes: %u" (I.count_nodes 0 bo) in
 266          let st = info st nodes in
 267          L.time_stamp ("PO: DONE       " ^ name);
 268          C.Constant (name, Some bo, ty, pars, attrs), st.info
 269       in
 270       L.time_stamp ("PO: OPTIMIZING " ^ name);
 271       if !debug then Printf.eprintf "BEGIN: %s\n" name;
 272       let nodes = Printf.sprintf "Initial nodes: %u" (I.count_nodes 0 bo) in
 273       wrap g (info st nodes) c bo
 274    | obj                                         -> obj, ""
 275
 276 let optimize_term c bo =
 277    let st = {info = ""; dummy = ()} in
 278    let bo = H.cic_bc c bo in
 279    let g st bo = bo, st.info in
 280    wrap g st c bo