helm/software/components/binaries/transcript/engine.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module R = Helm_registry
  27 module X = HExtlib
  28 module T = Types
  29 module G = Grafite
  30
  31 type script = {
  32    name    : string;
  33    is_ma   : bool;
  34    contents: T.items
  35 }
  36
  37 type status = {
  38    heading_path: string;
  39    heading_lines: int;
  40    input_package: string;
  41    output_package: string;
  42    input_base_uri: string;
  43    output_base_uri: string;
  44    input_path: string;
  45    output_path: string;
  46    input_type: string;
  47    output_type: T.output_kind;
  48    coercions: (string * string) list;
  49    files: string list;
  50    requires: (string * string) list;
  51    scripts: script array
  52 }
  53
  54 let default_script = {
  55    name = ""; is_ma = false; contents = []
  56 }
  57
  58 let default_scripts = 2
  59
  60 let load_registry registry =
  61    let suffix = ".conf.xml" in
  62    let registry =
  63       if Filename.check_suffix registry suffix then registry
  64       else registry ^ suffix
  65    in
  66    Printf.eprintf "reading configuration %s ...\n" registry; flush stderr;
  67    R.load_from registry
  68
  69 let set_files st =
  70    let eof ich = try Some (input_line ich) with End_of_file -> None in
  71    let trim l = Filename.chop_extension (Str.string_after l 2) in
  72    let cmd = Printf.sprintf "cd %s && find -name *%s" st.input_path st.input_type in
  73    let ich = Unix.open_process_in cmd in
  74    let rec aux files =
  75       match eof ich with
  76          | None   -> List.rev files
  77          | Some l -> aux (trim l :: files)
  78    in
  79    let files = aux [] in
  80    let _ = Unix.close_process_in ich in
  81    {st with files = files}
  82
  83 let set_requires st =
  84    let map file = (Filename.basename file, file) in
  85    let requires = List.rev_map map st.files in
  86    {st with requires = requires}
  87
  88 let init () =
  89    let transcript_dir = Filename.dirname Sys.argv.(0) in
  90    let default_registry = Filename.concat transcript_dir "transcript" in
  91    load_registry default_registry
  92
  93 let make cwd registry =
  94    let id x = x in
  95    let get_coercions = R.get_list (R.pair id id) in
  96    let get_output_type key =
  97       match R.get_string key with
  98          | "procedural"  -> T.Procedural
  99          | "declarative" -> T.Declarative
 100          | _             -> failwith "unknown output type"
 101    in
 102    load_registry registry;
 103    let st = {
 104       heading_path = R.get_string "transcript.heading_path";
 105       heading_lines = R.get_int "transcript.heading_lines";
 106       input_package = R.get_string "package.input_name";
 107       output_package = R.get_string "package.output_name";
 108       input_base_uri = R.get_string "package.input_base_uri";
 109       output_base_uri = R.get_string "package.output_base_uri";
 110       input_path = R.get_string "package.input_path";
 111       output_path = R.get_string "package.output_path";
 112       input_type = R.get_string "package.input_type";
 113       output_type = get_output_type "package.output_type";
 114       coercions = get_coercions "package.coercion";
 115       files = [];
 116       requires = [];
 117       scripts = Array.make default_scripts default_script
 118    } in
 119    let st = {st with
 120       heading_path = Filename.concat cwd st.heading_path;
 121       output_path = Filename.concat cwd st.output_path;
 122    } in
 123    prerr_endline "reading file names ...";
 124    let st = set_files st in
 125    let st = set_requires st in
 126    st
 127
 128 let get_index st name =
 129    let rec get_index name i =
 130       if i >= Array.length st.scripts then None else
 131       if st.scripts.(i).name = name then Some i else
 132       get_index name (succ i)
 133    in
 134    match get_index name 0, get_index "" 0 with
 135       | Some i, _ | _, Some i -> i
 136       | None, None            -> failwith "not enought script entries"
 137
 138 let is_ma st name =
 139    let i = get_index st name in
 140    let script = st.scripts.(i) in
 141    st.scripts.(i) <- {script with is_ma = true}
 142
 143 let set_items st name items =
 144    let i = get_index st name in
 145    let script = st.scripts.(i) in
 146    let contents = List.rev_append items script.contents in
 147    st.scripts.(i) <- {script with name = name; contents = contents}
 148
 149 let set_heading st name =
 150    let heading = st.heading_path, st.heading_lines in
 151    set_items st name [T.Heading heading]
 152
 153 let require st name inc =
 154    set_items st name [T.Include inc]
 155
 156 let get_coercion st str =
 157    try List.assoc str st.coercions with Not_found -> ""
 158
 159 let make_path path =
 160    List.fold_left Filename.concat "" (List.rev path)
 161
 162 let make_prefix path =
 163    String.concat "__" (List.rev path) ^ "__"
 164
 165 let make_script_name st script name =
 166    let ext = if script.is_ma then ".ma" else ".mma" in
 167    Filename.concat st.output_path (name ^ ext)
 168
 169 let commit st name =
 170    let i = get_index st name in
 171    let script = st.scripts.(i) in
 172    let path = Filename.concat st.output_path (Filename.dirname name) in
 173    let name = make_script_name st script name in
 174    let cmd = Printf.sprintf "mkdir -p %s" path in
 175    let _ = Sys.command cmd in
 176    let och = open_out name in
 177    G.commit st.output_type och script.contents;
 178    close_out och;
 179    st.scripts.(i) <- default_script
 180
 181 let produce st =
 182    let init name = set_heading st name in
 183    let partition = function
 184       | T.Coercion (false, _)
 185       | T.Notation (false, _) -> false
 186       | _                     -> true
 187    in
 188    let produce st name =
 189       let in_base_uri = Filename.concat st.input_base_uri name in
 190       let out_base_uri = Filename.concat st.output_base_uri name in
 191       let filter path = function
 192          | T.Inline (b, k, obj, p, f)   ->
 193             let obj, p =
 194                if b then Filename.concat (make_path path) obj, make_prefix path
 195                else obj, p
 196             in
 197             let s = obj ^ G.string_of_inline_kind k in
 198             path, Some (T.Inline (b, k, Filename.concat in_base_uri s, p, f))
 199          | T.Include s                  ->
 200             begin
 201                try path, Some (T.Include (List.assoc s st.requires))
 202                with Not_found -> path, None
 203             end
 204          | T.Coercion (b, obj)          ->
 205             let str = get_coercion st obj in
 206             if str <> "" then path, Some (T.Coercion (b, str)) else
 207             let base_uri = if b then out_base_uri else in_base_uri in
 208             let s = obj ^ G.string_of_inline_kind T.Con in
 209             path, Some (T.Coercion (b, Filename.concat base_uri s))
 210          | T.Section (b, id, _) as item ->
 211             let path = if b then id :: path else List.tl path in
 212             path, Some item
 213          | item                         -> path, Some item
 214       in
 215       Printf.eprintf "processing file name: %s ...\n" name; flush stderr;
 216       let file = Filename.concat st.input_path (name ^ st.input_type) in
 217       let ich = open_in file in
 218       let lexbuf = Lexing.from_channel ich in
 219       try
 220          let items = V8Parser.items V8Lexer.token lexbuf in
 221          close_in ich;
 222          let _, rev_items = X.list_rev_map_filter_fold filter [] items in
 223          let items = List.rev rev_items in
 224          let local_items, global_items = List.partition partition items in
 225          let comment = T.Line (Printf.sprintf "From %s" name) in
 226          if global_items <> [] then
 227             set_items st st.input_package (comment :: global_items);
 228          init name; require st name st.input_package;
 229          set_items st name local_items; commit st name
 230       with e ->
 231          prerr_endline (Printexc.to_string e); close_in ich
 232    in
 233    is_ma st st.input_package;
 234    init st.input_package; require st st.input_package "preamble";
 235    List.iter (produce st) st.files;
 236    commit st st.input_package