helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let level_of precedence =
  61   if precedence < min_precedence || precedence > max_precedence then
  62     raise (Level_not_found precedence);
  63   string_of_int precedence
  64
  65 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  66 let gram_ident s = Gramext.Stoken ("IDENT", s)
  67 let gram_number s = Gramext.Stoken ("NUMBER", s)
  68 let gram_keyword s = Gramext.Stoken ("", s)
  69 let gram_term = function
  70   | Ast.Self _ -> Gramext.Sself
  71   | Ast.Level precedence ->
  72       Gramext.Snterml
  73         (Grammar.Entry.obj (term: 'a Grammar.Entry.e), level_of precedence)
  74 ;;
  75
  76 let gram_of_literal =
  77   function
  78   | `Symbol s -> gram_symbol s
  79   | `Keyword s -> gram_keyword s
  80   | `Number s -> gram_number s
  81
  82 type binding =
  83   | NoBinding
  84   | Binding of string * Env.value_type
  85   | Env of (string * Env.value_type) list
  86
  87 let make_action action bindings =
  88   let rec aux (vl : CicNotationEnv.t) =
  89     function
  90       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  91     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  92     (* LUCA: DEFCON 3 BEGIN *)
  93     | Binding (name, Env.TermType l) :: tl ->
  94         Gramext.action
  95           (fun (v:Ast.term) ->
  96             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
  97     | Binding (name, Env.StringType) :: tl ->
  98         Gramext.action
  99           (fun (v:string) ->
 100             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 101     | Binding (name, Env.NumType) :: tl ->
 102         Gramext.action
 103           (fun (v:string) ->
 104             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 105     | Binding (name, Env.OptType t) :: tl ->
 106         Gramext.action
 107           (fun (v:'a option) ->
 108             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 109     | Binding (name, Env.ListType t) :: tl ->
 110         Gramext.action
 111           (fun (v:'a list) ->
 112             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 113     | Env _ :: tl ->
 114         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 115     (* LUCA: DEFCON 3 END *)
 116   in
 117     aux [] (List.rev bindings)
 118
 119 let flatten_opt =
 120   let rec aux acc =
 121     function
 122       [] -> List.rev acc
 123     | NoBinding :: tl -> aux acc tl
 124     | Env names :: tl -> aux (List.rev names @ acc) tl
 125     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 126   in
 127   aux []
 128
 129   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 130 let extract_term_production pattern =
 131   let rec aux = function
 132     | Ast.AttributedTerm (_, t) -> aux t
 133     | Ast.Literal l -> aux_literal l
 134     | Ast.Layout l -> aux_layout l
 135     | Ast.Magic m -> aux_magic m
 136     | Ast.Variable v -> aux_variable v
 137     | t ->
 138         prerr_endline (CicNotationPp.pp_term t);
 139         assert false
 140   and aux_literal =
 141     function
 142     | `Symbol s -> [NoBinding, gram_symbol s]
 143     | `Keyword s ->
 144         (* assumption: s will be registered as a keyword with the lexer *)
 145         [NoBinding, gram_keyword s]
 146     | `Number s -> [NoBinding, gram_number s]
 147   and aux_layout = function
 148     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 149     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 150     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 151     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 152     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 153     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule"] @ aux p1 @ aux p2 @ aux p3
 154     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 155     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 156     | Ast.Root (p1, p2) ->
 157         [NoBinding, gram_symbol "\\root"] @ aux p2
 158         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 159     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 160     | Ast.Break -> []
 161     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 162     | Ast.Group pl -> List.flatten (List.map aux pl)
 163     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 164   and aux_magic magic =
 165     match magic with
 166     | Ast.Opt p ->
 167         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 168         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 169           match env_opt with
 170           | Some env -> List.map Env.opt_binding_some env
 171           | None -> List.map Env.opt_binding_of_name p_names
 172         in
 173         [ Env (List.map Env.opt_declaration p_names),
 174           Gramext.srules
 175             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 176               Gramext.action action ] ]
 177     | Ast.List0 (p, _)
 178     | Ast.List1 (p, _) ->
 179         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 180         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 181           CicNotationEnv.coalesce_env p_names env_list
 182         in
 183         let gram_of_list s =
 184           match magic with
 185           | Ast.List0 (_, None) -> Gramext.Slist0 s
 186           | Ast.List1 (_, None) -> Gramext.Slist1 s
 187           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 188           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 189           | _ -> assert false
 190         in
 191         [ Env (List.map Env.list_declaration p_names),
 192           Gramext.srules
 193             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 194               Gramext.action action ] ]
 195     | _ -> assert false
 196   and aux_variable =
 197     function
 198     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 199     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 200         [Binding (s, Env.TermType level), gram_term lv]
 201     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 202     | Ast.Ascription (p, s) -> assert false (* TODO *)
 203     | Ast.FreshVar _ -> assert false
 204   and inner_pattern p =
 205     let p_bindings, p_atoms = List.split (aux p) in
 206     let p_names = flatten_opt p_bindings in
 207     let action =
 208       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 209         p_bindings
 210     in
 211     p_bindings, p_atoms, p_names, action
 212   in
 213   aux pattern
 214
 215 type rule_id = Grammar.token Gramext.g_symbol list
 216
 217 let compare_rule_id x y =
 218   let rec aux = function
 219     | [],[] -> 0
 220     | [],_ -> ~-1
 221     | _,[] -> 1
 222     | s1::tl1, s2::tl2 ->
 223         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 224         else
 225           let d = List.length tl1 - List.length tl2 in
 226           if d <> 0 then d else 1 (* bad and broken *)
 227   in
 228     aux (x,y)
 229
 230   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 231 let owned_keywords = Hashtbl.create 23
 232
 233 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 234
 235 let check_l1_pattern level1_pattern level associativity =
 236   let variables = ref 0 in
 237   let symbols = ref 0 in
 238   let rec aux = function
 239     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 240     | Ast.Literal _ as l -> incr symbols; l
 241     | Ast.Layout l -> Ast.Layout (aux_layout l)
 242     | Ast.Magic m -> Ast.Magic (aux_magic m)
 243     | Ast.Variable v -> (aux_variable v)
 244     | t -> assert false
 245   and aux_layout = function
 246     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 247     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 248     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 249     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 250     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 251     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 252     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 253     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 254     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 255     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 256     | Ast.Break as t -> t
 257     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 258     | Ast.Group pl -> Ast.Group (List.map aux pl)
 259     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 260   and aux_magic magic =
 261     match magic with
 262     | Ast.Opt p -> Ast.Opt (aux p)
 263     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 264     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 265     | _ -> assert false
 266   and aux_variable =
 267     function
 268     | Ast.NumVar _ as t -> Ast.Variable t
 269     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 270         incr variables;
 271         if !variables > 2 then
 272           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 273           "associative notation"));
 274         (match !variables, associativity with
 275         | 1,Gramext.LeftA ->
 276              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 277         | 1,Gramext.RightA ->
 278              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 279         | 2,Gramext.LeftA ->
 280              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 281         | 2,Gramext.RightA ->
 282              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 283         | _ -> assert false)
 284     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 285           raise (Parse_error ("Variables can not be declared with a " ^
 286             "precedence in an associative notation"))
 287        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 288     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 289        raise(Parse_error("Left recursive rule with precedence not greater " ^
 290         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 291     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 292     | Ast.IdentVar _ as t -> Ast.Variable t
 293     | Ast.Ascription _ -> assert false (* TODO *)
 294     | Ast.FreshVar _ -> assert false
 295   in
 296   if associativity <> Gramext.NonA && level = min_precedence then
 297     raise (Parse_error ("You can not specify an associative notation " ^
 298     "at level "^string_of_int min_precedence ^ "; increase it"));
 299   let cp = aux level1_pattern in
 300 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 301   if !variables <> 2 && associativity <> Gramext.NonA then
 302     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 303      "associative notation"));
 304   CL1P (cp,level)
 305 ;;
 306
 307 let extend (CL1P (level1_pattern,precedence)) action =
 308   let p_bindings, p_atoms =
 309     List.split (extract_term_production level1_pattern)
 310   in
 311   let level = level_of precedence in
 312   let _ =
 313     Grammar.extend
 314       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 315         Some (Gramext.Level level),
 316         [ None,
 317           Some (*Gramext.NonA*) Gramext.NonA,
 318           [ p_atoms,
 319             (make_action
 320               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 321                 (action env loc))
 322               p_bindings) ]]]
 323   in
 324   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 325   let rule_id = p_atoms in
 326   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 327   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 328   rule_id
 329
 330 let delete rule_id =
 331   let atoms = rule_id in
 332   (try
 333     let keywords = Hashtbl.find owned_keywords rule_id in
 334     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 335   with Not_found -> assert false);
 336   Grammar.delete_rule term atoms
 337
 338 (** {2 Grammar} *)
 339
 340 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 341 let parse_level2_ast_ref = ref (fun _ -> assert false)
 342 let parse_level2_meta_ref = ref (fun _ -> assert false)
 343
 344 let fold_cluster binder terms ty body =
 345   List.fold_right
 346     (fun term body -> Ast.Binder (binder, (term, ty), body))
 347     terms body  (* terms are names: either Ident or FreshVar *)
 348
 349 let fold_exists terms ty body =
 350   List.fold_right
 351     (fun term body ->
 352       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 353       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 354     terms body
 355
 356 let fold_binder binder pt_names body =
 357   List.fold_right
 358     (fun (names, ty) body -> fold_cluster binder names ty body)
 359     pt_names body
 360
 361 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 362 let return_term_of_level loc term l =
 363   Ast.AttributedTerm (`Loc loc, term l)
 364
 365   (* create empty precedence level for "term" *)
 366 let _ =
 367   let dummy_action =
 368     Gramext.action (fun _ ->
 369       failwith "internal error, lexer generated a dummy token")
 370   in
 371   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 372    * empty after the deletion. The lexer never generate the Stoken below. *)
 373   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 374   let mk_level_list first last =
 375     let rec aux acc = function
 376       | i when i < first -> acc
 377       | i ->
 378           aux
 379             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 380              :: acc)
 381             (i - 1)
 382     in
 383     aux [] last
 384   in
 385   Grammar.extend
 386     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 387       None,
 388       mk_level_list min_precedence max_precedence ]
 389
 390 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 391 EXTEND
 392   GLOBAL: level1_pattern;
 393
 394   level1_pattern: [
 395     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 396   ];
 397   l1_pattern: [
 398     [ p = LIST1 l1_simple_pattern ->
 399         fun l -> List.map (fun x -> x l) p ]
 400   ];
 401   literal: [
 402     [ s = SYMBOL -> `Symbol s
 403     | k = QKEYWORD -> `Keyword k
 404     | n = NUMBER -> `Number n
 405     ]
 406   ];
 407   sep:       [ [ "sep";      sep = literal -> sep ] ];
 408   l1_magic_pattern: [
 409     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 410             fun l -> Ast.List0 (p l, sep)
 411     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 412             fun l -> Ast.List1 (p l, sep)
 413     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 414     ]
 415   ];
 416   l1_pattern_variable: [
 417     [ "term"; precedence = NUMBER; id = IDENT ->
 418         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 419     | "number"; id = IDENT -> Ast.NumVar id
 420     | "ident"; id = IDENT -> Ast.IdentVar id
 421     ]
 422   ];
 423   mstyle: [
 424     [ id = IDENT;
 425       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 426   l1_simple_pattern:
 427     [ "layout" LEFTA
 428       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 429           return_term_of_level loc
 430             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 431       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 432           return_term_of_level loc
 433             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 434       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 435           return_term_of_level loc
 436             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 437       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 438           return_term_of_level loc
 439             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 440       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 441           return_term_of_level loc
 442             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 443       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 444           return_term_of_level loc
 445             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 446       | p1 = SELF; SYMBOL "\\frac"; p2 = SELF ->
 447           return_term_of_level loc
 448             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 449       | SYMBOL "\\infrule"; p1 = SELF; p2 = SELF; p3 = SELF ->
 450           return_term_of_level loc
 451             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 452       | SYMBOL "\\sqrt"; p = SELF ->
 453           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 454       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 455           return_term_of_level loc
 456             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 457       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 458           return_term_of_level loc
 459             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 460       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 461           return_term_of_level loc
 462             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 463       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 464           return_term_of_level loc
 465             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 466       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 467           return_term_of_level loc
 468             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 469       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 470       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 471           return_term_of_level loc
 472             (fun l ->
 473                Ast.Layout (Ast.Mstyle (m, t l)))
 474       | LPAREN; p = l1_pattern; RPAREN ->
 475           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 476       ]
 477     | "simple" NONA
 478       [ i = IDENT ->
 479          return_term_of_level loc
 480            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 481       | m = l1_magic_pattern ->
 482              return_term_of_level loc (fun l -> Ast.Magic (m l))
 483       | v = l1_pattern_variable ->
 484              return_term_of_level loc (fun _ -> Ast.Variable v)
 485       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 486       ]
 487     ];
 488   END
 489 (* }}} *)
 490
 491 (* {{{ Grammar for ast magics, notation level 2 *)
 492 EXTEND
 493   GLOBAL: level2_meta;
 494   l2_variable: [
 495     [ "term"; precedence = NUMBER; id = IDENT ->
 496         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 497     | "number"; id = IDENT -> Ast.NumVar id
 498     | "ident"; id = IDENT -> Ast.IdentVar id
 499     | "fresh"; id = IDENT -> Ast.FreshVar id
 500     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 501     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 502     ]
 503   ];
 504   l2_magic: [
 505     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 506       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 507         Ast.Fold (kind, base, [id], recursive)
 508     | "default"; some = level2_meta; none = level2_meta ->
 509         Ast.Default (some, none)
 510     | "if"; p_test = level2_meta;
 511       "then"; p_true = level2_meta;
 512       "else"; p_false = level2_meta ->
 513         Ast.If (p_test, p_true, p_false)
 514     | "fail" -> Ast.Fail
 515     ]
 516   ];
 517   level2_meta: [
 518     [ magic = l2_magic -> Ast.Magic magic
 519     | var = l2_variable -> Ast.Variable var
 520     | blob = UNPARSED_AST ->
 521         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 522     ]
 523   ];
 524 END
 525 (* }}} *)
 526
 527 (* {{{ Grammar for ast patterns, notation level 2 *)
 528 EXTEND
 529   GLOBAL: level2_ast term let_defs protected_binder_vars;
 530   level2_ast: [ [ p = term -> p ] ];
 531   sort: [
 532     [ "Prop" -> `Prop
 533     | "Set" -> `Set
 534     | "Type" -> `Type (CicUniv.fresh ())
 535     | "CProp" -> `CProp (CicUniv.fresh ())
 536     ]
 537   ];
 538   explicit_subst: [
 539     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 540       SYMBOL "[";
 541       substs = LIST1 [
 542         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 543       ] SEP SYMBOL ";";
 544       SYMBOL "]" ->
 545         substs
 546     ]
 547   ];
 548   meta_subst: [
 549     [ s = SYMBOL "_" -> None
 550     | p = term -> Some p ]
 551   ];
 552   meta_substs: [
 553     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 554   ];
 555   possibly_typed_name: [
 556     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 557         id, Some typ
 558     | arg = single_arg -> arg, None
 559     | SYMBOL "_" -> Ast.Ident ("_", None), None
 560     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 561         Ast.Ident ("_", None), Some typ
 562     ]
 563   ];
 564   match_pattern: [
 565     [ id = IDENT -> Ast.Pattern (id, None, [])
 566     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 567        Ast.Pattern (id, None, vars)
 568     | id = IDENT; vars = LIST1 possibly_typed_name ->
 569        Ast.Pattern (id, None, vars)
 570     | SYMBOL "_" -> Ast.Wildcard
 571     ]
 572   ];
 573   binder: [
 574     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 575     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 576     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 577     ]
 578   ];
 579   arg: [
 580     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 581       SYMBOL ":"; ty = term; RPAREN ->
 582         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 583     | name = IDENT -> [Ast.Ident (name, None)], None
 584     | blob = UNPARSED_META ->
 585         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 586         match meta with
 587         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 588         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 589         | _ -> failwith "Invalid bound name."
 590    ]
 591   ];
 592   single_arg: [
 593     [ name = IDENT -> Ast.Ident (name, None)
 594     | blob = UNPARSED_META ->
 595         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 596         match meta with
 597         | Ast.Variable (Ast.FreshVar _)
 598         | Ast.Variable (Ast.IdentVar _) -> meta
 599         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 600         | _ -> failwith "Invalid index name."
 601     ]
 602   ];
 603   let_defs: [
 604     [ defs = LIST1 [
 605         name = single_arg;
 606         args = LIST1 arg;
 607         index_name = OPT [ "on"; id = single_arg -> id ];
 608         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 609         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 610           let rec position_of name p = function
 611             | [] -> None, p
 612             | n :: _ when n = name -> Some p, p
 613             | _ :: tl -> position_of name (p + 1) tl
 614           in
 615           let rec find_arg name n = function
 616             | [] ->
 617                 Ast.fail loc (sprintf "Argument %s not found"
 618                   (CicNotationPp.pp_term name))
 619             | (l,_) :: tl ->
 620                 (match position_of name 0 l with
 621                 | None, len -> find_arg name (n + len) tl
 622                 | Some where, len -> n + where)
 623           in
 624           let index =
 625             match index_name with
 626             | None -> 0
 627             | Some index_name -> find_arg index_name 0 args
 628           in
 629           let args =
 630            List.concat
 631             (List.map
 632              (function (names,ty) -> List.map (function x -> x,ty) names
 633              ) args)
 634           in
 635            args, (name, ty), body, index
 636       ] SEP "and" ->
 637         defs
 638     ]
 639   ];
 640   binder_vars: [
 641     [ vars = [
 642           l = LIST1 single_arg SEP SYMBOL "," -> l
 643         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 644       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 645     ]
 646   ];
 647   protected_binder_vars: [
 648     [ LPAREN; vars = binder_vars; RPAREN -> vars
 649     ]
 650   ];
 651   maybe_protected_binder_vars: [
 652     [ vars = binder_vars -> vars
 653     | vars = protected_binder_vars -> vars
 654     ]
 655   ];
 656   term: LEVEL "10"
 657   [
 658     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 659       p1 = term; "in"; p2 = term ->
 660         return_term loc (Ast.LetIn (var, p1, p2))
 661     | LETCOREC; defs = let_defs; "in";
 662       body = term ->
 663         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 664     | LETREC; defs = let_defs; "in";
 665       body = term ->
 666         return_term loc (Ast.LetRec (`Inductive, defs, body))
 667     ]
 668   ];
 669   term: LEVEL "20"
 670     [
 671       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 672           return_term loc (fold_cluster b vars typ body)
 673       ]
 674     ];
 675   term: LEVEL "70"
 676     [
 677       [ p1 = term; p2 = term LEVEL "71" ->
 678           let rec aux = function
 679             | Ast.Appl (hd :: tl)
 680             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 681                 aux hd @ tl
 682             | term -> [term]
 683           in
 684           return_term loc (Ast.Appl (aux p1 @ [p2]))
 685       ]
 686     ];
 687   term: LEVEL "90"
 688     [
 689       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 690       | id = IDENT; s = explicit_subst ->
 691           return_term loc (Ast.Ident (id, Some s))
 692       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 693       | u = URI -> return_term loc (Ast.Uri (u, None))
 694       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 695       | IMPLICIT -> return_term loc (Ast.Implicit)
 696       | PLACEHOLDER -> return_term loc Ast.UserInput
 697       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 698       | m = META; s = meta_substs ->
 699           return_term loc (Ast.Meta (int_of_string m, s))
 700       | s = sort -> return_term loc (Ast.Sort s)
 701       | "match"; t = term;
 702         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 703         outtyp = OPT [ "return"; ty = term -> ty ];
 704         "with"; SYMBOL "[";
 705         patterns = LIST0 [
 706           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 707           rhs = term ->
 708             lhs, rhs
 709         ] SEP SYMBOL "|";
 710         SYMBOL "]" ->
 711           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 712       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 713           return_term loc (Ast.Cast (p1, p2))
 714       | LPAREN; p = term; RPAREN -> p
 715       | blob = UNPARSED_META ->
 716           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 717       ]
 718     ];
 719 END
 720 (* }}} *)
 721
 722 (** {2 API implementation} *)
 723
 724 let exc_located_wrapper f =
 725   try
 726     f ()
 727   with
 728   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 729       raise (HExtlib.Localized (floc, Parse_error msg))
 730   | Stdpp.Exc_located (floc, exn) ->
 731       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 732
 733 let parse_level1_pattern precedence lexbuf =
 734   exc_located_wrapper
 735     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf) precedence)
 736
 737 let parse_level2_ast lexbuf =
 738   exc_located_wrapper
 739     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 740
 741 let parse_level2_meta lexbuf =
 742   exc_located_wrapper
 743     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 744
 745 let _ =
 746   parse_level1_pattern_ref := parse_level1_pattern;
 747   parse_level2_ast_ref := parse_level2_ast;
 748   parse_level2_meta_ref := parse_level2_meta
 749
 750 let parse_term lexbuf =
 751   exc_located_wrapper
 752     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 753
 754 (** {2 Debugging} *)
 755
 756 let print_l2_pattern () =
 757   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 758   Format.pp_print_flush Format.std_formatter ();
 759   flush stdout
 760
 761 (* vim:set encoding=utf8 foldmethod=marker: *)