helm/software/components/cic_disambiguation/cicDisambiguate.ml

   1 (*
   2 Copyright (C) 1999-2006, HELM Team.
   3
   4 This file is part of HELM, an Hypertextual, Electronic
   5 Library of Mathematics, developed at the Computer Science
   6 Department, University of Bologna, Italy.
   7
   8 HELM is free software; you can redistribute it and/or
   9 modify it under the terms of the GNU General Public License
  10 as published by the Free Software Foundation; either version 2
  11 of the License, or (at your option) any later version.
  12
  13 HELM is distributed in the hope that it will be useful,
  14 but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 GNU General Public License for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with this program; if not, write to the Free Software
  20 Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 02110-1301 USA.
  22
  23 For details, see the HELM web site: http://helm.cs.unibo.it/
  24 *)
  25
  26 open Printf
  27 module Ast = CicNotationPt
  28
  29 let debug = false
  30 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  31
  32 let rec string_context_of_context =
  33  List.map
  34   (function
  35    | Cic.Name n -> Some n
  36    | Cic.Anonymous -> Some "_")
  37 ;;
  38
  39 let refine_term metasenv subst context uri ~use_coercions
  40  term expty ugraph ~localization_tbl =
  41 (*   if benchmark then incr actual_refinements; *)
  42   assert (uri=None);
  43   debug_print (lazy (sprintf "TEST_INTERPRETATION: %s" (CicPp.ppterm term)));
  44   let saved_use_coercions = !CicRefine.insert_coercions in
  45   try
  46     CicRefine.insert_coercions := use_coercions;
  47     let term =
  48       match expty with
  49       | None -> term
  50       | Some ty -> Cic.Cast(term,ty)
  51     in
  52     let term', _, metasenv',ugraph1 =
  53             CicRefine.type_of_aux' metasenv context term ugraph ~localization_tbl
  54     in
  55     let term' =
  56       match expty, term' with
  57       | None,_ -> term'
  58       | Some _,Cic.Cast (term',_) -> term'
  59       | _ -> assert false
  60     in
  61      CicRefine.insert_coercions := saved_use_coercions;
  62      (Disambiguate.Ok (term', metasenv',[],ugraph1))
  63   with
  64    exn ->
  65     CicRefine.insert_coercions := saved_use_coercions;
  66     let rec process_exn loc =
  67      function
  68         HExtlib.Localized (loc,exn) -> process_exn loc exn
  69       | CicRefine.Uncertain msg ->
  70           debug_print (lazy ("UNCERTAIN!!! [" ^ (Lazy.force msg) ^ "] " ^ CicPp.ppterm term)) ;
  71           Disambiguate.Uncertain (lazy (loc,Lazy.force msg))
  72       | CicRefine.RefineFailure msg ->
  73           debug_print (lazy (sprintf "PRUNED!!!\nterm%s\nmessage:%s"
  74             (CicPp.ppterm term) (Lazy.force msg)));
  75           Disambiguate.Ko (lazy (loc,Lazy.force msg))
  76      | exn -> raise exn
  77     in
  78      process_exn Stdpp.dummy_loc exn
  79
  80 let refine_obj metasenv subst context uri ~use_coercions obj _ ugraph
  81  ~localization_tbl =
  82    assert (context = []);
  83    assert (metasenv = []);
  84    assert (subst = []);
  85    debug_print (lazy (sprintf "TEST_INTERPRETATION: %s" (CicPp.ppobj obj))) ;
  86    let saved_use_coercions = !CicRefine.insert_coercions in
  87    try
  88      CicRefine.insert_coercions := use_coercions;
  89      let obj', metasenv,ugraph =
  90        CicRefine.typecheck metasenv uri obj ~localization_tbl
  91      in
  92       CicRefine.insert_coercions := saved_use_coercions;
  93       (Disambiguate.Ok (obj', metasenv,[],ugraph))
  94    with
  95      exn ->
  96       CicRefine.insert_coercions := saved_use_coercions;
  97       let rec process_exn loc =
  98        function
  99           HExtlib.Localized (loc,exn) -> process_exn loc exn
 100         | CicRefine.Uncertain msg ->
 101             debug_print (lazy ("UNCERTAIN!!! [" ^
 102               (Lazy.force msg) ^ "] " ^ CicPp.ppobj obj)) ;
 103             Disambiguate.Uncertain (lazy (loc,Lazy.force msg))
 104         | CicRefine.RefineFailure msg ->
 105             debug_print (lazy (sprintf "PRUNED!!!\nterm%s\nmessage:%s"
 106               (CicPp.ppobj obj) (Lazy.force msg))) ;
 107             Disambiguate.Ko (lazy (loc,Lazy.force msg))
 108        | exn -> raise exn
 109       in
 110        process_exn Stdpp.dummy_loc exn
 111 ;;
 112
 113 let interpretate_term ~mk_choice ?(create_dummy_ids=false) ~context ~env ~uri
 114  ~is_path ast ~localization_tbl ~obj_context
 115 =
 116   (* create_dummy_ids shouldbe used only for interpretating patterns *)
 117   assert (uri = None);
 118   let rec aux ~localize loc context = function
 119     | CicNotationPt.AttributedTerm (`Loc loc, term) ->
 120         let res = aux ~localize loc context term in
 121          if localize then Cic.CicHash.add localization_tbl res loc;
 122          res
 123     | CicNotationPt.AttributedTerm (_, term) -> aux ~localize loc context term
 124     | CicNotationPt.Appl (CicNotationPt.Symbol (symb, i) :: args) ->
 125         let cic_args = List.map (aux ~localize loc context) args in
 126         Disambiguate.resolve ~mk_choice ~env
 127           (DisambiguateTypes.Symbol (symb, i)) (`Args cic_args)
 128     | CicNotationPt.Appl terms ->
 129        Cic.Appl (List.map (aux ~localize loc context) terms)
 130     | CicNotationPt.Binder (binder_kind, (var, typ), body) ->
 131         let cic_type = aux_option ~localize loc context (Some `Type) typ in
 132         let cic_name = CicNotationUtil.cic_name_of_name var in
 133         let cic_body = aux ~localize loc (cic_name :: context) body in
 134         (match binder_kind with
 135         | `Lambda -> Cic.Lambda (cic_name, cic_type, cic_body)
 136         | `Pi
 137         | `Forall -> Cic.Prod (cic_name, cic_type, cic_body)
 138         | `Exists ->
 139             Disambiguate.resolve ~mk_choice ~env
 140              (DisambiguateTypes.Symbol ("exists", 0))
 141              (`Args [ cic_type; Cic.Lambda (cic_name, cic_type, cic_body) ]))
 142     | CicNotationPt.Case (term, indty_ident, outtype, branches) ->
 143         let cic_term = aux ~localize loc context term in
 144         let cic_outtype = aux_option ~localize loc context None outtype in
 145         let do_branch ((head, _, args), term) =
 146          let rec do_branch' context = function
 147            | [] -> aux ~localize loc context term
 148            | (name, typ) :: tl ->
 149                let cic_name = CicNotationUtil.cic_name_of_name name in
 150                let cic_body = do_branch' (cic_name :: context) tl in
 151                let typ =
 152                  match typ with
 153                  | None -> Cic.Implicit (Some `Type)
 154                  | Some typ -> aux ~localize loc context typ
 155                in
 156                Cic.Lambda (cic_name, typ, cic_body)
 157          in
 158           do_branch' context args
 159         in
 160         let indtype_uri, indtype_no =
 161           if create_dummy_ids then
 162             (UriManager.uri_of_string "cic:/fake_indty.con", 0)
 163           else
 164           match indty_ident with
 165           | Some (indty_ident, _) ->
 166              (match
 167                Disambiguate.resolve ~mk_choice ~env
 168                 (DisambiguateTypes.Id indty_ident) (`Args [])
 169               with
 170               | Cic.MutInd (uri, tyno, _) -> (uri, tyno)
 171               | Cic.Implicit _ ->
 172                  raise (Disambiguate.Try_again
 173                    (lazy "The type of the term to be matched
 174                   is still unknown"))
 175               | _ ->
 176                 raise (DisambiguateTypes.Invalid_choice (lazy (loc,"The type of the term to be matched is not (co)inductive!"))))
 177           | None ->
 178               let rec fst_constructor =
 179                 function
 180                    (Ast.Pattern (head, _, _), _) :: _ -> head
 181                  | (Ast.Wildcard, _) :: tl -> fst_constructor tl
 182                  | [] -> raise (DisambiguateTypes.Invalid_choice (lazy (loc,"The type of the term to be matched cannot be determined because it is an inductive type without constructors or because all patterns use wildcards")))
 183               in
 184               (match Disambiguate.resolve ~mk_choice ~env
 185                 (DisambiguateTypes.Id (fst_constructor branches))
 186                 (`Args []) with
 187               | Cic.MutConstruct (indtype_uri, indtype_no, _, _) ->
 188                   (indtype_uri, indtype_no)
 189               | Cic.Implicit _ ->
 190                  raise (Disambiguate.Try_again (lazy "The type of the term to be matched
 191                   is still unknown"))
 192               | _ ->
 193                 raise (DisambiguateTypes.Invalid_choice (lazy (loc,"The type of the term to be matched is not (co)inductive!"))))
 194         in
 195         let branches =
 196          if create_dummy_ids then
 197           List.map
 198            (function
 199                Ast.Wildcard,term -> ("wildcard",None,[]), term
 200              | Ast.Pattern _,_ ->
 201                 raise (DisambiguateTypes.Invalid_choice (lazy (loc, "Syntax error: the left hand side of a branch patterns must be \"_\"")))
 202            ) branches
 203          else
 204          match fst(CicEnvironment.get_obj CicUniv.oblivion_ugraph indtype_uri) with
 205             Cic.InductiveDefinition (il,_,leftsno,_) ->
 206              let _,_,_,cl =
 207               try
 208                List.nth il indtype_no
 209               with _ -> assert false
 210              in
 211               let rec count_prod t =
 212                 match CicReduction.whd [] t with
 213                     Cic.Prod (_, _, t) -> 1 + (count_prod t)
 214                   | _ -> 0
 215               in
 216               let rec sort branches cl =
 217                match cl with
 218                   [] ->
 219                    let rec analyze unused unrecognized useless =
 220                     function
 221                        [] ->
 222                         if unrecognized != [] then
 223                          raise (DisambiguateTypes.Invalid_choice
 224                           (lazy (loc,
 225                             ("Unrecognized constructors: " ^
 226                              String.concat " " unrecognized))))
 227                         else if useless > 0 then
 228                          raise (DisambiguateTypes.Invalid_choice
 229                            (lazy (loc,
 230                             ("The last " ^ string_of_int useless ^
 231                              "case" ^ if useless > 1 then "s are" else " is" ^
 232                              " unused"))))
 233                         else
 234                          []
 235                      | (Ast.Wildcard,_)::tl when not unused ->
 236                          analyze true unrecognized useless tl
 237                      | (Ast.Pattern (head,_,_),_)::tl when not unused ->
 238                          analyze unused (head::unrecognized) useless tl
 239                      | _::tl -> analyze unused unrecognized (useless + 1) tl
 240                    in
 241                     analyze false [] 0 branches
 242                 | (name,ty)::cltl ->
 243                    let rec find_and_remove =
 244                     function
 245                        [] ->
 246                         raise
 247                          (DisambiguateTypes.Invalid_choice
 248                           (lazy (loc, ("Missing case: " ^ name))))
 249                      | ((Ast.Wildcard, _) as branch :: _) as branches ->
 250                          branch, branches
 251                      | (Ast.Pattern (name',_,_),_) as branch :: tl
 252                         when name = name' ->
 253                          branch,tl
 254                      | branch::tl ->
 255                         let found,rest = find_and_remove tl in
 256                          found, branch::rest
 257                    in
 258                     let branch,tl = find_and_remove branches in
 259                     match branch with
 260                        Ast.Pattern (name,y,args),term ->
 261                         if List.length args = count_prod ty - leftsno then
 262                          ((name,y,args),term)::sort tl cltl
 263                         else
 264                          raise
 265                           (DisambiguateTypes.Invalid_choice
 266                             (lazy (loc,"Wrong number of arguments for " ^
 267                             name)))
 268                      | Ast.Wildcard,term ->
 269                         let rec mk_lambdas =
 270                          function
 271                             0 -> term
 272                           | n ->
 273                              CicNotationPt.Binder
 274                               (`Lambda, (CicNotationPt.Ident ("_", None), None),
 275                                 mk_lambdas (n - 1))
 276                         in
 277                          (("wildcard",None,[]),
 278                           mk_lambdas (count_prod ty - leftsno)) :: sort tl cltl
 279               in
 280                sort branches cl
 281           | _ -> assert false
 282         in
 283         Cic.MutCase (indtype_uri, indtype_no, cic_outtype, cic_term,
 284           (List.map do_branch branches))
 285     | CicNotationPt.Cast (t1, t2) ->
 286         let cic_t1 = aux ~localize loc context t1 in
 287         let cic_t2 = aux ~localize loc context t2 in
 288         Cic.Cast (cic_t1, cic_t2)
 289     | CicNotationPt.LetIn ((name, typ), def, body) ->
 290         let cic_def = aux ~localize loc context def in
 291         let cic_name = CicNotationUtil.cic_name_of_name name in
 292         let cic_typ =
 293           match typ with
 294           | None -> Cic.Implicit (Some `Type)
 295           | Some t -> aux ~localize loc context t
 296         in
 297         let cic_body = aux ~localize loc (cic_name :: context) body in
 298         Cic.LetIn (cic_name, cic_def, cic_typ, cic_body)
 299     | CicNotationPt.LetRec (kind, defs, body) ->
 300         let context' =
 301           List.fold_left
 302             (fun acc (_, (name, _), _, _) ->
 303               CicNotationUtil.cic_name_of_name name :: acc)
 304             context defs
 305         in
 306         let cic_body =
 307          let unlocalized_body = aux ~localize:false loc context' body in
 308          match unlocalized_body with
 309             Cic.Rel n when n <= List.length defs -> `AvoidLetInNoAppl n
 310           | Cic.Appl (Cic.Rel n::l) when n <= List.length defs ->
 311              (try
 312                let l' =
 313                 List.map
 314                  (function t ->
 315                    let t',subst,metasenv =
 316                     CicMetaSubst.delift_rels [] [] (List.length defs) t
 317                    in
 318                     assert (subst=[]);
 319                     assert (metasenv=[]);
 320                     t') l
 321                in
 322                 (* We can avoid the LetIn. But maybe we need to recompute l'
 323                    so that it is localized *)
 324                 if localize then
 325                  match body with
 326                     CicNotationPt.AttributedTerm (_,CicNotationPt.Appl(_::l)) ->
 327                      (* since we avoid the letin, the context has no
 328                       * recfuns in it *)
 329                      let l' = List.map (aux ~localize loc context) l in
 330                       `AvoidLetIn (n,l')
 331                   | _ -> assert false
 332                 else
 333                  `AvoidLetIn (n,l')
 334               with
 335                CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
 336                 if localize then
 337                  `AddLetIn (aux ~localize loc context' body)
 338                 else
 339                  `AddLetIn unlocalized_body)
 340           | _ ->
 341              if localize then
 342               `AddLetIn (aux ~localize loc context' body)
 343              else
 344               `AddLetIn unlocalized_body
 345         in
 346         let inductiveFuns =
 347           List.map
 348             (fun (params, (name, typ), body, decr_idx) ->
 349               let add_binders kind t =
 350                List.fold_right
 351                 (fun var t -> CicNotationPt.Binder (kind, var, t)) params t
 352               in
 353               let cic_body =
 354                aux ~localize loc context' (add_binders `Lambda body) in
 355               let cic_type =
 356                aux_option ~localize loc context (Some `Type)
 357                 (HExtlib.map_option (add_binders `Pi) typ) in
 358               let name =
 359                 match CicNotationUtil.cic_name_of_name name with
 360                 | Cic.Anonymous ->
 361                     CicNotationPt.fail loc
 362                       "Recursive functions cannot be anonymous"
 363                 | Cic.Name name -> name
 364               in
 365               (name, decr_idx, cic_type, cic_body))
 366             defs
 367         in
 368         let fix_or_cofix n =
 369          match kind with
 370             `Inductive -> Cic.Fix (n,inductiveFuns)
 371           | `CoInductive ->
 372               let coinductiveFuns =
 373                 List.map
 374                  (fun (name, _, typ, body) -> name, typ, body)
 375                  inductiveFuns
 376               in
 377                Cic.CoFix (n,coinductiveFuns)
 378         in
 379          let counter = ref ~-1 in
 380          let build_term funs (var,_,ty,_) t =
 381           incr counter;
 382           Cic.LetIn (Cic.Name var, fix_or_cofix !counter, ty, t)
 383          in
 384           (match cic_body with
 385               `AvoidLetInNoAppl n ->
 386                 let n' = List.length inductiveFuns - n in
 387                  fix_or_cofix n'
 388             | `AvoidLetIn (n,l) ->
 389                 let n' = List.length inductiveFuns - n in
 390                  Cic.Appl (fix_or_cofix n'::l)
 391             | `AddLetIn cic_body ->
 392                 List.fold_right (build_term inductiveFuns) inductiveFuns
 393                  cic_body)
 394     | CicNotationPt.Ident _
 395     | CicNotationPt.Uri _
 396     | CicNotationPt.NRef _ when is_path -> raise Disambiguate.PathNotWellFormed
 397     | CicNotationPt.NRef _ -> assert false
 398     | CicNotationPt.Ident (name,subst)
 399     | CicNotationPt.Uri (name, subst) as ast ->
 400         let is_uri = function CicNotationPt.Uri _ -> true | _ -> false in
 401         (try
 402           if is_uri ast then raise Not_found;(* don't search the env for URIs *)
 403           let index =
 404            Disambiguate.find_in_context name (string_context_of_context context)
 405           in
 406           if subst <> None then
 407             CicNotationPt.fail loc "Explicit substitutions not allowed here";
 408           Cic.Rel index
 409         with Not_found ->
 410           let cic =
 411             if is_uri ast then  (* we have the URI, build the term out of it *)
 412               try
 413                 CicUtil.term_of_uri (UriManager.uri_of_string name)
 414               with UriManager.IllFormedUri _ ->
 415                 CicNotationPt.fail loc "Ill formed URI"
 416             else
 417              try
 418               List.assoc name obj_context
 419              with
 420               Not_found ->
 421                Disambiguate.resolve ~mk_choice ~env
 422                 (DisambiguateTypes.Id name) (`Args [])
 423           in
 424           let mk_subst uris =
 425             let ids_to_uris =
 426               List.map (fun uri -> UriManager.name_of_uri uri, uri) uris
 427             in
 428             (match subst with
 429             | Some subst ->
 430                 List.map
 431                   (fun (s, term) ->
 432                     (try
 433                       List.assoc s ids_to_uris, aux ~localize loc context term
 434                      with Not_found ->
 435                        raise (DisambiguateTypes.Invalid_choice (lazy (loc, "The provided explicit named substitution is trying to instantiate a named variable the object is not abstracted on")))))
 436                   subst
 437             | None -> List.map (fun uri -> uri, Cic.Implicit None) uris)
 438           in
 439           (try
 440             match cic with
 441             | Cic.Const (uri, []) ->
 442                 let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph uri in
 443                 let uris = CicUtil.params_of_obj o in
 444                 Cic.Const (uri, mk_subst uris)
 445             | Cic.Var (uri, []) ->
 446                 let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph uri in
 447                 let uris = CicUtil.params_of_obj o in
 448                 Cic.Var (uri, mk_subst uris)
 449             | Cic.MutInd (uri, i, []) ->
 450                (try
 451                  let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph uri in
 452                  let uris = CicUtil.params_of_obj o in
 453                  Cic.MutInd (uri, i, mk_subst uris)
 454                 with
 455                  CicEnvironment.Object_not_found _ ->
 456                   (* if we are here it is probably the case that during the
 457                      definition of a mutual inductive type we have met an
 458                      occurrence of the type in one of its constructors.
 459                      However, the inductive type is not yet in the environment
 460                   *)
 461                   (*here the explicit_named_substituion is assumed to be of length 0 *)
 462                   Cic.MutInd (uri,i,[]))
 463             | Cic.MutConstruct (uri, i, j, []) ->
 464                 let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph uri in
 465                 let uris = CicUtil.params_of_obj o in
 466                 Cic.MutConstruct (uri, i, j, mk_subst uris)
 467             | Cic.Meta _ | Cic.Implicit _ as t ->
 468 (*
 469                 debug_print (lazy (sprintf
 470                   "Warning: %s must be instantiated with _[%s] but we do not enforce it"
 471                   (CicPp.ppterm t)
 472                   (String.concat "; "
 473                     (List.map
 474                       (fun (s, term) -> s ^ " := " ^ CicNotationPtPp.pp_term term)
 475                       subst))));
 476 *)
 477                 t
 478             | _ ->
 479               raise (DisambiguateTypes.Invalid_choice (lazy (loc, "??? Can this happen?")))
 480            with
 481              CicEnvironment.CircularDependency _ ->
 482                raise (DisambiguateTypes.Invalid_choice (lazy (loc,"Circular dependency in the environment")))))
 483     | CicNotationPt.Implicit -> Cic.Implicit None
 484     | CicNotationPt.UserInput -> Cic.Implicit (Some `Hole)
 485     | CicNotationPt.Num (num, i) ->
 486        Disambiguate.resolve ~mk_choice ~env
 487         (DisambiguateTypes.Num i) (`Num_arg num)
 488     | CicNotationPt.Meta (index, subst) ->
 489         let cic_subst =
 490           List.map
 491             (function
 492                 None -> None
 493               | Some term -> Some (aux ~localize loc context term))
 494             subst
 495         in
 496         Cic.Meta (index, cic_subst)
 497     | CicNotationPt.Sort `Prop -> Cic.Sort Cic.Prop
 498     | CicNotationPt.Sort `Set -> Cic.Sort Cic.Set
 499     | CicNotationPt.Sort (`Type u) -> Cic.Sort (Cic.Type u)
 500     | CicNotationPt.Sort (`NType _) -> Cic.Sort (Cic.Type (CicUniv.fresh ()))
 501     | CicNotationPt.Sort (`NCProp _) -> Cic.Sort (Cic.CProp (CicUniv.fresh ()))
 502     | CicNotationPt.Sort (`CProp u) -> Cic.Sort (Cic.CProp u)
 503     | CicNotationPt.Symbol (symbol, instance) ->
 504         Disambiguate.resolve ~mk_choice ~env
 505          (DisambiguateTypes.Symbol (symbol, instance)) (`Args [])
 506     | CicNotationPt.Variable _
 507     | CicNotationPt.Magic _
 508     | CicNotationPt.Layout _
 509     | CicNotationPt.Literal _ -> assert false (* god bless Bologna *)
 510   and aux_option ~localize loc context annotation = function
 511     | None -> Cic.Implicit annotation
 512     | Some term -> aux ~localize loc context term
 513   in
 514    aux ~localize:true HExtlib.dummy_floc context ast
 515
 516 let interpretate_path ~context path =
 517  let localization_tbl = Cic.CicHash.create 23 in
 518   (* here we are throwing away useful localization informations!!! *)
 519   fst (
 520    interpretate_term ~mk_choice:(fun _ -> assert false) ~create_dummy_ids:true
 521     ~context ~env:DisambiguateTypes.Environment.empty ~uri:None ~is_path:true
 522     path ~localization_tbl ~obj_context:[], localization_tbl)
 523
 524 let interpretate_obj ~mk_choice ~context ~env ~uri ~is_path obj
 525  ~localization_tbl
 526 =
 527  assert (context = []);
 528  assert (is_path = false);
 529  let interpretate_term ?(obj_context=[]) =
 530   interpretate_term ~mk_choice ~localization_tbl ~obj_context in
 531  match obj with
 532   | CicNotationPt.Inductive (params,tyl) ->
 533      let uri = match uri with Some uri -> uri | None -> assert false in
 534      let context,params =
 535       let context,res =
 536        List.fold_left
 537         (fun (context,res) (name,t) ->
 538           let t =
 539            match t with
 540               None -> CicNotationPt.Implicit
 541             | Some t -> t in
 542           let name = CicNotationUtil.cic_name_of_name name in
 543            name::context,(name, interpretate_term context env None false t)::res
 544         ) ([],[]) params
 545       in
 546        context,List.rev res in
 547      let add_params =
 548       List.fold_right (fun (name,ty) t -> Cic.Prod (name,ty,t)) params in
 549      let obj_context =
 550       snd (
 551        List.fold_left
 552         (*here the explicit_named_substituion is assumed to be of length 0 *)
 553         (fun (i,res) (name,_,_,_) -> i + 1,(name,Cic.MutInd (uri,i,[]))::res)
 554         (0,[]) tyl) in
 555      let tyl =
 556       List.map
 557        (fun (name,b,ty,cl) ->
 558          let ty' = add_params (interpretate_term context env None false ty) in
 559          let cl' =
 560           List.map
 561            (fun (name,ty) ->
 562              let ty' =
 563               add_params
 564                (interpretate_term ~obj_context ~context ~env ~uri:None
 565                  ~is_path:false ty)
 566              in
 567               name,ty'
 568            ) cl
 569          in
 570           name,b,ty',cl'
 571        ) tyl
 572      in
 573       Cic.InductiveDefinition (tyl,[],List.length params,[])
 574   | CicNotationPt.Record (params,name,ty,fields) ->
 575      let uri = match uri with Some uri -> uri | None -> assert false in
 576      let context,params =
 577       let context,res =
 578        List.fold_left
 579         (fun (context,res) (name,t) ->
 580           let t =
 581            match t with
 582               None -> CicNotationPt.Implicit
 583             | Some t -> t in
 584           let name = CicNotationUtil.cic_name_of_name name in
 585            name::context,(name, interpretate_term context env None false t)::res
 586         ) ([],[]) params
 587       in
 588        context,List.rev res in
 589      let add_params =
 590       List.fold_right
 591        (fun (name,ty) t -> Cic.Prod (name,ty,t)) params in
 592      let ty' = add_params (interpretate_term context env None false ty) in
 593      let fields' =
 594       snd (
 595        List.fold_left
 596         (fun (context,res) (name,ty,_coercion,arity) ->
 597           let context' = Cic.Name name :: context in
 598            context',(name,interpretate_term context env None false ty)::res
 599         ) (context,[]) fields) in
 600      let concl =
 601       (*here the explicit_named_substituion is assumed to be of length 0 *)
 602       let mutind = Cic.MutInd (uri,0,[]) in
 603       if params = [] then mutind
 604       else
 605        Cic.Appl
 606         (mutind::CicUtil.mk_rels (List.length params) (List.length fields)) in
 607      let con =
 608       List.fold_left
 609        (fun t (name,ty) -> Cic.Prod (Cic.Name name,ty,t))
 610        concl fields' in
 611      let con' = add_params con in
 612      let tyl = [name,true,ty',["mk_" ^ name,con']] in
 613      let field_names = List.map (fun (x,_,y,z) -> x,y,z) fields in
 614       Cic.InductiveDefinition
 615        (tyl,[],List.length params,[`Class (`Record field_names)])
 616   | CicNotationPt.Theorem (flavour, name, ty, bo) ->
 617      let attrs = [`Flavour flavour] in
 618      let ty' = interpretate_term [] env None false ty in
 619      (match bo,flavour with
 620         None,`Axiom ->
 621          Cic.Constant (name,None,ty',[],attrs)
 622       | Some bo,`Axiom -> assert false
 623       | None,_ ->
 624          Cic.CurrentProof (name,[],Cic.Implicit None,ty',[],attrs)
 625       | Some bo,_ ->
 626          let bo' = Some (interpretate_term [] env None false bo) in
 627           Cic.Constant (name,bo',ty',[],attrs))
 628 ;;
 629
 630 let interpretate_term ~mk_choice ?(create_dummy_ids=false) ~context ~env ~uri
 631  ~is_path ast ~localization_tbl
 632 =
 633   let context =
 634    List.map (function None -> Cic.Anonymous | Some (n,_) -> n) context
 635   in
 636    interpretate_term ~mk_choice ~create_dummy_ids ~context ~env ~uri ~is_path
 637     ast ~localization_tbl ~obj_context:[]
 638 ;;
 639
 640 let string_context_of_context =
 641   List.map (function None -> None | Some (Cic.Name n,_) -> Some n | Some
 642   (Cic.Anonymous,_) -> Some "_");;
 643
 644 let disambiguate_term ~context ~metasenv ~subst ~expty
 645   ?(initial_ugraph = CicUniv.oblivion_ugraph)
 646   ~mk_implicit ~description_of_alias ~mk_choice
 647   ~aliases ~universe ~lookup_in_library (text,prefix_len,term)
 648 =
 649   let mk_localization_tbl x = Cic.CicHash.create x in
 650    MultiPassDisambiguator.disambiguate_thing ~context ~metasenv ~subst
 651     ~initial_ugraph ~aliases ~string_context_of_context
 652     ~universe ~lookup_in_library ~mk_implicit ~description_of_alias
 653     ~uri:None ~pp_thing:CicNotationPp.pp_term
 654     ~domain_of_thing:Disambiguate.domain_of_term
 655     ~interpretate_thing:(interpretate_term (?create_dummy_ids:None) ~mk_choice)
 656     ~refine_thing:refine_term (text,prefix_len,term)
 657     ~mk_localization_tbl
 658     ~expty
 659     ~freshen_thing:CicNotationUtil.freshen_term
 660     ~passes:(MultiPassDisambiguator.passes ())
 661
 662 let disambiguate_obj ~mk_implicit ~description_of_alias ~mk_choice
 663  ~aliases ~universe ~lookup_in_library ~uri (text,prefix_len,obj)
 664 =
 665   let mk_localization_tbl x = Cic.CicHash.create x in
 666   MultiPassDisambiguator.disambiguate_thing ~context:[] ~metasenv:[] ~subst:[]
 667     ~aliases ~universe ~uri ~string_context_of_context
 668     ~pp_thing:(CicNotationPp.pp_obj CicNotationPp.pp_term)
 669     ~domain_of_thing:Disambiguate.domain_of_obj
 670     ~lookup_in_library ~mk_implicit ~description_of_alias
 671     ~initial_ugraph:CicUniv.empty_ugraph
 672     ~interpretate_thing:(interpretate_obj ~mk_choice)
 673     ~refine_thing:refine_obj
 674     ~mk_localization_tbl
 675     ~expty:None
 676     ~passes:(MultiPassDisambiguator.passes ())
 677     ~freshen_thing:CicNotationUtil.freshen_obj
 678     (text,prefix_len,obj)