helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let level_of precedence =
  61   if precedence < min_precedence || precedence > max_precedence then
  62     raise (Level_not_found precedence);
  63   string_of_int precedence ^ "N"
  64
  65 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  66 let gram_ident s = Gramext.Stoken ("IDENT", s)
  67 let gram_number s = Gramext.Stoken ("NUMBER", s)
  68 let gram_keyword s = Gramext.Stoken ("", s)
  69 let gram_term = function
  70   | None -> Gramext.Sself
  71   | Some (precedence) ->
  72       Gramext.Snterml (Grammar.Entry.obj (term: 'a Grammar.Entry.e),level_of precedence)
  73 ;;
  74
  75 let gram_of_literal =
  76   function
  77   | `Symbol s -> gram_symbol s
  78   | `Keyword s -> gram_keyword s
  79   | `Number s -> gram_number s
  80
  81 type binding =
  82   | NoBinding
  83   | Binding of string * Env.value_type
  84   | Env of (string * Env.value_type) list
  85
  86 let make_action action bindings =
  87   let rec aux (vl : CicNotationEnv.t) =
  88     function
  89       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  90     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  91     (* LUCA: DEFCON 3 BEGIN *)
  92     | Binding (name, Env.TermType l) :: tl ->
  93         Gramext.action
  94           (fun (v:Ast.term) ->
  95             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
  96     | Binding (name, Env.StringType) :: tl ->
  97         Gramext.action
  98           (fun (v:string) ->
  99             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 100     | Binding (name, Env.NumType) :: tl ->
 101         Gramext.action
 102           (fun (v:string) ->
 103             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 104     | Binding (name, Env.OptType t) :: tl ->
 105         Gramext.action
 106           (fun (v:'a option) ->
 107             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 108     | Binding (name, Env.ListType t) :: tl ->
 109         Gramext.action
 110           (fun (v:'a list) ->
 111             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 112     | Env _ :: tl ->
 113         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 114     (* LUCA: DEFCON 3 END *)
 115   in
 116     aux [] (List.rev bindings)
 117
 118 let flatten_opt =
 119   let rec aux acc =
 120     function
 121       [] -> List.rev acc
 122     | NoBinding :: tl -> aux acc tl
 123     | Env names :: tl -> aux (List.rev names @ acc) tl
 124     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 125   in
 126   aux []
 127
 128   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 129 let extract_term_production pattern =
 130   let rec aux = function
 131     | Ast.AttributedTerm (_, t) -> aux t
 132     | Ast.Literal l -> aux_literal l
 133     | Ast.Layout l -> aux_layout l
 134     | Ast.Magic m -> aux_magic m
 135     | Ast.Variable v -> aux_variable v
 136     | t ->
 137         prerr_endline (CicNotationPp.pp_term t);
 138         assert false
 139   and aux_literal =
 140     function
 141     | `Symbol s -> [NoBinding, gram_symbol s]
 142     | `Keyword s ->
 143         (* assumption: s will be registered as a keyword with the lexer *)
 144         [NoBinding, gram_keyword s]
 145     | `Number s -> [NoBinding, gram_number s]
 146   and aux_layout = function
 147     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 148     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 149     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 150     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 151     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 152     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 153     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 154     | Ast.Root (p1, p2) ->
 155         [NoBinding, gram_symbol "\\root"] @ aux p2
 156         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 157     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 158     | Ast.Break -> []
 159     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 160     | Ast.Group pl -> List.flatten (List.map aux pl)
 161   and aux_magic magic =
 162     match magic with
 163     | Ast.Opt p ->
 164         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 165         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 166           match env_opt with
 167           | Some env -> List.map Env.opt_binding_some env
 168           | None -> List.map Env.opt_binding_of_name p_names
 169         in
 170         [ Env (List.map Env.opt_declaration p_names),
 171           Gramext.srules
 172             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 173               Gramext.action action ] ]
 174     | Ast.List0 (p, _)
 175     | Ast.List1 (p, _) ->
 176         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 177         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 178           CicNotationEnv.coalesce_env p_names env_list
 179         in
 180         let gram_of_list s =
 181           match magic with
 182           | Ast.List0 (_, None) -> Gramext.Slist0 s
 183           | Ast.List1 (_, None) -> Gramext.Slist1 s
 184           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 185           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 186           | _ -> assert false
 187         in
 188         [ Env (List.map Env.list_declaration p_names),
 189           Gramext.srules
 190             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 191               Gramext.action action ] ]
 192     | _ -> assert false
 193   and aux_variable =
 194     function
 195     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 196     | Ast.TermVar (s,level) ->
 197         [Binding (s, Env.TermType level), gram_term level]
 198     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 199     | Ast.Ascription (p, s) -> assert false (* TODO *)
 200     | Ast.FreshVar _ -> assert false
 201   and inner_pattern p =
 202     let p_bindings, p_atoms = List.split (aux p) in
 203     let p_names = flatten_opt p_bindings in
 204     let action =
 205       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 206         p_bindings
 207     in
 208     p_bindings, p_atoms, p_names, action
 209   in
 210   aux pattern
 211
 212 type rule_id = Grammar.token Gramext.g_symbol list
 213
 214   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 215 let owned_keywords = Hashtbl.create 23
 216
 217 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 218
 219 let check_l1_pattern level1_pattern level associativity =
 220   let variables = ref 0 in
 221   let symbols = ref 0 in
 222   let rec aux = function
 223     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 224     | Ast.Literal _ as l -> incr symbols; l
 225     | Ast.Layout l -> Ast.Layout (aux_layout l)
 226     | Ast.Magic m -> Ast.Magic (aux_magic m)
 227     | Ast.Variable v -> Ast.Variable (aux_variable v)
 228     | t -> assert false
 229   and aux_layout = function
 230     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 231     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 232     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 233     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 234     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 235     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 236     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 237     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 238     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 239     | Ast.Break as t -> t
 240     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 241     | Ast.Group pl -> Ast.Group (List.map aux pl)
 242   and aux_magic magic =
 243     match magic with
 244     | Ast.Opt p -> Ast.Opt (aux p)
 245     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 246     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 247     | _ -> assert false
 248   and aux_variable =
 249     function
 250     | Ast.NumVar _ as t -> t
 251     | Ast.TermVar (s,None) when associativity <> Gramext.NonA ->
 252         incr variables;
 253         if !variables > 2 then
 254           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 255           "associative notation"));
 256         (match !variables, associativity with
 257         | 1,Gramext.LeftA -> Ast.TermVar (s, None) (*Ast.TermVar (s, Some
 258         (level-1)) *)
 259         | 1,Gramext.RightA -> Ast.TermVar (s, None)
 260         | 2,Gramext.LeftA ->Ast.TermVar (s, None)
 261         | 2,Gramext.RightA -> Ast.TermVar (s, Some (level-1))
 262         | _ -> assert false)
 263     | Ast.TermVar (s,Some _) when associativity <> Gramext.NonA ->
 264           raise (Parse_error ("Variables can not be declared with a " ^
 265             "precedence in an associative notation"))
 266        (* avoid camlp5 divergence due to non-Sself recursion at the same level *)
 267     | Ast.TermVar (s,Some l) when l <= level && !variables=0 && !symbols=0 ->
 268           raise (Parse_error ("Left recursive rule with precedence not greater " ^
 269             "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 270     | Ast.TermVar _ as t -> incr variables; t
 271     | Ast.IdentVar _ as t -> t
 272     | Ast.Ascription _ -> assert false (* TODO *)
 273     | Ast.FreshVar _ -> assert false
 274   in
 275   if associativity <> Gramext.NonA && level = min_precedence then
 276     raise (Parse_error ("You can not specify an associative notation " ^
 277     "at level "^string_of_int min_precedence ^ "; increase it"));
 278   let cp = CL1P (aux level1_pattern, level) in
 279   if !variables <> 2 && associativity <> Gramext.NonA then
 280     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 281      "associative notation"));
 282   cp
 283 ;;
 284
 285 let extend (CL1P (level1_pattern,precedence)) action =
 286   let p_bindings, p_atoms =
 287     List.split (extract_term_production level1_pattern)
 288   in
 289   let level = level_of precedence in
 290   let _ =
 291     Grammar.extend
 292       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 293         Some (Gramext.Level level),
 294         [ None,
 295           Some (*Gramext.NonA*) Gramext.NonA,
 296           [ p_atoms,
 297             (make_action
 298               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 299                 (action env loc))
 300               p_bindings) ]]]
 301   in
 302   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 303   let rule_id = p_atoms in
 304   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 305   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 306   rule_id
 307
 308 let delete rule_id =
 309   let atoms = rule_id in
 310   (try
 311     let keywords = Hashtbl.find owned_keywords rule_id in
 312     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 313   with Not_found -> assert false);
 314   Grammar.delete_rule term atoms
 315
 316 (** {2 Grammar} *)
 317
 318 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 319 let parse_level2_ast_ref = ref (fun _ -> assert false)
 320 let parse_level2_meta_ref = ref (fun _ -> assert false)
 321
 322 let fold_cluster binder terms ty body =
 323   List.fold_right
 324     (fun term body -> Ast.Binder (binder, (term, ty), body))
 325     terms body  (* terms are names: either Ident or FreshVar *)
 326
 327 let fold_exists terms ty body =
 328   List.fold_right
 329     (fun term body ->
 330       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 331       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 332     terms body
 333
 334 let fold_binder binder pt_names body =
 335   List.fold_right
 336     (fun (names, ty) body -> fold_cluster binder names ty body)
 337     pt_names body
 338
 339 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 340
 341   (* create empty precedence level for "term" *)
 342 let _ =
 343   let dummy_action =
 344     Gramext.action (fun _ ->
 345       failwith "internal error, lexer generated a dummy token")
 346   in
 347   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 348    * empty after the deletion. The lexer never generate the Stoken below. *)
 349   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 350   let mk_level_list first last =
 351     let rec aux acc = function
 352       | i when i < first -> acc
 353       | i ->
 354           aux
 355             ((Some (string_of_int i ^ "N"), Some (*Gramext.NonA*)Gramext.NonA, dummy_prod)
 356              :: acc)
 357             (i - 1)
 358     in
 359     aux [] last
 360   in
 361   Grammar.extend
 362     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 363       None,
 364       mk_level_list min_precedence max_precedence ]
 365
 366 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 367 EXTEND
 368   GLOBAL: level1_pattern;
 369
 370   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 371   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 372   literal: [
 373     [ s = SYMBOL -> `Symbol s
 374     | k = QKEYWORD -> `Keyword k
 375     | n = NUMBER -> `Number n
 376     ]
 377   ];
 378   sep:       [ [ "sep";      sep = literal -> sep ] ];
 379 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 380   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 381   l1_magic_pattern: [
 382     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> Ast.List0 (p, sep)
 383     | "list1"; p = l1_simple_pattern; sep = OPT sep -> Ast.List1 (p, sep)
 384     | "opt";   p = l1_simple_pattern -> Ast.Opt p
 385     ]
 386   ];
 387   l1_pattern_variable: [
 388     [ "term"; precedence = NUMBER; id = IDENT ->
 389         Ast.TermVar (id, Some (int_of_string precedence))
 390     | "number"; id = IDENT -> Ast.NumVar id
 391     | "ident"; id = IDENT -> Ast.IdentVar id
 392     ]
 393   ];
 394   l1_simple_pattern:
 395     [ "layout" LEFTA
 396       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 397           return_term loc (Ast.Layout (Ast.Sub (p1, p2)))
 398       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 399           return_term loc (Ast.Layout (Ast.Sup (p1, p2)))
 400       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 401           return_term loc (Ast.Layout (Ast.Below (p1, p2)))
 402       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 403           return_term loc (Ast.Layout (Ast.Above (p1, p2)))
 404       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 405           return_term loc (Ast.Layout (Ast.Over (p1, p2)))
 406       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 407           return_term loc (Ast.Layout (Ast.Atop (p1, p2)))
 408 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 409           return_term loc (Array (p, csep, rsep)) *)
 410       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 411           return_term loc (Ast.Layout (Ast.Frac (p1, p2)))
 412       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Ast.Layout (Ast.Sqrt p))
 413       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 414           return_term loc (Ast.Layout (Ast.Root (arg, index)))
 415       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 416           return_term loc (Ast.Layout (Ast.Box ((Ast.H, false, false), p)))
 417       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 418           return_term loc (Ast.Layout (Ast.Box ((Ast.V, false, false), p)))
 419       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 420           return_term loc (Ast.Layout (Ast.Box ((Ast.HV, false, false), p)))
 421       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 422           return_term loc (Ast.Layout (Ast.Box ((Ast.HOV, false, false), p)))
 423       | "break" -> return_term loc (Ast.Layout Ast.Break)
 424 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 425       | LPAREN; p = l1_pattern; RPAREN ->
 426           return_term loc (CicNotationUtil.group p)
 427       ]
 428     | "simple" NONA
 429       [ i = IDENT -> return_term loc (Ast.Variable (Ast.TermVar (i,None)))
 430       | m = l1_magic_pattern -> return_term loc (Ast.Magic m)
 431       | v = l1_pattern_variable -> return_term loc (Ast.Variable v)
 432       | l = literal -> return_term loc (Ast.Literal l)
 433       ]
 434     ];
 435   END
 436 (* }}} *)
 437
 438 (* {{{ Grammar for ast magics, notation level 2 *)
 439 EXTEND
 440   GLOBAL: level2_meta;
 441   l2_variable: [
 442     [ "term"; precedence = NUMBER; id = IDENT ->
 443         Ast.TermVar (id,Some (int_of_string precedence))
 444     | "number"; id = IDENT -> Ast.NumVar id
 445     | "ident"; id = IDENT -> Ast.IdentVar id
 446     | "fresh"; id = IDENT -> Ast.FreshVar id
 447     | "anonymous" -> Ast.TermVar ("_",None)
 448     | id = IDENT -> Ast.TermVar (id,None)
 449     ]
 450   ];
 451   l2_magic: [
 452     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 453       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 454         Ast.Fold (kind, base, [id], recursive)
 455     | "default"; some = level2_meta; none = level2_meta ->
 456         Ast.Default (some, none)
 457     | "if"; p_test = level2_meta;
 458       "then"; p_true = level2_meta;
 459       "else"; p_false = level2_meta ->
 460         Ast.If (p_test, p_true, p_false)
 461     | "fail" -> Ast.Fail
 462     ]
 463   ];
 464   level2_meta: [
 465     [ magic = l2_magic -> Ast.Magic magic
 466     | var = l2_variable -> Ast.Variable var
 467     | blob = UNPARSED_AST ->
 468         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 469     ]
 470   ];
 471 END
 472 (* }}} *)
 473
 474 (* {{{ Grammar for ast patterns, notation level 2 *)
 475 EXTEND
 476   GLOBAL: level2_ast term let_defs protected_binder_vars;
 477   level2_ast: [ [ p = term -> p ] ];
 478   sort: [
 479     [ "Prop" -> `Prop
 480     | "Set" -> `Set
 481     | "Type" -> `Type (CicUniv.fresh ())
 482     | "CProp" -> `CProp (CicUniv.fresh ())
 483     ]
 484   ];
 485   explicit_subst: [
 486     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 487       SYMBOL "[";
 488       substs = LIST1 [
 489         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 490       ] SEP SYMBOL ";";
 491       SYMBOL "]" ->
 492         substs
 493     ]
 494   ];
 495   meta_subst: [
 496     [ s = SYMBOL "_" -> None
 497     | p = term -> Some p ]
 498   ];
 499   meta_substs: [
 500     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 501   ];
 502   possibly_typed_name: [
 503     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 504         id, Some typ
 505     | arg = single_arg -> arg, None
 506     | SYMBOL "_" -> Ast.Ident ("_", None), None
 507     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 508         Ast.Ident ("_", None), Some typ
 509     ]
 510   ];
 511   match_pattern: [
 512     [ id = IDENT -> Ast.Pattern (id, None, [])
 513     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 514        Ast.Pattern (id, None, vars)
 515     | id = IDENT; vars = LIST1 possibly_typed_name ->
 516        Ast.Pattern (id, None, vars)
 517     | SYMBOL "_" -> Ast.Wildcard
 518     ]
 519   ];
 520   binder: [
 521     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 522 (*     | SYMBOL <:unicode<exists>> |+ ∃ +| -> `Exists *)
 523     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 524     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 525     ]
 526   ];
 527   arg: [
 528     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 529       SYMBOL ":"; ty = term; RPAREN ->
 530         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 531     | name = IDENT -> [Ast.Ident (name, None)], None
 532     | blob = UNPARSED_META ->
 533         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 534         match meta with
 535         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 536         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 537         | _ -> failwith "Invalid bound name."
 538    ]
 539   ];
 540   single_arg: [
 541     [ name = IDENT -> Ast.Ident (name, None)
 542     | blob = UNPARSED_META ->
 543         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 544         match meta with
 545         | Ast.Variable (Ast.FreshVar _)
 546         | Ast.Variable (Ast.IdentVar _) -> meta
 547         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 548         | _ -> failwith "Invalid index name."
 549     ]
 550   ];
 551   let_defs: [
 552     [ defs = LIST1 [
 553         name = single_arg;
 554         args = LIST1 arg;
 555         index_name = OPT [ "on"; id = single_arg -> id ];
 556         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 557         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 558           let rec position_of name p = function
 559             | [] -> None, p
 560             | n :: _ when n = name -> Some p, p
 561             | _ :: tl -> position_of name (p + 1) tl
 562           in
 563           let rec find_arg name n = function
 564             | [] ->
 565                 Ast.fail loc (sprintf "Argument %s not found"
 566                   (CicNotationPp.pp_term name))
 567             | (l,_) :: tl ->
 568                 (match position_of name 0 l with
 569                 | None, len -> find_arg name (n + len) tl
 570                 | Some where, len -> n + where)
 571           in
 572           let index =
 573             match index_name with
 574             | None -> 0
 575             | Some index_name -> find_arg index_name 0 args
 576           in
 577           let args =
 578            List.concat
 579             (List.map
 580              (function (names,ty) -> List.map (function x -> x,ty) names
 581              ) args)
 582           in
 583            args, (name, ty), body, index
 584       ] SEP "and" ->
 585         defs
 586     ]
 587   ];
 588   binder_vars: [
 589     [ vars = [
 590           l = LIST1 single_arg SEP SYMBOL "," -> l
 591         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 592       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 593     ]
 594   ];
 595   protected_binder_vars: [
 596     [ LPAREN; vars = binder_vars; RPAREN -> vars
 597     ]
 598   ];
 599   maybe_protected_binder_vars: [
 600     [ vars = binder_vars -> vars
 601     | vars = protected_binder_vars -> vars
 602     ]
 603   ];
 604   term: LEVEL "10N"
 605   [
 606     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 607       p1 = term; "in"; p2 = term ->
 608         return_term loc (Ast.LetIn (var, p1, p2))
 609     | LETCOREC; defs = let_defs; "in";
 610       body = term ->
 611         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 612     | LETREC; defs = let_defs; "in";
 613       body = term ->
 614         return_term loc (Ast.LetRec (`Inductive, defs, body))
 615     ]
 616   ];
 617   term: LEVEL "20N"
 618     [
 619       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19N" ->
 620           return_term loc (fold_cluster b vars typ body)
 621       | SYMBOL <:unicode<exists>> (* ∃ *);
 622         (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19N"->
 623           return_term loc (fold_exists vars typ body)
 624       ]
 625     ];
 626   term: LEVEL "70N"
 627     [
 628       [ p1 = term; p2 = term LEVEL "71N" ->
 629           let rec aux = function
 630             | Ast.Appl (hd :: tl)
 631             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 632                 aux hd @ tl
 633             | term -> [term]
 634           in
 635           return_term loc (Ast.Appl (aux p1 @ [p2]))
 636       ]
 637     ];
 638   term: LEVEL "90N"
 639     [
 640       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 641       | id = IDENT; s = explicit_subst ->
 642           return_term loc (Ast.Ident (id, Some s))
 643       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 644       | u = URI -> return_term loc (Ast.Uri (u, None))
 645       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 646       | IMPLICIT -> return_term loc (Ast.Implicit)
 647       | PLACEHOLDER -> return_term loc Ast.UserInput
 648       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 649       | m = META; s = meta_substs ->
 650           return_term loc (Ast.Meta (int_of_string m, s))
 651       | s = sort -> return_term loc (Ast.Sort s)
 652       | "match"; t = term;
 653         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 654         outtyp = OPT [ "return"; ty = term -> ty ];
 655         "with"; SYMBOL "[";
 656         patterns = LIST0 [
 657           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 658           rhs = term ->
 659             lhs, rhs
 660         ] SEP SYMBOL "|";
 661         SYMBOL "]" ->
 662           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 663       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 664           return_term loc (Ast.Cast (p1, p2))
 665       | LPAREN; p = term; RPAREN -> p
 666       | blob = UNPARSED_META ->
 667           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 668       ]
 669     ];
 670 END
 671 (* }}} *)
 672
 673 (** {2 API implementation} *)
 674
 675 let exc_located_wrapper f =
 676   try
 677     f ()
 678   with
 679   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 680       raise (HExtlib.Localized (floc, Parse_error msg))
 681   | Stdpp.Exc_located (floc, exn) ->
 682       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 683
 684 let parse_level1_pattern lexbuf =
 685   exc_located_wrapper
 686     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf))
 687
 688 let parse_level2_ast lexbuf =
 689   exc_located_wrapper
 690     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 691
 692 let parse_level2_meta lexbuf =
 693   exc_located_wrapper
 694     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 695
 696 let _ =
 697   parse_level1_pattern_ref := parse_level1_pattern;
 698   parse_level2_ast_ref := parse_level2_ast;
 699   parse_level2_meta_ref := parse_level2_meta
 700
 701 let parse_term lexbuf =
 702   exc_located_wrapper
 703     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 704
 705 (** {2 Debugging} *)
 706
 707 let print_l2_pattern () =
 708   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 709   Format.pp_print_flush Format.std_formatter ();
 710   flush stdout
 711
 712 (* vim:set encoding=utf8 foldmethod=marker: *)