helm/software/components/binaries/matitaprover/matitaprover.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)
  13
  14 module OT = struct type t = string  let compare = Pervasives.compare end
  15 module HC = Map.Make(OT)
  16
  17 type leaf = int * string
  18
  19 let cache = ref HC.empty
  20 let num = ref 100
  21
  22 let hash s =
  23   try HC.find s !cache
  24   with Not_found ->
  25           cache := HC.add s (!num,s) !cache;
  26           decr num;
  27           HC.find s !cache
  28 ;;
  29
  30 hash "==";;
  31 hash "_";;
  32
  33 let problem_file = ref "no-file-given";;
  34 let tptppath = ref "/";;
  35 let seconds = ref 300;;
  36
  37 let fail_msg () =
  38       print_endline ("% SZS status Timeout for " ^
  39         Filename.basename !problem_file)
  40 ;;
  41
  42 module type LeafComparer =
  43   sig
  44     val cmp : leaf -> leaf -> int
  45   end
  46 ;;
  47
  48 module MakeBlob(C:LeafComparer) : Terms.Blob
  49   with type t = leaf and type input = Ast.term = struct
  50         type t = leaf
  51         let eq a b = a == b
  52         let compare a b = C.cmp a b
  53         let eqP = hash "=="
  54         let pp (_,a) =  a
  55         type input = Ast.term
  56         let rec embed m = function
  57             | Ast.Variable name ->
  58                 (try m, List.assoc name m
  59                  with Not_found ->
  60                     let t = Terms.Var ~-(List.length m) in
  61                     (name,t)::m, t)
  62             | Ast.Constant name -> m, Terms.Leaf (hash name)
  63             | Ast.Function (name,args) ->
  64                 let m, args =
  65                   HExtlib.list_mapi_acc
  66                     (fun x _ m -> embed m x) m args
  67                 in
  68                 m, Terms.Node (Terms.Leaf (hash name):: args)
  69         ;;
  70         let saturate bo ty =
  71           let vars, ty = embed [] ty in
  72           let _, bo = embed vars bo in
  73           let bo = Terms.Node (bo :: List.map snd (List.rev vars)) in
  74           bo, ty
  75         ;;
  76         let embed t = snd(embed [] t);;
  77
  78   end
  79 ;;
  80
  81 let success_msg bag l (pp : ?margin:int -> leaf Terms.unit_clause -> string) =
  82   print_endline ("% SZS status Unsatisfiable for " ^
  83     Filename.basename !problem_file);
  84   print_endline ("% SZS output start CNFRefutation for " ^
  85     Filename.basename !problem_file);
  86   flush stdout;
  87   List.iter (fun x ->
  88     print_endline (pp ~margin:max_int
  89       (fst(Terms.M.find x bag)))) l;
  90   print_endline ("% SZS output end CNFRefutation for " ^
  91     Filename.basename !problem_file)
  92 ;;
  93
  94 let start_msg passives g_passives (pp : leaf Terms.unit_clause -> string) =
  95         prerr_endline (string_of_int (Unix.getpid ()));
  96 (*
  97   prerr_endline "Facts";
  98   List.iter (fun x -> prerr_endline (" " ^ pp x)) passives;
  99   prerr_endline "Goal";
 100   prerr_endline (" " ^ pp g_passives)
 101 *)
 102 ;;
 103
 104 module Main(C:LeafComparer) = struct
 105  let main goal hypotheses =
 106    let module B = MakeBlob(C) in
 107    let module Pp = Pp.Pp(B) in
 108    let module P = Paramod.Paramod(B) in
 109    let bag = Terms.M.empty, 0 in
 110    let bag, g_passives = P.mk_goal bag goal in
 111    let bag, passives =
 112      HExtlib.list_mapi_acc (fun x _ b -> P.mk_passive b x) bag hypotheses
 113    in
 114    start_msg passives g_passives Pp.pp_unit_clause;
 115    match
 116      P.paramod
 117       ~max_steps:max_int bag ~g_passives:[g_passives] ~passives
 118    with
 119    | [] -> ()
 120    | (bag,_,l)::_ -> success_msg bag l Pp.pp_unit_clause
 121  ;;
 122 end
 123
 124 let killall l =
 125   List.iter (fun pid -> try Unix.kill pid 9 with _ -> ()) l
 126 ;;
 127
 128 let main () =
 129   let childs = ref [] in
 130   let _ =
 131     Sys.signal 24 (Sys.Signal_handle
 132       (fun _ -> fail_msg (); killall !childs; exit 1))
 133   in
 134   let _ =
 135     Sys.signal Sys.sigalrm
 136       (Sys.Signal_handle (fun _ -> fail_msg (); killall !childs; exit 1))
 137   in
 138   Arg.parse [
 139    "--tptppath", Arg.String (fun p -> tptppath := p),
 140      ("[path]  TPTP lib root, default " ^ !tptppath);
 141    "--timeout", Arg.Int (fun p -> seconds := p),
 142      ("[seconds]  timeout, default " ^ string_of_int !seconds);
 143    ] (fun x -> problem_file := x) "
 144 Matitaprover is the first order automatic prover that equips the
 145 Matita interactive theorem prover (http://matita.cs.unibo.it).
 146
 147 Developed by A.Asperti, M.Denes and E.Tassi, released under GPL-2.1
 148
 149 If --tptppath is given, instead of the problem file you can just give the
 150 problem name with the .p suffix (e.g. BOO001-1.p)
 151
 152 If --tptppath is not given, included files (i.e. axiom sets) are searched
 153 in the current directory only.
 154
 155 usage: matitaprover [options] problemfile";
 156   let hypotheses, goals = Tptp_cnf.parse ~tptppath:!tptppath !problem_file in
 157   let goal = match goals with [x] -> x | _ -> assert false in
 158   let _ = Unix.alarm !seconds in
 159   childs :=
 160     List.map
 161       (fun f ->
 162          let pid = Unix.fork () in
 163          if pid = 0 then (f ();exit 0) else pid)
 164     [
 165       (fun () ->
 166         let module M = Main(struct let cmp (a,_) (b,_) = compare a b end) in
 167         M.main goal hypotheses)
 168     ;
 169       (fun () ->
 170         let module M = Main(struct let cmp (a,_) (b,_) = compare b a end) in
 171         M.main goal hypotheses)
 172     ];
 173   let _ = Unix.wait () in
 174   killall !childs;
 175   exit 0;
 176 ;;
 177
 178 main ()