helm/software/components/cic_unification/cicUnification.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception UnificationFailure of string Lazy.t;;
  31 exception Uncertain of string Lazy.t;;
  32 exception AssertFailure of string Lazy.t;;
  33
  34 let verbose = false;;
  35 let debug_print = fun _ -> ()
  36
  37 let profiler_toa = HExtlib.profile "fo_unif_subst.type_of_aux'"
  38 let profiler_beta_expand = HExtlib.profile "fo_unif_subst.beta_expand"
  39 let profiler_deref = HExtlib.profile "fo_unif_subst.deref'"
  40 let profiler_are_convertible = HExtlib.profile "fo_unif_subst.are_convertible"
  41
  42 let profile = HExtlib.profile "U/CicTypeChecker.type_of_aux'"
  43
  44 let type_of_aux' metasenv subst context term ugraph =
  45 let foo () =
  46   try
  47     profile.HExtlib.profile
  48       (CicTypeChecker.type_of_aux' ~subst metasenv context term) ugraph
  49   with
  50       CicTypeChecker.TypeCheckerFailure msg ->
  51         let msg =
  52          lazy
  53           (sprintf
  54            "Kernel Type checking error:
  55 %s\n%s\ncontext=\n%s\nmetasenv=\n%s\nsubstitution=\n%s\nException:\n%s.\nToo bad."
  56              (CicMetaSubst.ppterm ~metasenv subst term)
  57              (CicMetaSubst.ppterm ~metasenv [] term)
  58              (CicMetaSubst.ppcontext ~metasenv subst context)
  59              (CicMetaSubst.ppmetasenv subst metasenv)
  60              (CicMetaSubst.ppsubst ~metasenv subst) (Lazy.force msg)) in
  61         raise (AssertFailure msg)
  62     | CicTypeChecker.AssertFailure msg ->
  63         let msg = lazy
  64          (sprintf
  65            "Kernel Type checking assertion failure:
  66 %s\n%s\ncontext=\n%s\nmetasenv=\n%s\nsubstitution=\n%s\nException:\n%s.\nToo bad."
  67              (CicMetaSubst.ppterm ~metasenv subst term)
  68              (CicMetaSubst.ppterm ~metasenv [] term)
  69              (CicMetaSubst.ppcontext ~metasenv subst context)
  70              (CicMetaSubst.ppmetasenv subst metasenv)
  71              (CicMetaSubst.ppsubst ~metasenv subst) (Lazy.force msg)) in
  72         raise (AssertFailure msg)
  73 in profiler_toa.HExtlib.profile foo ()
  74 ;;
  75
  76 let exists_a_meta l =
  77   List.exists
  78     (function
  79        | Cic.Meta _
  80        | Cic.Appl (Cic.Meta _::_) -> true
  81        | _ -> false) l
  82
  83 let rec deref subst t =
  84   let snd (_,a,_) = a in
  85   match t with
  86       Cic.Meta(n,l) ->
  87         (try
  88            deref subst
  89              (CicSubstitution.subst_meta
  90                 l (snd (CicUtil.lookup_subst n subst)))
  91          with
  92              CicUtil.Subst_not_found _ -> t)
  93     | Cic.Appl(Cic.Meta(n,l)::args) ->
  94         (match deref subst (Cic.Meta(n,l)) with
  95            | Cic.Lambda _ as t ->
  96                deref subst (CicReduction.head_beta_reduce (Cic.Appl(t::args)))
  97            | r -> Cic.Appl(r::args))
  98     | Cic.Appl(((Cic.Lambda _) as t)::args) ->
  99            deref subst (CicReduction.head_beta_reduce (Cic.Appl(t::args)))
 100     | t -> t
 101 ;;
 102
 103 let deref subst t =
 104  let foo () = deref subst t
 105  in profiler_deref.HExtlib.profile foo ()
 106
 107 exception WrongShape;;
 108 let eta_reduce after_beta_expansion after_beta_expansion_body
 109      before_beta_expansion
 110  =
 111  try
 112   match before_beta_expansion,after_beta_expansion_body with
 113      Cic.Appl l, Cic.Appl l' ->
 114       let rec all_but_last check_last =
 115        function
 116           [] -> assert false
 117         | [Cic.Rel 1] -> []
 118         | [_] -> if check_last then raise WrongShape else []
 119         | he::tl -> he::(all_but_last check_last tl)
 120       in
 121        let all_but_last check_last l =
 122         match all_but_last check_last l with
 123            [] -> assert false
 124          | [he] -> he
 125          | l -> Cic.Appl l
 126        in
 127        let t = CicSubstitution.subst (Cic.Rel (-1)) (all_but_last true l') in
 128        let all_but_last = all_but_last false l in
 129         (* here we should test alpha-equivalence; however we know by
 130            construction that here alpha_equivalence is equivalent to = *)
 131         if t = all_but_last then
 132          all_but_last
 133         else
 134          after_beta_expansion
 135    | _,_ -> after_beta_expansion
 136  with
 137   WrongShape -> after_beta_expansion
 138
 139 let rec beta_expand num test_equality_only metasenv subst context t arg ugraph =
 140  let module S = CicSubstitution in
 141  let module C = Cic in
 142 let foo () =
 143   let rec aux metasenv subst n context t' ugraph =
 144    try
 145
 146     let subst,metasenv,ugraph1 =
 147      fo_unif_subst test_equality_only subst context metasenv
 148       (CicSubstitution.lift n arg) t' ugraph
 149
 150     in
 151      subst,metasenv,C.Rel (1 + n),ugraph1
 152    with
 153       Uncertain _
 154     | UnificationFailure _ ->
 155        match t' with
 156         | C.Rel m  -> subst,metasenv,
 157            (if m <= n then C.Rel m else C.Rel (m+1)),ugraph
 158         | C.Var (uri,exp_named_subst) ->
 159            let subst,metasenv,exp_named_subst',ugraph1 =
 160             aux_exp_named_subst metasenv subst n context exp_named_subst ugraph
 161            in
 162             subst,metasenv,C.Var (uri,exp_named_subst'),ugraph1
 163         | C.Meta (i,l) ->
 164             (* andrea: in general, beta_expand can create badly typed
 165              terms. This happens quite seldom in practice, UNLESS we
 166              iterate on the local context. For this reason, we renounce
 167              to iterate and just lift *)
 168             let l =
 169               List.map
 170                 (function
 171                      Some t -> Some (CicSubstitution.lift 1 t)
 172                    | None -> None) l in
 173             subst, metasenv, C.Meta (i,l), ugraph
 174         | C.Sort _
 175         | C.Implicit _ as t -> subst,metasenv,t,ugraph
 176         | C.Cast (te,ty) ->
 177             let subst,metasenv,te',ugraph1 =
 178               aux metasenv subst n context te ugraph in
 179             let subst,metasenv,ty',ugraph2 =
 180               aux metasenv subst n context ty ugraph1 in
 181             (* TASSI: sure this is in serial? *)
 182             subst,metasenv,(C.Cast (te', ty')),ugraph2
 183         | C.Prod (nn,s,t) ->
 184            let subst,metasenv,s',ugraph1 =
 185              aux metasenv subst n context s ugraph in
 186            let subst,metasenv,t',ugraph2 =
 187              aux metasenv subst (n+1) ((Some (nn, C.Decl s))::context) t
 188                ugraph1
 189            in
 190            (* TASSI: sure this is in serial? *)
 191            subst,metasenv,(C.Prod (nn, s', t')),ugraph2
 192         | C.Lambda (nn,s,t) ->
 193            let subst,metasenv,s',ugraph1 =
 194              aux metasenv subst n context s ugraph in
 195            let subst,metasenv,t',ugraph2 =
 196             aux metasenv subst (n+1) ((Some (nn, C.Decl s))::context) t ugraph1
 197            in
 198            (* TASSI: sure this is in serial? *)
 199             subst,metasenv,(C.Lambda (nn, s', t')),ugraph2
 200         | C.LetIn (nn,s,ty,t) ->
 201            let subst,metasenv,s',ugraph1 =
 202              aux metasenv subst n context s ugraph in
 203            let subst,metasenv,ty',ugraph1 =
 204              aux metasenv subst n context ty ugraph in
 205            let subst,metasenv,t',ugraph2 =
 206             aux metasenv subst (n+1) ((Some (nn, C.Def (s,ty)))::context) t
 207               ugraph1
 208            in
 209            (* TASSI: sure this is in serial? *)
 210             subst,metasenv,(C.LetIn (nn, s', ty', t')),ugraph2
 211         | C.Appl l ->
 212            let subst,metasenv,revl',ugraph1 =
 213             List.fold_left
 214              (fun (subst,metasenv,appl,ugraph) t ->
 215                let subst,metasenv,t',ugraph1 =
 216                  aux metasenv subst n context t ugraph in
 217                 subst,metasenv,(t'::appl),ugraph1
 218              ) (subst,metasenv,[],ugraph) l
 219            in
 220             subst,metasenv,(C.Appl (List.rev revl')),ugraph1
 221         | C.Const (uri,exp_named_subst) ->
 222            let subst,metasenv,exp_named_subst',ugraph1 =
 223             aux_exp_named_subst metasenv subst n context exp_named_subst ugraph
 224            in
 225             subst,metasenv,(C.Const (uri,exp_named_subst')),ugraph1
 226         | C.MutInd (uri,i,exp_named_subst) ->
 227            let subst,metasenv,exp_named_subst',ugraph1 =
 228             aux_exp_named_subst metasenv subst n context exp_named_subst ugraph
 229            in
 230             subst,metasenv,(C.MutInd (uri,i,exp_named_subst')),ugraph1
 231         | C.MutConstruct (uri,i,j,exp_named_subst) ->
 232            let subst,metasenv,exp_named_subst',ugraph1 =
 233             aux_exp_named_subst metasenv subst n context exp_named_subst ugraph
 234            in
 235             subst,metasenv,(C.MutConstruct (uri,i,j,exp_named_subst')),ugraph1
 236         | C.MutCase (sp,i,outt,t,pl) ->
 237            let subst,metasenv,outt',ugraph1 =
 238              aux metasenv subst n context outt ugraph in
 239            let subst,metasenv,t',ugraph2 =
 240              aux metasenv subst n context t ugraph1 in
 241            let subst,metasenv,revpl',ugraph3 =
 242             List.fold_left
 243              (fun (subst,metasenv,pl,ugraph) t ->
 244                let subst,metasenv,t',ugraph1 =
 245                  aux metasenv subst n context t ugraph in
 246                subst,metasenv,(t'::pl),ugraph1
 247              ) (subst,metasenv,[],ugraph2) pl
 248            in
 249            subst,metasenv,(C.MutCase (sp,i,outt', t', List.rev revpl')),ugraph3
 250            (* TASSI: not sure this is serial *)
 251         | C.Fix (i,fl) ->
 252 (*CSC: not implemented
 253            let tylen = List.length fl in
 254             let substitutedfl =
 255              List.map
 256               (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
 257                fl
 258             in
 259              C.Fix (i, substitutedfl)
 260 *)
 261             subst,metasenv,(CicSubstitution.lift 1 t' ),ugraph
 262         | C.CoFix (i,fl) ->
 263 (*CSC: not implemented
 264            let tylen = List.length fl in
 265             let substitutedfl =
 266              List.map
 267               (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
 268                fl
 269             in
 270              C.CoFix (i, substitutedfl)
 271
 272 *)
 273             subst,metasenv,(CicSubstitution.lift 1 t'), ugraph
 274
 275   and aux_exp_named_subst metasenv subst n context ens ugraph =
 276    List.fold_right
 277     (fun (uri,t) (subst,metasenv,l,ugraph) ->
 278       let subst,metasenv,t',ugraph1 = aux metasenv subst n context t ugraph in
 279        subst,metasenv,((uri,t')::l),ugraph1) ens (subst,metasenv,[],ugraph)
 280   in
 281   let argty,ugraph1 = type_of_aux' metasenv subst context arg ugraph in
 282   let fresh_name =
 283    FreshNamesGenerator.mk_fresh_name ~subst
 284     metasenv context (Cic.Name ("Hbeta" ^ string_of_int num)) ~typ:argty
 285   in
 286    let subst,metasenv,t',ugraph2 = aux metasenv subst 0 context t ugraph1 in
 287    let t'' = eta_reduce (C.Lambda (fresh_name,argty,t')) t' t in
 288    subst, metasenv, t'', ugraph2
 289 in profiler_beta_expand.HExtlib.profile foo ()
 290
 291
 292 and beta_expand_many test_equality_only metasenv subst context t args ugraph =
 293   let _,subst,metasenv,hd,ugraph =
 294     List.fold_right
 295       (fun arg (num,subst,metasenv,t,ugraph) ->
 296          let subst,metasenv,t,ugraph1 =
 297            beta_expand num test_equality_only
 298              metasenv subst context t arg ugraph
 299          in
 300            num+1,subst,metasenv,t,ugraph1
 301       ) args (1,subst,metasenv,t,ugraph)
 302   in
 303     subst,metasenv,hd,ugraph
 304
 305
 306 (* NUOVA UNIFICAZIONE *)
 307 (* A substitution is a (int * Cic.term) list that associates a
 308    metavariable i with its body.
 309    A metaenv is a (int * Cic.term) list that associate a metavariable
 310    i with is type.
 311    fo_unif_new takes a metasenv, a context, two terms t1 and t2 and gives back
 312    a new substitution which is _NOT_ unwinded. It must be unwinded before
 313    applying it. *)
 314
 315 and fo_unif_subst test_equality_only subst context metasenv t1 t2 ugraph =
 316  let module C = Cic in
 317  let module R = CicReduction in
 318  let module S = CicSubstitution in
 319  let t1 = deref subst t1 in
 320  let t2 = deref subst t2 in
 321  let (&&&) a b = (a && b) || ((not a) && (not b)) in
 322 (* let bef = Sys.time () in *)
 323  let b,ugraph =
 324   if not (CicUtil.is_meta_closed (CicMetaSubst.apply_subst subst t1) &&& CicUtil.is_meta_closed (CicMetaSubst.apply_subst subst t2)) then
 325    false,ugraph
 326   else
 327 let foo () =
 328    R.are_convertible ~subst ~metasenv context t1 t2 ugraph
 329 in profiler_are_convertible.HExtlib.profile foo ()
 330  in
 331 (* let aft = Sys.time () in
 332 if (aft -. bef > 2.0) then prerr_endline ("LEEEENTO: " ^ CicMetaSubst.ppterm_in_context subst ~metasenv t1 context ^ " <===> " ^ CicMetaSubst.ppterm_in_context subst ~metasenv t2 context); *)
 333    if b then
 334      subst, metasenv, ugraph
 335    else
 336    match (t1, t2) with
 337      | (C.Meta (n,ln), C.Meta (m,lm)) when n=m ->
 338          let _,subst,metasenv,ugraph1 =
 339            (try
 340               List.fold_left2
 341                 (fun (j,subst,metasenv,ugraph) t1 t2 ->
 342                    match t1,t2 with
 343                        None,_
 344                      | _,None -> j+1,subst,metasenv,ugraph
 345                      | Some t1', Some t2' ->
 346                          (* First possibility:  restriction    *)
 347                          (* Second possibility: unification    *)
 348                          (* Third possibility:  convertibility *)
 349                          let b, ugraph1 =
 350                          R.are_convertible
 351                            ~subst ~metasenv context t1' t2' ugraph
 352                          in
 353                          if b then
 354                            j+1,subst,metasenv, ugraph1
 355                          else
 356                            (try
 357                               let subst,metasenv,ugraph2 =
 358                                 fo_unif_subst
 359                                   test_equality_only
 360                                   subst context metasenv t1' t2' ugraph
 361                               in
 362                                 j+1,subst,metasenv,ugraph2
 363                             with
 364                                 Uncertain _
 365                               | UnificationFailure _ ->
 366 debug_print (lazy ("restringo Meta n." ^ (string_of_int n) ^ "on variable n." ^ (string_of_int j)));
 367                                   let metasenv, subst =
 368                                     CicMetaSubst.restrict
 369                                       subst [(n,j)] metasenv in
 370                                     j+1,subst,metasenv,ugraph1)
 371                 ) (1,subst,metasenv,ugraph) ln lm
 372             with
 373                 Exit ->
 374                   raise
 375                     (UnificationFailure (lazy "1"))
 376                     (*
 377                     (sprintf
 378                       "Error trying to unify %s with %s: the algorithm tried to check whether the two substitutions are convertible; if they are not, it tried to unify the two substitutions. No restriction was attempted."
 379                       (CicMetaSubst.ppterm ~metasenv subst t1)
 380                       (CicMetaSubst.ppterm ~metasenv subst t2))) *)
 381               | Invalid_argument _ ->
 382                   raise
 383                     (UnificationFailure (lazy "2")))
 384                     (*
 385                     (sprintf
 386                       "Error trying to unify %s with %s: the lengths of the two local contexts do not match."
 387                       (CicMetaSubst.ppterm ~metasenv subst t1)
 388                       (CicMetaSubst.ppterm ~metasenv subst t2)))) *)
 389          in subst,metasenv,ugraph1
 390      | (C.Meta (n,_), C.Meta (m,_)) when n>m ->
 391          fo_unif_subst test_equality_only subst context metasenv t2 t1 ugraph
 392      | (C.Meta (n,l), t)
 393      | (t, C.Meta (n,l)) ->
 394          let swap =
 395            match t1,t2 with
 396                C.Meta (n,_), C.Meta (m,_) when n < m -> false
 397              | _, C.Meta _ -> false
 398              | _,_ -> true
 399          in
 400          let lower = fun x y -> if swap then y else x in
 401          let upper = fun x y -> if swap then x else y in
 402          let fo_unif_subst_ordered
 403              test_equality_only subst context metasenv m1 m2 ugraph =
 404            fo_unif_subst test_equality_only subst context metasenv
 405              (lower m1 m2) (upper m1 m2) ugraph
 406          in
 407          begin
 408          let subst,metasenv,ugraph1 =
 409            let (_,_,meta_type) =  CicUtil.lookup_meta n metasenv in
 410            (try
 411               let tyt,ugraph1 =
 412                 type_of_aux' metasenv subst context t ugraph
 413               in
 414                 fo_unif_subst
 415                   test_equality_only
 416                   subst context metasenv tyt (S.subst_meta l meta_type) ugraph1
 417             with
 418                 UnificationFailure _ as e -> raise e
 419               | Uncertain msg -> raise (UnificationFailure msg)
 420               | AssertFailure _ ->
 421                   debug_print (lazy "siamo allo huge hack");
 422                   (* TODO huge hack!!!!
 423                    * we keep on unifying/refining in the hope that
 424                    * the problem will be eventually solved.
 425                    * In the meantime we're breaking a big invariant:
 426                    * the terms that we are unifying are no longer well
 427                    * typed in the current context (in the worst case
 428                    * we could even diverge) *)
 429                   (subst, metasenv,ugraph)) in
 430          let t',metasenv,subst =
 431            try
 432              CicMetaSubst.delift n subst context metasenv l t
 433            with
 434                (CicMetaSubst.MetaSubstFailure msg)->
 435                  raise (UnificationFailure msg)
 436              | (CicMetaSubst.Uncertain msg) -> raise (Uncertain msg)
 437          in
 438          let t'',ugraph2 =
 439            match t' with
 440                C.Sort (C.Type u) when not test_equality_only ->
 441                  let u' = CicUniv.fresh () in
 442                  let s = C.Sort (C.Type u') in
 443                   (try
 444                     let ugraph2 =
 445                      CicUniv.add_ge (upper u u') (lower u u') ugraph1
 446                     in
 447                      s,ugraph2
 448                    with
 449                     CicUniv.UniverseInconsistency msg ->
 450                      raise (UnificationFailure msg))
 451              | _ -> t',ugraph1
 452          in
 453          (* Unifying the types may have already instantiated n. Let's check *)
 454          try
 455            let (_, oldt,_) = CicUtil.lookup_subst n subst in
 456            let lifted_oldt = S.subst_meta l oldt in
 457              fo_unif_subst_ordered
 458                test_equality_only subst context metasenv t lifted_oldt ugraph2
 459          with
 460              CicUtil.Subst_not_found _ ->
 461                let (_, context, ty) = CicUtil.lookup_meta n metasenv in
 462                let subst = (n, (context, t'',ty)) :: subst in
 463                let metasenv =
 464                  List.filter (fun (m,_,_) -> not (n = m)) metasenv in
 465                subst, metasenv, ugraph2
 466          end
 467    | (C.Var (uri1,exp_named_subst1),C.Var (uri2,exp_named_subst2))
 468    | (C.Const (uri1,exp_named_subst1),C.Const (uri2,exp_named_subst2)) ->
 469       if UriManager.eq uri1 uri2 then
 470        fo_unif_subst_exp_named_subst test_equality_only subst context metasenv
 471         exp_named_subst1 exp_named_subst2 ugraph
 472       else
 473        raise (UnificationFailure (lazy
 474           (sprintf
 475             "Can't unify %s with %s due to different constants"
 476             (CicMetaSubst.ppterm ~metasenv subst t1)
 477             (CicMetaSubst.ppterm ~metasenv subst t2))))
 478    | C.MutInd (uri1,i1,exp_named_subst1),C.MutInd (uri2,i2,exp_named_subst2) ->
 479        if UriManager.eq uri1 uri2 && i1 = i2 then
 480          fo_unif_subst_exp_named_subst
 481            test_equality_only
 482            subst context metasenv exp_named_subst1 exp_named_subst2 ugraph
 483        else
 484          raise (UnificationFailure
 485            (lazy
 486             (sprintf
 487              "Can't unify %s with %s due to different inductive principles"
 488              (CicMetaSubst.ppterm ~metasenv subst t1)
 489              (CicMetaSubst.ppterm ~metasenv subst t2))))
 490    | C.MutConstruct (uri1,i1,j1,exp_named_subst1),
 491        C.MutConstruct (uri2,i2,j2,exp_named_subst2) ->
 492        if UriManager.eq uri1 uri2 && i1 = i2 && j1 = j2 then
 493          fo_unif_subst_exp_named_subst
 494            test_equality_only
 495            subst context metasenv exp_named_subst1 exp_named_subst2 ugraph
 496        else
 497          raise (UnificationFailure
 498           (lazy
 499             (sprintf
 500               "Can't unify %s with %s due to different inductive constructors"
 501               (CicMetaSubst.ppterm ~metasenv subst t1)
 502               (CicMetaSubst.ppterm ~metasenv subst t2))))
 503    | (C.Implicit _, _) | (_, C.Implicit _) ->  assert false
 504    | (C.Cast (te,ty), t2) -> fo_unif_subst test_equality_only
 505                               subst context metasenv te t2 ugraph
 506    | (t1, C.Cast (te,ty)) -> fo_unif_subst test_equality_only
 507                               subst context metasenv t1 te ugraph
 508    | (C.Prod (n1,s1,t1), C.Prod (_,s2,t2)) ->
 509        let subst',metasenv',ugraph1 =
 510          fo_unif_subst true subst context metasenv s1 s2 ugraph
 511        in
 512          fo_unif_subst test_equality_only
 513            subst' ((Some (n1,(C.Decl s1)))::context) metasenv' t1 t2 ugraph1
 514    | (C.Prod _, _) ->
 515        (match CicReduction.whd ~subst context t2 with
 516         | C.Prod _ as t2 ->
 517             fo_unif_subst test_equality_only subst context metasenv t1 t2 ugraph
 518         | _ -> raise (UnificationFailure (lazy (CicMetaSubst.ppterm ~metasenv subst t2^"Not a product"))))
 519    | (_, C.Prod _) ->
 520        (match CicReduction.whd ~subst context t1 with
 521         | C.Prod _ as t1 ->
 522             fo_unif_subst test_equality_only subst context metasenv t1 t2 ugraph
 523         | _ -> raise (UnificationFailure (lazy (CicMetaSubst.ppterm ~metasenv subst t1^"Not a product"))))
 524    | (C.Lambda (n1,s1,t1), C.Lambda (_,s2,t2)) ->
 525        let subst',metasenv',ugraph1 =
 526          fo_unif_subst test_equality_only subst context metasenv s1 s2 ugraph
 527        in
 528          fo_unif_subst test_equality_only
 529            subst' ((Some (n1,(C.Decl s1)))::context) metasenv' t1 t2 ugraph1
 530    | (C.LetIn (_,s1,ty1,t1), t2)
 531    | (t2, C.LetIn (_,s1,ty1,t1)) ->
 532        fo_unif_subst
 533         test_equality_only subst context metasenv t2 (S.subst s1 t1) ugraph
 534    | (C.Appl l1, C.Appl l2) ->
 535        (* andrea: this case should be probably rewritten in the
 536           spirit of deref *)
 537        (match l1,l2 with
 538           | C.Meta (i,_)::args1, C.Meta (j,_)::args2 when i = j ->
 539               (try
 540                  List.fold_left2
 541                    (fun (subst,metasenv,ugraph) t1 t2 ->
 542                       fo_unif_subst
 543                         test_equality_only subst context metasenv t1 t2 ugraph)
 544                    (subst,metasenv,ugraph) l1 l2
 545                with (Invalid_argument msg) ->
 546                  raise (UnificationFailure (lazy msg)))
 547           | C.Meta (i,l)::args, _ when not(exists_a_meta args) ->
 548               (* we verify that none of the args is a Meta,
 549                 since beta expanding with respoect to a metavariable
 550                 makes no sense  *)
 551  (*
 552               (try
 553                  let (_,t,_) = CicUtil.lookup_subst i subst in
 554                  let lifted = S.subst_meta l t in
 555                  let reduced = CicReduction.head_beta_reduce (Cic.Appl (lifted::args)) in
 556                    fo_unif_subst
 557                     test_equality_only
 558                      subst context metasenv reduced t2 ugraph
 559                with CicUtil.Subst_not_found _ -> *)
 560               let subst,metasenv,beta_expanded,ugraph1 =
 561                 beta_expand_many
 562                   test_equality_only metasenv subst context t2 args ugraph
 563               in
 564                 fo_unif_subst test_equality_only subst context metasenv
 565                   (C.Meta (i,l)) beta_expanded ugraph1
 566           | _, C.Meta (i,l)::args when not(exists_a_meta args)  ->
 567               (* (try
 568                  let (_,t,_) = CicUtil.lookup_subst i subst in
 569                  let lifted = S.subst_meta l t in
 570                  let reduced = CicReduction.head_beta_reduce (Cic.Appl (lifted::args)) in
 571                    fo_unif_subst
 572                      test_equality_only
 573                      subst context metasenv t1 reduced ugraph
 574                with CicUtil.Subst_not_found _ -> *)
 575                  let subst,metasenv,beta_expanded,ugraph1 =
 576                    beta_expand_many
 577                      test_equality_only
 578                      metasenv subst context t1 args ugraph
 579                  in
 580                    fo_unif_subst test_equality_only subst context metasenv
 581                      (C.Meta (i,l)) beta_expanded ugraph1
 582           | _,_ ->
 583               let lr1 = List.rev l1 in
 584               let lr2 = List.rev l2 in
 585               let rec
 586                   fo_unif_l test_equality_only subst metasenv (l1,l2) ugraph =
 587                 match (l1,l2) with
 588                     [],_
 589                   | _,[] -> assert false
 590                   | ([h1],[h2]) ->
 591                       fo_unif_subst
 592                         test_equality_only subst context metasenv h1 h2 ugraph
 593                   | ([h],l)
 594                   | (l,[h]) ->
 595                       fo_unif_subst test_equality_only subst context metasenv
 596                         h (C.Appl (List.rev l)) ugraph
 597                   | ((h1::l1),(h2::l2)) ->
 598                       let subst', metasenv',ugraph1 =
 599                         fo_unif_subst
 600                           test_equality_only
 601                           subst context metasenv h1 h2 ugraph
 602                       in
 603                         fo_unif_l
 604                           test_equality_only subst' metasenv' (l1,l2) ugraph1
 605               in
 606               (try
 607                 fo_unif_l
 608                   test_equality_only subst metasenv (lr1, lr2)  ugraph
 609               with
 610               | UnificationFailure s
 611               | Uncertain s as exn ->
 612                   (match l1, l2 with
 613                   | (((Cic.Const (uri1, ens1)) as c1) :: tl1),
 614                      (((Cic.Const (uri2, ens2)) as c2) :: tl2) when
 615                     CoercDb.is_a_coercion' c1 &&
 616                     CoercDb.is_a_coercion' c2 &&
 617                     not (UriManager.eq uri1 uri2) ->
 618 (*DEBUGGING ONLY:
 619 prerr_endline ("<<<< " ^ CicMetaSubst.ppterm_in_context ~metasenv subst (C.Appl l1) context ^ " <==> " ^ CicMetaSubst.ppterm_in_context ~metasenv subst (C.Appl l2) context);
 620 let res =
 621 *)
 622                      let rec look_for_first_coercion c tl =
 623                       match
 624                        CicMetaSubst.apply_subst subst (HExtlib.list_last tl)
 625                       with
 626                          Cic.Appl ((Cic.Const (uri1,ens1) as c')::tl')
 627                           when CoercDb.is_a_coercion' c' ->
 628                            look_for_first_coercion c' tl'
 629                        | last_tl -> c,last_tl
 630                      in
 631                       let c1,last_tl1 = look_for_first_coercion c1 tl1 in
 632                       let c2,last_tl2 = look_for_first_coercion c2 tl2 in
 633                       let car1 =
 634                         CoercDb.coerc_carr_of_term (CoercGraph.source_of c1) in
 635                       let car2 =
 636                         CoercDb.coerc_carr_of_term (CoercGraph.source_of c2) in
 637                       if CoercDb.eq_carr car1 car2 then
 638                        (match last_tl1,last_tl2 with
 639                            C.Meta (i1,_),C.Meta(i2,_) when i1=i2 -> raise exn
 640                          | C.Meta _, _
 641                          | _, C.Meta _ ->
 642                            let subst,metasenv,ugraph =
 643                             fo_unif_subst test_equality_only subst context
 644                              metasenv last_tl1 last_tl2 ugraph
 645                            in
 646                             fo_unif_subst test_equality_only subst context
 647                              metasenv (C.Appl l1) (C.Appl l2) ugraph
 648                          | _ -> raise exn)
 649                       else
 650                        let meets =
 651                          CoercGraph.meets metasenv subst context car1 car2
 652                        in
 653                         (match meets with
 654                         | [] -> raise exn
 655                         | (carr,metasenv,to1,to2)::xxx ->
 656                           (match xxx with
 657                           [] -> ()
 658                           | (m2,_,c2,c2')::_ ->
 659                           let m1,_,c1,c1' = carr,metasenv,to1,to2 in
 660                           let unopt =
 661                             function Some (_,t) -> CicPp.ppterm t
 662                             | None -> "id"
 663                           in
 664                           HLog.warn
 665                             ("There are two minimal joins of "^
 666                             CoercDb.name_of_carr car1^" and "^
 667                             CoercDb.name_of_carr car2^": " ^
 668                             CoercDb.name_of_carr m1 ^ " via "^unopt c1^" + "^
 669                             unopt c1'^" and " ^ CoercDb.name_of_carr m2^" via "^
 670                             unopt c2^" + "^unopt c2'));
 671                           let last_tl1',(subst,metasenv,ugraph) =
 672                            match last_tl1,to1 with
 673                             | Cic.Meta (i1,l1),Some (last,coerced) ->
 674                                 last,
 675                                   fo_unif_subst test_equality_only subst context
 676                                      metasenv coerced last_tl1 ugraph
 677                             | _ -> last_tl1,(subst,metasenv,ugraph)
 678                           in
 679                           let last_tl2',(subst,metasenv,ugraph) =
 680                            match last_tl2,to2 with
 681                             | Cic.Meta (i2,l2),Some (last,coerced) ->
 682                                 last,
 683                                   fo_unif_subst test_equality_only subst context
 684                                      metasenv coerced last_tl2 ugraph
 685                             | _ -> last_tl2,(subst,metasenv,ugraph)
 686                           in
 687                         (*DEBUGGING ONLY:
 688 prerr_endline ("OK " ^ CicMetaSubst.ppterm_in_context ~metasenv subst last_tl1' context ^ " <==> " ^ CicMetaSubst.ppterm_in_context ~metasenv subst last_tl2' context);
 689 *)
 690                            let subst,metasenv,ugraph =
 691                             fo_unif_subst test_equality_only subst context
 692                              metasenv last_tl1' last_tl2' ugraph
 693                            in
 694                             fo_unif_subst test_equality_only subst context
 695                              metasenv (C.Appl l1) (C.Appl l2) ugraph)
 696 (*DEBUGGING ONLY:
 697 in
 698 let subst,metasenv,ugraph = res in
 699 prerr_endline (">>>> " ^ CicMetaSubst.ppterm_in_context ~metasenv subst (C.Appl l1) context ^ " <==> " ^ CicMetaSubst.ppterm_in_context ~metasenv subst (C.Appl l2) context);
 700 res
 701 *)
 702                   (*CSC: This is necessary because of the "elim H" tactic
 703                          where the type of H is only reducible to an
 704                          inductive type. This could be extended from inductive
 705                          types to any rigid term. However, the code is
 706                          duplicated in two places: inside applications and
 707                          outside them. Probably it would be better to
 708                          work with lambda-bar terms instead. *)
 709                   | (Cic.MutInd _::_, Cic.MutInd _::_) -> raise exn
 710                   | (_, Cic.MutInd _::_) ->
 711                      let t1' = R.whd ~subst context t1 in
 712                      (match t1' with
 713                           C.Appl (C.MutInd _::_) ->
 714                             fo_unif_subst test_equality_only
 715                               subst context metasenv t1' t2 ugraph
 716                         | _ -> raise (UnificationFailure (lazy "88")))
 717                   | (Cic.MutInd _::_,_) ->
 718                      let t2' = R.whd ~subst context t2 in
 719                      (match t2' with
 720                           C.Appl (C.MutInd _::_) ->
 721                             fo_unif_subst test_equality_only
 722                               subst context metasenv t1 t2' ugraph
 723                         | _ -> raise
 724                             (UnificationFailure
 725                                (lazy ("not a mutind :"^CicMetaSubst.ppterm ~metasenv subst t2 ))))
 726                   | _ -> raise exn)))
 727    | (C.MutCase (_,_,outt1,t1',pl1), C.MutCase (_,_,outt2,t2',pl2))->
 728        let subst', metasenv',ugraph1 =
 729         fo_unif_subst test_equality_only subst context metasenv outt1 outt2
 730           ugraph in
 731        let subst'',metasenv'',ugraph2 =
 732         fo_unif_subst test_equality_only subst' context metasenv' t1' t2'
 733           ugraph1 in
 734        (try
 735          List.fold_left2
 736           (fun (subst,metasenv,ugraph) t1 t2 ->
 737             fo_unif_subst
 738              test_equality_only subst context metasenv t1 t2 ugraph
 739           ) (subst'',metasenv'',ugraph2) pl1 pl2
 740         with
 741          Invalid_argument _ ->
 742           raise (UnificationFailure (lazy "6.1")))
 743            (* (sprintf
 744               "Error trying to unify %s with %s: the number of branches is not the same."
 745               (CicMetaSubst.ppterm ~metasenv subst t1)
 746               (CicMetaSubst.ppterm ~metasenv subst t2)))) *)
 747    | (C.Rel _, _) | (_,  C.Rel _) ->
 748        if t1 = t2 then
 749          subst, metasenv,ugraph
 750        else
 751         raise (UnificationFailure (lazy
 752            (sprintf
 753              "Can't unify %s with %s because they are not convertible"
 754              (CicMetaSubst.ppterm ~metasenv subst t1)
 755              (CicMetaSubst.ppterm ~metasenv subst t2))))
 756    | (C.Appl (C.Meta(i,l)::args),t2) when not(exists_a_meta args) ->
 757        let subst,metasenv,beta_expanded,ugraph1 =
 758          beta_expand_many
 759            test_equality_only metasenv subst context t2 args ugraph
 760        in
 761          fo_unif_subst test_equality_only subst context metasenv
 762            (C.Meta (i,l)) beta_expanded ugraph1
 763    | (t1,C.Appl (C.Meta(i,l)::args)) when not(exists_a_meta args) ->
 764        let subst,metasenv,beta_expanded,ugraph1 =
 765          beta_expand_many
 766            test_equality_only metasenv subst context t1 args ugraph
 767        in
 768          fo_unif_subst test_equality_only subst context metasenv
 769            beta_expanded (C.Meta (i,l)) ugraph1
 770 (* Works iff there are no arguments applied to it; similar to the
 771    case below
 772    | (_, C.MutInd _) ->
 773        let t1' = R.whd ~subst context t1 in
 774        (match t1' with
 775             C.MutInd _ ->
 776               fo_unif_subst test_equality_only
 777                 subst context metasenv t1' t2 ugraph
 778           | _ -> raise (UnificationFailure (lazy "8")))
 779 *)
 780 (* The following idea could be exploited again; right now we have no
 781    longer any example requiring it
 782    | (C.Prod _, t2) ->
 783        let t2' = R.whd ~subst context t2 in
 784        (match t2' with
 785             C.Prod _ ->
 786               fo_unif_subst test_equality_only
 787                 subst context metasenv t1 t2' ugraph
 788           | _ -> raise (UnificationFailure (lazy "8")))
 789    | (t1, C.Prod _) ->
 790        let t1' = R.whd ~subst context t1 in
 791        (match t1' with
 792             C.Prod _ ->
 793               fo_unif_subst test_equality_only
 794                 subst context metasenv t1' t2 ugraph
 795           | _ -> (* raise (UnificationFailure "9")) *)
 796              raise
 797                 (UnificationFailure (lazy (sprintf
 798                    "Can't unify %s with %s because they are not convertible"
 799                    (CicMetaSubst.ppterm ~metasenv subst t1)
 800                    (CicMetaSubst.ppterm ~metasenv subst t2)))))
 801 *)
 802    | (_,_) ->
 803      (* delta-beta reduction should almost never be a problem for
 804         unification since:
 805          1. long computations require iota reduction
 806          2. it is extremely rare that a close term t1 (that could be unified
 807             to t2) beta-delta reduces to t1' while t2 does not beta-delta
 808             reduces in the same way. This happens only if one meta of t2
 809             occurs in head position during beta reduction. In this unluky
 810             case too much reduction will be performed on t1 and unification
 811             will surely fail. *)
 812      let t1' = CicReduction.head_beta_reduce ~delta:true t1 in
 813      let t2' = CicReduction.head_beta_reduce ~delta:true t2 in
 814       if t1 = t1' && t2 = t2' then
 815        raise (UnificationFailure
 816         (lazy
 817           (sprintf
 818             "Can't unify %s with %s because they are not convertible"
 819             (CicMetaSubst.ppterm ~metasenv subst t1)
 820             (CicMetaSubst.ppterm ~metasenv subst t2))))
 821       else
 822        try
 823         fo_unif_subst test_equality_only subst context metasenv t1' t2' ugraph
 824        with
 825           UnificationFailure _
 826         | Uncertain _ ->
 827            raise (UnificationFailure
 828             (lazy
 829               (sprintf
 830                 "Can't unify %s with %s because they are not convertible"
 831                 (CicMetaSubst.ppterm ~metasenv subst t1)
 832                 (CicMetaSubst.ppterm ~metasenv subst t2))))
 833
 834 and fo_unif_subst_exp_named_subst test_equality_only subst context metasenv
 835  exp_named_subst1 exp_named_subst2 ugraph
 836 =
 837  try
 838   List.fold_left2
 839    (fun (subst,metasenv,ugraph) (uri1,t1) (uri2,t2) ->
 840      assert (uri1=uri2) ;
 841      fo_unif_subst test_equality_only subst context metasenv t1 t2 ugraph
 842    ) (subst,metasenv,ugraph) exp_named_subst1 exp_named_subst2
 843  with
 844   Invalid_argument _ ->
 845    let print_ens ens =
 846     String.concat " ; "
 847      (List.map
 848        (fun (uri,t) ->
 849          UriManager.string_of_uri uri ^ " := " ^ (CicMetaSubst.ppterm ~metasenv subst t)
 850        ) ens)
 851    in
 852     raise (UnificationFailure (lazy (sprintf
 853      "Error trying to unify the two explicit named substitutions (local contexts) %s and %s: their lengths is different." (print_ens exp_named_subst1) (print_ens exp_named_subst2))))
 854
 855 (* A substitution is a (int * Cic.term) list that associates a               *)
 856 (* metavariable i with its body.                                             *)
 857 (* metasenv is of type Cic.metasenv                                          *)
 858 (* fo_unif takes a metasenv, a context, two terms t1 and t2 and gives back   *)
 859 (* a new substitution which is already unwinded and ready to be applied and  *)
 860 (* a new metasenv in which some hypothesis in the contexts of the            *)
 861 (* metavariables may have been restricted.                                   *)
 862 let fo_unif metasenv context t1 t2 ugraph =
 863  fo_unif_subst false [] context metasenv t1 t2 ugraph ;;
 864
 865 let enrich_msg msg subst context metasenv t1 t2 ugraph =
 866  lazy (
 867   if verbose then
 868    sprintf "[Verbose] Unification error unifying %s of type %s with %s of type %s in context\n%s\nand metasenv\n%s\nand substitution\n%s\nbecause %s"
 869     (CicMetaSubst.ppterm ~metasenv subst t1)
 870     (try
 871       let ty_t1,_ = type_of_aux' metasenv subst context t1 ugraph in
 872       CicPp.ppterm ty_t1
 873     with
 874     | UnificationFailure s
 875     | Uncertain s
 876     | AssertFailure s -> sprintf "MALFORMED(t1): \n<BEGIN>%s\n<END>" (Lazy.force s))
 877     (CicMetaSubst.ppterm ~metasenv subst t2)
 878     (try
 879       let ty_t2,_ = type_of_aux' metasenv subst context t2 ugraph in
 880       CicPp.ppterm ty_t2
 881     with
 882     | UnificationFailure s
 883     | Uncertain s
 884     | AssertFailure s -> sprintf "MALFORMED(t2): \n<BEGIN>%s\n<END>" (Lazy.force s))
 885     (CicMetaSubst.ppcontext ~metasenv subst context)
 886     (CicMetaSubst.ppmetasenv subst metasenv)
 887     (CicMetaSubst.ppsubst ~metasenv subst) (Lazy.force msg)
 888  else
 889    sprintf "Unification error unifying %s of type %s with %s of type %s in context\n%s\nand metasenv\n%s\nbecause %s"
 890     (CicMetaSubst.ppterm_in_context ~metasenv subst t1 context)
 891     (try
 892       let ty_t1,_ = type_of_aux' metasenv subst context t1 ugraph in
 893       CicMetaSubst.ppterm_in_context ~metasenv subst ty_t1 context
 894     with
 895     | UnificationFailure s
 896     | Uncertain s
 897     | AssertFailure s -> sprintf "MALFORMED(t1): \n<BEGIN>%s\n<END>" (Lazy.force s))
 898     (CicMetaSubst.ppterm_in_context ~metasenv subst t2 context)
 899     (try
 900       let ty_t2,_ = type_of_aux' metasenv subst context t2 ugraph in
 901       CicMetaSubst.ppterm_in_context ~metasenv subst ty_t2 context
 902     with
 903     | UnificationFailure s
 904     | Uncertain s
 905     | AssertFailure s -> sprintf "MALFORMED(t2): \n<BEGIN>%s\n<END>" (Lazy.force s))
 906     (CicMetaSubst.ppcontext ~metasenv subst context)
 907     (CicMetaSubst.ppmetasenv subst metasenv)
 908     (Lazy.force msg)
 909  )
 910
 911 let fo_unif_subst subst context metasenv t1 t2 ugraph =
 912   try
 913     fo_unif_subst false subst context metasenv t1 t2 ugraph
 914   with
 915   | AssertFailure msg ->
 916      raise (AssertFailure (enrich_msg msg subst context metasenv t1 t2 ugraph))
 917   | UnificationFailure msg ->
 918      raise (UnificationFailure (enrich_msg msg subst context metasenv t1 t2 ugraph))
 919 ;;