helm/software/components/cic/cicParser.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 let debug = false
  29 let debug_print s = if debug then prerr_endline (Lazy.force s)
  30
  31 open Printf
  32
  33 (* ZACK TODO element from the DTD still to be handled:
  34    <!ELEMENT CurrentProof (Conjecture*,body)>
  35    <!ELEMENT Sequent %sequent;>
  36    <!ELEMENT Conjecture %sequent;>
  37    <!ELEMENT Decl %term;>
  38    <!ELEMENT Def %term;>
  39    <!ELEMENT Hidden EMPTY>
  40    <!ELEMENT Goal %term;>
  41 *)
  42
  43 exception Getter_failure of string * string
  44 exception Parser_failure of string
  45
  46 type stack_entry =
  47   | Arg of string * Cic.annterm (* relative uri, term *)
  48   (* constants' body and types resides in differne files, thus we can't simple
  49    * keep constants in Cic_obj stack entries *)
  50   | Cic_attributes of Cic.attribute list
  51   | Cic_constant_body of string * string * UriManager.uri list * Cic.annterm
  52       * Cic.attribute list
  53       (* id, for, params, body, object attributes *)
  54   | Cic_constant_type of string * string * UriManager.uri list * Cic.annterm
  55       * Cic.attribute list
  56       (* id, name, params, type, object attributes *)
  57   | Cic_term of Cic.annterm (* term *)
  58   | Cic_obj of Cic.annobj   (* object *)
  59   | Cofix_fun of Cic.id * string * Cic.annterm * Cic.annterm
  60       (* id, name, type, body *)
  61   | Constructor of string * Cic.annterm   (* name, type *)
  62   | Decl of Cic.id * Cic.name * Cic.annterm (* id, binder, source *)
  63   | Def of Cic.id * Cic.name * Cic.annterm * Cic.annterm  (* id, binder, source, type *)
  64   | Fix_fun of Cic.id * string * int * Cic.annterm * Cic.annterm
  65       (* id, name, ind. index, type, body *)
  66   | Inductive_type of string * string * bool * Cic.annterm *
  67       (string * Cic.annterm) list (* id, name, inductive, arity, constructors *)
  68   | Meta_subst of Cic.annterm option
  69   | Obj_class of Cic.object_class
  70   | Obj_flavour of Cic.object_flavour
  71   | Obj_field of string (* field name *)
  72   | Obj_generated
  73   | Tag of string * (string * string) list  (* tag name, attributes *)
  74       (* ZACK TODO add file position to tag stack entry so that when attribute
  75        * errors occur, the position of their _start_tag_ could be printed
  76        * instead of the current position (usually the end tag) *)
  77
  78 type ctxt = {
  79   mutable stack: stack_entry list;
  80   mutable xml_parser: XmlPushParser.xml_parser option;
  81   mutable filename: string;
  82   uri: UriManager.uri;
  83 }
  84
  85 let string_of_stack ctxt =
  86   "[" ^ (String.concat "; "
  87     (List.map
  88       (function
  89       | Arg (reluri, _) -> sprintf "Arg %s" reluri
  90       | Cic_attributes _ -> "Cic_attributes"
  91       | Cic_constant_body (id, name, _, _, _) ->
  92           sprintf "Cic_constant_body %s (id=%s)" name id
  93       | Cic_constant_type (id, name, _, _, _) ->
  94           sprintf "Cic_constant_type %s (id=%s)" name id
  95       | Cic_term _ -> "Cic_term"
  96       | Cic_obj _ -> "Cic_obj"
  97       | Constructor (name, _) -> "Constructor " ^ name
  98       | Cofix_fun (id, _, _, _) -> sprintf "Cofix_fun (id=%s)" id
  99       | Decl (id, _, _) -> sprintf "Decl (id=%s)" id
 100       | Def (id, _, _, _) -> sprintf "Def (id=%s)" id
 101       | Fix_fun (id, _, _, _, _) -> sprintf "Fix_fun (id=%s)" id
 102       | Inductive_type (id, name, _, _, _) ->
 103           sprintf "Inductive_type %s (id=%s)" name id
 104       | Meta_subst _ -> "Meta_subst"
 105       | Obj_class _ -> "Obj_class"
 106       | Obj_flavour _ -> "Obj_flavour"
 107       | Obj_field name -> "Obj_field " ^ name
 108       | Obj_generated -> "Obj_generated"
 109       | Tag (tag, _) -> "Tag " ^ tag)
 110       ctxt.stack)) ^ "]"
 111
 112 let compare_attrs (a1, v1) (a2, v2) = Pervasives.compare a1 a2
 113 let sort_attrs = List.sort compare_attrs
 114
 115 let new_parser_context uri = {
 116   stack = [];
 117   xml_parser = None;
 118   filename = "-";
 119   uri = uri;
 120 }
 121
 122 let get_parser ctxt =
 123   match ctxt.xml_parser with
 124   | Some p -> p
 125   | None -> assert false
 126
 127 (** {2 Error handling} *)
 128
 129 let parse_error ctxt msg =
 130   let (line, col) = XmlPushParser.get_position (get_parser ctxt) in
 131   raise (Parser_failure (sprintf "[%s: line %d, column %d] %s"
 132     ctxt.filename line col msg))
 133
 134 let attribute_error ctxt tag =
 135   parse_error ctxt ("wrong attribute set for " ^ tag)
 136
 137 (** {2 Parsing context management} *)
 138
 139 let pop ctxt =
 140 (*  debug_print (lazy "pop");*)
 141   match ctxt.stack with
 142   | hd :: tl -> (ctxt.stack <- tl)
 143   | _ -> assert false
 144
 145 let push ctxt v =
 146 (*  debug_print (lazy "push");*)
 147   ctxt.stack <- v :: ctxt.stack
 148
 149 let set_top ctxt v =
 150 (*  debug_print (lazy "set_top");*)
 151   match ctxt.stack with
 152   | _ :: tl -> (ctxt.stack <- v :: tl)
 153   | _ -> assert false
 154
 155   (** pop the last tag from the open tags stack returning a pair <tag_name,
 156    * attribute_list> *)
 157 let pop_tag ctxt =
 158   match ctxt.stack with
 159   | Tag (tag, attrs) :: tl ->
 160       ctxt.stack <- tl;
 161       (tag, attrs)
 162   | _ -> parse_error ctxt "unexpected extra content"
 163
 164   (** pop the last tag from the open tags stack returning its attributes.
 165    * Attributes are returned as a list of pair <name, value> _sorted_ by
 166    * attribute name *)
 167 let pop_tag_attrs ctxt = sort_attrs (snd (pop_tag ctxt))
 168
 169 let pop_cics ctxt =
 170   let rec aux acc stack =
 171     match stack with
 172     | Cic_term t :: tl -> aux (t :: acc) tl
 173     | tl -> acc, tl
 174   in
 175   let values, new_stack = aux [] ctxt.stack in
 176   ctxt.stack <- new_stack;
 177   values
 178
 179 let pop_class_modifiers ctxt =
 180   let rec aux acc stack =
 181     match stack with
 182     | (Cic_term (Cic.ASort _) as m) :: tl
 183     | (Obj_field _ as m) :: tl ->
 184         aux (m :: acc) tl
 185     | tl -> acc, tl
 186   in
 187   let values, new_stack = aux [] ctxt.stack in
 188   ctxt.stack <- new_stack;
 189   values
 190
 191 let pop_meta_substs ctxt =
 192   let rec aux acc stack =
 193     match stack with
 194     | Meta_subst t :: tl -> aux (t :: acc) tl
 195     | tl -> acc, tl
 196   in
 197   let values, new_stack = aux [] ctxt.stack in
 198   ctxt.stack <- new_stack;
 199   values
 200
 201 let pop_fix_funs ctxt =
 202   let rec aux acc stack =
 203     match stack with
 204     | Fix_fun (id, name, index, typ, body) :: tl ->
 205         aux ((id, name, index, typ, body) :: acc) tl
 206     | tl -> acc, tl
 207   in
 208   let values, new_stack = aux [] ctxt.stack in
 209   ctxt.stack <- new_stack;
 210   values
 211
 212 let pop_cofix_funs ctxt =
 213   let rec aux acc stack =
 214     match stack with
 215     | Cofix_fun (id, name, typ, body) :: tl ->
 216         aux ((id, name, typ, body) :: acc) tl
 217     | tl -> acc, tl
 218   in
 219   let values, new_stack = aux [] ctxt.stack in
 220   ctxt.stack <- new_stack;
 221   values
 222
 223 let pop_constructors ctxt =
 224   let rec aux acc stack =
 225     match stack with
 226     | Constructor (name, t) :: tl -> aux ((name, t) :: acc) tl
 227     | tl -> acc, tl
 228   in
 229   let values, new_stack = aux [] ctxt.stack in
 230   ctxt.stack <- new_stack;
 231   values
 232
 233 let pop_inductive_types ctxt =
 234   let rec aux acc stack =
 235     match stack with
 236     | Inductive_type (id, name, ind, arity, ctors) :: tl ->
 237         aux ((id, name, ind, arity, ctors) :: acc) tl
 238     | tl -> acc, tl
 239   in
 240   let values, new_stack = aux [] ctxt.stack in
 241   if values = [] then
 242     parse_error ctxt "no \"InductiveType\" element found";
 243   ctxt.stack <- new_stack;
 244   values
 245
 246   (** travels the stack (without popping) for the first term subject of explicit
 247    * named substitution and return its URI *)
 248 let find_base_uri ctxt =
 249   let rec aux = function
 250     | Cic_term (Cic.AConst (_, uri, _)) :: _
 251     | Cic_term (Cic.AMutInd (_, uri, _, _)) :: _
 252     | Cic_term (Cic.AMutConstruct (_, uri, _, _, _)) :: _
 253     | Cic_term (Cic.AVar (_, uri, _)) :: _ ->
 254         uri
 255     | Arg _ :: tl -> aux tl
 256     | _ -> parse_error ctxt "no \"arg\" element found"
 257   in
 258   UriManager.buri_of_uri (aux ctxt.stack)
 259
 260   (** backwardly eats the stack building an explicit named substitution from Arg
 261    * stack entries *)
 262 let pop_subst ctxt base_uri =
 263   let rec aux acc stack =
 264     match stack with
 265     | Arg (rel_uri, term) :: tl ->
 266         let uri = UriManager.uri_of_string (base_uri ^ "/" ^ rel_uri) in
 267         aux ((uri, term) :: acc) tl
 268     | tl -> acc, tl
 269   in
 270   let subst, new_stack = aux [] ctxt.stack in
 271   if subst = [] then
 272     parse_error ctxt "no \"arg\" element found";
 273   ctxt.stack <- new_stack;
 274   subst
 275
 276 let pop_cic ctxt =
 277   match ctxt.stack with
 278   | Cic_term t :: tl ->
 279       ctxt.stack <- tl;
 280       t
 281   | _ -> parse_error ctxt "no cic term found"
 282
 283 let pop_obj_attributes ctxt =
 284   match ctxt.stack with
 285   | Cic_attributes attributes :: tl ->
 286       ctxt.stack <- tl;
 287       attributes
 288   | _ -> []
 289
 290 (** {2 Auxiliary functions} *)
 291
 292 let uri_of_string = UriManager.uri_of_string
 293
 294 let uri_list_of_string =
 295   let space_RE = Str.regexp " " in
 296   fun s ->
 297     List.map uri_of_string (Str.split space_RE s)
 298
 299 let sort_of_string ctxt = function
 300   | "Prop" -> Cic.Prop
 301   | "Set"  -> Cic.Set
 302   | "CProp" -> Cic.CProp
 303   (* THIS CASE IS HERE ONLY TO ALLOW THE PARSING OF COQ LIBRARY
 304    * THIS SHOULD BE REMOVED AS SOON AS univ_maker OR COQ'S EXPORTATION
 305    * IS FIXED *)
 306   | "Type" ->  Cic.Type (CicUniv.fresh ~uri:ctxt.uri ())
 307   | s ->
 308       let len = String.length s in
 309       if not(len > 5) then parse_error ctxt "sort expected";
 310       if not(String.sub s 0 5 = "Type:") then parse_error ctxt "sort expected";
 311       try
 312         Cic.Type
 313           (CicUniv.fresh
 314             ~uri:ctxt.uri
 315             ~id:(int_of_string (String.sub s 5 (len - 5))) ())
 316       with
 317       | Failure "int_of_string"
 318       | Invalid_argument _ -> parse_error ctxt "sort expected"
 319
 320 let patch_subst ctxt subst = function
 321   | Cic.AConst (id, uri, _) -> Cic.AConst (id, uri, subst)
 322   | Cic.AMutInd (id, uri, typeno, _) ->
 323       Cic.AMutInd (id, uri, typeno, subst)
 324   | Cic.AMutConstruct (id, uri, typeno, consno, _) ->
 325       Cic.AMutConstruct (id, uri, typeno, consno, subst)
 326   | Cic.AVar (id, uri, _) -> Cic.AVar (id, uri, subst)
 327   | _ ->
 328       parse_error ctxt
 329         ("only \"CONST\", \"VAR\", \"MUTIND\", and \"MUTCONSTRUCT\" can be" ^
 330         " instantiated")
 331
 332   (** backwardly eats the stack seeking for the first open tag carrying
 333    * "helm:exception" attributes. If found return Some of a pair containing
 334    * exception name and argument. Return None otherwise *)
 335 let find_helm_exception ctxt =
 336   let rec aux = function
 337     | [] -> None
 338     | Tag (_, attrs) :: tl ->
 339         (try
 340           let exn = List.assoc "helm:exception" attrs in
 341           let arg =
 342             try List.assoc "helm:exception_arg" attrs with Not_found -> ""
 343           in
 344           Some (exn, arg)
 345         with Not_found -> aux tl)
 346     | _ :: tl -> aux tl
 347   in
 348   aux ctxt.stack
 349
 350 (** {2 Push parser callbacks}
 351  * each callback needs to be instantiated to a parsing context *)
 352
 353 let start_element ctxt tag attrs =
 354 (*  debug_print (lazy (sprintf "<%s%s>" tag (match attrs with | [] -> "" | _ -> " " ^ String.concat " " (List.map (fun (a,v) -> sprintf "%s=\"%s\"" a v) attrs))));*)
 355   push ctxt (Tag (tag, attrs))
 356
 357 let end_element ctxt tag =
 358 (*  debug_print (lazy (sprintf "</%s>" tag));*)
 359 (*  debug_print (lazy (string_of_stack ctxt));*)
 360   let attribute_error () = attribute_error ctxt tag in
 361   let parse_error = parse_error ctxt in
 362   let sort_of_string = sort_of_string ctxt in
 363   match tag with
 364   | "REL" ->
 365       push ctxt (Cic_term
 366         (match pop_tag_attrs ctxt with
 367         | ["binder", binder; "id", id; "idref", idref; "value", value]
 368         | ["binder", binder; "id", id; "idref", idref; "sort", _;
 369            "value", value] ->
 370             Cic.ARel (id, idref, int_of_string value, binder)
 371         | _ -> attribute_error ()))
 372   | "VAR" ->
 373       push ctxt (Cic_term
 374         (match pop_tag_attrs ctxt with
 375         | ["id", id; "uri", uri]
 376         | ["id", id; "sort", _; "uri", uri] ->
 377             Cic.AVar (id, uri_of_string uri, [])
 378         | _ -> attribute_error ()))
 379   | "CONST" ->
 380       push ctxt (Cic_term
 381         (match pop_tag_attrs ctxt with
 382         | ["id", id; "uri", uri]
 383         | ["id", id; "sort", _; "uri", uri] ->
 384             Cic.AConst (id, uri_of_string uri, [])
 385         | _ -> attribute_error ()))
 386   | "SORT" ->
 387       push ctxt (Cic_term
 388         (match pop_tag_attrs ctxt with
 389         | ["id", id; "value", sort] -> Cic.ASort (id, sort_of_string sort)
 390         | _ -> attribute_error ()))
 391   | "APPLY" ->
 392       let args = pop_cics ctxt in
 393       push ctxt (Cic_term
 394         (match pop_tag_attrs ctxt with
 395         | ["id", id ]
 396         | ["id", id; "sort", _] -> Cic.AAppl (id, args)
 397         | _ -> attribute_error ()))
 398   | "decl" ->
 399       let source = pop_cic ctxt in
 400       push ctxt
 401         (match pop_tag_attrs ctxt with
 402         | ["binder", binder; "id", id ]
 403         | ["binder", binder; "id", id; "type", _] ->
 404             Decl (id, Cic.Name binder, source)
 405         | ["id", id]
 406         | ["id", id; "type", _] -> Decl (id, Cic.Anonymous, source)
 407         | _ -> attribute_error ())
 408   | "def" ->  (* same as "decl" above *)
 409       let ty = pop_cic ctxt in
 410       let source = pop_cic ctxt in
 411       push ctxt
 412         (match pop_tag_attrs ctxt with
 413         | ["binder", binder; "id", id]
 414         | ["binder", binder; "id", id; "sort", _] ->
 415             Def (id, Cic.Name binder, source, ty)
 416         | ["id", id]
 417         | ["id", id; "sort", _] -> Def (id, Cic.Anonymous, source, ty)
 418         | _ -> attribute_error ())
 419   | "arity"           (* transparent elements (i.e. which contain a CIC) *)
 420   | "body"
 421   | "inductiveTerm"
 422   | "pattern"
 423   | "patternsType"
 424   | "target"
 425   | "term"
 426   | "type" ->
 427       let term = pop_cic ctxt in
 428       pop ctxt; (* pops start tag matching current end tag (e.g. <arity>) *)
 429       push ctxt (Cic_term term)
 430   | "substitution" ->   (* optional transparent elements (i.e. which _may_
 431                          * contain a CIC) *)
 432       set_top ctxt  (* replace <substitution> *)
 433         (match ctxt.stack with
 434         | Cic_term term :: tl ->
 435             ctxt.stack <- tl;
 436             (Meta_subst (Some term))
 437         | _ ->  Meta_subst None)
 438   | "PROD" ->
 439       let target = pop_cic ctxt in
 440       let rec add_decl target = function
 441         | Decl (id, binder, source) :: tl ->
 442             add_decl (Cic.AProd (id, binder, source, target)) tl
 443         | tl ->
 444             ctxt.stack <- tl;
 445             target
 446       in
 447       let term = add_decl target ctxt.stack in
 448       (match pop_tag_attrs ctxt with
 449         []
 450       | ["type", _] -> ()
 451       | _ -> attribute_error ());
 452       push ctxt (Cic_term term)
 453   | "LAMBDA" ->
 454       let target = pop_cic ctxt in
 455       let rec add_decl target = function
 456         | Decl (id, binder, source) :: tl ->
 457             add_decl (Cic.ALambda (id, binder, source, target)) tl
 458         | tl ->
 459             ctxt.stack <- tl;
 460             target
 461       in
 462       let term = add_decl target ctxt.stack in
 463       (match pop_tag_attrs ctxt with
 464         []
 465       | ["sort", _] -> ()
 466       | _ -> attribute_error ());
 467       push ctxt (Cic_term term)
 468   | "LETIN" ->
 469       let target = pop_cic ctxt in
 470       let rec add_def target = function
 471         | Def (id, binder, source, ty) :: tl ->
 472             add_def (Cic.ALetIn (id, binder, source, ty, target)) tl
 473         | tl ->
 474             ctxt.stack <- tl;
 475             target
 476       in
 477       let term = add_def target ctxt.stack in
 478       (match pop_tag_attrs ctxt with
 479         []
 480       | ["sort", _] -> ()
 481       | _ -> attribute_error ());
 482       push ctxt (Cic_term term)
 483   | "CAST" ->
 484       let typ = pop_cic ctxt in
 485       let term = pop_cic ctxt in
 486       push ctxt (Cic_term
 487         (match pop_tag_attrs ctxt with
 488           ["id", id]
 489         | ["id", id; "sort", _] -> Cic.ACast (id, term, typ)
 490         | _ -> attribute_error ()));
 491   | "IMPLICIT" ->
 492       push ctxt (Cic_term
 493         (match pop_tag_attrs ctxt with
 494         | ["id", id] -> Cic.AImplicit (id, None)
 495         | ["annotation", annotation; "id", id] ->
 496             let implicit_annotation =
 497               match annotation with
 498               | "closed" -> `Closed
 499               | "hole" -> `Hole
 500               | "type" -> `Type
 501               | _ -> parse_error "invalid value for \"annotation\" attribute"
 502             in
 503             Cic.AImplicit (id, Some implicit_annotation)
 504         | _ -> attribute_error ()))
 505   | "META" ->
 506       let meta_substs = pop_meta_substs ctxt in
 507       push ctxt (Cic_term
 508         (match pop_tag_attrs ctxt with
 509         | ["id", id; "no", no]
 510         | ["id", id; "no", no; "sort", _] ->
 511             Cic.AMeta (id, int_of_string no, meta_substs)
 512         | _ -> attribute_error ()));
 513   | "MUTIND" ->
 514       push ctxt (Cic_term
 515         (match pop_tag_attrs ctxt with
 516         | ["id", id; "noType", noType; "uri", uri] ->
 517             Cic.AMutInd (id, uri_of_string uri, int_of_string noType, [])
 518         | _ -> attribute_error ()));
 519   | "MUTCONSTRUCT" ->
 520       push ctxt (Cic_term
 521         (match pop_tag_attrs ctxt with
 522         | ["id", id; "noConstr", noConstr; "noType", noType; "uri", uri]
 523         | ["id", id; "noConstr", noConstr; "noType", noType; "sort", _;
 524            "uri", uri] ->
 525             Cic.AMutConstruct (id, uri_of_string uri, int_of_string noType,
 526               int_of_string noConstr, [])
 527         | _ -> attribute_error ()));
 528   | "FixFunction" ->
 529       let body = pop_cic ctxt in
 530       let typ = pop_cic ctxt in
 531       push ctxt
 532         (match pop_tag_attrs ctxt with
 533         | ["id", id; "name", name; "recIndex", recIndex] ->
 534             Fix_fun (id, name, int_of_string recIndex, typ, body)
 535         | _ -> attribute_error ())
 536   | "CofixFunction" ->
 537       let body = pop_cic ctxt in
 538       let typ = pop_cic ctxt in
 539       push ctxt
 540         (match pop_tag_attrs ctxt with
 541         | ["id", id; "name", name] ->
 542             Cofix_fun (id, name, typ, body)
 543         | _ -> attribute_error ())
 544   | "FIX" ->
 545       let fix_funs = pop_fix_funs ctxt in
 546       push ctxt (Cic_term
 547         (match pop_tag_attrs ctxt with
 548         | ["id", id; "noFun", noFun]
 549         | ["id", id; "noFun", noFun; "sort", _] ->
 550             Cic.AFix (id, int_of_string noFun, fix_funs)
 551         | _ -> attribute_error ()))
 552   | "COFIX" ->
 553       let cofix_funs = pop_cofix_funs ctxt in
 554       push ctxt (Cic_term
 555         (match pop_tag_attrs ctxt with
 556         | ["id", id; "noFun", noFun]
 557         | ["id", id; "noFun", noFun; "sort", _] ->
 558             Cic.ACoFix (id, int_of_string noFun, cofix_funs)
 559         | _ -> attribute_error ()))
 560   | "MUTCASE" ->
 561       (match pop_cics ctxt with
 562       | patternsType :: inductiveTerm :: patterns ->
 563           push ctxt (Cic_term
 564             (match pop_tag_attrs ctxt with
 565             | ["id", id; "noType", noType; "uriType", uriType]
 566             | ["id", id; "noType", noType; "sort", _; "uriType", uriType] ->
 567                 Cic.AMutCase (id, uri_of_string uriType, int_of_string noType,
 568                   patternsType, inductiveTerm, patterns)
 569             | _ -> attribute_error ()))
 570       | _ -> parse_error "invalid \"MUTCASE\" content")
 571   | "Constructor" ->
 572       let typ = pop_cic ctxt in
 573       push ctxt
 574         (match pop_tag_attrs ctxt with
 575         | ["name", name] -> Constructor (name, typ)
 576         | _ -> attribute_error ())
 577   | "InductiveType" ->
 578       let constructors = pop_constructors ctxt in
 579       let arity = pop_cic ctxt in
 580       push ctxt
 581         (match pop_tag_attrs ctxt with
 582         | ["id", id; "inductive", inductive; "name", name] ->
 583             Inductive_type (id, name, bool_of_string inductive, arity,
 584               constructors)
 585         | _ -> attribute_error ())
 586   | "InductiveDefinition" ->
 587       let inductive_types = pop_inductive_types ctxt in
 588       let obj_attributes = pop_obj_attributes ctxt in
 589       push ctxt (Cic_obj
 590         (match pop_tag_attrs ctxt with
 591         | ["id", id; "noParams", noParams; "params", params] ->
 592             Cic.AInductiveDefinition (id, inductive_types,
 593               uri_list_of_string params, int_of_string noParams, obj_attributes)
 594         | _ -> attribute_error ()))
 595   | "ConstantType" ->
 596       let typ = pop_cic ctxt in
 597       let obj_attributes = pop_obj_attributes ctxt in
 598       push ctxt
 599         (match pop_tag_attrs ctxt with
 600         | ["id", id; "name", name; "params", params] ->
 601             Cic_constant_type (id, name, uri_list_of_string params, typ,
 602               obj_attributes)
 603         | _ -> attribute_error ())
 604   | "ConstantBody" ->
 605       let body = pop_cic ctxt in
 606       let obj_attributes = pop_obj_attributes ctxt in
 607       push ctxt
 608         (match pop_tag_attrs ctxt with
 609         | ["for", for_; "id", id; "params", params] ->
 610             Cic_constant_body (id, for_, uri_list_of_string params, body,
 611               obj_attributes)
 612         | _ -> attribute_error ())
 613   | "Variable" ->
 614       let typ = pop_cic ctxt in
 615       let body =
 616         match pop_cics ctxt with
 617         | [] -> None
 618         | [t] -> Some t
 619         | _ -> parse_error "wrong content for \"Variable\""
 620       in
 621       let obj_attributes = pop_obj_attributes ctxt in
 622       push ctxt (Cic_obj
 623         (match pop_tag_attrs ctxt with
 624         | ["id", id; "name", name; "params", params] ->
 625             Cic.AVariable (id, name, body, typ, uri_list_of_string params,
 626               obj_attributes)
 627         | _ -> attribute_error ()))
 628   | "arg" ->
 629       let term = pop_cic ctxt in
 630       push ctxt
 631         (match pop_tag_attrs ctxt with
 632         | ["relUri", relUri] -> Arg (relUri, term)
 633         | _ -> attribute_error ())
 634   | "instantiate" ->
 635         (* explicit named substitution handling: when the end tag of an element
 636          * subject of exlicit named subst (MUTIND, MUTCONSTRUCT, CONST, VAR) it
 637          * is stored on the stack with no substitutions (i.e. []). When the end
 638          * tag of an "instantiate" element is found we patch the term currently
 639          * on the stack with the substitution built from "instantiate" children
 640          *)
 641         (* XXX inefficiency here: first travels the <arg> elements in order to
 642          * find the baseUri, then in order to build the explicit named subst *)
 643       let base_uri = find_base_uri ctxt in
 644       let subst = pop_subst ctxt base_uri in
 645       let term = pop_cic ctxt in
 646         (* comment from CicParser3.ml:
 647          * CSC: the "id" optional attribute should be parsed and reflected in
 648          *      Cic.annterm and id = string_of_xml_attr (n#attribute "id") *)
 649         (* replace <instantiate> *)
 650       set_top ctxt (Cic_term (patch_subst ctxt subst term))
 651   | "attributes" ->
 652       let rec aux acc = function  (* retrieve object attributes *)
 653         | Obj_class c :: tl -> aux (`Class c :: acc) tl
 654         | Obj_flavour f :: tl -> aux (`Flavour f :: acc) tl
 655         | Obj_generated :: tl -> aux (`Generated :: acc) tl
 656         | tl -> acc, tl
 657       in
 658       let obj_attrs, new_stack = aux [] ctxt.stack in
 659       ctxt.stack <- new_stack;
 660       set_top ctxt (Cic_attributes obj_attrs)
 661   | "generated" -> set_top ctxt Obj_generated
 662   | "field" ->
 663       push ctxt
 664         (match pop_tag_attrs ctxt with
 665         | ["name", name] -> Obj_field name
 666         | _ -> attribute_error ())
 667   | "flavour" ->
 668       push ctxt
 669         (match pop_tag_attrs ctxt with
 670         | [ "value", "definition"] -> Obj_flavour `Definition
 671         | [ "value", "mutual_definition"] -> Obj_flavour `MutualDefinition
 672         | [ "value", "fact"] -> Obj_flavour `Fact
 673         | [ "value", "lemma"] -> Obj_flavour `Lemma
 674         | [ "value", "remark"] -> Obj_flavour `Remark
 675         | [ "value", "theorem"] -> Obj_flavour `Theorem
 676         | [ "value", "variant"] -> Obj_flavour `Variant
 677         | [ "value", "axiom"] -> Obj_flavour `Axiom
 678         | _ -> attribute_error ())
 679   | "class" ->
 680       let class_modifiers = pop_class_modifiers ctxt in
 681       push ctxt
 682         (match pop_tag_attrs ctxt with
 683         | ["value", "coercion"] -> Obj_class (`Coercion 0)
 684         | ("value", "coercion")::["arity",n]
 685         | ("arity",n)::["value", "coercion"] ->
 686             let arity = try int_of_string n with Failure _ ->
 687               parse_error "\"arity\" must be an integer"
 688             in
 689             Obj_class (`Coercion arity)
 690         | ["value", "elim"] ->
 691             (match class_modifiers with
 692             | [Cic_term (Cic.ASort (_, sort))] -> Obj_class (`Elim sort)
 693             | _ ->
 694                 parse_error
 695                   "unexpected extra content for \"elim\" object class")
 696         | ["value", "record"] ->
 697             let fields =
 698               List.map
 699                 (function
 700                   | Obj_field name ->
 701                       (match Str.split (Str.regexp " ") name with
 702                       | [name] -> name, false, 0
 703                       | [name;"coercion"] -> name,true,0
 704                       | [name;"coercion"; n] ->
 705                           let n =
 706                             try int_of_string n
 707                             with Failure _ ->
 708                               parse_error "int expected after \"coercion\""
 709                           in
 710                           name,true,n
 711                       | _ ->
 712                           parse_error
 713                             "wrong \"field\"'s name attribute")
 714                   | _ ->
 715                       parse_error
 716                         "unexpected extra content for \"record\" object class")
 717                 class_modifiers
 718             in
 719             Obj_class (`Record fields)
 720         | ["value", "projection"] -> Obj_class `Projection
 721         | ["value", "inversion"] -> Obj_class `InversionPrinciple
 722         | _ -> attribute_error ())
 723   | tag ->
 724       match find_helm_exception ctxt with
 725       | Some (exn, arg) -> raise (Getter_failure (exn, arg))
 726       | None -> parse_error (sprintf "unknown element \"%s\"" tag)
 727
 728 (** {2 Parser internals} *)
 729
 730 let has_gz_suffix fname =
 731   try
 732     let idx = String.rindex fname '.' in
 733     let suffix = String.sub fname idx (String.length fname - idx) in
 734     suffix = ".gz"
 735   with Not_found -> false
 736
 737 let parse uri filename =
 738   let ctxt = new_parser_context uri in
 739   ctxt.filename <- filename;
 740   let module P = XmlPushParser in
 741   let callbacks = {
 742     P.default_callbacks with
 743       P.start_element = Some (start_element ctxt);
 744       P.end_element = Some (end_element ctxt);
 745   } in
 746   let xml_parser = P.create_parser callbacks in
 747   ctxt.xml_parser <- Some xml_parser;
 748   try
 749     (try
 750       let xml_source =
 751         if has_gz_suffix filename then `Gzip_file filename
 752         else `File filename
 753       in
 754       P.parse xml_parser xml_source
 755     with exn ->
 756       ctxt.xml_parser <- None;
 757       (* ZACK: the above "<- None" is vital for garbage collection. Without it
 758        * we keep in memory a circular structure parser -> callbacks -> ctxt ->
 759        * parser. I don't know if the ocaml garbage collector is supposed to
 760        * collect such structures, but for sure the expat bindings will (orribly)
 761        * leak when used in conjunction with such structures *)
 762       raise exn);
 763     ctxt.xml_parser <- None; (* ZACK: same comment as above *)
 764 (*    debug_print (lazy (string_of_stack stack));*)
 765     (* assert (List.length ctxt.stack = 1) *)
 766     List.hd ctxt.stack
 767   with
 768   | Failure "int_of_string" -> parse_error ctxt "integer number expected"
 769   | Invalid_argument "bool_of_string" -> parse_error ctxt "boolean expected"
 770   | P.Parse_error msg -> parse_error ctxt ("parse error: " ^ msg)
 771   | Sys.Break
 772   | Parser_failure _
 773   | Getter_failure _ as exn ->
 774       raise exn
 775   | exn ->
 776       raise (Parser_failure ("CicParser: uncaught exception: " ^ Printexc.to_string exn))
 777
 778 (** {2 API implementation} *)
 779
 780 let annobj_of_xml uri filename filenamebody =
 781   match filenamebody with
 782   | None ->
 783       (match parse uri filename with
 784       | Cic_constant_type (id, name, params, typ, obj_attributes) ->
 785           Cic.AConstant (id, None, name, None, typ, params, obj_attributes)
 786       | Cic_obj obj -> obj
 787       | _ -> raise (Parser_failure ("no object found in " ^ filename)))
 788   | Some filenamebody ->
 789       (match parse uri filename, parse uri filenamebody with
 790       | Cic_constant_type (type_id, name, params, typ, obj_attributes),
 791         Cic_constant_body (body_id, _, _, body, _) ->
 792           Cic.AConstant (type_id, Some body_id, name, Some body, typ, params,obj_attributes)
 793       | _ ->
 794           raise (Parser_failure (sprintf "no constant found in %s, %s"
 795             filename filenamebody)))
 796
 797 let obj_of_xml uri filename filenamebody =
 798  Deannotate.deannotate_obj (annobj_of_xml uri filename filenamebody)