helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let level_of precedence =
  61   if precedence < min_precedence || precedence > max_precedence then
  62     raise (Level_not_found precedence);
  63   string_of_int precedence
  64
  65 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  66 let gram_ident s = Gramext.Stoken ("IDENT", s)
  67 let gram_number s = Gramext.Stoken ("NUMBER", s)
  68 let gram_keyword s = Gramext.Stoken ("", s)
  69 let gram_term = function
  70   | Ast.Self _ -> Gramext.Sself
  71   | Ast.Level precedence ->
  72       Gramext.Snterml
  73         (Grammar.Entry.obj (term: 'a Grammar.Entry.e), level_of precedence)
  74 ;;
  75
  76 let gram_of_literal =
  77   function
  78   | `Symbol s -> gram_symbol s
  79   | `Keyword s -> gram_keyword s
  80   | `Number s -> gram_number s
  81
  82 type binding =
  83   | NoBinding
  84   | Binding of string * Env.value_type
  85   | Env of (string * Env.value_type) list
  86
  87 let make_action action bindings =
  88   let rec aux (vl : CicNotationEnv.t) =
  89     function
  90       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  91     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  92     (* LUCA: DEFCON 3 BEGIN *)
  93     | Binding (name, Env.TermType l) :: tl ->
  94         Gramext.action
  95           (fun (v:Ast.term) ->
  96             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
  97     | Binding (name, Env.StringType) :: tl ->
  98         Gramext.action
  99           (fun (v:string) ->
 100             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 101     | Binding (name, Env.NumType) :: tl ->
 102         Gramext.action
 103           (fun (v:string) ->
 104             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 105     | Binding (name, Env.OptType t) :: tl ->
 106         Gramext.action
 107           (fun (v:'a option) ->
 108             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 109     | Binding (name, Env.ListType t) :: tl ->
 110         Gramext.action
 111           (fun (v:'a list) ->
 112             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 113     | Env _ :: tl ->
 114         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 115     (* LUCA: DEFCON 3 END *)
 116   in
 117     aux [] (List.rev bindings)
 118
 119 let flatten_opt =
 120   let rec aux acc =
 121     function
 122       [] -> List.rev acc
 123     | NoBinding :: tl -> aux acc tl
 124     | Env names :: tl -> aux (List.rev names @ acc) tl
 125     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 126   in
 127   aux []
 128
 129   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 130 let extract_term_production pattern =
 131   let rec aux = function
 132     | Ast.AttributedTerm (_, t) -> aux t
 133     | Ast.Literal l -> aux_literal l
 134     | Ast.Layout l -> aux_layout l
 135     | Ast.Magic m -> aux_magic m
 136     | Ast.Variable v -> aux_variable v
 137     | t ->
 138         prerr_endline (CicNotationPp.pp_term t);
 139         assert false
 140   and aux_literal =
 141     function
 142     | `Symbol s -> [NoBinding, gram_symbol s]
 143     | `Keyword s ->
 144         (* assumption: s will be registered as a keyword with the lexer *)
 145         [NoBinding, gram_keyword s]
 146     | `Number s -> [NoBinding, gram_number s]
 147   and aux_layout = function
 148     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 149     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 150     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 151     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 152     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 153     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 154     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 155     | Ast.Root (p1, p2) ->
 156         [NoBinding, gram_symbol "\\root"] @ aux p2
 157         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 158     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 159     | Ast.Break -> []
 160     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 161     | Ast.Group pl -> List.flatten (List.map aux pl)
 162   and aux_magic magic =
 163     match magic with
 164     | Ast.Opt p ->
 165         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 166         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 167           match env_opt with
 168           | Some env -> List.map Env.opt_binding_some env
 169           | None -> List.map Env.opt_binding_of_name p_names
 170         in
 171         [ Env (List.map Env.opt_declaration p_names),
 172           Gramext.srules
 173             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 174               Gramext.action action ] ]
 175     | Ast.List0 (p, _)
 176     | Ast.List1 (p, _) ->
 177         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 178         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 179           CicNotationEnv.coalesce_env p_names env_list
 180         in
 181         let gram_of_list s =
 182           match magic with
 183           | Ast.List0 (_, None) -> Gramext.Slist0 s
 184           | Ast.List1 (_, None) -> Gramext.Slist1 s
 185           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 186           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 187           | _ -> assert false
 188         in
 189         [ Env (List.map Env.list_declaration p_names),
 190           Gramext.srules
 191             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 192               Gramext.action action ] ]
 193     | _ -> assert false
 194   and aux_variable =
 195     function
 196     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 197     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 198         [Binding (s, Env.TermType level), gram_term lv]
 199     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 200     | Ast.Ascription (p, s) -> assert false (* TODO *)
 201     | Ast.FreshVar _ -> assert false
 202   and inner_pattern p =
 203     let p_bindings, p_atoms = List.split (aux p) in
 204     let p_names = flatten_opt p_bindings in
 205     let action =
 206       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 207         p_bindings
 208     in
 209     p_bindings, p_atoms, p_names, action
 210   in
 211   aux pattern
 212
 213 type rule_id = Grammar.token Gramext.g_symbol list
 214
 215   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 216 let owned_keywords = Hashtbl.create 23
 217
 218 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 219
 220 let check_l1_pattern level1_pattern level associativity =
 221   let variables = ref 0 in
 222   let symbols = ref 0 in
 223   let rec aux = function
 224     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 225     | Ast.Literal _ as l -> incr symbols; l
 226     | Ast.Layout l -> Ast.Layout (aux_layout l)
 227     | Ast.Magic m -> Ast.Magic (aux_magic m)
 228     | Ast.Variable v -> (aux_variable v)
 229     | t -> assert false
 230   and aux_layout = function
 231     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 232     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 233     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 234     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 235     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 236     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 237     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 238     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 239     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 240     | Ast.Break as t -> t
 241     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 242     | Ast.Group pl -> Ast.Group (List.map aux pl)
 243   and aux_magic magic =
 244     match magic with
 245     | Ast.Opt p -> Ast.Opt (aux p)
 246     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 247     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 248     | _ -> assert false
 249   and aux_variable =
 250     function
 251     | Ast.NumVar _ as t -> Ast.Variable t
 252     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 253         incr variables;
 254         if !variables > 2 then
 255           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 256           "associative notation"));
 257         (match !variables, associativity with
 258         | 1,Gramext.LeftA ->
 259              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 260         | 1,Gramext.RightA ->
 261              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 262         | 2,Gramext.LeftA ->
 263              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 264         | 2,Gramext.RightA ->
 265              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 266         | _ -> assert false)
 267     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 268           raise (Parse_error ("Variables can not be declared with a " ^
 269             "precedence in an associative notation"))
 270        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 271     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 272        raise(Parse_error("Left recursive rule with precedence not greater " ^
 273         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 274     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 275     | Ast.IdentVar _ as t -> Ast.Variable t
 276     | Ast.Ascription _ -> assert false (* TODO *)
 277     | Ast.FreshVar _ -> assert false
 278   in
 279   if associativity <> Gramext.NonA && level = min_precedence then
 280     raise (Parse_error ("You can not specify an associative notation " ^
 281     "at level "^string_of_int min_precedence ^ "; increase it"));
 282   let cp = aux level1_pattern in
 283 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 284   if !variables <> 2 && associativity <> Gramext.NonA then
 285     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 286      "associative notation"));
 287   CL1P (cp,level)
 288 ;;
 289
 290 let extend (CL1P (level1_pattern,precedence)) action =
 291   let p_bindings, p_atoms =
 292     List.split (extract_term_production level1_pattern)
 293   in
 294   let level = level_of precedence in
 295   let _ =
 296     Grammar.extend
 297       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 298         Some (Gramext.Level level),
 299         [ None,
 300           Some (*Gramext.NonA*) Gramext.NonA,
 301           [ p_atoms,
 302             (make_action
 303               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 304                 (action env loc))
 305               p_bindings) ]]]
 306   in
 307   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 308   let rule_id = p_atoms in
 309   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 310   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 311   rule_id
 312
 313 let delete rule_id =
 314   let atoms = rule_id in
 315   (try
 316     let keywords = Hashtbl.find owned_keywords rule_id in
 317     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 318   with Not_found -> assert false);
 319   Grammar.delete_rule term atoms
 320
 321 (** {2 Grammar} *)
 322
 323 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 324 let parse_level2_ast_ref = ref (fun _ -> assert false)
 325 let parse_level2_meta_ref = ref (fun _ -> assert false)
 326
 327 let fold_cluster binder terms ty body =
 328   List.fold_right
 329     (fun term body -> Ast.Binder (binder, (term, ty), body))
 330     terms body  (* terms are names: either Ident or FreshVar *)
 331
 332 let fold_exists terms ty body =
 333   List.fold_right
 334     (fun term body ->
 335       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 336       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 337     terms body
 338
 339 let fold_binder binder pt_names body =
 340   List.fold_right
 341     (fun (names, ty) body -> fold_cluster binder names ty body)
 342     pt_names body
 343
 344 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 345 let return_term_of_level loc term l =
 346   Ast.AttributedTerm (`Loc loc, term l)
 347
 348   (* create empty precedence level for "term" *)
 349 let _ =
 350   let dummy_action =
 351     Gramext.action (fun _ ->
 352       failwith "internal error, lexer generated a dummy token")
 353   in
 354   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 355    * empty after the deletion. The lexer never generate the Stoken below. *)
 356   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 357   let mk_level_list first last =
 358     let rec aux acc = function
 359       | i when i < first -> acc
 360       | i ->
 361           aux
 362             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 363              :: acc)
 364             (i - 1)
 365     in
 366     aux [] last
 367   in
 368   Grammar.extend
 369     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 370       None,
 371       mk_level_list min_precedence max_precedence ]
 372
 373 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 374 EXTEND
 375   GLOBAL: level1_pattern;
 376
 377   level1_pattern: [
 378     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 379   ];
 380   l1_pattern: [
 381     [ p = LIST1 l1_simple_pattern ->
 382         fun l -> List.map (fun x -> x l) p ]
 383   ];
 384   literal: [
 385     [ s = SYMBOL -> `Symbol s
 386     | k = QKEYWORD -> `Keyword k
 387     | n = NUMBER -> `Number n
 388     ]
 389   ];
 390   sep:       [ [ "sep";      sep = literal -> sep ] ];
 391   l1_magic_pattern: [
 392     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 393             fun l -> Ast.List0 (p l, sep)
 394     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 395             fun l -> Ast.List1 (p l, sep)
 396     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 397     ]
 398   ];
 399   l1_pattern_variable: [
 400     [ "term"; precedence = NUMBER; id = IDENT ->
 401         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 402     | "number"; id = IDENT -> Ast.NumVar id
 403     | "ident"; id = IDENT -> Ast.IdentVar id
 404     ]
 405   ];
 406   l1_simple_pattern:
 407     [ "layout" LEFTA
 408       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 409           return_term_of_level loc
 410             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 411       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 412           return_term_of_level loc
 413             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 414       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 415           return_term_of_level loc
 416             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 417       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 418           return_term_of_level loc
 419             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 420       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 421           return_term_of_level loc
 422             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 423       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 424           return_term_of_level loc
 425             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 426       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 427           return_term_of_level loc
 428             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 429       | SYMBOL "\\sqrt"; p = SELF ->
 430           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 431       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 432           return_term_of_level loc
 433             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 434       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 435           return_term_of_level loc
 436             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 437       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 438           return_term_of_level loc
 439             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 440       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 441           return_term_of_level loc
 442             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 443       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 444           return_term_of_level loc
 445             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 446       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 447       | LPAREN; p = l1_pattern; RPAREN ->
 448           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 449       ]
 450     | "simple" NONA
 451       [ i = IDENT ->
 452          return_term_of_level loc
 453            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 454       | m = l1_magic_pattern ->
 455              return_term_of_level loc (fun l -> Ast.Magic (m l))
 456       | v = l1_pattern_variable ->
 457              return_term_of_level loc (fun _ -> Ast.Variable v)
 458       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 459       ]
 460     ];
 461   END
 462 (* }}} *)
 463
 464 (* {{{ Grammar for ast magics, notation level 2 *)
 465 EXTEND
 466   GLOBAL: level2_meta;
 467   l2_variable: [
 468     [ "term"; precedence = NUMBER; id = IDENT ->
 469         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 470     | "number"; id = IDENT -> Ast.NumVar id
 471     | "ident"; id = IDENT -> Ast.IdentVar id
 472     | "fresh"; id = IDENT -> Ast.FreshVar id
 473     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 474     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 475     ]
 476   ];
 477   l2_magic: [
 478     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 479       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 480         Ast.Fold (kind, base, [id], recursive)
 481     | "default"; some = level2_meta; none = level2_meta ->
 482         Ast.Default (some, none)
 483     | "if"; p_test = level2_meta;
 484       "then"; p_true = level2_meta;
 485       "else"; p_false = level2_meta ->
 486         Ast.If (p_test, p_true, p_false)
 487     | "fail" -> Ast.Fail
 488     ]
 489   ];
 490   level2_meta: [
 491     [ magic = l2_magic -> Ast.Magic magic
 492     | var = l2_variable -> Ast.Variable var
 493     | blob = UNPARSED_AST ->
 494         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 495     ]
 496   ];
 497 END
 498 (* }}} *)
 499
 500 (* {{{ Grammar for ast patterns, notation level 2 *)
 501 EXTEND
 502   GLOBAL: level2_ast term let_defs protected_binder_vars;
 503   level2_ast: [ [ p = term -> p ] ];
 504   sort: [
 505     [ "Prop" -> `Prop
 506     | "Set" -> `Set
 507     | "Type" -> `Type (CicUniv.fresh ())
 508     | "CProp" -> `CProp (CicUniv.fresh ())
 509     ]
 510   ];
 511   explicit_subst: [
 512     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 513       SYMBOL "[";
 514       substs = LIST1 [
 515         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 516       ] SEP SYMBOL ";";
 517       SYMBOL "]" ->
 518         substs
 519     ]
 520   ];
 521   meta_subst: [
 522     [ s = SYMBOL "_" -> None
 523     | p = term -> Some p ]
 524   ];
 525   meta_substs: [
 526     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 527   ];
 528   possibly_typed_name: [
 529     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 530         id, Some typ
 531     | arg = single_arg -> arg, None
 532     | SYMBOL "_" -> Ast.Ident ("_", None), None
 533     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 534         Ast.Ident ("_", None), Some typ
 535     ]
 536   ];
 537   match_pattern: [
 538     [ id = IDENT -> Ast.Pattern (id, None, [])
 539     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 540        Ast.Pattern (id, None, vars)
 541     | id = IDENT; vars = LIST1 possibly_typed_name ->
 542        Ast.Pattern (id, None, vars)
 543     | SYMBOL "_" -> Ast.Wildcard
 544     ]
 545   ];
 546   binder: [
 547     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 548 (*     | SYMBOL <:unicode<exists>> |+ ∃ +| -> `Exists *)
 549     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 550     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 551     ]
 552   ];
 553   arg: [
 554     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 555       SYMBOL ":"; ty = term; RPAREN ->
 556         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 557     | name = IDENT -> [Ast.Ident (name, None)], None
 558     | blob = UNPARSED_META ->
 559         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 560         match meta with
 561         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 562         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 563         | _ -> failwith "Invalid bound name."
 564    ]
 565   ];
 566   single_arg: [
 567     [ name = IDENT -> Ast.Ident (name, None)
 568     | blob = UNPARSED_META ->
 569         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 570         match meta with
 571         | Ast.Variable (Ast.FreshVar _)
 572         | Ast.Variable (Ast.IdentVar _) -> meta
 573         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 574         | _ -> failwith "Invalid index name."
 575     ]
 576   ];
 577   let_defs: [
 578     [ defs = LIST1 [
 579         name = single_arg;
 580         args = LIST1 arg;
 581         index_name = OPT [ "on"; id = single_arg -> id ];
 582         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 583         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 584           let rec position_of name p = function
 585             | [] -> None, p
 586             | n :: _ when n = name -> Some p, p
 587             | _ :: tl -> position_of name (p + 1) tl
 588           in
 589           let rec find_arg name n = function
 590             | [] ->
 591                 Ast.fail loc (sprintf "Argument %s not found"
 592                   (CicNotationPp.pp_term name))
 593             | (l,_) :: tl ->
 594                 (match position_of name 0 l with
 595                 | None, len -> find_arg name (n + len) tl
 596                 | Some where, len -> n + where)
 597           in
 598           let index =
 599             match index_name with
 600             | None -> 0
 601             | Some index_name -> find_arg index_name 0 args
 602           in
 603           let args =
 604            List.concat
 605             (List.map
 606              (function (names,ty) -> List.map (function x -> x,ty) names
 607              ) args)
 608           in
 609            args, (name, ty), body, index
 610       ] SEP "and" ->
 611         defs
 612     ]
 613   ];
 614   binder_vars: [
 615     [ vars = [
 616           l = LIST1 single_arg SEP SYMBOL "," -> l
 617         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 618       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 619     ]
 620   ];
 621   protected_binder_vars: [
 622     [ LPAREN; vars = binder_vars; RPAREN -> vars
 623     ]
 624   ];
 625   maybe_protected_binder_vars: [
 626     [ vars = binder_vars -> vars
 627     | vars = protected_binder_vars -> vars
 628     ]
 629   ];
 630   term: LEVEL "10"
 631   [
 632     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 633       p1 = term; "in"; p2 = term ->
 634         return_term loc (Ast.LetIn (var, p1, p2))
 635     | LETCOREC; defs = let_defs; "in";
 636       body = term ->
 637         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 638     | LETREC; defs = let_defs; "in";
 639       body = term ->
 640         return_term loc (Ast.LetRec (`Inductive, defs, body))
 641     ]
 642   ];
 643   term: LEVEL "20"
 644     [
 645       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 646           return_term loc (fold_cluster b vars typ body)
 647       | SYMBOL <:unicode<exists>> (* ∃ *);
 648         (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19"->
 649           return_term loc (fold_exists vars typ body)
 650       ]
 651     ];
 652   term: LEVEL "70"
 653     [
 654       [ p1 = term; p2 = term LEVEL "71" ->
 655           let rec aux = function
 656             | Ast.Appl (hd :: tl)
 657             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 658                 aux hd @ tl
 659             | term -> [term]
 660           in
 661           return_term loc (Ast.Appl (aux p1 @ [p2]))
 662       ]
 663     ];
 664   term: LEVEL "90"
 665     [
 666       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 667       | id = IDENT; s = explicit_subst ->
 668           return_term loc (Ast.Ident (id, Some s))
 669       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 670       | u = URI -> return_term loc (Ast.Uri (u, None))
 671       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 672       | IMPLICIT -> return_term loc (Ast.Implicit)
 673       | PLACEHOLDER -> return_term loc Ast.UserInput
 674       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 675       | m = META; s = meta_substs ->
 676           return_term loc (Ast.Meta (int_of_string m, s))
 677       | s = sort -> return_term loc (Ast.Sort s)
 678       | "match"; t = term;
 679         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 680         outtyp = OPT [ "return"; ty = term -> ty ];
 681         "with"; SYMBOL "[";
 682         patterns = LIST0 [
 683           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 684           rhs = term ->
 685             lhs, rhs
 686         ] SEP SYMBOL "|";
 687         SYMBOL "]" ->
 688           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 689       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 690           return_term loc (Ast.Cast (p1, p2))
 691       | LPAREN; p = term; RPAREN -> p
 692       | blob = UNPARSED_META ->
 693           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 694       ]
 695     ];
 696 END
 697 (* }}} *)
 698
 699 (** {2 API implementation} *)
 700
 701 let exc_located_wrapper f =
 702   try
 703     f ()
 704   with
 705   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 706       raise (HExtlib.Localized (floc, Parse_error msg))
 707   | Stdpp.Exc_located (floc, exn) ->
 708       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 709
 710 let parse_level1_pattern precedence lexbuf =
 711   exc_located_wrapper
 712     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf) precedence)
 713
 714 let parse_level2_ast lexbuf =
 715   exc_located_wrapper
 716     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 717
 718 let parse_level2_meta lexbuf =
 719   exc_located_wrapper
 720     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 721
 722 let _ =
 723   parse_level1_pattern_ref := parse_level1_pattern;
 724   parse_level2_ast_ref := parse_level2_ast;
 725   parse_level2_meta_ref := parse_level2_meta
 726
 727 let parse_term lexbuf =
 728   exc_located_wrapper
 729     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 730
 731 (** {2 Debugging} *)
 732
 733 let print_l2_pattern () =
 734   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 735   Format.pp_print_flush Format.std_formatter ();
 736   flush stdout
 737
 738 (* vim:set encoding=utf8 foldmethod=marker: *)