helm/software/components/acic_procedural/proceduralTypes.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module HEL = HExtlib
  27 module C   = Cic
  28 module I   = CicInspect
  29 module G   = GrafiteAst
  30 module N   = CicNotationPt
  31
  32 module H   = ProceduralHelpers
  33
  34 (* functions to be moved ****************************************************)
  35
  36 let list_rev_map2 map l1 l2 =
  37    let rec aux res = function
  38       | hd1 :: tl1, hd2 :: tl2 -> aux (map hd1 hd2 :: res) (tl1, tl2)
  39       | _                      -> res
  40    in
  41    aux [] (l1, l2)
  42
  43 let list_map2_filter map l1 l2 =
  44    let rec filter l = function
  45       | []           -> l
  46       | None :: tl   -> filter l tl
  47       | Some a :: tl -> filter (a :: l) tl
  48   in
  49   filter [] (list_rev_map2 map l1 l2)
  50
  51 let list_init f i =
  52    let rec aux a j = if j < 0 then a else aux (f j :: a) (pred j) in
  53    aux [] i
  54
  55 (****************************************************************************)
  56
  57 type flavour  = C.object_flavour
  58 type name     = string option
  59 type hyp      = string
  60 type what     = C.annterm
  61 type how      = bool
  62 type using    = C.annterm
  63 type count    = int
  64 type note     = string
  65 type where    = (hyp * name) option
  66 type inferred = C.annterm
  67 type pattern  = C.annterm
  68 type body     = C.annterm option
  69 type types    = C.anninductiveType list
  70 type lpsno    = int
  71
  72 type step = Note of note
  73           | Inductive of types * lpsno * note
  74           | Statement of flavour * name * what * body * note
  75           | Qed of note
  76           | Id of note
  77           | Exact of what * note
  78           | Intros of count option * name list * note
  79           | Cut of name * what * note
  80           | LetIn of name * what * note
  81           | Rewrite of how * what * where * pattern * note
  82           | Elim of what * using option * pattern * note
  83           | Cases of what * pattern * note
  84           | Apply of what * note
  85           | Change of inferred * what * where * pattern * note
  86           | Clear of hyp list * note
  87           | ClearBody of hyp * note
  88           | Branch of step list list * note
  89           | Reflexivity of note
  90
  91 (* annterm constructors *****************************************************)
  92
  93 let mk_arel i b = C.ARel ("", "", i, b)
  94
  95 (* FG: this is really awful !! *)
  96 let arel_of_name = function
  97    | C.Name s    -> mk_arel 0 s
  98    | C.Anonymous -> mk_arel 0 "_"
  99
 100 (* helper functions on left params for use with inductive types *************)
 101
 102 let strip_lps lpsno arity =
 103    let rec aux no lps = function
 104       | C.AProd (_, name, w, t) when no > 0 ->
 105          let lp = name, Some w in
 106          aux (pred no) (lp :: lps) t
 107       | t                                   -> lps, t
 108    in
 109    aux lpsno [] arity
 110
 111 let merge_lps lps1 lps2 =
 112    let map (n1, w1) (n2, _) =
 113       let n = match n1, n2 with
 114          | C.Name _, _ -> n1
 115          | _           -> n2
 116       in
 117       n, w1
 118    in
 119    if lps1 = [] then lps2 else
 120    List.map2 map lps1 lps2
 121
 122 (* grafite ast constructors *************************************************)
 123
 124 let floc = HEL.dummy_floc
 125
 126 let mk_note str = G.Comment (floc, G.Note (floc, str))
 127
 128 let mk_tacnote str a =
 129    if str = "" then mk_note "" :: a else mk_note "" :: mk_note str :: a
 130
 131 let mk_notenote str a =
 132    if str = "" then a else mk_note str :: a
 133
 134 let mk_thnote str a =
 135    if str = "" then a else mk_note "" :: mk_note str :: a
 136
 137 let mk_inductive types lpsno =
 138    let map1 (lps1, cons) (name, arity) =
 139       let lps2, arity = strip_lps lpsno arity in
 140       merge_lps lps1 lps2, (name, arity) :: cons
 141    in
 142    let map2 (lps1, types) (_, name, kind, arity, cons) =
 143       let lps2, arity = strip_lps lpsno arity in
 144       let lps1, rev_cons = List.fold_left map1 (lps1, []) cons in
 145       merge_lps lps1 lps2, (name, kind, arity, List.rev rev_cons) :: types
 146    in
 147    let map3 (name, xw) = arel_of_name name, xw in
 148    let rev_lps, rev_types = List.fold_left map2 ([], []) types in
 149    let lpars, types = List.rev_map map3 rev_lps, List.rev rev_types in
 150    let obj = N.Inductive (lpars, types) in
 151    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 152
 153 let mk_statement flavour name t v =
 154    let name = match name with Some name -> name | None -> assert false in
 155    let obj = N.Theorem (flavour, name, t, v) in
 156    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 157
 158 let mk_qed =
 159    G.Executable (floc, G.Command (floc, G.Qed floc))
 160
 161 let mk_tactic tactic punctation =
 162    G.Executable (floc, G.Tactic (floc, Some tactic, punctation))
 163
 164 let mk_punctation punctation =
 165    G.Executable (floc, G.Tactic (floc, None, punctation))
 166
 167 let mk_id punctation =
 168    let tactic = G.IdTac floc in
 169    mk_tactic tactic punctation
 170
 171 let mk_exact t punctation =
 172    let tactic = G.Exact (floc, t) in
 173    mk_tactic tactic punctation
 174
 175 let mk_intros xi xids punctation =
 176    let tactic = G.Intros (floc, (xi, xids)) in
 177    mk_tactic tactic punctation
 178
 179 let mk_cut name what punctation =
 180    let name = match name with Some name -> name | None -> assert false in
 181    let tactic = G.Cut (floc, Some name, what) in
 182    mk_tactic tactic punctation
 183
 184 let mk_letin name what punctation =
 185    let name = match name with Some name -> name | None -> assert false in
 186    let tactic = G.LetIn (floc, what, name) in
 187    mk_tactic tactic punctation
 188
 189 let mk_rewrite direction what where pattern punctation =
 190    let direction = if direction then `RightToLeft else `LeftToRight in
 191    let pattern, rename = match where with
 192       | None                      -> (None, [], Some pattern), []
 193       | Some (premise, Some name) -> (None, [premise, pattern], None), [Some name]
 194       | Some (premise, None)      -> (None, [premise, pattern], None), []
 195    in
 196    let tactic = G.Rewrite (floc, direction, what, pattern, rename) in
 197    mk_tactic tactic punctation
 198
 199 let mk_elim what using pattern punctation =
 200    let pattern = None, [], Some pattern in
 201    let tactic = G.Elim (floc, what, using, pattern, (Some 0, [])) in
 202    mk_tactic tactic punctation
 203
 204 let mk_cases what pattern punctation =
 205    let pattern = None, [], Some pattern in
 206    let tactic = G.Cases (floc, what, pattern, (Some 0, [])) in
 207    mk_tactic tactic punctation
 208
 209 let mk_apply t punctation =
 210    let tactic = G.Apply (floc, t) in
 211    mk_tactic tactic punctation
 212
 213 let mk_change t where pattern punctation =
 214    let pattern = match where with
 215       | None              -> None, [], Some pattern
 216       | Some (premise, _) -> None, [premise, pattern], None
 217    in
 218    let tactic = G.Change (floc, pattern, t) in
 219    mk_tactic tactic punctation
 220
 221 let mk_clear ids punctation =
 222    let tactic = G.Clear (floc, ids) in
 223    mk_tactic tactic punctation
 224
 225 let mk_clearbody id punctation =
 226    let tactic = G.ClearBody (floc, id) in
 227    mk_tactic tactic punctation
 228
 229 let mk_reflexivity punctation =
 230    let tactic = G.Reflexivity floc in
 231    mk_tactic tactic punctation
 232
 233 let mk_ob =
 234    let punctation = G.Branch floc in
 235    mk_punctation punctation
 236
 237 let mk_dot = G.Dot floc
 238
 239 let mk_sc = G.Semicolon floc
 240
 241 let mk_cb = G.Merge floc
 242
 243 let mk_vb = G.Shift floc
 244
 245 (* rendering ****************************************************************)
 246
 247 let rec render_step sep a = function
 248    | Note s                    -> mk_notenote s a
 249    | Statement (f, n, t, v, s) -> mk_statement f n t v :: mk_thnote s a
 250    | Inductive (lps, ts, s)    -> mk_inductive lps ts :: mk_thnote s a
 251    | Qed s                     -> mk_qed :: mk_tacnote s a
 252    | Exact (t, s)              -> mk_exact t sep :: mk_tacnote s a
 253    | Id s                      -> mk_id sep :: mk_tacnote s a
 254    | Intros (c, ns, s)         -> mk_intros c ns sep :: mk_tacnote s a
 255    | Cut (n, t, s)             -> mk_cut n t sep :: mk_tacnote s a
 256    | LetIn (n, t, s)           -> mk_letin n t sep :: mk_tacnote s a
 257    | Rewrite (b, t, w, e, s)   -> mk_rewrite b t w e sep :: mk_tacnote s a
 258    | Elim (t, xu, e, s)        -> mk_elim t xu e sep :: mk_tacnote s a
 259    | Cases (t, e, s)           -> mk_cases t e sep :: mk_tacnote s a
 260    | Apply (t, s)              -> mk_apply t sep :: mk_tacnote s a
 261    | Change (t, _, w, e, s)    -> mk_change t w e sep :: mk_tacnote s a
 262    | Clear (ns, s)             -> mk_clear ns sep :: mk_tacnote s a
 263    | ClearBody (n, s)          -> mk_clearbody n sep :: mk_tacnote s a
 264    | Branch ([], s)            -> a
 265    | Branch ([ps], s)          -> render_steps sep a ps
 266    | Branch (ps :: pss, s)     ->
 267       let a = mk_ob :: mk_tacnote s a in
 268       let a = List.fold_left (render_steps mk_vb) a (List.rev pss) in
 269       mk_punctation sep :: render_steps mk_cb a ps
 270    | Reflexivity s             -> mk_reflexivity sep :: mk_tacnote s a
 271
 272 and render_steps sep a = function
 273    | []                                          -> a
 274    | [p]                                         -> render_step sep a p
 275    | p :: Branch ([], _) :: ps                   ->
 276       render_steps sep a (p :: ps)
 277    | p :: ((Branch (_ :: _ :: _, _) :: _) as ps) ->
 278       render_steps sep (render_step mk_sc a p) ps
 279    | p :: ps                                     ->
 280       render_steps sep (render_step mk_sc a p) ps
 281
 282 let render_steps a = render_steps mk_dot a
 283
 284 (* counting *****************************************************************)
 285
 286 let rec count_step a = function
 287    | Note _
 288    | Statement _
 289    | Inductive _
 290    | Qed _                  -> a
 291 (* level A0 *)
 292    | Branch (pps, _)        -> List.fold_left count_steps a pps
 293    | Clear _
 294    | ClearBody _
 295    | Id _
 296    | Intros (Some 0, [], _)
 297 (* leval A1 *)
 298    | Exact _
 299 (* level B1 *)
 300    | Cut _
 301    | LetIn _
 302 (* level B2 *)
 303    | Change _               -> a
 304 (* level C *)
 305    | _                      -> succ a
 306
 307 and count_steps a = List.fold_left count_step a
 308
 309 let count = I.count_nodes ~meta:false
 310
 311 let rec count_node a = function
 312    | Note _
 313    | Inductive _
 314    | Statement _
 315    | Qed _
 316    | Reflexivity _
 317    | Id _
 318    | Intros _
 319    | Clear _
 320    | ClearBody _             -> a
 321    | Exact (t, _)
 322    | Cut (_, t, _)
 323    | LetIn (_, t, _)
 324    | Apply (t, _)            -> count a (H.cic t)
 325    | Rewrite (_, t, _, p, _)
 326    | Elim (t, _, p, _)
 327    | Cases (t, p, _)
 328    | Change (t, _, _, p, _)  -> let a = count a (H.cic t) in count a (H.cic p)
 329    | Branch (ss, _)          -> List.fold_left count_nodes a ss
 330
 331 and count_nodes a = List.fold_left count_node a
 332
 333 (* helpers ******************************************************************)
 334
 335 let rec note_of_step = function
 336    | Note s
 337    | Statement (_, _, _, _, s)
 338    | Inductive (_, _, s)
 339    | Qed s
 340    | Exact (_, s)
 341    | Id s
 342    | Intros (_, _, s)
 343    | Cut (_, _, s)
 344    | LetIn (_, _, s)
 345    | Rewrite (_, _, _, _, s)
 346    | Elim (_, _, _, s)
 347    | Cases (_, _, s)
 348    | Apply (_, s)
 349    | Change (_, _, _, _, s)
 350    | Clear (_, s)
 351    | ClearBody (_, s)
 352    | Reflexivity s
 353    | Branch (_, s)             -> s