helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let min_precedence = 0
  37 let max_precedence = 100
  38
  39 type ('a,'b,'c,'d) grammars = {
  40   level1_pattern: 'a Grammar.Entry.e;
  41   level2_ast: 'b Grammar.Entry.e;
  42   level2_ast_grammar : Grammar.g;
  43   term: 'b Grammar.Entry.e;
  44   let_defs: 'c Grammar.Entry.e;
  45   protected_binder_vars: 'd Grammar.Entry.e;
  46   level2_meta: 'b Grammar.Entry.e;
  47 }
  48
  49 let initial_grammars () =
  50   let level1_pattern_grammar =
  51     Grammar.gcreate (CicNotationLexer.level1_pattern_lexer ()) in
  52   let level2_ast_grammar =
  53     Grammar.gcreate (CicNotationLexer.level2_ast_lexer ()) in
  54   let level2_meta_grammar =
  55     Grammar.gcreate (CicNotationLexer.level2_meta_lexer ()) in
  56   let level1_pattern =
  57     Grammar.Entry.create level1_pattern_grammar "level1_pattern" in
  58   let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast" in
  59   let term = Grammar.Entry.create level2_ast_grammar "term" in
  60   let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs" in
  61   let protected_binder_vars =
  62     Grammar.Entry.create level2_ast_grammar "protected_binder_vars" in
  63   let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta" in
  64   { level1_pattern=level1_pattern;
  65     level2_ast=level2_ast;
  66     term=term;
  67     let_defs=let_defs;
  68     protected_binder_vars=protected_binder_vars;
  69     level2_meta=level2_meta;
  70     level2_ast_grammar=level2_ast_grammar;
  71 }
  72 ;;
  73
  74 let grammars = ref (initial_grammars ());;
  75
  76 let int_of_string s =
  77   try
  78     Pervasives.int_of_string s
  79   with Failure _ ->
  80     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  81
  82 (** {2 Grammar extension} *)
  83
  84 let level_of precedence =
  85   if precedence < min_precedence || precedence > max_precedence then
  86     raise (Level_not_found precedence);
  87   string_of_int precedence
  88
  89 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  90 let gram_ident s = Gramext.Stoken ("IDENT", s)
  91 let gram_number s = Gramext.Stoken ("NUMBER", s)
  92 let gram_keyword s = Gramext.Stoken ("", s)
  93 let gram_term = function
  94   | Ast.Self _ -> Gramext.Sself
  95   | Ast.Level precedence ->
  96       Gramext.Snterml
  97         (Grammar.Entry.obj (!grammars.term: 'a Grammar.Entry.e),
  98          level_of precedence)
  99 ;;
 100
 101 let gram_of_literal =
 102   function
 103   | `Symbol s -> gram_symbol s
 104   | `Keyword s -> gram_keyword s
 105   | `Number s -> gram_number s
 106
 107 type binding =
 108   | NoBinding
 109   | Binding of string * Env.value_type
 110   | Env of (string * Env.value_type) list
 111
 112 let make_action action bindings =
 113   let rec aux (vl : CicNotationEnv.t) =
 114     function
 115       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
 116     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
 117     (* LUCA: DEFCON 3 BEGIN *)
 118     | Binding (name, Env.TermType l) :: tl ->
 119         Gramext.action
 120           (fun (v:Ast.term) ->
 121             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
 122     | Binding (name, Env.StringType) :: tl ->
 123         Gramext.action
 124           (fun (v:string) ->
 125             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 126     | Binding (name, Env.NumType) :: tl ->
 127         Gramext.action
 128           (fun (v:string) ->
 129             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 130     | Binding (name, Env.OptType t) :: tl ->
 131         Gramext.action
 132           (fun (v:'a option) ->
 133             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 134     | Binding (name, Env.ListType t) :: tl ->
 135         Gramext.action
 136           (fun (v:'a list) ->
 137             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 138     | Env _ :: tl ->
 139         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 140     (* LUCA: DEFCON 3 END *)
 141   in
 142     aux [] (List.rev bindings)
 143
 144 let flatten_opt =
 145   let rec aux acc =
 146     function
 147       [] -> List.rev acc
 148     | NoBinding :: tl -> aux acc tl
 149     | Env names :: tl -> aux (List.rev names @ acc) tl
 150     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 151   in
 152   aux []
 153
 154   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 155 let extract_term_production pattern =
 156   let rec aux = function
 157     | Ast.AttributedTerm (_, t) -> aux t
 158     | Ast.Literal l -> aux_literal l
 159     | Ast.Layout l -> aux_layout l
 160     | Ast.Magic m -> aux_magic m
 161     | Ast.Variable v -> aux_variable v
 162     | t ->
 163         prerr_endline (CicNotationPp.pp_term t);
 164         assert false
 165   and aux_literal =
 166     function
 167     | `Symbol s -> [NoBinding, gram_symbol s]
 168     | `Keyword s ->
 169         (* assumption: s will be registered as a keyword with the lexer *)
 170         [NoBinding, gram_keyword s]
 171     | `Number s -> [NoBinding, gram_number s]
 172   and aux_layout = function
 173     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 174     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 175     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 176     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 177     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 178     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule"] @ aux p1 @ aux p2 @ aux p3
 179     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 180     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 181     | Ast.Root (p1, p2) ->
 182         [NoBinding, gram_symbol "\\root"] @ aux p2
 183         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 184     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 185     | Ast.Break -> []
 186     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 187     | Ast.Group pl -> List.flatten (List.map aux pl)
 188     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 189   and aux_magic magic =
 190     match magic with
 191     | Ast.Opt p ->
 192         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 193         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 194           match env_opt with
 195           | Some env -> List.map Env.opt_binding_some env
 196           | None -> List.map Env.opt_binding_of_name p_names
 197         in
 198         [ Env (List.map Env.opt_declaration p_names),
 199           Gramext.srules
 200             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 201               Gramext.action action ] ]
 202     | Ast.List0 (p, _)
 203     | Ast.List1 (p, _) ->
 204         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 205         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 206           CicNotationEnv.coalesce_env p_names env_list
 207         in
 208         let gram_of_list s =
 209           match magic with
 210           | Ast.List0 (_, None) -> Gramext.Slist0 s
 211           | Ast.List1 (_, None) -> Gramext.Slist1 s
 212           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 213           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 214           | _ -> assert false
 215         in
 216         [ Env (List.map Env.list_declaration p_names),
 217           Gramext.srules
 218             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 219               Gramext.action action ] ]
 220     | _ -> assert false
 221   and aux_variable =
 222     function
 223     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 224     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 225         [Binding (s, Env.TermType level), gram_term lv]
 226     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 227     | Ast.Ascription (p, s) -> assert false (* TODO *)
 228     | Ast.FreshVar _ -> assert false
 229   and inner_pattern p =
 230     let p_bindings, p_atoms = List.split (aux p) in
 231     let p_names = flatten_opt p_bindings in
 232     let action =
 233       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 234         p_bindings
 235     in
 236     p_bindings, p_atoms, p_names, action
 237   in
 238   aux pattern
 239
 240 type rule_id = Grammar.token Gramext.g_symbol list
 241
 242 let compare_rule_id x y =
 243   let rec aux = function
 244     | [],[] -> 0
 245     | [],_ -> ~-1
 246     | _,[] -> 1
 247     | ((s1::tl1) as x),((s2::tl2) as y) ->
 248         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 249         else Pervasives.compare x y
 250   in
 251     aux (x,y)
 252
 253   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 254 let initial_owned_keywords () = Hashtbl.create 23
 255 let owned_keywords = ref (initial_owned_keywords ())
 256
 257 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 258
 259 let check_l1_pattern level1_pattern level associativity =
 260   let variables = ref 0 in
 261   let symbols = ref 0 in
 262   let rec aux = function
 263     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 264     | Ast.Literal _ as l -> incr symbols; l
 265     | Ast.Layout l -> Ast.Layout (aux_layout l)
 266     | Ast.Magic m -> Ast.Magic (aux_magic m)
 267     | Ast.Variable v -> (aux_variable v)
 268     | t -> assert false
 269   and aux_layout = function
 270     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 271     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 272     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 273     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 274     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 275     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 276     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 277     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 278     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 279     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 280     | Ast.Break as t -> t
 281     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 282     | Ast.Group pl -> Ast.Group (List.map aux pl)
 283     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 284   and aux_magic magic =
 285     match magic with
 286     | Ast.Opt p -> Ast.Opt (aux p)
 287     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 288     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 289     | _ -> assert false
 290   and aux_variable =
 291     function
 292     | Ast.NumVar _ as t -> Ast.Variable t
 293     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 294         incr variables;
 295         if !variables > 2 then
 296           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 297           "associative notation"));
 298         (match !variables, associativity with
 299         | 1,Gramext.LeftA ->
 300              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 301         | 1,Gramext.RightA ->
 302              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 303         | 2,Gramext.LeftA ->
 304              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 305         | 2,Gramext.RightA ->
 306              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 307         | _ -> assert false)
 308     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 309           raise (Parse_error ("Variables can not be declared with a " ^
 310             "precedence in an associative notation"))
 311        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 312     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 313        raise(Parse_error("Left recursive rule with precedence not greater " ^
 314         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 315     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 316     | Ast.IdentVar _ as t -> Ast.Variable t
 317     | Ast.Ascription _ -> assert false (* TODO *)
 318     | Ast.FreshVar _ -> assert false
 319   in
 320   if associativity <> Gramext.NonA && level = min_precedence then
 321     raise (Parse_error ("You can not specify an associative notation " ^
 322     "at level "^string_of_int min_precedence ^ "; increase it"));
 323   let cp = aux level1_pattern in
 324 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 325   if !variables <> 2 && associativity <> Gramext.NonA then
 326     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 327      "associative notation"));
 328   CL1P (cp,level)
 329 ;;
 330
 331 let extend (CL1P (level1_pattern,precedence)) action =
 332   let p_bindings, p_atoms =
 333     List.split (extract_term_production level1_pattern)
 334   in
 335   let level = level_of precedence in
 336   let _ =
 337     Grammar.extend
 338       [ Grammar.Entry.obj (!grammars.term: 'a Grammar.Entry.e),
 339         Some (Gramext.Level level),
 340         [ None,
 341           Some (*Gramext.NonA*) Gramext.NonA,
 342           [ p_atoms,
 343             (make_action
 344               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 345                 (action env loc))
 346               p_bindings) ]]]
 347   in
 348   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 349   let rule_id = p_atoms in
 350   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 351   Hashtbl.add !owned_keywords rule_id keywords;  (* keywords may be [] *)
 352   rule_id
 353
 354 let delete rule_id =
 355   let atoms = rule_id in
 356   (try
 357     let keywords = Hashtbl.find !owned_keywords rule_id in
 358     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 359   with Not_found -> assert false);
 360   Grammar.delete_rule !grammars.term atoms
 361
 362 (** {2 Grammar} *)
 363
 364 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 365 let parse_level2_ast_ref = ref (fun _ -> assert false)
 366 let parse_level2_meta_ref = ref (fun _ -> assert false)
 367
 368 let fold_cluster binder terms ty body =
 369   List.fold_right
 370     (fun term body -> Ast.Binder (binder, (term, ty), body))
 371     terms body  (* terms are names: either Ident or FreshVar *)
 372
 373 let fold_exists terms ty body =
 374   List.fold_right
 375     (fun term body ->
 376       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 377       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 378     terms body
 379
 380 let fold_binder binder pt_names body =
 381   List.fold_right
 382     (fun (names, ty) body -> fold_cluster binder names ty body)
 383     pt_names body
 384
 385 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 386 let return_term_of_level loc term l =
 387   Ast.AttributedTerm (`Loc loc, term l)
 388
 389   (* create empty precedence level for "term" *)
 390 let initialize_grammars () =
 391   let dummy_action =
 392     Gramext.action (fun _ ->
 393       failwith "internal error, lexer generated a dummy token")
 394   in
 395   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 396    * empty after the deletion. The lexer never generate the Stoken below. *)
 397   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 398   let mk_level_list first last =
 399     let rec aux acc = function
 400       | i when i < first -> acc
 401       | i ->
 402           aux
 403             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 404              :: acc)
 405             (i - 1)
 406     in
 407     aux [] last
 408   in
 409   Grammar.extend
 410     [ Grammar.Entry.obj (!grammars.term: 'a Grammar.Entry.e),
 411       None,
 412       mk_level_list min_precedence max_precedence ];
 413 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 414   begin
 415   let level1_pattern = !grammars.level1_pattern in
 416 EXTEND
 417   GLOBAL: level1_pattern;
 418
 419   level1_pattern: [
 420     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 421   ];
 422   l1_pattern: [
 423     [ p = LIST1 l1_simple_pattern ->
 424         fun l -> List.map (fun x -> x l) p ]
 425   ];
 426   literal: [
 427     [ s = SYMBOL -> `Symbol s
 428     | k = QKEYWORD -> `Keyword k
 429     | n = NUMBER -> `Number n
 430     ]
 431   ];
 432   sep:       [ [ "sep";      sep = literal -> sep ] ];
 433   l1_magic_pattern: [
 434     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 435             fun l -> Ast.List0 (p l, sep)
 436     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 437             fun l -> Ast.List1 (p l, sep)
 438     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 439     ]
 440   ];
 441   l1_pattern_variable: [
 442     [ "term"; precedence = NUMBER; id = IDENT ->
 443         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 444     | "number"; id = IDENT -> Ast.NumVar id
 445     | "ident"; id = IDENT -> Ast.IdentVar id
 446     ]
 447   ];
 448   mstyle: [
 449     [ id = IDENT;
 450       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 451   l1_simple_pattern:
 452     [ "layout" LEFTA
 453       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 454           return_term_of_level loc
 455             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 456       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 457           return_term_of_level loc
 458             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 459       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 460           return_term_of_level loc
 461             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 462       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 463           return_term_of_level loc
 464             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 465       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 466           return_term_of_level loc
 467             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 468       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 469           return_term_of_level loc
 470             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 471       | p1 = SELF; SYMBOL "\\frac"; p2 = SELF ->
 472           return_term_of_level loc
 473             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 474       | SYMBOL "\\infrule"; p1 = SELF; p2 = SELF; p3 = SELF ->
 475           return_term_of_level loc
 476             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 477       | SYMBOL "\\sqrt"; p = SELF ->
 478           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 479       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 480           return_term_of_level loc
 481             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 482       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 483           return_term_of_level loc
 484             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 485       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 486           return_term_of_level loc
 487             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 488       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 489           return_term_of_level loc
 490             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 491       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 492           return_term_of_level loc
 493             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 494       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 495       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 496           return_term_of_level loc
 497             (fun l ->
 498                Ast.Layout (Ast.Mstyle (m, t l)))
 499       | LPAREN; p = l1_pattern; RPAREN ->
 500           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 501       ]
 502     | "simple" NONA
 503       [ i = IDENT ->
 504          return_term_of_level loc
 505            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 506       | m = l1_magic_pattern ->
 507              return_term_of_level loc (fun l -> Ast.Magic (m l))
 508       | v = l1_pattern_variable ->
 509              return_term_of_level loc (fun _ -> Ast.Variable v)
 510       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 511       ]
 512     ];
 513   END
 514   end;
 515 (* }}} *)
 516 (* {{{ Grammar for ast magics, notation level 2 *)
 517   begin
 518   let level2_meta = !grammars.level2_meta in
 519 EXTEND
 520   GLOBAL: level2_meta;
 521   l2_variable: [
 522     [ "term"; precedence = NUMBER; id = IDENT ->
 523         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 524     | "number"; id = IDENT -> Ast.NumVar id
 525     | "ident"; id = IDENT -> Ast.IdentVar id
 526     | "fresh"; id = IDENT -> Ast.FreshVar id
 527     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 528     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 529     ]
 530   ];
 531   l2_magic: [
 532     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 533       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 534         Ast.Fold (kind, base, [id], recursive)
 535     | "default"; some = level2_meta; none = level2_meta ->
 536         Ast.Default (some, none)
 537     | "if"; p_test = level2_meta;
 538       "then"; p_true = level2_meta;
 539       "else"; p_false = level2_meta ->
 540         Ast.If (p_test, p_true, p_false)
 541     | "fail" -> Ast.Fail
 542     ]
 543   ];
 544   level2_meta: [
 545     [ magic = l2_magic -> Ast.Magic magic
 546     | var = l2_variable -> Ast.Variable var
 547     | blob = UNPARSED_AST ->
 548         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 549     ]
 550   ];
 551 END
 552   end;
 553 (* }}} *)
 554 (* {{{ Grammar for ast patterns, notation level 2 *)
 555   begin
 556   let level2_ast = !grammars.level2_ast in
 557   let term = !grammars.term in
 558   let let_defs = !grammars.let_defs in
 559   let protected_binder_vars = !grammars.protected_binder_vars in
 560 EXTEND
 561   GLOBAL: level2_ast term let_defs protected_binder_vars;
 562   level2_ast: [ [ p = term -> p ] ];
 563   sort: [
 564     [ "Prop" -> `Prop
 565     | "Set" -> `Set
 566     | "Type"; SYMBOL "["; n = NUMBER; SYMBOL "]" -> `NType n
 567     | "Type" -> `Type (CicUniv.fresh ())
 568     | "CProp" -> `CProp (CicUniv.fresh ())
 569     ]
 570   ];
 571   explicit_subst: [
 572     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 573       SYMBOL "[";
 574       substs = LIST1 [
 575         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 576       ] SEP SYMBOL ";";
 577       SYMBOL "]" ->
 578         substs
 579     ]
 580   ];
 581   meta_subst: [
 582     [ s = SYMBOL "_" -> None
 583     | p = term -> Some p ]
 584   ];
 585   meta_substs: [
 586     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 587   ];
 588   possibly_typed_name: [
 589     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 590         id, Some typ
 591     | arg = single_arg -> arg, None
 592     | SYMBOL "_" -> Ast.Ident ("_", None), None
 593     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 594         Ast.Ident ("_", None), Some typ
 595     ]
 596   ];
 597   match_pattern: [
 598     [ id = IDENT -> Ast.Pattern (id, None, [])
 599     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 600        Ast.Pattern (id, None, vars)
 601     | id = IDENT; vars = LIST1 possibly_typed_name ->
 602        Ast.Pattern (id, None, vars)
 603     | SYMBOL "_" -> Ast.Wildcard
 604     ]
 605   ];
 606   binder: [
 607     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 608     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 609     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 610     ]
 611   ];
 612   arg: [
 613     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 614       SYMBOL ":"; ty = term; RPAREN ->
 615         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 616     | name = IDENT -> [Ast.Ident (name, None)], None
 617     | blob = UNPARSED_META ->
 618         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 619         match meta with
 620         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 621         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 622         | _ -> failwith "Invalid bound name."
 623    ]
 624   ];
 625   single_arg: [
 626     [ name = IDENT -> Ast.Ident (name, None)
 627     | blob = UNPARSED_META ->
 628         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 629         match meta with
 630         | Ast.Variable (Ast.FreshVar _)
 631         | Ast.Variable (Ast.IdentVar _) -> meta
 632         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 633         | _ -> failwith "Invalid index name."
 634     ]
 635   ];
 636   let_defs: [
 637     [ defs = LIST1 [
 638         name = single_arg;
 639         args = LIST1 arg;
 640         index_name = OPT [ "on"; id = single_arg -> id ];
 641         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 642         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 643           let rec position_of name p = function
 644             | [] -> None, p
 645             | n :: _ when n = name -> Some p, p
 646             | _ :: tl -> position_of name (p + 1) tl
 647           in
 648           let rec find_arg name n = function
 649             | [] ->
 650                 Ast.fail loc (sprintf "Argument %s not found"
 651                   (CicNotationPp.pp_term name))
 652             | (l,_) :: tl ->
 653                 (match position_of name 0 l with
 654                 | None, len -> find_arg name (n + len) tl
 655                 | Some where, len -> n + where)
 656           in
 657           let index =
 658             match index_name with
 659             | None -> 0
 660             | Some index_name -> find_arg index_name 0 args
 661           in
 662           let args =
 663            List.concat
 664             (List.map
 665              (function (names,ty) -> List.map (function x -> x,ty) names
 666              ) args)
 667           in
 668            args, (name, ty), body, index
 669       ] SEP "and" ->
 670         defs
 671     ]
 672   ];
 673   binder_vars: [
 674     [ vars = [
 675           l = LIST1 single_arg SEP SYMBOL "," -> l
 676         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 677       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 678     ]
 679   ];
 680   protected_binder_vars: [
 681     [ LPAREN; vars = binder_vars; RPAREN -> vars
 682     ]
 683   ];
 684   maybe_protected_binder_vars: [
 685     [ vars = binder_vars -> vars
 686     | vars = protected_binder_vars -> vars
 687     ]
 688   ];
 689   term: LEVEL "10"
 690   [
 691     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 692       p1 = term; "in"; p2 = term ->
 693         return_term loc (Ast.LetIn (var, p1, p2))
 694     | LETCOREC; defs = let_defs; "in";
 695       body = term ->
 696         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 697     | LETREC; defs = let_defs; "in";
 698       body = term ->
 699         return_term loc (Ast.LetRec (`Inductive, defs, body))
 700     ]
 701   ];
 702   term: LEVEL "20"
 703     [
 704       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 705           return_term loc (fold_cluster b vars typ body)
 706       ]
 707     ];
 708   term: LEVEL "70"
 709     [
 710       [ p1 = term; p2 = term LEVEL "71" ->
 711           let rec aux = function
 712             | Ast.Appl (hd :: tl)
 713             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 714                 aux hd @ tl
 715             | term -> [term]
 716           in
 717           return_term loc (Ast.Appl (aux p1 @ [p2]))
 718       ]
 719     ];
 720   term: LEVEL "90"
 721     [
 722       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 723       | id = IDENT; s = explicit_subst ->
 724           return_term loc (Ast.Ident (id, Some s))
 725       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 726       | u = URI -> return_term loc (Ast.Uri (u, None))
 727       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 728       | IMPLICIT -> return_term loc (Ast.Implicit)
 729       | PLACEHOLDER -> return_term loc Ast.UserInput
 730       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 731       | m = META; s = meta_substs ->
 732           return_term loc (Ast.Meta (int_of_string m, s))
 733       | s = sort -> return_term loc (Ast.Sort s)
 734       | "match"; t = term;
 735         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 736         outtyp = OPT [ "return"; ty = term -> ty ];
 737         "with"; SYMBOL "[";
 738         patterns = LIST0 [
 739           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 740           rhs = term ->
 741             lhs, rhs
 742         ] SEP SYMBOL "|";
 743         SYMBOL "]" ->
 744           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 745       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 746           return_term loc (Ast.Cast (p1, p2))
 747       | LPAREN; p = term; RPAREN -> p
 748       | blob = UNPARSED_META ->
 749           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 750       ]
 751     ];
 752 END
 753   end
 754 (* }}} *)
 755 ;;
 756
 757 let _ = initialize_grammars ();;
 758
 759 let history = ref [];;
 760
 761 let push () =
 762   CicNotationLexer.push ();
 763   history := (!owned_keywords,!grammars) :: !history;
 764   owned_keywords := (initial_owned_keywords ());
 765   grammars := initial_grammars ();
 766   initialize_grammars ()
 767 ;;
 768
 769 let pop () =
 770   CicNotationLexer.pop ();
 771   match !history with
 772   | [] -> assert false
 773   | (kw,gram) :: old_history ->
 774       owned_keywords := kw;
 775       grammars := gram;
 776       history := old_history
 777 ;;
 778
 779 (** {2 API implementation} *)
 780
 781 let exc_located_wrapper f =
 782   try
 783     f ()
 784   with
 785   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 786       raise (HExtlib.Localized (floc, Parse_error msg))
 787   | Stdpp.Exc_located (floc, exn) ->
 788       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 789
 790 let parse_level1_pattern precedence lexbuf =
 791   exc_located_wrapper
 792     (fun () -> Grammar.Entry.parse !grammars.level1_pattern (Obj.magic lexbuf) precedence)
 793
 794 let parse_level2_ast lexbuf =
 795   exc_located_wrapper
 796     (fun () -> Grammar.Entry.parse !grammars.level2_ast (Obj.magic lexbuf))
 797
 798 let parse_level2_meta lexbuf =
 799   exc_located_wrapper
 800     (fun () -> Grammar.Entry.parse !grammars.level2_meta (Obj.magic lexbuf))
 801
 802 let _ =
 803   parse_level1_pattern_ref := parse_level1_pattern;
 804   parse_level2_ast_ref := parse_level2_ast;
 805   parse_level2_meta_ref := parse_level2_meta
 806
 807 let parse_term lexbuf =
 808   exc_located_wrapper
 809     (fun () -> (Grammar.Entry.parse !grammars.term (Obj.magic lexbuf)))
 810
 811 let level2_ast_grammar () = !grammars.level2_ast_grammar
 812 let term  () = !grammars.term
 813 let let_defs  () = !grammars.let_defs
 814 let protected_binder_vars  () = !grammars.protected_binder_vars
 815
 816
 817 (** {2 Debugging} *)
 818
 819 let print_l2_pattern () =
 820   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj !grammars.term);
 821   Format.pp_print_flush Format.std_formatter ();
 822   flush stdout
 823
 824 (* vim:set encoding=utf8 foldmethod=marker: *)