helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  61 let gram_ident s = Gramext.Stoken ("IDENT", s)
  62 let gram_number s = Gramext.Stoken ("NUMBER", s)
  63 let gram_keyword s = Gramext.Stoken ("", s)
  64 let gram_term = Gramext.Sself
  65
  66 let gram_of_literal =
  67   function
  68   | `Symbol s -> gram_symbol s
  69   | `Keyword s -> gram_keyword s
  70   | `Number s -> gram_number s
  71
  72 type binding =
  73   | NoBinding
  74   | Binding of string * Env.value_type
  75   | Env of (string * Env.value_type) list
  76
  77 let make_action action bindings =
  78   let rec aux (vl : CicNotationEnv.t) =
  79     function
  80       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  81     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  82     (* LUCA: DEFCON 3 BEGIN *)
  83     | Binding (name, Env.TermType) :: tl ->
  84         Gramext.action
  85           (fun (v:Ast.term) ->
  86             aux ((name, (Env.TermType, Env.TermValue v))::vl) tl)
  87     | Binding (name, Env.StringType) :: tl ->
  88         Gramext.action
  89           (fun (v:string) ->
  90             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
  91     | Binding (name, Env.NumType) :: tl ->
  92         Gramext.action
  93           (fun (v:string) ->
  94             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
  95     | Binding (name, Env.OptType t) :: tl ->
  96         Gramext.action
  97           (fun (v:'a option) ->
  98             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
  99     | Binding (name, Env.ListType t) :: tl ->
 100         Gramext.action
 101           (fun (v:'a list) ->
 102             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 103     | Env _ :: tl ->
 104         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 105     (* LUCA: DEFCON 3 END *)
 106   in
 107     aux [] (List.rev bindings)
 108
 109 let flatten_opt =
 110   let rec aux acc =
 111     function
 112       [] -> List.rev acc
 113     | NoBinding :: tl -> aux acc tl
 114     | Env names :: tl -> aux (List.rev names @ acc) tl
 115     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 116   in
 117   aux []
 118
 119   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 120 let extract_term_production pattern =
 121   let rec aux = function
 122     | Ast.AttributedTerm (_, t) -> aux t
 123     | Ast.Literal l -> aux_literal l
 124     | Ast.Layout l -> aux_layout l
 125     | Ast.Magic m -> aux_magic m
 126     | Ast.Variable v -> aux_variable v
 127     | t ->
 128         prerr_endline (CicNotationPp.pp_term t);
 129         assert false
 130   and aux_literal =
 131     function
 132     | `Symbol s -> [NoBinding, gram_symbol s]
 133     | `Keyword s ->
 134         (* assumption: s will be registered as a keyword with the lexer *)
 135         [NoBinding, gram_keyword s]
 136     | `Number s -> [NoBinding, gram_number s]
 137   and aux_layout = function
 138     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 139     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 140     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 141     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 142     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 143     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 144     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 145     | Ast.Root (p1, p2) ->
 146         [NoBinding, gram_symbol "\\root"] @ aux p2
 147         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 148     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 149     | Ast.Break -> []
 150     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 151     | Ast.Group pl -> List.flatten (List.map aux pl)
 152   and aux_magic magic =
 153     match magic with
 154     | Ast.Opt p ->
 155         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 156         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 157           match env_opt with
 158           | Some env -> List.map Env.opt_binding_some env
 159           | None -> List.map Env.opt_binding_of_name p_names
 160         in
 161         [ Env (List.map Env.opt_declaration p_names),
 162           Gramext.srules
 163             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 164               Gramext.action action ] ]
 165     | Ast.List0 (p, _)
 166     | Ast.List1 (p, _) ->
 167         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 168 (*         let env0 = List.map list_binding_of_name p_names in
 169         let grow_env_entry env n v =
 170           List.map
 171             (function
 172               | (n', (ty, ListValue vl)) as entry ->
 173                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 174               | _ -> assert false)
 175             env
 176         in
 177         let grow_env env_i env =
 178           List.fold_left
 179             (fun env (n, (_, v)) -> grow_env_entry env n v)
 180             env env_i
 181         in *)
 182         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 183           CicNotationEnv.coalesce_env p_names env_list
 184         in
 185         let gram_of_list s =
 186           match magic with
 187           | Ast.List0 (_, None) -> Gramext.Slist0 s
 188           | Ast.List1 (_, None) -> Gramext.Slist1 s
 189           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 190           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 191           | _ -> assert false
 192         in
 193         [ Env (List.map Env.list_declaration p_names),
 194           Gramext.srules
 195             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 196               Gramext.action action ] ]
 197     | _ -> assert false
 198   and aux_variable =
 199     function
 200     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 201     | Ast.TermVar s -> [Binding (s, Env.TermType), gram_term]
 202     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 203     | Ast.Ascription (p, s) -> assert false (* TODO *)
 204     | Ast.FreshVar _ -> assert false
 205   and inner_pattern p =
 206     let p_bindings, p_atoms = List.split (aux p) in
 207     let p_names = flatten_opt p_bindings in
 208     let action =
 209       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 210         p_bindings
 211     in
 212     p_bindings, p_atoms, p_names, action
 213   in
 214   aux pattern
 215
 216 let level_of precedence associativity =
 217   if precedence < min_precedence || precedence > max_precedence then
 218     raise (Level_not_found precedence);
 219   let assoc_string =
 220     match associativity with
 221     | Gramext.NonA -> "N"
 222     | Gramext.LeftA -> "L"
 223     | Gramext.RightA -> "R"
 224   in
 225   string_of_int precedence ^ assoc_string
 226
 227 type rule_id = Token.t Gramext.g_symbol list
 228
 229   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 230 let owned_keywords = Hashtbl.create 23
 231
 232 let extend level1_pattern ~precedence ~associativity action =
 233   let p_bindings, p_atoms =
 234     List.split (extract_term_production level1_pattern)
 235   in
 236   let level = level_of precedence associativity in
 237 (*   let p_names = flatten_opt p_bindings in *)
 238   let _ =
 239     Grammar.extend
 240       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 241         Some (Gramext.Level level),
 242         [ None,
 243           Some associativity,
 244           [ p_atoms,
 245             (make_action
 246               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 247                 (action env loc))
 248               p_bindings) ]]]
 249   in
 250   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 251   let rule_id = p_atoms in
 252   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 253   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 254   rule_id
 255
 256 let delete rule_id =
 257   let atoms = rule_id in
 258   (try
 259     let keywords = Hashtbl.find owned_keywords rule_id in
 260     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 261   with Not_found -> assert false);
 262   Grammar.delete_rule term atoms
 263
 264 (** {2 Grammar} *)
 265
 266 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 267 let parse_level2_ast_ref = ref (fun _ -> assert false)
 268 let parse_level2_meta_ref = ref (fun _ -> assert false)
 269
 270 let fold_cluster binder terms ty body =
 271   List.fold_right
 272     (fun term body -> Ast.Binder (binder, (term, ty), body))
 273     terms body  (* terms are names: either Ident or FreshVar *)
 274
 275 let fold_exists terms ty body =
 276   List.fold_right
 277     (fun term body ->
 278       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 279       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 280     terms body
 281
 282 let fold_binder binder pt_names body =
 283   List.fold_right
 284     (fun (names, ty) body -> fold_cluster binder names ty body)
 285     pt_names body
 286
 287 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 288
 289   (* create empty precedence level for "term" *)
 290 let _ =
 291   let dummy_action =
 292     Gramext.action (fun _ ->
 293       failwith "internal error, lexer generated a dummy token")
 294   in
 295   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 296    * empty after the deletion. The lexer never generate the Stoken below. *)
 297   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 298   let mk_level_list first last =
 299     let rec aux acc = function
 300       | i when i < first -> acc
 301       | i ->
 302           aux
 303             ((Some (string_of_int i ^ "N"), Some Gramext.NonA, dummy_prod)
 304              :: (Some (string_of_int i ^ "L"), Some Gramext.LeftA, dummy_prod)
 305              :: (Some (string_of_int i ^ "R"), Some Gramext.RightA, dummy_prod)
 306              :: acc)
 307             (i - 1)
 308     in
 309     aux [] last
 310   in
 311   Grammar.extend
 312     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 313       None,
 314       mk_level_list min_precedence max_precedence ]
 315
 316 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 317 EXTEND
 318   GLOBAL: level1_pattern;
 319
 320   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 321   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 322   literal: [
 323     [ s = SYMBOL -> `Symbol s
 324     | k = QKEYWORD -> `Keyword k
 325     | n = NUMBER -> `Number n
 326     ]
 327   ];
 328   sep:       [ [ "sep";      sep = literal -> sep ] ];
 329 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 330   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 331   l1_magic_pattern: [
 332     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> Ast.List0 (p, sep)
 333     | "list1"; p = l1_simple_pattern; sep = OPT sep -> Ast.List1 (p, sep)
 334     | "opt";   p = l1_simple_pattern -> Ast.Opt p
 335     ]
 336   ];
 337   l1_pattern_variable: [
 338     [ "term"; id = IDENT -> Ast.TermVar id
 339     | "number"; id = IDENT -> Ast.NumVar id
 340     | "ident"; id = IDENT -> Ast.IdentVar id
 341     ]
 342   ];
 343   l1_simple_pattern:
 344     [ "layout" LEFTA
 345       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 346           return_term loc (Ast.Layout (Ast.Sub (p1, p2)))
 347       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 348           return_term loc (Ast.Layout (Ast.Sup (p1, p2)))
 349       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 350           return_term loc (Ast.Layout (Ast.Below (p1, p2)))
 351       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 352           return_term loc (Ast.Layout (Ast.Above (p1, p2)))
 353       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 354           return_term loc (Ast.Layout (Ast.Over (p1, p2)))
 355       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 356           return_term loc (Ast.Layout (Ast.Atop (p1, p2)))
 357 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 358           return_term loc (Array (p, csep, rsep)) *)
 359       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 360           return_term loc (Ast.Layout (Ast.Frac (p1, p2)))
 361       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Ast.Layout (Ast.Sqrt p))
 362       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 363           return_term loc (Ast.Layout (Ast.Root (arg, index)))
 364       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 365           return_term loc (Ast.Layout (Ast.Box ((Ast.H, false, false), p)))
 366       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 367           return_term loc (Ast.Layout (Ast.Box ((Ast.V, false, false), p)))
 368       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 369           return_term loc (Ast.Layout (Ast.Box ((Ast.HV, false, false), p)))
 370       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 371           return_term loc (Ast.Layout (Ast.Box ((Ast.HOV, false, false), p)))
 372       | "break" -> return_term loc (Ast.Layout Ast.Break)
 373 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 374       | LPAREN; p = l1_pattern; RPAREN ->
 375           return_term loc (CicNotationUtil.group p)
 376       ]
 377     | "simple" NONA
 378       [ i = IDENT -> return_term loc (Ast.Variable (Ast.TermVar i))
 379       | m = l1_magic_pattern -> return_term loc (Ast.Magic m)
 380       | v = l1_pattern_variable -> return_term loc (Ast.Variable v)
 381       | l = literal -> return_term loc (Ast.Literal l)
 382       ]
 383     ];
 384   END
 385 (* }}} *)
 386
 387 (* {{{ Grammar for ast magics, notation level 2 *)
 388 EXTEND
 389   GLOBAL: level2_meta;
 390   l2_variable: [
 391     [ "term"; id = IDENT -> Ast.TermVar id
 392     | "number"; id = IDENT -> Ast.NumVar id
 393     | "ident"; id = IDENT -> Ast.IdentVar id
 394     | "fresh"; id = IDENT -> Ast.FreshVar id
 395     | "anonymous" -> Ast.TermVar "_"
 396     | id = IDENT -> Ast.TermVar id
 397     ]
 398   ];
 399   l2_magic: [
 400     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 401       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 402         Ast.Fold (kind, base, [id], recursive)
 403     | "default"; some = level2_meta; none = level2_meta ->
 404         Ast.Default (some, none)
 405     | "if"; p_test = level2_meta;
 406       "then"; p_true = level2_meta;
 407       "else"; p_false = level2_meta ->
 408         Ast.If (p_test, p_true, p_false)
 409     | "fail" -> Ast.Fail
 410     ]
 411   ];
 412   level2_meta: [
 413     [ magic = l2_magic -> Ast.Magic magic
 414     | var = l2_variable -> Ast.Variable var
 415     | blob = UNPARSED_AST ->
 416         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 417     ]
 418   ];
 419 END
 420 (* }}} *)
 421
 422 (* {{{ Grammar for ast patterns, notation level 2 *)
 423 EXTEND
 424   GLOBAL: level2_ast term let_defs protected_binder_vars;
 425   level2_ast: [ [ p = term -> p ] ];
 426   sort: [
 427     [ "Prop" -> `Prop
 428     | "Set" -> `Set
 429     | "Type" -> `Type (CicUniv.fresh ())
 430     | "CProp" -> `CProp
 431     ]
 432   ];
 433   explicit_subst: [
 434     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 435       SYMBOL "[";
 436       substs = LIST1 [
 437         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 438       ] SEP SYMBOL ";";
 439       SYMBOL "]" ->
 440         substs
 441     ]
 442   ];
 443   meta_subst: [
 444     [ s = SYMBOL "_" -> None
 445     | p = term -> Some p ]
 446   ];
 447   meta_substs: [
 448     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 449   ];
 450   possibly_typed_name: [
 451     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 452         id, Some typ
 453     | arg = single_arg -> arg, None
 454     | SYMBOL "_" -> Ast.Ident ("_", None), None
 455     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 456         Ast.Ident ("_", None), Some typ
 457     ]
 458   ];
 459   match_pattern: [
 460     [ id = IDENT -> id, None, []
 461     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 462         id, None, vars
 463     | id = IDENT; vars = LIST1 possibly_typed_name -> id, None, vars
 464     ]
 465   ];
 466   binder: [
 467     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 468 (*     | SYMBOL <:unicode<exists>> |+ ∃ +| -> `Exists *)
 469     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 470     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 471     ]
 472   ];
 473   arg: [
 474     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 475       SYMBOL ":"; ty = term; RPAREN ->
 476         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 477     | name = IDENT -> [Ast.Ident (name, None)], None
 478     | blob = UNPARSED_META ->
 479         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 480         match meta with
 481         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 482         | Ast.Variable (Ast.TermVar "_") -> [Ast.Ident ("_", None)], None
 483         | _ -> failwith "Invalid bound name."
 484    ]
 485   ];
 486   single_arg: [
 487     [ name = IDENT -> Ast.Ident (name, None)
 488     | blob = UNPARSED_META ->
 489         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 490         match meta with
 491         | Ast.Variable (Ast.FreshVar _)
 492         | Ast.Variable (Ast.IdentVar _) -> meta
 493         | Ast.Variable (Ast.TermVar "_") -> Ast.Ident ("_", None)
 494         | _ -> failwith "Invalid index name."
 495     ]
 496   ];
 497   induction_kind: [
 498     [ "rec" -> `Inductive
 499     | "corec" -> `CoInductive
 500     ]
 501   ];
 502   let_defs: [
 503     [ defs = LIST1 [
 504         name = single_arg;
 505         args = LIST1 arg;
 506         index_name = OPT [ "on"; id = single_arg -> id ];
 507         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 508         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 509           let rec position_of name p = function
 510             | [] -> None, p
 511             | n :: _ when n = name -> Some p, p
 512             | _ :: tl -> position_of name (p + 1) tl
 513           in
 514           let rec find_arg name n = function
 515             | [] ->
 516                 Ast.fail loc (sprintf "Argument %s not found"
 517                   (CicNotationPp.pp_term name))
 518             | (l,_) :: tl ->
 519                 (match position_of name 0 l with
 520                 | None, len -> find_arg name (n + len) tl
 521                 | Some where, len -> n + where)
 522           in
 523           let index =
 524             match index_name with
 525             | None -> 0
 526             | Some index_name -> find_arg index_name 0 args
 527           in
 528           let args =
 529            List.concat
 530             (List.map
 531              (function (names,ty) -> List.map (function x -> x,ty) names
 532              ) args)
 533           in
 534            args, (name, ty), body, index
 535       ] SEP "and" ->
 536         defs
 537     ]
 538   ];
 539   binder_vars: [
 540     [ vars = [
 541           l = LIST1 single_arg SEP SYMBOL "," -> l
 542         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 543       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 544     ]
 545   ];
 546   protected_binder_vars: [
 547     [ LPAREN; vars = binder_vars; RPAREN -> vars
 548     ]
 549   ];
 550   maybe_protected_binder_vars: [
 551     [ vars = binder_vars -> vars
 552     | vars = protected_binder_vars -> vars
 553     ]
 554   ];
 555   term: LEVEL "10N" [ (* let in *)
 556     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 557       p1 = term; "in"; p2 = term ->
 558         return_term loc (Ast.LetIn (var, p1, p2))
 559     | "let"; k = induction_kind; defs = let_defs; "in";
 560       body = term ->
 561         return_term loc (Ast.LetRec (k, defs, body))
 562     ]
 563   ];
 564   term: LEVEL "20R"  (* binder *)
 565     [
 566       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term ->
 567           return_term loc (fold_cluster b vars typ body)
 568       | SYMBOL <:unicode<exists>> (* ∃ *);
 569         (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term ->
 570           return_term loc (fold_exists vars typ body)
 571       ]
 572     ];
 573   term: LEVEL "70L"  (* apply *)
 574     [
 575       [ p1 = term; p2 = term ->
 576           let rec aux = function
 577             | Ast.Appl (hd :: tl)
 578             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 579                 aux hd @ tl
 580             | term -> [term]
 581           in
 582           return_term loc (Ast.Appl (aux p1 @ [p2]))
 583       ]
 584     ];
 585   term: LEVEL "90N"  (* simple *)
 586     [
 587       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 588       | id = IDENT; s = explicit_subst ->
 589           return_term loc (Ast.Ident (id, Some s))
 590       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 591       | u = URI -> return_term loc (Ast.Uri (u, None))
 592       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 593       | IMPLICIT -> return_term loc (Ast.Implicit)
 594       | PLACEHOLDER -> return_term loc Ast.UserInput
 595       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 596       | m = META; s = meta_substs ->
 597           return_term loc (Ast.Meta (int_of_string m, s))
 598       | s = sort -> return_term loc (Ast.Sort s)
 599       | "match"; t = term;
 600         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 601         outtyp = OPT [ "return"; ty = term -> ty ];
 602         "with"; SYMBOL "[";
 603         patterns = LIST0 [
 604           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 605           rhs = term ->
 606             lhs, rhs
 607         ] SEP SYMBOL "|";
 608         SYMBOL "]" ->
 609           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 610       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 611           return_term loc (Ast.Cast (p1, p2))
 612       | LPAREN; p = term; RPAREN -> p
 613       | blob = UNPARSED_META ->
 614           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 615       ]
 616     ];
 617 END
 618 (* }}} *)
 619
 620 (** {2 API implementation} *)
 621
 622 let exc_located_wrapper f =
 623   try
 624     f ()
 625   with
 626   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 627       raise (HExtlib.Localized (floc, Parse_error msg))
 628   | Stdpp.Exc_located (floc, exn) ->
 629       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 630
 631 let parse_level1_pattern lexbuf =
 632   exc_located_wrapper
 633     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf))
 634
 635 let parse_level2_ast lexbuf =
 636   exc_located_wrapper
 637     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 638
 639 let parse_level2_meta lexbuf =
 640   exc_located_wrapper
 641     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 642
 643 let _ =
 644   parse_level1_pattern_ref := parse_level1_pattern;
 645   parse_level2_ast_ref := parse_level2_ast;
 646   parse_level2_meta_ref := parse_level2_meta
 647
 648 let parse_term lexbuf =
 649   exc_located_wrapper
 650     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 651
 652 (** {2 Debugging} *)
 653
 654 let print_l2_pattern () =
 655   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 656   Format.pp_print_flush Format.std_formatter ();
 657   flush stdout
 658
 659 (* vim:set encoding=utf8 foldmethod=marker: *)