helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let level_of precedence =
  61   if precedence < min_precedence || precedence > max_precedence then
  62     raise (Level_not_found precedence);
  63   string_of_int precedence
  64
  65 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  66 let gram_ident s = Gramext.Stoken ("IDENT", s)
  67 let gram_number s = Gramext.Stoken ("NUMBER", s)
  68 let gram_keyword s = Gramext.Stoken ("", s)
  69 let gram_term = function
  70   | Ast.Self _ -> Gramext.Sself
  71   | Ast.Level precedence ->
  72       Gramext.Snterml
  73         (Grammar.Entry.obj (term: 'a Grammar.Entry.e), level_of precedence)
  74 ;;
  75
  76 let gram_of_literal =
  77   function
  78   | `Symbol s -> gram_symbol s
  79   | `Keyword s -> gram_keyword s
  80   | `Number s -> gram_number s
  81
  82 type binding =
  83   | NoBinding
  84   | Binding of string * Env.value_type
  85   | Env of (string * Env.value_type) list
  86
  87 let make_action action bindings =
  88   let rec aux (vl : CicNotationEnv.t) =
  89     function
  90       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  91     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  92     (* LUCA: DEFCON 3 BEGIN *)
  93     | Binding (name, Env.TermType l) :: tl ->
  94         Gramext.action
  95           (fun (v:Ast.term) ->
  96             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
  97     | Binding (name, Env.StringType) :: tl ->
  98         Gramext.action
  99           (fun (v:string) ->
 100             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 101     | Binding (name, Env.NumType) :: tl ->
 102         Gramext.action
 103           (fun (v:string) ->
 104             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 105     | Binding (name, Env.OptType t) :: tl ->
 106         Gramext.action
 107           (fun (v:'a option) ->
 108             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 109     | Binding (name, Env.ListType t) :: tl ->
 110         Gramext.action
 111           (fun (v:'a list) ->
 112             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 113     | Env _ :: tl ->
 114         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 115     (* LUCA: DEFCON 3 END *)
 116   in
 117     aux [] (List.rev bindings)
 118
 119 let flatten_opt =
 120   let rec aux acc =
 121     function
 122       [] -> List.rev acc
 123     | NoBinding :: tl -> aux acc tl
 124     | Env names :: tl -> aux (List.rev names @ acc) tl
 125     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 126   in
 127   aux []
 128
 129   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 130 let extract_term_production pattern =
 131   let rec aux = function
 132     | Ast.AttributedTerm (_, t) -> aux t
 133     | Ast.Literal l -> aux_literal l
 134     | Ast.Layout l -> aux_layout l
 135     | Ast.Magic m -> aux_magic m
 136     | Ast.Variable v -> aux_variable v
 137     | t ->
 138         prerr_endline (CicNotationPp.pp_term t);
 139         assert false
 140   and aux_literal =
 141     function
 142     | `Symbol s -> [NoBinding, gram_symbol s]
 143     | `Keyword s ->
 144         (* assumption: s will be registered as a keyword with the lexer *)
 145         [NoBinding, gram_keyword s]
 146     | `Number s -> [NoBinding, gram_number s]
 147   and aux_layout = function
 148     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 149     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 150     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 151     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 152     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 153     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule"] @ aux p1 @ aux p2 @ aux p3
 154     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 155     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 156     | Ast.Root (p1, p2) ->
 157         [NoBinding, gram_symbol "\\root"] @ aux p2
 158         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 159     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 160     | Ast.Break -> []
 161     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 162     | Ast.Group pl -> List.flatten (List.map aux pl)
 163     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 164   and aux_magic magic =
 165     match magic with
 166     | Ast.Opt p ->
 167         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 168         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 169           match env_opt with
 170           | Some env -> List.map Env.opt_binding_some env
 171           | None -> List.map Env.opt_binding_of_name p_names
 172         in
 173         [ Env (List.map Env.opt_declaration p_names),
 174           Gramext.srules
 175             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 176               Gramext.action action ] ]
 177     | Ast.List0 (p, _)
 178     | Ast.List1 (p, _) ->
 179         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 180         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 181           CicNotationEnv.coalesce_env p_names env_list
 182         in
 183         let gram_of_list s =
 184           match magic with
 185           | Ast.List0 (_, None) -> Gramext.Slist0 s
 186           | Ast.List1 (_, None) -> Gramext.Slist1 s
 187           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 188           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 189           | _ -> assert false
 190         in
 191         [ Env (List.map Env.list_declaration p_names),
 192           Gramext.srules
 193             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 194               Gramext.action action ] ]
 195     | _ -> assert false
 196   and aux_variable =
 197     function
 198     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 199     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 200         [Binding (s, Env.TermType level), gram_term lv]
 201     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 202     | Ast.Ascription (p, s) -> assert false (* TODO *)
 203     | Ast.FreshVar _ -> assert false
 204   and inner_pattern p =
 205     let p_bindings, p_atoms = List.split (aux p) in
 206     let p_names = flatten_opt p_bindings in
 207     let action =
 208       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 209         p_bindings
 210     in
 211     p_bindings, p_atoms, p_names, action
 212   in
 213   aux pattern
 214
 215 type rule_id = Grammar.token Gramext.g_symbol list
 216
 217 let compare_rule_id x y =
 218   let rec aux = function
 219     | [],[] -> 0
 220     | [],_ -> ~-1
 221     | _,[] -> 1
 222     | ((s1::tl1) as x),((s2::tl2) as y) ->
 223         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 224         else Pervasives.compare x y
 225   in
 226     aux (x,y)
 227
 228   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 229 let initial_owned_keywords () = Hashtbl.create 23
 230
 231 let owned_keywords = ref (initial_owned_keywords ())
 232
 233 let history = ref [];;
 234
 235 let push () =
 236   history := !owned_keywords :: !history;
 237   owned_keywords := (initial_owned_keywords ())
 238 ;;
 239
 240 let pop () =
 241   match !history with
 242   | [] -> assert false
 243   | hd :: old_history ->
 244       owned_keywords := hd;
 245       history := old_history
 246 ;;
 247
 248 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 249
 250 let check_l1_pattern level1_pattern level associativity =
 251   let variables = ref 0 in
 252   let symbols = ref 0 in
 253   let rec aux = function
 254     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 255     | Ast.Literal _ as l -> incr symbols; l
 256     | Ast.Layout l -> Ast.Layout (aux_layout l)
 257     | Ast.Magic m -> Ast.Magic (aux_magic m)
 258     | Ast.Variable v -> (aux_variable v)
 259     | t -> assert false
 260   and aux_layout = function
 261     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 262     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 263     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 264     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 265     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 266     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 267     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 268     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 269     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 270     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 271     | Ast.Break as t -> t
 272     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 273     | Ast.Group pl -> Ast.Group (List.map aux pl)
 274     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 275   and aux_magic magic =
 276     match magic with
 277     | Ast.Opt p -> Ast.Opt (aux p)
 278     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 279     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 280     | _ -> assert false
 281   and aux_variable =
 282     function
 283     | Ast.NumVar _ as t -> Ast.Variable t
 284     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 285         incr variables;
 286         if !variables > 2 then
 287           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 288           "associative notation"));
 289         (match !variables, associativity with
 290         | 1,Gramext.LeftA ->
 291              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 292         | 1,Gramext.RightA ->
 293              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 294         | 2,Gramext.LeftA ->
 295              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 296         | 2,Gramext.RightA ->
 297              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 298         | _ -> assert false)
 299     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 300           raise (Parse_error ("Variables can not be declared with a " ^
 301             "precedence in an associative notation"))
 302        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 303     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 304        raise(Parse_error("Left recursive rule with precedence not greater " ^
 305         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 306     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 307     | Ast.IdentVar _ as t -> Ast.Variable t
 308     | Ast.Ascription _ -> assert false (* TODO *)
 309     | Ast.FreshVar _ -> assert false
 310   in
 311   if associativity <> Gramext.NonA && level = min_precedence then
 312     raise (Parse_error ("You can not specify an associative notation " ^
 313     "at level "^string_of_int min_precedence ^ "; increase it"));
 314   let cp = aux level1_pattern in
 315 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 316   if !variables <> 2 && associativity <> Gramext.NonA then
 317     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 318      "associative notation"));
 319   CL1P (cp,level)
 320 ;;
 321
 322 let extend (CL1P (level1_pattern,precedence)) action =
 323   let p_bindings, p_atoms =
 324     List.split (extract_term_production level1_pattern)
 325   in
 326   let level = level_of precedence in
 327   let _ =
 328     Grammar.extend
 329       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 330         Some (Gramext.Level level),
 331         [ None,
 332           Some (*Gramext.NonA*) Gramext.NonA,
 333           [ p_atoms,
 334             (make_action
 335               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 336                 (action env loc))
 337               p_bindings) ]]]
 338   in
 339   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 340   let rule_id = p_atoms in
 341   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 342   Hashtbl.add !owned_keywords rule_id keywords;  (* keywords may be [] *)
 343   rule_id
 344
 345 let delete rule_id =
 346   let atoms = rule_id in
 347   (try
 348     let keywords = Hashtbl.find !owned_keywords rule_id in
 349     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 350   with Not_found -> assert false);
 351   Grammar.delete_rule term atoms
 352
 353 (** {2 Grammar} *)
 354
 355 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 356 let parse_level2_ast_ref = ref (fun _ -> assert false)
 357 let parse_level2_meta_ref = ref (fun _ -> assert false)
 358
 359 let fold_cluster binder terms ty body =
 360   List.fold_right
 361     (fun term body -> Ast.Binder (binder, (term, ty), body))
 362     terms body  (* terms are names: either Ident or FreshVar *)
 363
 364 let fold_exists terms ty body =
 365   List.fold_right
 366     (fun term body ->
 367       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 368       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 369     terms body
 370
 371 let fold_binder binder pt_names body =
 372   List.fold_right
 373     (fun (names, ty) body -> fold_cluster binder names ty body)
 374     pt_names body
 375
 376 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 377 let return_term_of_level loc term l =
 378   Ast.AttributedTerm (`Loc loc, term l)
 379
 380   (* create empty precedence level for "term" *)
 381 let _ =
 382   let dummy_action =
 383     Gramext.action (fun _ ->
 384       failwith "internal error, lexer generated a dummy token")
 385   in
 386   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 387    * empty after the deletion. The lexer never generate the Stoken below. *)
 388   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 389   let mk_level_list first last =
 390     let rec aux acc = function
 391       | i when i < first -> acc
 392       | i ->
 393           aux
 394             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 395              :: acc)
 396             (i - 1)
 397     in
 398     aux [] last
 399   in
 400   Grammar.extend
 401     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 402       None,
 403       mk_level_list min_precedence max_precedence ]
 404
 405 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 406 EXTEND
 407   GLOBAL: level1_pattern;
 408
 409   level1_pattern: [
 410     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 411   ];
 412   l1_pattern: [
 413     [ p = LIST1 l1_simple_pattern ->
 414         fun l -> List.map (fun x -> x l) p ]
 415   ];
 416   literal: [
 417     [ s = SYMBOL -> `Symbol s
 418     | k = QKEYWORD -> `Keyword k
 419     | n = NUMBER -> `Number n
 420     ]
 421   ];
 422   sep:       [ [ "sep";      sep = literal -> sep ] ];
 423   l1_magic_pattern: [
 424     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 425             fun l -> Ast.List0 (p l, sep)
 426     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 427             fun l -> Ast.List1 (p l, sep)
 428     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 429     ]
 430   ];
 431   l1_pattern_variable: [
 432     [ "term"; precedence = NUMBER; id = IDENT ->
 433         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 434     | "number"; id = IDENT -> Ast.NumVar id
 435     | "ident"; id = IDENT -> Ast.IdentVar id
 436     ]
 437   ];
 438   mstyle: [
 439     [ id = IDENT;
 440       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 441   l1_simple_pattern:
 442     [ "layout" LEFTA
 443       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 444           return_term_of_level loc
 445             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 446       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 447           return_term_of_level loc
 448             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 449       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 450           return_term_of_level loc
 451             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 452       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 453           return_term_of_level loc
 454             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 455       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 456           return_term_of_level loc
 457             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 458       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 459           return_term_of_level loc
 460             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 461       | p1 = SELF; SYMBOL "\\frac"; p2 = SELF ->
 462           return_term_of_level loc
 463             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 464       | SYMBOL "\\infrule"; p1 = SELF; p2 = SELF; p3 = SELF ->
 465           return_term_of_level loc
 466             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 467       | SYMBOL "\\sqrt"; p = SELF ->
 468           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 469       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 470           return_term_of_level loc
 471             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 472       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 473           return_term_of_level loc
 474             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 475       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 476           return_term_of_level loc
 477             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 478       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 479           return_term_of_level loc
 480             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 481       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 482           return_term_of_level loc
 483             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 484       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 485       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 486           return_term_of_level loc
 487             (fun l ->
 488                Ast.Layout (Ast.Mstyle (m, t l)))
 489       | LPAREN; p = l1_pattern; RPAREN ->
 490           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 491       ]
 492     | "simple" NONA
 493       [ i = IDENT ->
 494          return_term_of_level loc
 495            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 496       | m = l1_magic_pattern ->
 497              return_term_of_level loc (fun l -> Ast.Magic (m l))
 498       | v = l1_pattern_variable ->
 499              return_term_of_level loc (fun _ -> Ast.Variable v)
 500       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 501       ]
 502     ];
 503   END
 504 (* }}} *)
 505
 506 (* {{{ Grammar for ast magics, notation level 2 *)
 507 EXTEND
 508   GLOBAL: level2_meta;
 509   l2_variable: [
 510     [ "term"; precedence = NUMBER; id = IDENT ->
 511         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 512     | "number"; id = IDENT -> Ast.NumVar id
 513     | "ident"; id = IDENT -> Ast.IdentVar id
 514     | "fresh"; id = IDENT -> Ast.FreshVar id
 515     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 516     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 517     ]
 518   ];
 519   l2_magic: [
 520     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 521       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 522         Ast.Fold (kind, base, [id], recursive)
 523     | "default"; some = level2_meta; none = level2_meta ->
 524         Ast.Default (some, none)
 525     | "if"; p_test = level2_meta;
 526       "then"; p_true = level2_meta;
 527       "else"; p_false = level2_meta ->
 528         Ast.If (p_test, p_true, p_false)
 529     | "fail" -> Ast.Fail
 530     ]
 531   ];
 532   level2_meta: [
 533     [ magic = l2_magic -> Ast.Magic magic
 534     | var = l2_variable -> Ast.Variable var
 535     | blob = UNPARSED_AST ->
 536         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 537     ]
 538   ];
 539 END
 540 (* }}} *)
 541
 542 (* {{{ Grammar for ast patterns, notation level 2 *)
 543 EXTEND
 544   GLOBAL: level2_ast term let_defs protected_binder_vars;
 545   level2_ast: [ [ p = term -> p ] ];
 546   sort: [
 547     [ "Prop" -> `Prop
 548     | "Set" -> `Set
 549     | "Type" -> `Type (CicUniv.fresh ())
 550     | "CProp" -> `CProp (CicUniv.fresh ())
 551     ]
 552   ];
 553   explicit_subst: [
 554     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 555       SYMBOL "[";
 556       substs = LIST1 [
 557         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 558       ] SEP SYMBOL ";";
 559       SYMBOL "]" ->
 560         substs
 561     ]
 562   ];
 563   meta_subst: [
 564     [ s = SYMBOL "_" -> None
 565     | p = term -> Some p ]
 566   ];
 567   meta_substs: [
 568     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 569   ];
 570   possibly_typed_name: [
 571     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 572         id, Some typ
 573     | arg = single_arg -> arg, None
 574     | SYMBOL "_" -> Ast.Ident ("_", None), None
 575     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 576         Ast.Ident ("_", None), Some typ
 577     ]
 578   ];
 579   match_pattern: [
 580     [ id = IDENT -> Ast.Pattern (id, None, [])
 581     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 582        Ast.Pattern (id, None, vars)
 583     | id = IDENT; vars = LIST1 possibly_typed_name ->
 584        Ast.Pattern (id, None, vars)
 585     | SYMBOL "_" -> Ast.Wildcard
 586     ]
 587   ];
 588   binder: [
 589     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 590     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 591     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 592     ]
 593   ];
 594   arg: [
 595     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 596       SYMBOL ":"; ty = term; RPAREN ->
 597         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 598     | name = IDENT -> [Ast.Ident (name, None)], None
 599     | blob = UNPARSED_META ->
 600         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 601         match meta with
 602         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 603         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 604         | _ -> failwith "Invalid bound name."
 605    ]
 606   ];
 607   single_arg: [
 608     [ name = IDENT -> Ast.Ident (name, None)
 609     | blob = UNPARSED_META ->
 610         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 611         match meta with
 612         | Ast.Variable (Ast.FreshVar _)
 613         | Ast.Variable (Ast.IdentVar _) -> meta
 614         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 615         | _ -> failwith "Invalid index name."
 616     ]
 617   ];
 618   let_defs: [
 619     [ defs = LIST1 [
 620         name = single_arg;
 621         args = LIST1 arg;
 622         index_name = OPT [ "on"; id = single_arg -> id ];
 623         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 624         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 625           let rec position_of name p = function
 626             | [] -> None, p
 627             | n :: _ when n = name -> Some p, p
 628             | _ :: tl -> position_of name (p + 1) tl
 629           in
 630           let rec find_arg name n = function
 631             | [] ->
 632                 Ast.fail loc (sprintf "Argument %s not found"
 633                   (CicNotationPp.pp_term name))
 634             | (l,_) :: tl ->
 635                 (match position_of name 0 l with
 636                 | None, len -> find_arg name (n + len) tl
 637                 | Some where, len -> n + where)
 638           in
 639           let index =
 640             match index_name with
 641             | None -> 0
 642             | Some index_name -> find_arg index_name 0 args
 643           in
 644           let args =
 645            List.concat
 646             (List.map
 647              (function (names,ty) -> List.map (function x -> x,ty) names
 648              ) args)
 649           in
 650            args, (name, ty), body, index
 651       ] SEP "and" ->
 652         defs
 653     ]
 654   ];
 655   binder_vars: [
 656     [ vars = [
 657           l = LIST1 single_arg SEP SYMBOL "," -> l
 658         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 659       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 660     ]
 661   ];
 662   protected_binder_vars: [
 663     [ LPAREN; vars = binder_vars; RPAREN -> vars
 664     ]
 665   ];
 666   maybe_protected_binder_vars: [
 667     [ vars = binder_vars -> vars
 668     | vars = protected_binder_vars -> vars
 669     ]
 670   ];
 671   term: LEVEL "10"
 672   [
 673     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 674       p1 = term; "in"; p2 = term ->
 675         return_term loc (Ast.LetIn (var, p1, p2))
 676     | LETCOREC; defs = let_defs; "in";
 677       body = term ->
 678         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 679     | LETREC; defs = let_defs; "in";
 680       body = term ->
 681         return_term loc (Ast.LetRec (`Inductive, defs, body))
 682     ]
 683   ];
 684   term: LEVEL "20"
 685     [
 686       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 687           return_term loc (fold_cluster b vars typ body)
 688       ]
 689     ];
 690   term: LEVEL "70"
 691     [
 692       [ p1 = term; p2 = term LEVEL "71" ->
 693           let rec aux = function
 694             | Ast.Appl (hd :: tl)
 695             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 696                 aux hd @ tl
 697             | term -> [term]
 698           in
 699           return_term loc (Ast.Appl (aux p1 @ [p2]))
 700       ]
 701     ];
 702   term: LEVEL "90"
 703     [
 704       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 705       | id = IDENT; s = explicit_subst ->
 706           return_term loc (Ast.Ident (id, Some s))
 707       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 708       | u = URI -> return_term loc (Ast.Uri (u, None))
 709       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 710       | IMPLICIT -> return_term loc (Ast.Implicit)
 711       | PLACEHOLDER -> return_term loc Ast.UserInput
 712       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 713       | m = META; s = meta_substs ->
 714           return_term loc (Ast.Meta (int_of_string m, s))
 715       | s = sort -> return_term loc (Ast.Sort s)
 716       | "match"; t = term;
 717         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 718         outtyp = OPT [ "return"; ty = term -> ty ];
 719         "with"; SYMBOL "[";
 720         patterns = LIST0 [
 721           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 722           rhs = term ->
 723             lhs, rhs
 724         ] SEP SYMBOL "|";
 725         SYMBOL "]" ->
 726           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 727       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 728           return_term loc (Ast.Cast (p1, p2))
 729       | LPAREN; p = term; RPAREN -> p
 730       | blob = UNPARSED_META ->
 731           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 732       ]
 733     ];
 734 END
 735 (* }}} *)
 736
 737 (** {2 API implementation} *)
 738
 739 let exc_located_wrapper f =
 740   try
 741     f ()
 742   with
 743   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 744       raise (HExtlib.Localized (floc, Parse_error msg))
 745   | Stdpp.Exc_located (floc, exn) ->
 746       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 747
 748 let parse_level1_pattern precedence lexbuf =
 749   exc_located_wrapper
 750     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf) precedence)
 751
 752 let parse_level2_ast lexbuf =
 753   exc_located_wrapper
 754     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 755
 756 let parse_level2_meta lexbuf =
 757   exc_located_wrapper
 758     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 759
 760 let _ =
 761   parse_level1_pattern_ref := parse_level1_pattern;
 762   parse_level2_ast_ref := parse_level2_ast;
 763   parse_level2_meta_ref := parse_level2_meta
 764
 765 let parse_term lexbuf =
 766   exc_located_wrapper
 767     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 768
 769 (** {2 Debugging} *)
 770
 771 let print_l2_pattern () =
 772   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 773   Format.pp_print_flush Format.std_formatter ();
 774   flush stdout
 775
 776 (* vim:set encoding=utf8 foldmethod=marker: *)