helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let level_of precedence =
  61   if precedence < min_precedence || precedence > max_precedence then
  62     raise (Level_not_found precedence);
  63   string_of_int precedence
  64
  65 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  66 let gram_ident s = Gramext.Stoken ("IDENT", s)
  67 let gram_number s = Gramext.Stoken ("NUMBER", s)
  68 let gram_keyword s = Gramext.Stoken ("", s)
  69 let gram_term = function
  70   | Ast.Self _ -> Gramext.Sself
  71   | Ast.Level precedence ->
  72       Gramext.Snterml
  73         (Grammar.Entry.obj (term: 'a Grammar.Entry.e), level_of precedence)
  74 ;;
  75
  76 let gram_of_literal =
  77   function
  78   | `Symbol s -> gram_symbol s
  79   | `Keyword s -> gram_keyword s
  80   | `Number s -> gram_number s
  81
  82 type binding =
  83   | NoBinding
  84   | Binding of string * Env.value_type
  85   | Env of (string * Env.value_type) list
  86
  87 let make_action action bindings =
  88   let rec aux (vl : CicNotationEnv.t) =
  89     function
  90       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  91     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  92     (* LUCA: DEFCON 3 BEGIN *)
  93     | Binding (name, Env.TermType l) :: tl ->
  94         Gramext.action
  95           (fun (v:Ast.term) ->
  96             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
  97     | Binding (name, Env.StringType) :: tl ->
  98         Gramext.action
  99           (fun (v:string) ->
 100             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 101     | Binding (name, Env.NumType) :: tl ->
 102         Gramext.action
 103           (fun (v:string) ->
 104             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 105     | Binding (name, Env.OptType t) :: tl ->
 106         Gramext.action
 107           (fun (v:'a option) ->
 108             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 109     | Binding (name, Env.ListType t) :: tl ->
 110         Gramext.action
 111           (fun (v:'a list) ->
 112             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 113     | Env _ :: tl ->
 114         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 115     (* LUCA: DEFCON 3 END *)
 116   in
 117     aux [] (List.rev bindings)
 118
 119 let flatten_opt =
 120   let rec aux acc =
 121     function
 122       [] -> List.rev acc
 123     | NoBinding :: tl -> aux acc tl
 124     | Env names :: tl -> aux (List.rev names @ acc) tl
 125     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 126   in
 127   aux []
 128
 129   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 130 let extract_term_production pattern =
 131   let rec aux = function
 132     | Ast.AttributedTerm (_, t) -> aux t
 133     | Ast.Literal l -> aux_literal l
 134     | Ast.Layout l -> aux_layout l
 135     | Ast.Magic m -> aux_magic m
 136     | Ast.Variable v -> aux_variable v
 137     | t ->
 138         prerr_endline (CicNotationPp.pp_term t);
 139         assert false
 140   and aux_literal =
 141     function
 142     | `Symbol s -> [NoBinding, gram_symbol s]
 143     | `Keyword s ->
 144         (* assumption: s will be registered as a keyword with the lexer *)
 145         [NoBinding, gram_keyword s]
 146     | `Number s -> [NoBinding, gram_number s]
 147   and aux_layout = function
 148     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 149     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 150     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 151     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 152     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 153     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule"] @ aux p1 @ aux p2 @ aux p3
 154     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 155     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 156     | Ast.Root (p1, p2) ->
 157         [NoBinding, gram_symbol "\\root"] @ aux p2
 158         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 159     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 160     | Ast.Break -> []
 161     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 162     | Ast.Group pl -> List.flatten (List.map aux pl)
 163     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 164   and aux_magic magic =
 165     match magic with
 166     | Ast.Opt p ->
 167         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 168         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 169           match env_opt with
 170           | Some env -> List.map Env.opt_binding_some env
 171           | None -> List.map Env.opt_binding_of_name p_names
 172         in
 173         [ Env (List.map Env.opt_declaration p_names),
 174           Gramext.srules
 175             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 176               Gramext.action action ] ]
 177     | Ast.List0 (p, _)
 178     | Ast.List1 (p, _) ->
 179         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 180         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 181           CicNotationEnv.coalesce_env p_names env_list
 182         in
 183         let gram_of_list s =
 184           match magic with
 185           | Ast.List0 (_, None) -> Gramext.Slist0 s
 186           | Ast.List1 (_, None) -> Gramext.Slist1 s
 187           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 188           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 189           | _ -> assert false
 190         in
 191         [ Env (List.map Env.list_declaration p_names),
 192           Gramext.srules
 193             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 194               Gramext.action action ] ]
 195     | _ -> assert false
 196   and aux_variable =
 197     function
 198     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 199     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 200         [Binding (s, Env.TermType level), gram_term lv]
 201     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 202     | Ast.Ascription (p, s) -> assert false (* TODO *)
 203     | Ast.FreshVar _ -> assert false
 204   and inner_pattern p =
 205     let p_bindings, p_atoms = List.split (aux p) in
 206     let p_names = flatten_opt p_bindings in
 207     let action =
 208       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 209         p_bindings
 210     in
 211     p_bindings, p_atoms, p_names, action
 212   in
 213   aux pattern
 214
 215 type rule_id = Grammar.token Gramext.g_symbol list
 216
 217   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 218 let owned_keywords = Hashtbl.create 23
 219
 220 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 221
 222 let check_l1_pattern level1_pattern level associativity =
 223   let variables = ref 0 in
 224   let symbols = ref 0 in
 225   let rec aux = function
 226     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 227     | Ast.Literal _ as l -> incr symbols; l
 228     | Ast.Layout l -> Ast.Layout (aux_layout l)
 229     | Ast.Magic m -> Ast.Magic (aux_magic m)
 230     | Ast.Variable v -> (aux_variable v)
 231     | t -> assert false
 232   and aux_layout = function
 233     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 234     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 235     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 236     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 237     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 238     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 239     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 240     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 241     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 242     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 243     | Ast.Break as t -> t
 244     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 245     | Ast.Group pl -> Ast.Group (List.map aux pl)
 246     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 247   and aux_magic magic =
 248     match magic with
 249     | Ast.Opt p -> Ast.Opt (aux p)
 250     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 251     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 252     | _ -> assert false
 253   and aux_variable =
 254     function
 255     | Ast.NumVar _ as t -> Ast.Variable t
 256     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 257         incr variables;
 258         if !variables > 2 then
 259           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 260           "associative notation"));
 261         (match !variables, associativity with
 262         | 1,Gramext.LeftA ->
 263              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 264         | 1,Gramext.RightA ->
 265              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 266         | 2,Gramext.LeftA ->
 267              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 268         | 2,Gramext.RightA ->
 269              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 270         | _ -> assert false)
 271     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 272           raise (Parse_error ("Variables can not be declared with a " ^
 273             "precedence in an associative notation"))
 274        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 275     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 276        raise(Parse_error("Left recursive rule with precedence not greater " ^
 277         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 278     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 279     | Ast.IdentVar _ as t -> Ast.Variable t
 280     | Ast.Ascription _ -> assert false (* TODO *)
 281     | Ast.FreshVar _ -> assert false
 282   in
 283   if associativity <> Gramext.NonA && level = min_precedence then
 284     raise (Parse_error ("You can not specify an associative notation " ^
 285     "at level "^string_of_int min_precedence ^ "; increase it"));
 286   let cp = aux level1_pattern in
 287 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 288   if !variables <> 2 && associativity <> Gramext.NonA then
 289     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 290      "associative notation"));
 291   CL1P (cp,level)
 292 ;;
 293
 294 let extend (CL1P (level1_pattern,precedence)) action =
 295   let p_bindings, p_atoms =
 296     List.split (extract_term_production level1_pattern)
 297   in
 298   let level = level_of precedence in
 299   let _ =
 300     Grammar.extend
 301       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 302         Some (Gramext.Level level),
 303         [ None,
 304           Some (*Gramext.NonA*) Gramext.NonA,
 305           [ p_atoms,
 306             (make_action
 307               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 308                 (action env loc))
 309               p_bindings) ]]]
 310   in
 311   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 312   let rule_id = p_atoms in
 313   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 314   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 315   rule_id
 316
 317 let delete rule_id =
 318   let atoms = rule_id in
 319   (try
 320     let keywords = Hashtbl.find owned_keywords rule_id in
 321     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 322   with Not_found -> assert false);
 323   Grammar.delete_rule term atoms
 324
 325 (** {2 Grammar} *)
 326
 327 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 328 let parse_level2_ast_ref = ref (fun _ -> assert false)
 329 let parse_level2_meta_ref = ref (fun _ -> assert false)
 330
 331 let fold_cluster binder terms ty body =
 332   List.fold_right
 333     (fun term body -> Ast.Binder (binder, (term, ty), body))
 334     terms body  (* terms are names: either Ident or FreshVar *)
 335
 336 let fold_exists terms ty body =
 337   List.fold_right
 338     (fun term body ->
 339       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 340       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 341     terms body
 342
 343 let fold_binder binder pt_names body =
 344   List.fold_right
 345     (fun (names, ty) body -> fold_cluster binder names ty body)
 346     pt_names body
 347
 348 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 349 let return_term_of_level loc term l =
 350   Ast.AttributedTerm (`Loc loc, term l)
 351
 352   (* create empty precedence level for "term" *)
 353 let _ =
 354   let dummy_action =
 355     Gramext.action (fun _ ->
 356       failwith "internal error, lexer generated a dummy token")
 357   in
 358   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 359    * empty after the deletion. The lexer never generate the Stoken below. *)
 360   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 361   let mk_level_list first last =
 362     let rec aux acc = function
 363       | i when i < first -> acc
 364       | i ->
 365           aux
 366             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 367              :: acc)
 368             (i - 1)
 369     in
 370     aux [] last
 371   in
 372   Grammar.extend
 373     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 374       None,
 375       mk_level_list min_precedence max_precedence ]
 376
 377 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 378 EXTEND
 379   GLOBAL: level1_pattern;
 380
 381   level1_pattern: [
 382     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 383   ];
 384   l1_pattern: [
 385     [ p = LIST1 l1_simple_pattern ->
 386         fun l -> List.map (fun x -> x l) p ]
 387   ];
 388   literal: [
 389     [ s = SYMBOL -> `Symbol s
 390     | k = QKEYWORD -> `Keyword k
 391     | n = NUMBER -> `Number n
 392     ]
 393   ];
 394   sep:       [ [ "sep";      sep = literal -> sep ] ];
 395   l1_magic_pattern: [
 396     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 397             fun l -> Ast.List0 (p l, sep)
 398     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 399             fun l -> Ast.List1 (p l, sep)
 400     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 401     ]
 402   ];
 403   l1_pattern_variable: [
 404     [ "term"; precedence = NUMBER; id = IDENT ->
 405         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 406     | "number"; id = IDENT -> Ast.NumVar id
 407     | "ident"; id = IDENT -> Ast.IdentVar id
 408     ]
 409   ];
 410   mstyle: [
 411     [ id = IDENT;
 412       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 413   l1_simple_pattern:
 414     [ "layout" LEFTA
 415       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 416           return_term_of_level loc
 417             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 418       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 419           return_term_of_level loc
 420             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 421       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 422           return_term_of_level loc
 423             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 424       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 425           return_term_of_level loc
 426             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 427       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 428           return_term_of_level loc
 429             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 430       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 431           return_term_of_level loc
 432             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 433       | p1 = SELF; SYMBOL "\\frac"; p2 = SELF ->
 434           return_term_of_level loc
 435             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 436       | SYMBOL "\\infrule"; p1 = SELF; p2 = SELF; p3 = SELF ->
 437           return_term_of_level loc
 438             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 439       | SYMBOL "\\sqrt"; p = SELF ->
 440           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 441       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 442           return_term_of_level loc
 443             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 444       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 445           return_term_of_level loc
 446             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 447       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 448           return_term_of_level loc
 449             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 450       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 451           return_term_of_level loc
 452             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 453       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 454           return_term_of_level loc
 455             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 456       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 457       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 458           return_term_of_level loc
 459             (fun l ->
 460                Ast.Layout (Ast.Mstyle (m, t l)))
 461       | LPAREN; p = l1_pattern; RPAREN ->
 462           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 463       ]
 464     | "simple" NONA
 465       [ i = IDENT ->
 466          return_term_of_level loc
 467            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 468       | m = l1_magic_pattern ->
 469              return_term_of_level loc (fun l -> Ast.Magic (m l))
 470       | v = l1_pattern_variable ->
 471              return_term_of_level loc (fun _ -> Ast.Variable v)
 472       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 473       ]
 474     ];
 475   END
 476 (* }}} *)
 477
 478 (* {{{ Grammar for ast magics, notation level 2 *)
 479 EXTEND
 480   GLOBAL: level2_meta;
 481   l2_variable: [
 482     [ "term"; precedence = NUMBER; id = IDENT ->
 483         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 484     | "number"; id = IDENT -> Ast.NumVar id
 485     | "ident"; id = IDENT -> Ast.IdentVar id
 486     | "fresh"; id = IDENT -> Ast.FreshVar id
 487     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 488     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 489     ]
 490   ];
 491   l2_magic: [
 492     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 493       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 494         Ast.Fold (kind, base, [id], recursive)
 495     | "default"; some = level2_meta; none = level2_meta ->
 496         Ast.Default (some, none)
 497     | "if"; p_test = level2_meta;
 498       "then"; p_true = level2_meta;
 499       "else"; p_false = level2_meta ->
 500         Ast.If (p_test, p_true, p_false)
 501     | "fail" -> Ast.Fail
 502     ]
 503   ];
 504   level2_meta: [
 505     [ magic = l2_magic -> Ast.Magic magic
 506     | var = l2_variable -> Ast.Variable var
 507     | blob = UNPARSED_AST ->
 508         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 509     ]
 510   ];
 511 END
 512 (* }}} *)
 513
 514 (* {{{ Grammar for ast patterns, notation level 2 *)
 515 EXTEND
 516   GLOBAL: level2_ast term let_defs protected_binder_vars;
 517   level2_ast: [ [ p = term -> p ] ];
 518   sort: [
 519     [ "Prop" -> `Prop
 520     | "Set" -> `Set
 521     | "Type" -> `Type (CicUniv.fresh ())
 522     | "CProp" -> `CProp (CicUniv.fresh ())
 523     ]
 524   ];
 525   explicit_subst: [
 526     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 527       SYMBOL "[";
 528       substs = LIST1 [
 529         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 530       ] SEP SYMBOL ";";
 531       SYMBOL "]" ->
 532         substs
 533     ]
 534   ];
 535   meta_subst: [
 536     [ s = SYMBOL "_" -> None
 537     | p = term -> Some p ]
 538   ];
 539   meta_substs: [
 540     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 541   ];
 542   possibly_typed_name: [
 543     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 544         id, Some typ
 545     | arg = single_arg -> arg, None
 546     | SYMBOL "_" -> Ast.Ident ("_", None), None
 547     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 548         Ast.Ident ("_", None), Some typ
 549     ]
 550   ];
 551   match_pattern: [
 552     [ id = IDENT -> Ast.Pattern (id, None, [])
 553     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 554        Ast.Pattern (id, None, vars)
 555     | id = IDENT; vars = LIST1 possibly_typed_name ->
 556        Ast.Pattern (id, None, vars)
 557     | SYMBOL "_" -> Ast.Wildcard
 558     ]
 559   ];
 560   binder: [
 561     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 562     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 563     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 564     ]
 565   ];
 566   arg: [
 567     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 568       SYMBOL ":"; ty = term; RPAREN ->
 569         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 570     | name = IDENT -> [Ast.Ident (name, None)], None
 571     | blob = UNPARSED_META ->
 572         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 573         match meta with
 574         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 575         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 576         | _ -> failwith "Invalid bound name."
 577    ]
 578   ];
 579   single_arg: [
 580     [ name = IDENT -> Ast.Ident (name, None)
 581     | blob = UNPARSED_META ->
 582         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 583         match meta with
 584         | Ast.Variable (Ast.FreshVar _)
 585         | Ast.Variable (Ast.IdentVar _) -> meta
 586         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 587         | _ -> failwith "Invalid index name."
 588     ]
 589   ];
 590   let_defs: [
 591     [ defs = LIST1 [
 592         name = single_arg;
 593         args = LIST1 arg;
 594         index_name = OPT [ "on"; id = single_arg -> id ];
 595         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 596         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 597           let rec position_of name p = function
 598             | [] -> None, p
 599             | n :: _ when n = name -> Some p, p
 600             | _ :: tl -> position_of name (p + 1) tl
 601           in
 602           let rec find_arg name n = function
 603             | [] ->
 604                 Ast.fail loc (sprintf "Argument %s not found"
 605                   (CicNotationPp.pp_term name))
 606             | (l,_) :: tl ->
 607                 (match position_of name 0 l with
 608                 | None, len -> find_arg name (n + len) tl
 609                 | Some where, len -> n + where)
 610           in
 611           let index =
 612             match index_name with
 613             | None -> 0
 614             | Some index_name -> find_arg index_name 0 args
 615           in
 616           let args =
 617            List.concat
 618             (List.map
 619              (function (names,ty) -> List.map (function x -> x,ty) names
 620              ) args)
 621           in
 622            args, (name, ty), body, index
 623       ] SEP "and" ->
 624         defs
 625     ]
 626   ];
 627   binder_vars: [
 628     [ vars = [
 629           l = LIST1 single_arg SEP SYMBOL "," -> l
 630         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 631       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 632     ]
 633   ];
 634   protected_binder_vars: [
 635     [ LPAREN; vars = binder_vars; RPAREN -> vars
 636     ]
 637   ];
 638   maybe_protected_binder_vars: [
 639     [ vars = binder_vars -> vars
 640     | vars = protected_binder_vars -> vars
 641     ]
 642   ];
 643   term: LEVEL "10"
 644   [
 645     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 646       p1 = term; "in"; p2 = term ->
 647         return_term loc (Ast.LetIn (var, p1, p2))
 648     | LETCOREC; defs = let_defs; "in";
 649       body = term ->
 650         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 651     | LETREC; defs = let_defs; "in";
 652       body = term ->
 653         return_term loc (Ast.LetRec (`Inductive, defs, body))
 654     ]
 655   ];
 656   term: LEVEL "20"
 657     [
 658       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 659           return_term loc (fold_cluster b vars typ body)
 660       ]
 661     ];
 662   term: LEVEL "70"
 663     [
 664       [ p1 = term; p2 = term LEVEL "71" ->
 665           let rec aux = function
 666             | Ast.Appl (hd :: tl)
 667             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 668                 aux hd @ tl
 669             | term -> [term]
 670           in
 671           return_term loc (Ast.Appl (aux p1 @ [p2]))
 672       ]
 673     ];
 674   term: LEVEL "90"
 675     [
 676       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 677       | id = IDENT; s = explicit_subst ->
 678           return_term loc (Ast.Ident (id, Some s))
 679       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 680       | u = URI -> return_term loc (Ast.Uri (u, None))
 681       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 682       | IMPLICIT -> return_term loc (Ast.Implicit)
 683       | PLACEHOLDER -> return_term loc Ast.UserInput
 684       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 685       | m = META; s = meta_substs ->
 686           return_term loc (Ast.Meta (int_of_string m, s))
 687       | s = sort -> return_term loc (Ast.Sort s)
 688       | "match"; t = term;
 689         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 690         outtyp = OPT [ "return"; ty = term -> ty ];
 691         "with"; SYMBOL "[";
 692         patterns = LIST0 [
 693           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 694           rhs = term ->
 695             lhs, rhs
 696         ] SEP SYMBOL "|";
 697         SYMBOL "]" ->
 698           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 699       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 700           return_term loc (Ast.Cast (p1, p2))
 701       | LPAREN; p = term; RPAREN -> p
 702       | blob = UNPARSED_META ->
 703           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 704       ]
 705     ];
 706 END
 707 (* }}} *)
 708
 709 (** {2 API implementation} *)
 710
 711 let exc_located_wrapper f =
 712   try
 713     f ()
 714   with
 715   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 716       raise (HExtlib.Localized (floc, Parse_error msg))
 717   | Stdpp.Exc_located (floc, exn) ->
 718       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 719
 720 let parse_level1_pattern precedence lexbuf =
 721   exc_located_wrapper
 722     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf) precedence)
 723
 724 let parse_level2_ast lexbuf =
 725   exc_located_wrapper
 726     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 727
 728 let parse_level2_meta lexbuf =
 729   exc_located_wrapper
 730     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 731
 732 let _ =
 733   parse_level1_pattern_ref := parse_level1_pattern;
 734   parse_level2_ast_ref := parse_level2_ast;
 735   parse_level2_meta_ref := parse_level2_meta
 736
 737 let parse_term lexbuf =
 738   exc_located_wrapper
 739     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 740
 741 (** {2 Debugging} *)
 742
 743 let print_l2_pattern () =
 744   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 745   Format.pp_print_flush Format.std_formatter ();
 746   flush stdout
 747
 748 (* vim:set encoding=utf8 foldmethod=marker: *)