helm/software/components/acic_procedural/proceduralTypes.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module HEL = HExtlib
  27 module C   = Cic
  28 module I   = CicInspect
  29 module G   = GrafiteAst
  30 module N   = CicNotationPt
  31
  32 module H   = ProceduralHelpers
  33
  34 (* functions to be moved ****************************************************)
  35
  36 let list_rev_map2 map l1 l2 =
  37    let rec aux res = function
  38       | hd1 :: tl1, hd2 :: tl2 -> aux (map hd1 hd2 :: res) (tl1, tl2)
  39       | _                      -> res
  40    in
  41    aux [] (l1, l2)
  42
  43 let list_map2_filter map l1 l2 =
  44    let rec filter l = function
  45       | []           -> l
  46       | None :: tl   -> filter l tl
  47       | Some a :: tl -> filter (a :: l) tl
  48   in
  49   filter [] (list_rev_map2 map l1 l2)
  50
  51 let list_init f i =
  52    let rec aux a j = if j < 0 then a else aux (f j :: a) (pred j) in
  53    aux [] i
  54
  55 (****************************************************************************)
  56
  57 type flavour  = C.object_flavour
  58 type name     = string option
  59 type hyp      = string
  60 type what     = C.annterm
  61 type how      = bool
  62 type using    = C.annterm
  63 type count    = int
  64 type note     = string
  65 type where    = (hyp * name) option
  66 type inferred = C.annterm
  67 type pattern  = C.annterm
  68 type body     = C.annterm option
  69 type types    = C.anninductiveType list
  70 type lpsno    = int
  71
  72 type step = Note of note
  73           | Inductive of types * lpsno * note
  74           | Statement of flavour * name * what * body * note
  75           | Qed of note
  76           | Id of note
  77           | Exact of what * note
  78           | Intros of count option * name list * note
  79           | Cut of name * what * note
  80           | LetIn of name * what * note
  81           | Rewrite of how * what * where * pattern * note
  82           | Elim of what * using option * pattern * note
  83           | Cases of what * pattern * note
  84           | Apply of what * note
  85           | Change of inferred * what * where * pattern * note
  86           | Clear of hyp list * note
  87           | ClearBody of hyp * note
  88           | Branch of step list list * note
  89
  90 (* annterm constructors *****************************************************)
  91
  92 let mk_arel i b = C.ARel ("", "", i, b)
  93
  94 (* FG: this is really awful !! *)
  95 let arel_of_name = function
  96    | C.Name s    -> mk_arel 0 s
  97    | C.Anonymous -> mk_arel 0 "_"
  98
  99 (* helper functions on left params for use with inductive types *************)
 100
 101 let strip_lps lpsno arity =
 102    let rec aux no lps = function
 103       | C.AProd (_, name, w, t) when no > 0 ->
 104          let lp = name, Some w in
 105          aux (pred no) (lp :: lps) t
 106       | t                                   -> lps, t
 107    in
 108    aux lpsno [] arity
 109
 110 let merge_lps lps1 lps2 =
 111    let map (n1, w1) (n2, _) =
 112       let n = match n1, n2 with
 113          | C.Name _, _ -> n1
 114          | _           -> n2
 115       in
 116       n, w1
 117    in
 118    if lps1 = [] then lps2 else
 119    List.map2 map lps1 lps2
 120
 121 (* grafite ast constructors *************************************************)
 122
 123 let floc = HEL.dummy_floc
 124
 125 let mk_note str = G.Comment (floc, G.Note (floc, str))
 126
 127 let mk_tacnote str a =
 128    if str = "" then mk_note "" :: a else mk_note "" :: mk_note str :: a
 129
 130 let mk_notenote str a =
 131    if str = "" then a else mk_note str :: a
 132
 133 let mk_thnote str a =
 134    if str = "" then a else mk_note "" :: mk_note str :: a
 135
 136 let mk_inductive types lpsno =
 137    let map1 (lps1, cons) (name, arity) =
 138       let lps2, arity = strip_lps lpsno arity in
 139       merge_lps lps1 lps2, (name, arity) :: cons
 140    in
 141    let map2 (lps1, types) (_, name, kind, arity, cons) =
 142       let lps2, arity = strip_lps lpsno arity in
 143       let lps1, rev_cons = List.fold_left map1 (lps1, []) cons in
 144       merge_lps lps1 lps2, (name, kind, arity, List.rev rev_cons) :: types
 145    in
 146    let map3 (name, xw) = arel_of_name name, xw in
 147    let rev_lps, rev_types = List.fold_left map2 ([], []) types in
 148    let lpars, types = List.rev_map map3 rev_lps, List.rev rev_types in
 149    let obj = N.Inductive (lpars, types) in
 150    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 151
 152 let mk_statement flavour name t v =
 153    let name = match name with Some name -> name | None -> assert false in
 154    let obj = N.Theorem (flavour, name, t, v) in
 155    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 156
 157 let mk_qed =
 158    G.Executable (floc, G.Command (floc, G.Qed floc))
 159
 160 let mk_tactic tactic punctation =
 161    G.Executable (floc, G.Tactic (floc, Some tactic, punctation))
 162
 163 let mk_punctation punctation =
 164    G.Executable (floc, G.Tactic (floc, None, punctation))
 165
 166 let mk_id punctation =
 167    let tactic = G.IdTac floc in
 168    mk_tactic tactic punctation
 169
 170 let mk_exact t punctation =
 171    let tactic = G.Exact (floc, t) in
 172    mk_tactic tactic punctation
 173
 174 let mk_intros xi xids punctation =
 175    let tactic = G.Intros (floc, (xi, xids)) in
 176    mk_tactic tactic punctation
 177
 178 let mk_cut name what punctation =
 179    let name = match name with Some name -> name | None -> assert false in
 180    let tactic = G.Cut (floc, Some name, what) in
 181    mk_tactic tactic punctation
 182
 183 let mk_letin name what punctation =
 184    let name = match name with Some name -> name | None -> assert false in
 185    let tactic = G.LetIn (floc, what, name) in
 186    mk_tactic tactic punctation
 187
 188 let mk_rewrite direction what where pattern punctation =
 189    let direction = if direction then `RightToLeft else `LeftToRight in
 190    let pattern, rename = match where with
 191       | None                      -> (None, [], Some pattern), []
 192       | Some (premise, Some name) -> (None, [premise, pattern], None), [Some name]
 193       | Some (premise, None)      -> (None, [premise, pattern], None), []
 194    in
 195    let tactic = G.Rewrite (floc, direction, what, pattern, rename) in
 196    mk_tactic tactic punctation
 197
 198 let mk_elim what using pattern punctation =
 199    let pattern = None, [], Some pattern in
 200    let tactic = G.Elim (floc, what, using, pattern, (Some 0, [])) in
 201    mk_tactic tactic punctation
 202
 203 let mk_cases what pattern punctation =
 204    let pattern = None, [], Some pattern in
 205    let tactic = G.Cases (floc, what, pattern, (Some 0, [])) in
 206    mk_tactic tactic punctation
 207
 208 let mk_apply t punctation =
 209    let tactic = G.Apply (floc, t) in
 210    mk_tactic tactic punctation
 211
 212 let mk_change t where pattern punctation =
 213    let pattern = match where with
 214       | None              -> None, [], Some pattern
 215       | Some (premise, _) -> None, [premise, pattern], None
 216    in
 217    let tactic = G.Change (floc, pattern, t) in
 218    mk_tactic tactic punctation
 219
 220 let mk_clear ids punctation =
 221    let tactic = G.Clear (floc, ids) in
 222    mk_tactic tactic punctation
 223
 224 let mk_clearbody id punctation =
 225    let tactic = G.ClearBody (floc, id) in
 226    mk_tactic tactic punctation
 227
 228 let mk_ob =
 229    let punctation = G.Branch floc in
 230    mk_punctation punctation
 231
 232 let mk_dot = G.Dot floc
 233
 234 let mk_sc = G.Semicolon floc
 235
 236 let mk_cb = G.Merge floc
 237
 238 let mk_vb = G.Shift floc
 239
 240 (* rendering ****************************************************************)
 241
 242 let rec render_step sep a = function
 243    | Note s                    -> mk_notenote s a
 244    | Statement (f, n, t, v, s) -> mk_statement f n t v :: mk_thnote s a
 245    | Inductive (lps, ts, s)    -> mk_inductive lps ts :: mk_thnote s a
 246    | Qed s                     -> mk_qed :: mk_tacnote s a
 247    | Exact (t, s)              -> mk_exact t sep :: mk_tacnote s a
 248    | Id s                      -> mk_id sep :: mk_tacnote s a
 249    | Intros (c, ns, s)         -> mk_intros c ns sep :: mk_tacnote s a
 250    | Cut (n, t, s)             -> mk_cut n t sep :: mk_tacnote s a
 251    | LetIn (n, t, s)           -> mk_letin n t sep :: mk_tacnote s a
 252    | Rewrite (b, t, w, e, s)   -> mk_rewrite b t w e sep :: mk_tacnote s a
 253    | Elim (t, xu, e, s)        -> mk_elim t xu e sep :: mk_tacnote s a
 254    | Cases (t, e, s)           -> mk_cases t e sep :: mk_tacnote s a
 255    | Apply (t, s)              -> mk_apply t sep :: mk_tacnote s a
 256    | Change (t, _, w, e, s)    -> mk_change t w e sep :: mk_tacnote s a
 257    | Clear (ns, s)             -> mk_clear ns sep :: mk_tacnote s a
 258    | ClearBody (n, s)          -> mk_clearbody n sep :: mk_tacnote s a
 259    | Branch ([], s)            -> a
 260    | Branch ([ps], s)          -> render_steps sep a ps
 261    | Branch (ps :: pss, s)     ->
 262       let a = mk_ob :: mk_tacnote s a in
 263       let a = List.fold_left (render_steps mk_vb) a (List.rev pss) in
 264       mk_punctation sep :: render_steps mk_cb a ps
 265
 266 and render_steps sep a = function
 267    | []                                          -> a
 268    | [p]                                         -> render_step sep a p
 269    | p :: Branch ([], _) :: ps                   ->
 270       render_steps sep a (p :: ps)
 271    | p :: ((Branch (_ :: _ :: _, _) :: _) as ps) ->
 272       render_steps sep (render_step mk_sc a p) ps
 273    | p :: ps                                     ->
 274       render_steps sep (render_step mk_sc a p) ps
 275
 276 let render_steps a = render_steps mk_dot a
 277
 278 (* counting *****************************************************************)
 279
 280 let rec count_step a = function
 281    | Note _
 282    | Statement _
 283    | Inductive _
 284    | Qed _
 285 (* level 0 *)
 286    | Intros (Some 0, [], _)
 287    | Id _
 288    | Exact _
 289    | Change _
 290    | Clear _
 291    | ClearBody _            -> a
 292    | Branch (pps, _)        -> List.fold_left count_steps a pps
 293 (* level 1 *)
 294    | _                      -> succ a
 295
 296 and count_steps a = List.fold_left count_step a
 297
 298 let count = I.count_nodes ~meta:false
 299
 300 let rec count_node a = function
 301    | Note _
 302    | Inductive _
 303    | Statement _
 304    | Qed _
 305    | Id _
 306    | Intros _
 307    | Clear _
 308    | ClearBody _             -> a
 309    | Exact (t, _)
 310    | Cut (_, t, _)
 311    | LetIn (_, t, _)
 312    | Apply (t, _)            -> count a (H.cic t)
 313    | Rewrite (_, t, _, p, _)
 314    | Elim (t, _, p, _)
 315    | Cases (t, p, _)
 316    | Change (t, _, _, p, _)  -> let a = count a (H.cic t) in count a (H.cic p)
 317    | Branch (ss, _)          -> List.fold_left count_nodes a ss
 318
 319 and count_nodes a = List.fold_left count_node a