helm/software/components/acic_procedural/proceduralTypes.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module H = HExtlib
  27 module C = Cic
  28 module G = GrafiteAst
  29 module N = CicNotationPt
  30
  31 (* functions to be moved ****************************************************)
  32
  33 let list_map2_filter map l1 l2 =
  34    let rec filter l = function
  35       | []           -> l
  36       | None :: tl   -> filter l tl
  37       | Some a :: tl -> filter (a :: l) tl
  38   in
  39   filter [] (List.rev_map2 map l1 l2)
  40
  41 let rec list_split n l =
  42    if n = 0 then [], l else
  43    let l1, l2 = list_split (pred n) (List.tl l) in
  44    List.hd l :: l1, l2
  45
  46 let cont sep a = match sep with
  47    | None     -> a
  48    | Some sep -> sep :: a
  49
  50 let list_rev_map_concat map sep a l =
  51    let rec aux a = function
  52       | []          -> a
  53       | [x]         -> map a x
  54       | x :: y :: l -> aux (sep :: map a x) (y :: l)
  55    in
  56    aux a l
  57
  58 let is_atomic = function
  59    | C.ASort _
  60    | C.AConst _
  61    | C.AMutInd _
  62    | C.AMutConstruct _
  63    | C.AVar _
  64    | C.ARel _
  65    | C.AMeta _
  66    | C.AImplicit _     -> true
  67    | _                 -> false
  68
  69 (****************************************************************************)
  70
  71 type name  = string
  72 type what  = Cic.annterm
  73 type how   = bool
  74 type using = Cic.annterm
  75 type count = int
  76 type note  = string
  77 type where = (name * name) option
  78
  79 type step = Note of note
  80           | Theorem of name * what * note
  81           | Qed of note
  82           | Id of note
  83           | Intros of count option * name list * note
  84           | Cut of name * what * note
  85           | LetIn of name * what * note
  86           | Rewrite of how * what * where * note
  87           | Elim of what * using option * note
  88           | Apply of what * note
  89           | Whd of count * note
  90           | Branch of step list list * note
  91
  92 (* annterm constructors *****************************************************)
  93
  94 let mk_arel i b = Cic.ARel ("", "", i, b)
  95
  96 (* grafite ast constructors *************************************************)
  97
  98 let floc = H.dummy_floc
  99
 100 let hole = C.AImplicit ("", Some `Hole)
 101
 102 let mk_note str = G.Comment (floc, G.Note (floc, str))
 103
 104 let mk_theorem name t =
 105    let obj = N.Theorem (`Theorem, name, t, None) in
 106    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
 107
 108 let mk_qed =
 109    G.Executable (floc, G.Command (floc, G.Qed floc))
 110
 111 let mk_tactic tactic =
 112    G.Executable (floc, G.Tactical (floc, G.Tactic (floc, tactic), None))
 113
 114 let mk_id =
 115    let tactic = G.IdTac floc in
 116    mk_tactic tactic
 117
 118 let mk_intros xi ids =
 119    let tactic = G.Intros (floc, xi, ids) in
 120    mk_tactic tactic
 121
 122 let mk_cut name what =
 123    let tactic = G.Cut (floc, Some name, what) in
 124    mk_tactic tactic
 125
 126 let mk_letin name what =
 127    let tactic = G.LetIn (floc, what, name) in
 128    mk_tactic tactic
 129
 130 let mk_rewrite direction what where =
 131    let direction = if direction then `RightToLeft else `LeftToRight in
 132    let pattern, rename = match where with
 133       | None                 -> (None, [], Some hole), []
 134       | Some (premise, name) -> (None, [premise, hole], None), [name]
 135    in
 136    let tactic = G.Rewrite (floc, direction, what, pattern, rename) in
 137    mk_tactic tactic
 138
 139 let mk_elim what using =
 140    let tactic = G.Elim (floc, what, using, Some 0, []) in
 141    mk_tactic tactic
 142
 143 let mk_apply t =
 144    let tactic = G.Apply (floc, t) in
 145    mk_tactic tactic
 146
 147 let mk_whd i =
 148    let pattern = None, [], Some hole in
 149    let tactic = G.Reduce (floc, `Whd, pattern) in
 150    mk_tactic tactic
 151
 152 let mk_dot = G.Executable (floc, G.Tactical (floc, G.Dot floc, None))
 153
 154 let mk_sc = G.Executable (floc, G.Tactical (floc, G.Semicolon floc, None))
 155
 156 let mk_ob = G.Executable (floc, G.Tactical (floc, G.Branch floc, None))
 157
 158 let mk_cb = G.Executable (floc, G.Tactical (floc, G.Merge floc, None))
 159
 160 let mk_vb = G.Executable (floc, G.Tactical (floc, G.Shift floc, None))
 161
 162 (* rendering ****************************************************************)
 163
 164 let rec render_step sep a = function
 165    | Note s               -> mk_note s :: a
 166    | Theorem (n, t, s)    -> mk_note s :: mk_theorem n t :: a
 167    | Qed s                -> mk_note s :: mk_qed :: a
 168    | Id s                 -> mk_note s :: cont sep (mk_id :: a)
 169    | Intros (c, ns, s)    -> mk_note s :: cont sep (mk_intros c ns :: a)
 170    | Cut (n, t, s)        -> mk_note s :: cont sep (mk_cut n t :: a)
 171    | LetIn (n, t, s)      -> mk_note s :: cont sep (mk_letin n t :: a)
 172    | Rewrite (b, t, w, s) -> mk_note s :: cont sep (mk_rewrite b t w :: a)
 173    | Elim (t, xu, s)      -> mk_note s :: cont sep (mk_elim t xu :: a)
 174    | Apply (t, s)         -> mk_note s :: cont sep (mk_apply t :: a)
 175    | Whd (c, s)           -> mk_note s :: cont sep (mk_whd c :: a)
 176    | Branch ([], s)       -> a
 177    | Branch ([ps], s)     -> render_steps sep a ps
 178    | Branch (pss, s)      ->
 179       let a =  mk_ob :: a in
 180       let body = mk_cb :: list_rev_map_concat (render_steps None) mk_vb a pss in
 181       mk_note s :: cont sep body
 182
 183 and render_steps sep a = function
 184    | []                                          -> a
 185    | [p]                                         -> render_step sep a p
 186    | p :: Branch ([], _) :: ps                   ->
 187       render_steps sep a (p :: ps)
 188    | p :: ((Branch (_ :: _ :: _, _) :: _) as ps) ->
 189       render_steps sep (render_step (Some mk_sc) a p) ps
 190    | p :: ps                                     ->
 191       render_steps sep (render_step (Some mk_dot) a p) ps
 192
 193 let render_steps a = render_steps None a
 194
 195 (* counting *****************************************************************)
 196
 197 let rec count_step a = function
 198    | Note _
 199    | Theorem _
 200    | Qed _           -> a
 201    | Branch (pps, _) -> List.fold_left count_steps a pps
 202    | _               -> succ a
 203
 204 and count_steps a = List.fold_left count_step a