helm/software/components/acic_procedural/proceduralTypes.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module HEL = HExtlib
  27 module C   = Cic
  28 module I   = CicInspect
  29 module G   = GrafiteAst
  30 module N   = CicNotationPt
  31
  32 module H   = ProceduralHelpers
  33
  34 (* functions to be moved ****************************************************)
  35
  36 let list_rev_map2 map l1 l2 =
  37    let rec aux res = function
  38       | hd1 :: tl1, hd2 :: tl2 -> aux (map hd1 hd2 :: res) (tl1, tl2)
  39       | _                      -> res
  40    in
  41    aux [] (l1, l2)
  42
  43 let list_map2_filter map l1 l2 =
  44    let rec filter l = function
  45       | []           -> l
  46       | None :: tl   -> filter l tl
  47       | Some a :: tl -> filter (a :: l) tl
  48   in
  49   filter [] (list_rev_map2 map l1 l2)
  50
  51 let list_init f i =
  52    let rec aux a j = if j < 0 then a else aux (f j :: a) (pred j) in
  53    aux [] i
  54
  55 (****************************************************************************)
  56
  57 type flavour  = C.object_flavour
  58 type name     = string option
  59 type hyp      = string
  60 type what     = C.annterm
  61 type how      = bool
  62 type using    = C.annterm
  63 type count    = int
  64 type note     = string
  65 type where    = (hyp * name) option
  66 type inferred = C.annterm
  67 type pattern  = C.annterm
  68 type body     = C.annterm option
  69 type types    = C.anninductiveType list
  70 type lpsno    = int
  71 type fields   = (string * bool * int) list
  72
  73 type step = Note of note
  74           | Record of types * lpsno * fields * note
  75           | Inductive of types * lpsno * note
  76           | Statement of flavour * name * what * body * note
  77           | Qed of note
  78           | Id of note
  79           | Exact of what * note
  80           | Intros of count option * name list * note
  81           | Cut of name * what * note
  82           | LetIn of name * what * note
  83           | Rewrite of how * what * where * pattern * note
  84           | Elim of what * using option * pattern * note
  85           | Cases of what * pattern * note
  86           | Apply of what * note
  87           | Change of inferred * what * where * pattern * note
  88           | Clear of hyp list * note
  89           | ClearBody of hyp * note
  90           | Branch of step list list * note
  91           | Reflexivity of note
  92
  93 (* annterm constructors *****************************************************)
  94
  95 let mk_arel i b = C.ARel ("", "", i, b)
  96
  97 (* FG: this is really awful !! *)
  98 let arel_of_name = function
  99    | C.Name s    -> mk_arel 0 s
 100    | C.Anonymous -> mk_arel 0 "_"
 101
 102 (* helper functions on left params for use with inductive types *************)
 103
 104 let strip_lps lpsno arity =
 105    let rec aux no lps = function
 106       | C.AProd (_, name, w, t) when no > 0 ->
 107          let lp = name, Some w in
 108          aux (pred no) (lp :: lps) t
 109       | t                                   -> lps, t
 110    in
 111    aux lpsno [] arity
 112
 113 let merge_lps lps1 lps2 =
 114    let map (n1, w1) (n2, _) =
 115       let n = match n1, n2 with
 116          | C.Name _, _ -> n1
 117          | _           -> n2
 118       in
 119       n, w1
 120    in
 121    if lps1 = [] then lps2 else
 122    List.map2 map lps1 lps2
 123
 124 (* grafite ast constructors *************************************************)
 125
 126 let floc = HEL.dummy_floc
 127
 128 let mk_note str = G.Comment (floc, G.Note (floc, str))
 129
 130 let mk_tacnote str a =
 131    if str = "" then mk_note "" :: a else mk_note "" :: mk_note str :: a
 132
 133 let mk_notenote str a =
 134    if str = "" then a else mk_note str :: a
 135
 136 let mk_thnote str a =
 137    if str = "" then a else mk_note "" :: mk_note str :: a
 138
 139 let mk_pre_inductive types lpsno =
 140    let map1 (lps1, cons) (name, arity) =
 141       let lps2, arity = strip_lps lpsno arity in
 142       merge_lps lps1 lps2, (name, arity) :: cons
 143    in
 144    let map2 (lps1, types) (_, name, kind, arity, cons) =
 145       let lps2, arity = strip_lps lpsno arity in
 146       let lps1, rev_cons = List.fold_left map1 (lps1, []) cons in
 147       merge_lps lps1 lps2, (name, kind, arity, List.rev rev_cons) :: types
 148    in
 149    let map3 (name, xw) = arel_of_name name, xw in
 150    let rev_lps, rev_types = List.fold_left map2 ([], []) types in
 151    List.rev_map map3 rev_lps, List.rev rev_types
 152
 153 let mk_inductive types lpsno =
 154    let lpars, types = mk_pre_inductive types lpsno in
 155    let obj = N.Inductive (lpars, types) in
 156    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 157
 158 let mk_record types lpsno fields =
 159    match mk_pre_inductive types lpsno with
 160       | lpars, [name, _, ty, [_, cty]] ->
 161          let map (fields, cty) (name, coercion, arity) =
 162             match cty with
 163                | C.AProd (_, _, w, t) ->
 164                   (name, w, coercion, arity) :: fields, t
 165                | _                    ->
 166                   assert false
 167          in
 168          let rev_fields, _ = List.fold_left map ([], cty) fields in
 169          let fields = List.rev rev_fields in
 170          let obj = N.Record (lpars, name, ty, fields) in
 171          G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 172       | _ -> assert false
 173
 174 let mk_statement flavour name t v =
 175    let name = match name with Some name -> name | None -> assert false in
 176    let obj = N.Theorem (flavour, name, t, v) in
 177    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 178
 179 let mk_qed =
 180    G.Executable (floc, G.Command (floc, G.Qed floc))
 181
 182 let mk_tactic tactic punctation =
 183    G.Executable (floc, G.Tactic (floc, Some tactic, punctation))
 184
 185 let mk_punctation punctation =
 186    G.Executable (floc, G.Tactic (floc, None, punctation))
 187
 188 let mk_id punctation =
 189    let tactic = G.IdTac floc in
 190    mk_tactic tactic punctation
 191
 192 let mk_exact t punctation =
 193    let tactic = G.Exact (floc, t) in
 194    mk_tactic tactic punctation
 195
 196 let mk_intros xi xids punctation =
 197    let tactic = G.Intros (floc, (xi, xids)) in
 198    mk_tactic tactic punctation
 199
 200 let mk_cut name what punctation =
 201    let name = match name with Some name -> name | None -> assert false in
 202    let tactic = G.Cut (floc, Some name, what) in
 203    mk_tactic tactic punctation
 204
 205 let mk_letin name what punctation =
 206    let name = match name with Some name -> name | None -> assert false in
 207    let tactic = G.LetIn (floc, what, name) in
 208    mk_tactic tactic punctation
 209
 210 let mk_rewrite direction what where pattern punctation =
 211    let direction = if direction then `RightToLeft else `LeftToRight in
 212    let pattern, rename = match where with
 213       | None                      -> (None, [], Some pattern), []
 214       | Some (premise, Some name) -> (None, [premise, pattern], None), [Some name]
 215       | Some (premise, None)      -> (None, [premise, pattern], None), []
 216    in
 217    let tactic = G.Rewrite (floc, direction, what, pattern, rename) in
 218    mk_tactic tactic punctation
 219
 220 let mk_elim what using pattern punctation =
 221    let pattern = None, [], Some pattern in
 222    let tactic = G.Elim (floc, what, using, pattern, (Some 0, [])) in
 223    mk_tactic tactic punctation
 224
 225 let mk_cases what pattern punctation =
 226    let pattern = None, [], Some pattern in
 227    let tactic = G.Cases (floc, what, pattern, (Some 0, [])) in
 228    mk_tactic tactic punctation
 229
 230 let mk_apply t punctation =
 231    let tactic = G.Apply (floc, t) in
 232    mk_tactic tactic punctation
 233
 234 let mk_change t where pattern punctation =
 235    let pattern = match where with
 236       | None              -> None, [], Some pattern
 237       | Some (premise, _) -> None, [premise, pattern], None
 238    in
 239    let tactic = G.Change (floc, pattern, t) in
 240    mk_tactic tactic punctation
 241
 242 let mk_clear ids punctation =
 243    let tactic = G.Clear (floc, ids) in
 244    mk_tactic tactic punctation
 245
 246 let mk_clearbody id punctation =
 247    let tactic = G.ClearBody (floc, id) in
 248    mk_tactic tactic punctation
 249
 250 let mk_reflexivity punctation =
 251    let tactic = G.Reflexivity floc in
 252    mk_tactic tactic punctation
 253
 254 let mk_ob =
 255    let punctation = G.Branch floc in
 256    mk_punctation punctation
 257
 258 let mk_dot = G.Dot floc
 259
 260 let mk_sc = G.Semicolon floc
 261
 262 let mk_cb = G.Merge floc
 263
 264 let mk_vb = G.Shift floc
 265
 266 (* rendering ****************************************************************)
 267
 268 let rec render_step sep a = function
 269    | Note s                    -> mk_notenote s a
 270    | Statement (f, n, t, v, s) -> mk_statement f n t v :: mk_thnote s a
 271    | Inductive (ts, lps, s)    -> mk_inductive ts lps :: mk_thnote s a
 272    | Record (ts, lps, fs, s)   -> mk_record ts lps fs :: mk_thnote s a
 273    | Qed s                     -> mk_qed :: mk_tacnote s a
 274    | Exact (t, s)              -> mk_exact t sep :: mk_tacnote s a
 275    | Id s                      -> mk_id sep :: mk_tacnote s a
 276    | Intros (c, ns, s)         -> mk_intros c ns sep :: mk_tacnote s a
 277    | Cut (n, t, s)             -> mk_cut n t sep :: mk_tacnote s a
 278    | LetIn (n, t, s)           -> mk_letin n t sep :: mk_tacnote s a
 279    | Rewrite (b, t, w, e, s)   -> mk_rewrite b t w e sep :: mk_tacnote s a
 280    | Elim (t, xu, e, s)        -> mk_elim t xu e sep :: mk_tacnote s a
 281    | Cases (t, e, s)           -> mk_cases t e sep :: mk_tacnote s a
 282    | Apply (t, s)              -> mk_apply t sep :: mk_tacnote s a
 283    | Change (t, _, w, e, s)    -> mk_change t w e sep :: mk_tacnote s a
 284    | Clear (ns, s)             -> mk_clear ns sep :: mk_tacnote s a
 285    | ClearBody (n, s)          -> mk_clearbody n sep :: mk_tacnote s a
 286    | Branch ([], s)            -> a
 287    | Branch ([ps], s)          -> render_steps sep a ps
 288    | Branch (ps :: pss, s)     ->
 289       let a = mk_ob :: mk_tacnote s a in
 290       let a = List.fold_left (render_steps mk_vb) a (List.rev pss) in
 291       mk_punctation sep :: render_steps mk_cb a ps
 292    | Reflexivity s             -> mk_reflexivity sep :: mk_tacnote s a
 293
 294 and render_steps sep a = function
 295    | []                                          -> a
 296    | [p]                                         -> render_step sep a p
 297    | p :: Branch ([], _) :: ps                   ->
 298       render_steps sep a (p :: ps)
 299    | p :: ((Branch (_ :: _ :: _, _) :: _) as ps) ->
 300       render_steps sep (render_step mk_sc a p) ps
 301    | p :: ps                                     ->
 302       render_steps sep (render_step mk_sc a p) ps
 303
 304 let render_steps a = render_steps mk_dot a
 305
 306 (* counting *****************************************************************)
 307
 308 let rec count_step a = function
 309    | Note _
 310    | Statement _
 311    | Inductive _
 312    | Qed _                  -> a
 313 (* level A0 *)
 314    | Branch (pps, _)        -> List.fold_left count_steps a pps
 315    | Clear _
 316    | ClearBody _
 317    | Id _
 318    | Intros (Some 0, [], _)
 319 (* leval A1 *)
 320    | Exact _
 321 (* level B1 *)
 322    | Cut _
 323    | LetIn _
 324 (* level B2 *)
 325    | Change _               -> a
 326 (* level C *)
 327    | _                      -> succ a
 328
 329 and count_steps a = List.fold_left count_step a
 330
 331 let count = I.count_nodes ~meta:false
 332
 333 let rec count_node a = function
 334    | Note _
 335    | Record _
 336    | Inductive _
 337    | Statement _
 338    | Qed _
 339    | Reflexivity _
 340    | Id _
 341    | Intros _
 342    | Clear _
 343    | ClearBody _             -> a
 344    | Exact (t, _)
 345    | Cut (_, t, _)
 346    | LetIn (_, t, _)
 347    | Apply (t, _)            -> count a (H.cic t)
 348    | Rewrite (_, t, _, p, _)
 349    | Elim (t, _, p, _)
 350    | Cases (t, p, _)
 351    | Change (t, _, _, p, _)  -> let a = count a (H.cic t) in count a (H.cic p)
 352    | Branch (ss, _)          -> List.fold_left count_nodes a ss
 353
 354 and count_nodes a = List.fold_left count_node a
 355
 356 (* helpers ******************************************************************)
 357
 358 let rec note_of_step = function
 359    | Note s
 360    | Statement (_, _, _, _, s)
 361    | Inductive (_, _, s)
 362    | Record (_, _, _, s)
 363    | Qed s
 364    | Exact (_, s)
 365    | Id s
 366    | Intros (_, _, s)
 367    | Cut (_, _, s)
 368    | LetIn (_, _, s)
 369    | Rewrite (_, _, _, _, s)
 370    | Elim (_, _, _, s)
 371    | Cases (_, _, s)
 372    | Apply (_, s)
 373    | Change (_, _, _, _, s)
 374    | Clear (_, s)
 375    | ClearBody (_, s)
 376    | Reflexivity s
 377    | Branch (_, s)             -> s