helm/software/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let level1_pattern_grammar =
  37   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  38 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  39 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  40
  41 let min_precedence = 0
  42 let max_precedence = 100
  43
  44 let level1_pattern =
  45   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  46 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  47 let term = Grammar.Entry.create level2_ast_grammar "term"
  48 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  49 let protected_binder_vars = Grammar.Entry.create level2_ast_grammar "protected_binder_vars"
  50 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let level_of precedence =
  61   if precedence < min_precedence || precedence > max_precedence then
  62     raise (Level_not_found precedence);
  63   string_of_int precedence
  64
  65 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  66 let gram_ident s = Gramext.Stoken ("IDENT", s)
  67 let gram_number s = Gramext.Stoken ("NUMBER", s)
  68 let gram_keyword s = Gramext.Stoken ("", s)
  69 let gram_term = function
  70   | Ast.Self _ -> Gramext.Sself
  71   | Ast.Level precedence ->
  72       Gramext.Snterml
  73         (Grammar.Entry.obj (term: 'a Grammar.Entry.e), level_of precedence)
  74 ;;
  75
  76 let gram_of_literal =
  77   function
  78   | `Symbol s -> gram_symbol s
  79   | `Keyword s -> gram_keyword s
  80   | `Number s -> gram_number s
  81
  82 type binding =
  83   | NoBinding
  84   | Binding of string * Env.value_type
  85   | Env of (string * Env.value_type) list
  86
  87 let make_action action bindings =
  88   let rec aux (vl : CicNotationEnv.t) =
  89     function
  90       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  91     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  92     (* LUCA: DEFCON 3 BEGIN *)
  93     | Binding (name, Env.TermType l) :: tl ->
  94         Gramext.action
  95           (fun (v:Ast.term) ->
  96             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
  97     | Binding (name, Env.StringType) :: tl ->
  98         Gramext.action
  99           (fun (v:string) ->
 100             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 101     | Binding (name, Env.NumType) :: tl ->
 102         Gramext.action
 103           (fun (v:string) ->
 104             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 105     | Binding (name, Env.OptType t) :: tl ->
 106         Gramext.action
 107           (fun (v:'a option) ->
 108             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 109     | Binding (name, Env.ListType t) :: tl ->
 110         Gramext.action
 111           (fun (v:'a list) ->
 112             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 113     | Env _ :: tl ->
 114         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 115     (* LUCA: DEFCON 3 END *)
 116   in
 117     aux [] (List.rev bindings)
 118
 119 let flatten_opt =
 120   let rec aux acc =
 121     function
 122       [] -> List.rev acc
 123     | NoBinding :: tl -> aux acc tl
 124     | Env names :: tl -> aux (List.rev names @ acc) tl
 125     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 126   in
 127   aux []
 128
 129   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 130 let extract_term_production pattern =
 131   let rec aux = function
 132     | Ast.AttributedTerm (_, t) -> aux t
 133     | Ast.Literal l -> aux_literal l
 134     | Ast.Layout l -> aux_layout l
 135     | Ast.Magic m -> aux_magic m
 136     | Ast.Variable v -> aux_variable v
 137     | t ->
 138         prerr_endline (CicNotationPp.pp_term t);
 139         assert false
 140   and aux_literal =
 141     function
 142     | `Symbol s -> [NoBinding, gram_symbol s]
 143     | `Keyword s ->
 144         (* assumption: s will be registered as a keyword with the lexer *)
 145         [NoBinding, gram_keyword s]
 146     | `Number s -> [NoBinding, gram_number s]
 147   and aux_layout = function
 148     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 149     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 150     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 151     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 152     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 153     | Ast.InfRule (p1, p2, p3) -> aux p1 @ [NoBinding, gram_symbol "\\infrule"] @ aux p2 @ aux p3
 154     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 155     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 156     | Ast.Root (p1, p2) ->
 157         [NoBinding, gram_symbol "\\root"] @ aux p2
 158         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 159     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 160     | Ast.Break -> []
 161     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 162     | Ast.Group pl -> List.flatten (List.map aux pl)
 163   and aux_magic magic =
 164     match magic with
 165     | Ast.Opt p ->
 166         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 167         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 168           match env_opt with
 169           | Some env -> List.map Env.opt_binding_some env
 170           | None -> List.map Env.opt_binding_of_name p_names
 171         in
 172         [ Env (List.map Env.opt_declaration p_names),
 173           Gramext.srules
 174             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 175               Gramext.action action ] ]
 176     | Ast.List0 (p, _)
 177     | Ast.List1 (p, _) ->
 178         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 179         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 180           CicNotationEnv.coalesce_env p_names env_list
 181         in
 182         let gram_of_list s =
 183           match magic with
 184           | Ast.List0 (_, None) -> Gramext.Slist0 s
 185           | Ast.List1 (_, None) -> Gramext.Slist1 s
 186           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 187           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 188           | _ -> assert false
 189         in
 190         [ Env (List.map Env.list_declaration p_names),
 191           Gramext.srules
 192             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 193               Gramext.action action ] ]
 194     | _ -> assert false
 195   and aux_variable =
 196     function
 197     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 198     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 199         [Binding (s, Env.TermType level), gram_term lv]
 200     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 201     | Ast.Ascription (p, s) -> assert false (* TODO *)
 202     | Ast.FreshVar _ -> assert false
 203   and inner_pattern p =
 204     let p_bindings, p_atoms = List.split (aux p) in
 205     let p_names = flatten_opt p_bindings in
 206     let action =
 207       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 208         p_bindings
 209     in
 210     p_bindings, p_atoms, p_names, action
 211   in
 212   aux pattern
 213
 214 type rule_id = Grammar.token Gramext.g_symbol list
 215
 216   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 217 let owned_keywords = Hashtbl.create 23
 218
 219 type checked_l1_pattern = CL1P of CicNotationPt.term * int
 220
 221 let check_l1_pattern level1_pattern level associativity =
 222   let variables = ref 0 in
 223   let symbols = ref 0 in
 224   let rec aux = function
 225     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 226     | Ast.Literal _ as l -> incr symbols; l
 227     | Ast.Layout l -> Ast.Layout (aux_layout l)
 228     | Ast.Magic m -> Ast.Magic (aux_magic m)
 229     | Ast.Variable v -> (aux_variable v)
 230     | t -> assert false
 231   and aux_layout = function
 232     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 233     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 234     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 235     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 236     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 237     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 238     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 239     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 240     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 241     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 242     | Ast.Break as t -> t
 243     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 244     | Ast.Group pl -> Ast.Group (List.map aux pl)
 245   and aux_magic magic =
 246     match magic with
 247     | Ast.Opt p -> Ast.Opt (aux p)
 248     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 249     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 250     | _ -> assert false
 251   and aux_variable =
 252     function
 253     | Ast.NumVar _ as t -> Ast.Variable t
 254     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 255         incr variables;
 256         if !variables > 2 then
 257           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 258           "associative notation"));
 259         (match !variables, associativity with
 260         | 1,Gramext.LeftA ->
 261              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 262         | 1,Gramext.RightA ->
 263              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 264         | 2,Gramext.LeftA ->
 265              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 266         | 2,Gramext.RightA ->
 267              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 268         | _ -> assert false)
 269     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 270           raise (Parse_error ("Variables can not be declared with a " ^
 271             "precedence in an associative notation"))
 272        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 273     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 274        raise(Parse_error("Left recursive rule with precedence not greater " ^
 275         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 276     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 277     | Ast.IdentVar _ as t -> Ast.Variable t
 278     | Ast.Ascription _ -> assert false (* TODO *)
 279     | Ast.FreshVar _ -> assert false
 280   in
 281   if associativity <> Gramext.NonA && level = min_precedence then
 282     raise (Parse_error ("You can not specify an associative notation " ^
 283     "at level "^string_of_int min_precedence ^ "; increase it"));
 284   let cp = aux level1_pattern in
 285 (*   prerr_endline ("checked_pattern: " ^ CicNotationPp.pp_term cp); *)
 286   if !variables <> 2 && associativity <> Gramext.NonA then
 287     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 288      "associative notation"));
 289   CL1P (cp,level)
 290 ;;
 291
 292 let extend (CL1P (level1_pattern,precedence)) action =
 293   let p_bindings, p_atoms =
 294     List.split (extract_term_production level1_pattern)
 295   in
 296   let level = level_of precedence in
 297   let _ =
 298     Grammar.extend
 299       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 300         Some (Gramext.Level level),
 301         [ None,
 302           Some (*Gramext.NonA*) Gramext.NonA,
 303           [ p_atoms,
 304             (make_action
 305               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 306                 (action env loc))
 307               p_bindings) ]]]
 308   in
 309   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 310   let rule_id = p_atoms in
 311   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 312   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 313   rule_id
 314
 315 let delete rule_id =
 316   let atoms = rule_id in
 317   (try
 318     let keywords = Hashtbl.find owned_keywords rule_id in
 319     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 320   with Not_found -> assert false);
 321   Grammar.delete_rule term atoms
 322
 323 (** {2 Grammar} *)
 324
 325 let parse_level1_pattern_ref = ref (fun _ _ -> assert false)
 326 let parse_level2_ast_ref = ref (fun _ -> assert false)
 327 let parse_level2_meta_ref = ref (fun _ -> assert false)
 328
 329 let fold_cluster binder terms ty body =
 330   List.fold_right
 331     (fun term body -> Ast.Binder (binder, (term, ty), body))
 332     terms body  (* terms are names: either Ident or FreshVar *)
 333
 334 let fold_exists terms ty body =
 335   List.fold_right
 336     (fun term body ->
 337       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 338       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 339     terms body
 340
 341 let fold_binder binder pt_names body =
 342   List.fold_right
 343     (fun (names, ty) body -> fold_cluster binder names ty body)
 344     pt_names body
 345
 346 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 347 let return_term_of_level loc term l =
 348   Ast.AttributedTerm (`Loc loc, term l)
 349
 350   (* create empty precedence level for "term" *)
 351 let _ =
 352   let dummy_action =
 353     Gramext.action (fun _ ->
 354       failwith "internal error, lexer generated a dummy token")
 355   in
 356   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 357    * empty after the deletion. The lexer never generate the Stoken below. *)
 358   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 359   let mk_level_list first last =
 360     let rec aux acc = function
 361       | i when i < first -> acc
 362       | i ->
 363           aux
 364             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 365              :: acc)
 366             (i - 1)
 367     in
 368     aux [] last
 369   in
 370   Grammar.extend
 371     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 372       None,
 373       mk_level_list min_precedence max_precedence ]
 374
 375 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 376 EXTEND
 377   GLOBAL: level1_pattern;
 378
 379   level1_pattern: [
 380     [ p = l1_pattern; EOI -> fun l -> CicNotationUtil.boxify (p l) ]
 381   ];
 382   l1_pattern: [
 383     [ p = LIST1 l1_simple_pattern ->
 384         fun l -> List.map (fun x -> x l) p ]
 385   ];
 386   literal: [
 387     [ s = SYMBOL -> `Symbol s
 388     | k = QKEYWORD -> `Keyword k
 389     | n = NUMBER -> `Number n
 390     ]
 391   ];
 392   sep:       [ [ "sep";      sep = literal -> sep ] ];
 393   l1_magic_pattern: [
 394     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 395             fun l -> Ast.List0 (p l, sep)
 396     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 397             fun l -> Ast.List1 (p l, sep)
 398     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 399     ]
 400   ];
 401   l1_pattern_variable: [
 402     [ "term"; precedence = NUMBER; id = IDENT ->
 403         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 404     | "number"; id = IDENT -> Ast.NumVar id
 405     | "ident"; id = IDENT -> Ast.IdentVar id
 406     ]
 407   ];
 408   l1_simple_pattern:
 409     [ "layout" LEFTA
 410       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 411           return_term_of_level loc
 412             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 413       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 414           return_term_of_level loc
 415             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 416       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 417           return_term_of_level loc
 418             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 419       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 420           return_term_of_level loc
 421             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 422       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 423           return_term_of_level loc
 424             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 425       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 426           return_term_of_level loc
 427             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 428       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 429           return_term_of_level loc
 430             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 431       | SYMBOL "\\infrule"; p1 = SELF; p2 = SELF; p3 = SELF ->
 432           return_term_of_level loc
 433             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 434       | SYMBOL "\\sqrt"; p = SELF ->
 435           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 436       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 437           return_term_of_level loc
 438             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 439       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 440           return_term_of_level loc
 441             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 442       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 443           return_term_of_level loc
 444             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 445       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 446           return_term_of_level loc
 447             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 448       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 449           return_term_of_level loc
 450             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 451       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 452       | LPAREN; p = l1_pattern; RPAREN ->
 453           return_term_of_level loc (fun l -> CicNotationUtil.group (p l))
 454       ]
 455     | "simple" NONA
 456       [ i = IDENT ->
 457          return_term_of_level loc
 458            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 459       | m = l1_magic_pattern ->
 460              return_term_of_level loc (fun l -> Ast.Magic (m l))
 461       | v = l1_pattern_variable ->
 462              return_term_of_level loc (fun _ -> Ast.Variable v)
 463       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 464       ]
 465     ];
 466   END
 467 (* }}} *)
 468
 469 (* {{{ Grammar for ast magics, notation level 2 *)
 470 EXTEND
 471   GLOBAL: level2_meta;
 472   l2_variable: [
 473     [ "term"; precedence = NUMBER; id = IDENT ->
 474         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 475     | "number"; id = IDENT -> Ast.NumVar id
 476     | "ident"; id = IDENT -> Ast.IdentVar id
 477     | "fresh"; id = IDENT -> Ast.FreshVar id
 478     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 479     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 480     ]
 481   ];
 482   l2_magic: [
 483     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 484       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 485         Ast.Fold (kind, base, [id], recursive)
 486     | "default"; some = level2_meta; none = level2_meta ->
 487         Ast.Default (some, none)
 488     | "if"; p_test = level2_meta;
 489       "then"; p_true = level2_meta;
 490       "else"; p_false = level2_meta ->
 491         Ast.If (p_test, p_true, p_false)
 492     | "fail" -> Ast.Fail
 493     ]
 494   ];
 495   level2_meta: [
 496     [ magic = l2_magic -> Ast.Magic magic
 497     | var = l2_variable -> Ast.Variable var
 498     | blob = UNPARSED_AST ->
 499         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 500     ]
 501   ];
 502 END
 503 (* }}} *)
 504
 505 (* {{{ Grammar for ast patterns, notation level 2 *)
 506 EXTEND
 507   GLOBAL: level2_ast term let_defs protected_binder_vars;
 508   level2_ast: [ [ p = term -> p ] ];
 509   sort: [
 510     [ "Prop" -> `Prop
 511     | "Set" -> `Set
 512     | "Type" -> `Type (CicUniv.fresh ())
 513     | "CProp" -> `CProp (CicUniv.fresh ())
 514     ]
 515   ];
 516   explicit_subst: [
 517     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 518       SYMBOL "[";
 519       substs = LIST1 [
 520         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 521       ] SEP SYMBOL ";";
 522       SYMBOL "]" ->
 523         substs
 524     ]
 525   ];
 526   meta_subst: [
 527     [ s = SYMBOL "_" -> None
 528     | p = term -> Some p ]
 529   ];
 530   meta_substs: [
 531     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 532   ];
 533   possibly_typed_name: [
 534     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 535         id, Some typ
 536     | arg = single_arg -> arg, None
 537     | SYMBOL "_" -> Ast.Ident ("_", None), None
 538     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 539         Ast.Ident ("_", None), Some typ
 540     ]
 541   ];
 542   match_pattern: [
 543     [ id = IDENT -> Ast.Pattern (id, None, [])
 544     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 545        Ast.Pattern (id, None, vars)
 546     | id = IDENT; vars = LIST1 possibly_typed_name ->
 547        Ast.Pattern (id, None, vars)
 548     | SYMBOL "_" -> Ast.Wildcard
 549     ]
 550   ];
 551   binder: [
 552     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 553 (*     | SYMBOL <:unicode<exists>> |+ ∃ +| -> `Exists *)
 554     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 555     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 556     ]
 557   ];
 558   arg: [
 559     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 560       SYMBOL ":"; ty = term; RPAREN ->
 561         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 562     | name = IDENT -> [Ast.Ident (name, None)], None
 563     | blob = UNPARSED_META ->
 564         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 565         match meta with
 566         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 567         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 568         | _ -> failwith "Invalid bound name."
 569    ]
 570   ];
 571   single_arg: [
 572     [ name = IDENT -> Ast.Ident (name, None)
 573     | blob = UNPARSED_META ->
 574         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 575         match meta with
 576         | Ast.Variable (Ast.FreshVar _)
 577         | Ast.Variable (Ast.IdentVar _) -> meta
 578         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 579         | _ -> failwith "Invalid index name."
 580     ]
 581   ];
 582   let_defs: [
 583     [ defs = LIST1 [
 584         name = single_arg;
 585         args = LIST1 arg;
 586         index_name = OPT [ "on"; id = single_arg -> id ];
 587         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 588         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 589           let rec position_of name p = function
 590             | [] -> None, p
 591             | n :: _ when n = name -> Some p, p
 592             | _ :: tl -> position_of name (p + 1) tl
 593           in
 594           let rec find_arg name n = function
 595             | [] ->
 596                 Ast.fail loc (sprintf "Argument %s not found"
 597                   (CicNotationPp.pp_term name))
 598             | (l,_) :: tl ->
 599                 (match position_of name 0 l with
 600                 | None, len -> find_arg name (n + len) tl
 601                 | Some where, len -> n + where)
 602           in
 603           let index =
 604             match index_name with
 605             | None -> 0
 606             | Some index_name -> find_arg index_name 0 args
 607           in
 608           let args =
 609            List.concat
 610             (List.map
 611              (function (names,ty) -> List.map (function x -> x,ty) names
 612              ) args)
 613           in
 614            args, (name, ty), body, index
 615       ] SEP "and" ->
 616         defs
 617     ]
 618   ];
 619   binder_vars: [
 620     [ vars = [
 621           l = LIST1 single_arg SEP SYMBOL "," -> l
 622         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 623       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 624     ]
 625   ];
 626   protected_binder_vars: [
 627     [ LPAREN; vars = binder_vars; RPAREN -> vars
 628     ]
 629   ];
 630   maybe_protected_binder_vars: [
 631     [ vars = binder_vars -> vars
 632     | vars = protected_binder_vars -> vars
 633     ]
 634   ];
 635   term: LEVEL "10"
 636   [
 637     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 638       p1 = term; "in"; p2 = term ->
 639         return_term loc (Ast.LetIn (var, p1, p2))
 640     | LETCOREC; defs = let_defs; "in";
 641       body = term ->
 642         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 643     | LETREC; defs = let_defs; "in";
 644       body = term ->
 645         return_term loc (Ast.LetRec (`Inductive, defs, body))
 646     ]
 647   ];
 648   term: LEVEL "20"
 649     [
 650       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 651           return_term loc (fold_cluster b vars typ body)
 652       | SYMBOL <:unicode<exists>> (* ∃ *);
 653         (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19"->
 654           return_term loc (fold_exists vars typ body)
 655       ]
 656     ];
 657   term: LEVEL "70"
 658     [
 659       [ p1 = term; p2 = term LEVEL "71" ->
 660           let rec aux = function
 661             | Ast.Appl (hd :: tl)
 662             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 663                 aux hd @ tl
 664             | term -> [term]
 665           in
 666           return_term loc (Ast.Appl (aux p1 @ [p2]))
 667       ]
 668     ];
 669   term: LEVEL "90"
 670     [
 671       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 672       | id = IDENT; s = explicit_subst ->
 673           return_term loc (Ast.Ident (id, Some s))
 674       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 675       | u = URI -> return_term loc (Ast.Uri (u, None))
 676       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 677       | IMPLICIT -> return_term loc (Ast.Implicit)
 678       | PLACEHOLDER -> return_term loc Ast.UserInput
 679       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 680       | m = META; s = meta_substs ->
 681           return_term loc (Ast.Meta (int_of_string m, s))
 682       | s = sort -> return_term loc (Ast.Sort s)
 683       | "match"; t = term;
 684         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 685         outtyp = OPT [ "return"; ty = term -> ty ];
 686         "with"; SYMBOL "[";
 687         patterns = LIST0 [
 688           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 689           rhs = term ->
 690             lhs, rhs
 691         ] SEP SYMBOL "|";
 692         SYMBOL "]" ->
 693           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 694       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 695           return_term loc (Ast.Cast (p1, p2))
 696       | LPAREN; p = term; RPAREN -> p
 697       | blob = UNPARSED_META ->
 698           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 699       ]
 700     ];
 701 END
 702 (* }}} *)
 703
 704 (** {2 API implementation} *)
 705
 706 let exc_located_wrapper f =
 707   try
 708     f ()
 709   with
 710   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 711       raise (HExtlib.Localized (floc, Parse_error msg))
 712   | Stdpp.Exc_located (floc, exn) ->
 713       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 714
 715 let parse_level1_pattern precedence lexbuf =
 716   exc_located_wrapper
 717     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf) precedence)
 718
 719 let parse_level2_ast lexbuf =
 720   exc_located_wrapper
 721     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 722
 723 let parse_level2_meta lexbuf =
 724   exc_located_wrapper
 725     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 726
 727 let _ =
 728   parse_level1_pattern_ref := parse_level1_pattern;
 729   parse_level2_ast_ref := parse_level2_ast;
 730   parse_level2_meta_ref := parse_level2_meta
 731
 732 let parse_term lexbuf =
 733   exc_located_wrapper
 734     (fun () -> (Grammar.Entry.parse term (Obj.magic lexbuf)))
 735
 736 (** {2 Debugging} *)
 737
 738 let print_l2_pattern () =
 739   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 740   Format.pp_print_flush Format.std_formatter ();
 741   flush stdout
 742
 743 (* vim:set encoding=utf8 foldmethod=marker: *)