helm/software/components/binaries/transcript/engine.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module R  = Helm_registry
  27 module X  = HExtlib
  28 module T  = Types
  29 module G  = Grafite
  30 module HG = Http_getter
  31
  32 module O = Options
  33
  34 type script = {
  35    name    : string;
  36    is_ma   : bool;
  37    contents: T.items
  38 }
  39
  40 type status = {
  41    heading_path: string;
  42    heading_lines: int;
  43    input_package: string;
  44    output_package: string;
  45    input_base_uri: string;
  46    output_base_uri: string;
  47    input_path: string;
  48    output_path: string;
  49    input_type: T.input_kind;
  50    output_type: T.output_kind;
  51    input_ext: string;
  52    includes: (string * string) list;
  53    coercions: (string * string) list;
  54    files: string list;
  55    requires: (string * string) list;
  56    scripts: script array
  57 }
  58
  59 let default_script = {
  60    name = ""; is_ma = false; contents = []
  61 }
  62
  63 let default_scripts = 2
  64
  65 let load_registry registry =
  66    let suffix = ".conf.xml" in
  67    let registry =
  68       if Filename.check_suffix registry suffix then registry
  69       else registry ^ suffix
  70    in
  71    Printf.eprintf "reading configuration %s ...\n" registry; flush stderr;
  72    R.load_from registry
  73
  74 let set_files st =
  75    let eof ich = try Some (input_line ich) with End_of_file -> None in
  76    let trim l = Filename.chop_extension (Str.string_after l 2) in
  77    let cmd = Printf.sprintf "cd %s && find -name *%s" st.input_path st.input_ext in
  78    let ich = Unix.open_process_in cmd in
  79    let rec aux files =
  80       match eof ich with
  81          | None   -> List.rev files
  82          | Some l -> aux (trim l :: files)
  83    in
  84    let files = aux [] in
  85    let _ = Unix.close_process_in ich in
  86    {st with files = files}
  87
  88 let set_requires st =
  89    let map file = (Filename.basename file, file) in
  90    let requires = List.rev_map map st.files in
  91    {st with requires = requires}
  92
  93 let init () =
  94    let transcript_dir = Filename.dirname Sys.argv.(0) in
  95    let default_registry = Filename.concat transcript_dir "transcript" in
  96    let matita_registry = Filename.concat !O.cwd "matita" in
  97    load_registry default_registry;
  98    load_registry matita_registry;
  99    HG.init ()
 100
 101 let make registry =
 102    let id x = x in
 103    let get_pairs = R.get_list (R.pair id id) in
 104    let get_input_type key =
 105       match R.get_string key with
 106          | "gallina8" -> T.Gallina8, ".v"
 107          | "grafite"  -> T.Grafite, ".ma"
 108          | _          -> failwith "unknown input type"
 109    in
 110    let get_output_type key =
 111       match R.get_string key with
 112          | "procedural"  -> T.Procedural
 113          | "declarative" -> T.Declarative
 114          | _             -> failwith "unknown output type"
 115    in
 116    load_registry registry;
 117    let input_type, input_ext = get_input_type "package.input_type" in
 118    let heading_lines = match input_type with
 119       | T.Grafite -> 0
 120       | _         -> R.get_int "transcript.heading_lines"
 121    in
 122    let st = {
 123       heading_path = R.get_string "transcript.heading_path";
 124       heading_lines = heading_lines;
 125       input_package = R.get_string "package.input_name";
 126       output_package = R.get_string "package.output_name";
 127       input_base_uri = R.get_string "package.input_base_uri";
 128       output_base_uri = R.get_string "package.output_base_uri";
 129       input_path = R.get_string "package.input_path";
 130       output_path = R.get_string "package.output_path";
 131       input_type = input_type;
 132       output_type = get_output_type "package.output_type";
 133       input_ext = input_ext;
 134       includes = get_pairs "package.include";
 135       coercions = get_pairs "package.coercion";
 136       files = [];
 137       requires = [];
 138       scripts = Array.make default_scripts default_script
 139    } in
 140    let st = {st with
 141       heading_path = Filename.concat !O.cwd st.heading_path;
 142       input_path = Filename.concat !O.cwd st.input_path;
 143       output_path = Filename.concat !O.cwd st.output_path
 144    } in
 145    prerr_endline "reading file names ...";
 146    let st = set_files st in
 147    let st = set_requires st in
 148    st
 149
 150 let get_index st name =
 151    let rec get_index name i =
 152       if i >= Array.length st.scripts then None else
 153       if st.scripts.(i).name = name then Some i else
 154       get_index name (succ i)
 155    in
 156    match get_index name 0, get_index "" 0 with
 157       | Some i, _ | _, Some i -> i
 158       | None, None            -> failwith "not enought script entries"
 159
 160 let is_ma st name =
 161    let i = get_index st name in
 162    let script = st.scripts.(i) in
 163    st.scripts.(i) <- {script with is_ma = true}
 164
 165 let set_items st name items =
 166    let i = get_index st name in
 167    let script = st.scripts.(i) in
 168    let contents = List.rev_append items script.contents in
 169    st.scripts.(i) <- {script with name = name; contents = contents}
 170
 171 let set_heading st name =
 172    let heading = st.heading_path, st.heading_lines in
 173    set_items st name [T.Heading heading]
 174
 175 let require st name inc =
 176    set_items st name [T.Include inc]
 177
 178 let get_coercion st str =
 179    try List.assoc str st.coercions with Not_found -> ""
 180
 181 let make_path path =
 182    List.fold_left Filename.concat "" (List.rev path)
 183
 184 let make_prefix path =
 185    String.concat "__" (List.rev path) ^ "__"
 186
 187 let make_script_name st script name =
 188    let ext = if script.is_ma then ".ma" else ".mma" in
 189    Filename.concat st.output_path (name ^ ext)
 190
 191 let commit st name =
 192    let i = get_index st name in
 193    let script = st.scripts.(i) in
 194    let path = Filename.concat st.output_path (Filename.dirname name) in
 195    let name = make_script_name st script name in
 196    let cmd = Printf.sprintf "mkdir -p %s" path in
 197    let _ = Sys.command cmd in
 198    let och = open_out name in
 199    G.commit st.output_type och script.contents;
 200    close_out och;
 201    st.scripts.(i) <- default_script
 202
 203 let produce st =
 204    let init name = set_heading st name in
 205    let partition = function
 206       | T.Coercion (false, _)
 207       | T.Notation (false, _) -> false
 208       | _                     -> true
 209    in
 210    let get_items = match st.input_type with
 211       | T.Gallina8 -> Gallina8Parser.items Gallina8Lexer.token
 212       | T.Grafite  -> GrafiteParser.items GrafiteLexer.token
 213    in
 214    let produce st name =
 215       let in_base_uri = Filename.concat st.input_base_uri name in
 216       let out_base_uri = Filename.concat st.output_base_uri name in
 217       let filter path = function
 218          | T.Inline (b, k, obj, p, f)   ->
 219             let obj, p =
 220                if b then Filename.concat (make_path path) obj, make_prefix path
 221                else obj, p
 222             in
 223             let s = obj ^ G.string_of_inline_kind k in
 224             path, Some (T.Inline (b, k, Filename.concat in_base_uri s, p, f))
 225          | T.Include s                  ->
 226             begin
 227                try path, Some (T.Include (List.assoc s st.requires))
 228                with Not_found -> path, None
 229             end
 230          | T.Coercion (b, obj)          ->
 231             let str = get_coercion st obj in
 232             if str <> "" then path, Some (T.Coercion (b, str)) else
 233             let base_uri = if b then out_base_uri else in_base_uri in
 234             let s = obj ^ G.string_of_inline_kind T.Con in
 235             path, Some (T.Coercion (b, Filename.concat base_uri s))
 236          | T.Section (b, id, _) as item ->
 237             let path = if b then id :: path else List.tl path in
 238             path, Some item
 239          | item                         -> path, Some item
 240       in
 241       let set_includes st name =
 242          try require st name (List.assoc name st.includes)
 243          with Not_found -> ()
 244       in
 245       Printf.eprintf "processing file name: %s ...\n" name; flush stderr;
 246       let file = Filename.concat st.input_path (name ^ st.input_ext) in
 247       let ich = open_in file in
 248       let lexbuf = Lexing.from_channel ich in
 249       try
 250          let items = get_items lexbuf in close_in ich;
 251          let _, rev_items = X.list_rev_map_filter_fold filter [] items in
 252          let items = List.rev rev_items in
 253          let local_items, global_items = List.partition partition items in
 254          let comment = T.Line (Printf.sprintf "From %s" name) in
 255          if global_items <> [] then
 256             set_items st st.input_package (comment :: global_items);
 257          init name; require st name st.input_package; set_includes st name;
 258          set_items st name local_items; commit st name
 259       with e ->
 260          prerr_endline (Printexc.to_string e); close_in ich
 261    in
 262    is_ma st st.input_package;
 263    init st.input_package; require st st.input_package "preamble";
 264    List.iter (produce st) st.files;
 265    commit st st.input_package